// File: @openzeppelin/contracts/GSN/Context.sol


pragma solidity ^0.6.0;

/*
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with GSN meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address payable) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes memory) {
        this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691
        return msg.data;
    }
}

// File: @openzeppelin/contracts/access/Ownable.sol


pragma solidity ^0.6.0;

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor () internal {
        address msgSender = _msgSender();
        _owner = msgSender;
        emit OwnershipTransferred(address(0), msgSender);
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(_owner == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        emit OwnershipTransferred(_owner, address(0));
        _owner = address(0);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        emit OwnershipTransferred(_owner, newOwner);
        _owner = newOwner;
    }
}

// File: @openzeppelin/contracts/math/SafeMath.sol


pragma solidity ^0.6.0;

/**
 * @dev Wrappers over Solidity's arithmetic operations with added overflow
 * checks.
 *
 * Arithmetic operations in Solidity wrap on overflow. This can easily result
 * in bugs, because programmers usually assume that an overflow raises an
 * error, which is the standard behavior in high level programming languages.
 * `SafeMath` restores this intuition by reverting the transaction when an
 * operation overflows.
 *
 * Using this library instead of the unchecked operations eliminates an entire
 * class of bugs, so it's recommended to use it always.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     *
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        require(c >= a, "SafeMath: addition overflow");

        return c;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        return sub(a, b, "SafeMath: subtraction overflow");
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b <= a, errorMessage);
        uint256 c = a - b;

        return c;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     *
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
        // benefit is lost if 'b' is also tested.
        // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
        if (a == 0) {
            return 0;
        }

        uint256 c = a * b;
        require(c / a == b, "SafeMath: multiplication overflow");

        return c;
    }

    /**
     * @dev Returns the integer division of two unsigned integers. Reverts on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        return div(a, b, "SafeMath: division by zero");
    }

    /**
     * @dev Returns the integer division of two unsigned integers. Reverts with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b > 0, errorMessage);
        uint256 c = a / b;
        // assert(a == b * c + a % b); // There is no case in which this doesn't hold

        return c;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * Reverts when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        return mod(a, b, "SafeMath: modulo by zero");
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * Reverts with custom message when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b != 0, errorMessage);
        return a % b;
    }
}

// File: @openzeppelin/contracts/token/ERC20/IERC20.sol


pragma solidity ^0.6.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

// File: @openzeppelin/contracts/utils/Address.sol


pragma solidity ^0.6.2;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // According to EIP-1052, 0x0 is the value returned for not-yet created accounts
        // and 0xc5d2460186f7233c927e7db2dcc703c0e500b653ca82273b7bfad8045d85a470 is returned
        // for accounts without code, i.e. `keccak256('')`
        bytes32 codehash;
        bytes32 accountHash = 0xc5d2460186f7233c927e7db2dcc703c0e500b653ca82273b7bfad8045d85a470;
        // solhint-disable-next-line no-inline-assembly
        assembly { codehash := extcodehash(account) }
        return (codehash != accountHash && codehash != 0x0);
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        // solhint-disable-next-line avoid-low-level-calls, avoid-call-value
        (bool success, ) = recipient.call{ value: amount }("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain`call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
      return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        return _functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value, string memory errorMessage) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        return _functionCallWithValue(target, data, value, errorMessage);
    }

    function _functionCallWithValue(address target, bytes memory data, uint256 weiValue, string memory errorMessage) private returns (bytes memory) {
        require(isContract(target), "Address: call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.call{ value: weiValue }(data);
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                // solhint-disable-next-line no-inline-assembly
                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// File: @openzeppelin/contracts/token/ERC20/ERC20.sol


pragma solidity ^0.6.0;





/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20PresetMinterPauser}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.zeppelin.solutions/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * We have followed general OpenZeppelin guidelines: functions revert instead
 * of returning `false` on failure. This behavior is nonetheless conventional
 * and does not conflict with the expectations of ERC20 applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20 is Context, IERC20 {
    using SafeMath for uint256;
    using Address for address;

    mapping (address => uint256) private _balances;

    mapping (address => mapping (address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;
    uint8 private _decimals;

    /**
     * @dev Sets the values for {name} and {symbol}, initializes {decimals} with
     * a default value of 18.
     *
     * To select a different value for {decimals}, use {_setupDecimals}.
     *
     * All three of these values are immutable: they can only be set once during
     * construction.
     */
    constructor (string memory name, string memory symbol) public {
        _name = name;
        _symbol = symbol;
        _decimals = 18;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5,05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the value {ERC20} uses, unless {_setupDecimals} is
     * called.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view returns (uint8) {
        return _decimals;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view override returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view override returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `recipient` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address recipient, uint256 amount) public virtual override returns (bool) {
        _transfer(_msgSender(), recipient, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public virtual override returns (bool) {
        _approve(_msgSender(), spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20};
     *
     * Requirements:
     * - `sender` and `recipient` cannot be the zero address.
     * - `sender` must have a balance of at least `amount`.
     * - the caller must have allowance for ``sender``'s tokens of at least
     * `amount`.
     */
    function transferFrom(address sender, address recipient, uint256 amount) public virtual override returns (bool) {
        _transfer(sender, recipient, amount);
        _approve(sender, _msgSender(), _allowances[sender][_msgSender()].sub(amount, "ERC20: transfer amount exceeds allowance"));
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
        _approve(_msgSender(), spender, _allowances[_msgSender()][spender].add(addedValue));
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
        _approve(_msgSender(), spender, _allowances[_msgSender()][spender].sub(subtractedValue, "ERC20: decreased allowance below zero"));
        return true;
    }

    /**
     * @dev Moves tokens `amount` from `sender` to `recipient`.
     *
     * This is internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `sender` cannot be the zero address.
     * - `recipient` cannot be the zero address.
     * - `sender` must have a balance of at least `amount`.
     */
    function _transfer(address sender, address recipient, uint256 amount) internal virtual {
        require(sender != address(0), "ERC20: transfer from the zero address");
        require(recipient != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(sender, recipient, amount);

        _balances[sender] = _balances[sender].sub(amount, "ERC20: transfer amount exceeds balance");
        _balances[recipient] = _balances[recipient].add(amount);
        emit Transfer(sender, recipient, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements
     *
     * - `to` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply = _totalSupply.add(amount);
        _balances[account] = _balances[account].add(amount);
        emit Transfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        _balances[account] = _balances[account].sub(amount, "ERC20: burn amount exceeds balance");
        _totalSupply = _totalSupply.sub(amount);
        emit Transfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner`s tokens.
     *
     * This is internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(address owner, address spender, uint256 amount) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Sets {decimals} to a value other than the default one of 18.
     *
     * WARNING: This function should only be called from the constructor. Most
     * applications that interact with token contracts will not expect
     * {decimals} to ever change, and may work incorrectly if it does.
     */
    function _setupDecimals(uint8 decimals_) internal {
        _decimals = decimals_;
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be to transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(address from, address to, uint256 amount) internal virtual { }
}

// File: @openzeppelin/contracts/token/ERC20/ERC20Burnable.sol


pragma solidity ^0.6.0;



/**
 * @dev Extension of {ERC20} that allows token holders to destroy both their own
 * tokens and those that they have an allowance for, in a way that can be
 * recognized off-chain (via event analysis).
 */
abstract contract ERC20Burnable is Context, ERC20 {
    /**
     * @dev Destroys `amount` tokens from the caller.
     *
     * See {ERC20-_burn}.
     */
    function burn(uint256 amount) public virtual {
        _burn(_msgSender(), amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, deducting from the caller's
     * allowance.
     *
     * See {ERC20-_burn} and {ERC20-allowance}.
     *
     * Requirements:
     *
     * - the caller must have allowance for ``accounts``'s tokens of at least
     * `amount`.
     */
    function burnFrom(address account, uint256 amount) public virtual {
        uint256 decreasedAllowance = allowance(account, _msgSender()).sub(amount, "ERC20: burn amount exceeds allowance");

        _approve(account, _msgSender(), decreasedAllowance);
        _burn(account, amount);
    }
}

// File: contract-dependencies/Roles.sol

pragma solidity ^0.6.0;

/**
 * @title Roles
 * @dev Library for managing addresses assigned to a Role.
 */
library Roles {
    struct Role {
        mapping (address => bool) bearer;
    }

    /**
     * @dev Give an account access to this role.
     */
    function add(Role storage role, address account) internal {
        require(!has(role, account), "Roles: account already has role");
        role.bearer[account] = true;
    }

    /**
     * @dev Remove an account's access to this role.
     */
    function remove(Role storage role, address account) internal {
        require(has(role, account), "Roles: account does not have role");
        role.bearer[account] = false;
    }

    /**
     * @dev Check if an account has this role.
     * @return bool
     */
    function has(Role storage role, address account) internal view returns (bool) {
        require(account != address(0), "Roles: account is the zero address");
        return role.bearer[account];
    }
}

// File: contract-dependencies/MinterRole.sol

pragma solidity ^0.6.8;


abstract contract MinterRole {
    using Roles for Roles.Role;

    event MinterAdded(address indexed account);
    event MinterRemoved(address indexed account);

    uint256 public mintersCount;
    address[] public mintersArray;

    Roles.Role private _minters;

    modifier onlyMinter() {
        require(isMinter(msg.sender), "MinterRole: caller does not have the Minter role");
        _;
    }

    function isMinter(address account) public view returns (bool) {
        return _minters.has(account);
    }

    function renounceMinter() public {
        _removeMinter(msg.sender);
    }

    function _addMinter(address account) internal {
        mintersCount++;
        mintersArray.push(account);
        _minters.add(account);
        emit MinterAdded(account);
    }

    function _removeMinter(address account) internal {
        uint256 index;

        for(uint256 i = 0; i < mintersArray.length; i++) {
            if(mintersArray[i] == account) {
                index = i;
            }
        }

        mintersArray[index] = mintersArray[mintersArray.length - 1];
        mintersArray.pop();

        mintersCount--;
        _minters.remove(account);
        emit MinterRemoved(account);
    }
}

// File: contract-dependencies/OwnerRole.sol

pragma solidity ^0.6.8;


abstract contract OwnerRole {
    using Roles for Roles.Role;

    event OwnerAdded(address indexed account);
    event OwnerRemoved(address indexed account);

    uint256 public ownersCount;
    address[] public ownersArray;

    Roles.Role private _owners;

    modifier onlyOwner() {
        require(isOwner(msg.sender), "OwnerRole: caller does not have the Owner role");
        _;
    }

    function isOwner(address account) public view returns (bool) {
        return _owners.has(account);
    }

    function addOwner(address account) public onlyOwner {
        _addOwner(account);
    }

    function renounceOwner() public {
        _removeOwner(msg.sender);
    }

    function _addOwner(address account) internal {
        ownersCount++;
        ownersArray.push(account);
        _owners.add(account);
        emit OwnerAdded(account);
    }

    function _removeOwner(address account) internal {
        ownersCount--;

        uint256 index;

        for(uint256 i = 0; i < ownersArray.length; i++) {
            if(ownersArray[i] == account) {
                index = i;
            }
        }

        ownersArray[index] = ownersArray[ownersArray.length - 1];
        ownersArray.pop();

        _owners.remove(account);
        emit OwnerRemoved(account);
    }
}

// File: contract-dependencies/ERC20Mintable.sol

pragma solidity 0.6.8;




/**
 * @dev Extension of {ERC20} that adds a set of accounts with the {MinterRole},
 * which have permission to mint (create) new tokens as they see fit.
 *
 * At construction, the deployer of the contract is the only minter.
 */
abstract contract ERC20Mintable is ERC20, MinterRole, OwnerRole {
    /**
     * @dev See {ERC20-_mint}.
     *
     * Requirements:
     *
     * - the caller must have the {MinterRole}.
     */
    modifier onlyMinterOrOwner() {
        require(
            isMinter(msg.sender) || isOwner(msg.sender),
            "Caller is not a minter nor an owner."
        );
        _;
    }

    function removeMinter(address account) external onlyOwner {
        _removeMinter(account);
    }

    function addMinter(address account) external onlyOwner {
        _addMinter(account);
    }

    function mint(address account, uint256 amount)
        external
        onlyMinterOrOwner
        returns (bool)
    {
        _mint(account, amount);
        return true;
    }
}

// File: contracts/eXRD.sol

/*
    The ERC20 E-RADIX tokens have been generated by Radix Tokens (Jersey) Limited. 

    The purchase possession, exchange and use and ownership of these tokens are subject 
    to the terms and conditions, risk warnings and disclaimers issued by Radix Token’s Jersey Limited 
    which can be found at www.radixtokens.com/terms/ERC20token and which shall be binding on all 
    persons who acquires or seeks to acquire possess or control the use custody exchange or ownership 
    of these tokens and all successors in title including anyone who may claim or be entitled to 
    an equitable right title or interest in these tokens or any of them.
*/
pragma solidity 0.6.8;




contract eXRD is ERC20Burnable, ERC20Mintable {
    constructor(address depositAddress, uint256 amount)
        public
        ERC20("E-RADIX", "eXRD")
    {
        require(depositAddress != address(0));

        _addOwner(msg.sender);
        _mint(depositAddress, amount.mul((10**uint256(decimals()))));
    }
}

// File: contracts/Vault.sol

pragma solidity 0.6.8;




/*
    Stores a record of all allocations, and keeps track of unlocked amounts for different allocation groups.
    
    An allocation consists of a number of total tokens, the amount of already released tokens and an assignment to a group. 
    Allocations are created and funded (sending in tokens) in the same step. A group is a set of allocations that 
    all unlock in the same manner.

    The primary function of the vault contract is to allow the owner of the vault contract to set
    (increase only) the % unlocked (by group), making that % of each individual allocation within the group
    available for release. Releases are initiated by beneficiaries, sending tokens to their ethereum address.

    The owner of the contract also has the ability to revoke individual allocations, causing the
    associated funds to be withdrawn to the owner.
*/

contract Vault is Ownable {
    using SafeMath for uint256;

    eXRD public token;

    event AllocationRegistered(
        address indexed beneficiary,
        uint256 amount,
        uint256 group
    );
    event AllocationFullyReleased(address indexed beneficiary, uint256 allocationIndex);
    event Unlocked(uint256 indexed group, uint256 percentage);
    event Revoked(address indexed beneficiary, uint256 allocationIndex);
    event GroupAdded(string indexed name, uint256 indexed id);
    event Released(address indexed beneficiary, uint256 allocationIndex);
    event FundingAccountSet(address indexed account);

    struct Allocation {
        uint256 amount;
        uint256 released;
        uint256 group;
        bool revoked;
    }

    struct AllocationReference {
        address beneficiary;
        uint256 index;
    }

    struct Group {
        string name;
        bool active;
        uint256 allocationCount;
        mapping(uint256 => AllocationReference) allocations;
    }

    mapping(address => Allocation[]) private beneficiaryAllocations;
    mapping(address => uint256) private nbrOfAllocations;

    address[] private registeredBeneficiaries;
    mapping(address => bool) private isRegistered;

    mapping(uint256 => uint256) private unlockedPercentages;

    mapping(uint256 => Group) private groups;

    uint256 private groupCount;

    address private fundingAccount;

    bool releasesPaused;

    constructor(eXRD token_) public {
        token = token_;
    }

    /*
        Unlock a certain amount of tokens to a group.

        Unlocking happens incrementally using percentages. Every allocation
        for that group will have a percentage of its amount unlocked and ready to be released.
    */
    function unlock(uint256 group_, uint256 percentage_) external onlyOwner {
        require(
            group_ < groupCount,
            "Group does not exist."
        );

        require(
            percentage_ > 0 && percentage_ <= 100,
            "Percentage parameter invalid. Need to be > 0 and <= 100."
        );

        require(
            percentage_ > unlockedPercentages[group_],
            "Percentage has to be increasing."
        );

        unlockedPercentages[group_] = percentage_;

        if (percentage_ == 100) {
            groups[group_].active = false;
        }

        emit Unlocked(group_, percentage_);
    }

    function setFundingAccount(address account_) external onlyOwner {
        require(
            account_ != address(0),
            "Cannot set funding account to the zero address."
        );

        fundingAccount = account_;
        emit FundingAccountSet(account_);
    }

    /*
        Revoke an allocation for a beneficiary.

        This sets the revoke flag in the allocation, preventing more releases.
    */
    function revoke(address beneficiary_, uint256 allocationIndex_)
        external
        onlyOwner
    {
        require(
            beneficiary_ != address(0),
            "Cannot revoke for the zero address."
        );

        require(
            isRegistered[beneficiary_] == true,
            "Beneficiary is not registered."
        );

        require(
            nbrOfAllocations[beneficiary_] > allocationIndex_,
            "Allocation does not exist"
        );

        Allocation storage allocation = beneficiaryAllocations[beneficiary_][allocationIndex_];

        require(
            allocation.revoked == false,
            "Allocation already revoked"
        );

        allocation.revoked = true;
        uint256 toBeReleased = allocation.amount.sub(allocation.released);
        token.transfer(fundingAccount, toBeReleased);

        emit Revoked(beneficiary_, allocationIndex_);
    }

    /*
        Revoke allocations for a set of beneficiaries belonging to a specific group.
    */
    function revokeBeneficiariesInGroup(
        address[] calldata beneficiaries_,
        uint256 group_
    ) external onlyOwner {
        require(
            group_ < groupCount,
            "Group not registered in contract."
        );

        uint256 totalAmount = 0;

        for (uint256 i = 0; i < beneficiaries_.length; i++) {
            address beneficiary = beneficiaries_[i];

            require(
                beneficiary != address(0),
                "Cannot revoke for the zero address."
            );

            require(
                isRegistered[beneficiary] == true,
                "Beneficiary is not registered."
            );

            uint256 allocationCount = nbrOfAllocations[beneficiary];

            for (
                uint256 allocationIndex = 0;
                allocationIndex < allocationCount;
                allocationIndex++
            ) {

                Allocation storage allocation = beneficiaryAllocations[beneficiary][allocationIndex];

                require(
                    allocation.revoked == false,
                    "Allocation already revoked"
                );

                if (allocation.group == group_) {
                    allocation.revoked = true;
                    uint256 toBeReleased = allocation.amount.sub(
                        allocation.released
                    );

                    totalAmount += toBeReleased;

                    emit Revoked(beneficiary, allocationIndex);
                }
            }
        }

        token.transfer(fundingAccount, totalAmount);
    }

    /*
        Revoke all allocations for a specific group.
    */
    function revokeGroup(uint256 group_) external onlyOwner {
        require(
            group_ < groupCount,
            "Group not registered in contract."
        );

        uint256 totalAmount = 0;

        for (uint256 i = 0; i < groups[group_].allocationCount; i++) {
            AllocationReference memory allocationRef = groups[group_].allocations[i];
            Allocation storage allocation = beneficiaryAllocations[allocationRef.beneficiary][allocationRef.index];

            if(allocation.revoked == false) {
                allocation.revoked = true;
                uint256 toBeReleased = allocation.amount.sub(
                    allocation.released
                );

                totalAmount += toBeReleased;

                emit Revoked(allocationRef.beneficiary, allocationRef.index);
            }            
        }

        token.transfer(fundingAccount, totalAmount);
    }

    /*
        Adds a group and increments the group count.
    */  
    function addGroup(string calldata name_) external onlyOwner {
        groups[groupCount] = Group(name_, true, 0);

        emit GroupAdded(name_, groupCount);

        groupCount++;
    }

    /*
        Disable a group, preventing further allocations to be made in that group.
    */
    function disableGroup(uint256 group_) external onlyOwner {
        require(
            group_ < groupCount,
            "Group not registered in contract."
        );

        groups[group_].active = false;
    }

    /*
        Enable a group.
    */
    function enableGroup(uint256 group_) external onlyOwner {
        require(
            group_ < groupCount,
            "Group not registered in contract."
        );

        require(
            unlockedPercentages[group_] < 100,
            "Group has been fully unlocked."
        );

        groups[group_].active = true;
    }

    /*
        Adds a number of allocations.

        Pushes a new allocations to the allocation array for each beneficiary,
        sets the beneficiary as registered, increments nbrOfAllocations for the beneficiary,
        and transfers enough tokens to this contracts to be unlocked.
    */
    function addAllocations(
        address[] calldata beneficiaries_,
        uint256[] calldata amounts_,
        uint256[] calldata groups_
    ) external onlyOwner {
        require(
            beneficiaries_.length == amounts_.length &&
                beneficiaries_.length == groups_.length,
            "Length of input arrays do not match."
        );

        require(
            fundingAccount != address(0),
            "Funding account has to be set before allocating."
        );

        uint256 totalAmount = 0;

        for (uint256 i = 0; i < beneficiaries_.length; i++) {
            require(
                beneficiaries_[i] != address(0),
                "Beneficiary cannot be 0 address."
            );

            require(
                amounts_[i] > 0,
                "Cannot allocate zero amount."
            );

            Group memory registeredGroup = groups[groups_[i]];

            require(
                groups_[i] < groupCount,
                "Group not registered in contract."
            );

            require(registeredGroup.active == true, "Group is not active.");

            // Add new allocation to beneficiary
            beneficiaryAllocations[beneficiaries_[i]].push(Allocation(
                amounts_[i],
                0,
                groups_[i],
                false
            ));
            nbrOfAllocations[beneficiaries_[i]]++;

            // Add reference to the allocation to group allocation array
            groups[groups_[i]].allocations[groups[groups_[i]].allocationCount] = AllocationReference(
                beneficiaries_[i],
                beneficiaryAllocations[beneficiaries_[i]].length - 1
            );
            groups[groups_[i]].allocationCount++;
            
            if(!isRegistered[beneficiaries_[i]]) {
                registeredBeneficiaries.push(beneficiaries_[i]);
            }

            isRegistered[beneficiaries_[i]] = true;

            totalAmount += amounts_[i];

            emit AllocationRegistered(beneficiaries_[i], amounts_[i], groups_[i]);
        }
        
        token.transferFrom(fundingAccount, address(this), totalAmount);
    }

    /*
        Calculates the amount of tokens that can be released for an allocation.
    */
    function releasableAmount(address beneficiary_, uint256 allocationIndex_)
        public
        view
        returns (uint256)
    {
        require(
            isRegistered[beneficiary_] == true,
            "You have to be a registered address in order to release tokens."
        );
        
        require(
            allocationIndex_ < nbrOfAllocations[beneficiary_],
            "No allocation found."
        );

        require(
            beneficiaryAllocations[beneficiary_][allocationIndex_].revoked == false,
            "Allocation has been revoked."
        );

        uint256 amount = beneficiaryAllocations[beneficiary_][allocationIndex_].amount;
        uint256 released = beneficiaryAllocations[beneficiary_][allocationIndex_].released;
        uint256 group = beneficiaryAllocations[beneficiary_][allocationIndex_].group;
        uint256 unlocked = unlockedPercentages[group];

        uint256 amountUnlocked = amount.mul(unlocked).div(100);
        uint256 releasable = amountUnlocked.sub(released);

        return releasable;
    }

    /*
        Sends the tokens that have been unlocked for an allocation to the beneficiary.
    */
    function release(uint256 allocationIndex_) public {
        require(
            isRegistered[msg.sender] == true,
            "You have to be a registered address in order to release tokens."
        );

        require(releasesPaused == false, "Releases have been paused.");

        require(
            allocationIndex_ < nbrOfAllocations[msg.sender],
            "No allocation found."
        );

        Allocation storage allocation = beneficiaryAllocations[msg.sender][allocationIndex_];

        require(allocation.revoked == false, "Allocation has been revoked.");

        require(
            unlockedPercentages[allocation.group] > 0,
            "Group has not has any unlocked tokens yet."
        );

        uint256 releasable = releasableAmount(msg.sender, allocationIndex_);
        
        require(releasable > 0, "Nothing to release");

        allocation.released = allocation.released.add(releasable);

        emit Released(msg.sender, allocationIndex_);

        if (allocation.released == allocation.amount) {
            emit AllocationFullyReleased(msg.sender, allocationIndex_);
        }

        token.transfer(msg.sender, releasable);
    }

    function pauseReleases() external onlyOwner {
        releasesPaused = true;
    }

    function unpauseReleases() external onlyOwner {
        releasesPaused = false;
    }

    function getAllocationInGroup(uint256 group_, uint256 index_) public view returns (
        address,
        uint256
    ) {
        AllocationReference memory allocationRef = groups[group_].allocations[index_];
        return (
            allocationRef.beneficiary,
            allocationRef.index
        );
    }

    function getBeneficiaryAllocations(address beneficiary_, uint256 index_) public view returns (
        uint256 amount,
        uint256 released,
        uint256 group,
        bool revoked
    ) {
        Allocation memory allocation = beneficiaryAllocations[beneficiary_][index_];
        return (
            allocation.amount,
            allocation.released,
            allocation.group,
            allocation.revoked
        );
    }

    function getNbrOfAllocations(address beneficiary_) public view returns (uint256) {
        return nbrOfAllocations[beneficiary_];
    }

    function getRegisteredBeneficiaries(uint256 index_) public view returns (address) {
        return registeredBeneficiaries[index_];
    }

    function getIsRegistered(address beneficiary_) public view returns (bool) {
        return isRegistered[beneficiary_];
    }

    function getUnlockedPercentages(uint256 group_) public view returns (uint256) {
        return unlockedPercentages[group_];
    }

    function getGroup(uint256 group_) public view returns (
        string memory name,
        bool active,
        uint256 allocationCount
    ) {
        Group memory group = groups[group_];
        return (
            group.name,
            group.active,
            group.allocationCount
        );
    }

    function getGroupCount() public view returns (uint256) {
        return groupCount;
    }

    function getFundingAccount() public view returns (address) {
        return fundingAccount;
    }
}

{
  "compilationTarget": {
    "Vault.sol": "Vault"
  },
  "evmVersion": "istanbul",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}