// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC1155/IERC1155.sol)

pragma solidity ^0.8.0;

import "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC1155 compliant contract, as defined in the
 * https://eips.ethereum.org/EIPS/eip-1155[EIP].
 *
 * _Available since v3.1._
 */
interface IERC1155 is IERC165 {
    /**
     * @dev Emitted when `value` tokens of token type `id` are transferred from `from` to `to` by `operator`.
     */
    event TransferSingle(address indexed operator, address indexed from, address indexed to, uint256 id, uint256 value);

    /**
     * @dev Equivalent to multiple {TransferSingle} events, where `operator`, `from` and `to` are the same for all
     * transfers.
     */
    event TransferBatch(
        address indexed operator,
        address indexed from,
        address indexed to,
        uint256[] ids,
        uint256[] values
    );

    /**
     * @dev Emitted when `account` grants or revokes permission to `operator` to transfer their tokens, according to
     * `approved`.
     */
    event ApprovalForAll(address indexed account, address indexed operator, bool approved);

    /**
     * @dev Emitted when the URI for token type `id` changes to `value`, if it is a non-programmatic URI.
     *
     * If an {URI} event was emitted for `id`, the standard
     * https://eips.ethereum.org/EIPS/eip-1155#metadata-extensions[guarantees] that `value` will equal the value
     * returned by {IERC1155MetadataURI-uri}.
     */
    event URI(string value, uint256 indexed id);

    /**
     * @dev Returns the amount of tokens of token type `id` owned by `account`.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function balanceOf(address account, uint256 id) external view returns (uint256);

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {balanceOf}.
     *
     * Requirements:
     *
     * - `accounts` and `ids` must have the same length.
     */
    function balanceOfBatch(
        address[] calldata accounts,
        uint256[] calldata ids
    ) external view returns (uint256[] memory);

    /**
     * @dev Grants or revokes permission to `operator` to transfer the caller's tokens, according to `approved`,
     *
     * Emits an {ApprovalForAll} event.
     *
     * Requirements:
     *
     * - `operator` cannot be the caller.
     */
    function setApprovalForAll(address operator, bool approved) external;

    /**
     * @dev Returns true if `operator` is approved to transfer ``account``'s tokens.
     *
     * See {setApprovalForAll}.
     */
    function isApprovedForAll(address account, address operator) external view returns (bool);

    /**
     * @dev Transfers `amount` tokens of token type `id` from `from` to `to`.
     *
     * Emits a {TransferSingle} event.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - If the caller is not `from`, it must have been approved to spend ``from``'s tokens via {setApprovalForAll}.
     * - `from` must have a balance of tokens of type `id` of at least `amount`.
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155Received} and return the
     * acceptance magic value.
     */
    function safeTransferFrom(address from, address to, uint256 id, uint256 amount, bytes calldata data) external;

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {safeTransferFrom}.
     *
     * Emits a {TransferBatch} event.
     *
     * Requirements:
     *
     * - `ids` and `amounts` must have the same length.
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155BatchReceived} and return the
     * acceptance magic value.
     */
    function safeBatchTransferFrom(
        address from,
        address to,
        uint256[] calldata ids,
        uint256[] calldata amounts,
        bytes calldata data
    ) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

import { StarterPackPurchaseLib } from "../libraries/StarterPackPurchaseLib.sol";

// SPDX-License-Identifier: MIT
pragma solidity 0.8.17;

interface IStarterPackPurchase {
    error Disabled();
    error ParallelAlreadyReceived(address user);
    error CardBackAlreadyReceived(address user);
    error InvalidLength();
    error InvalidPayment(uint256 amount);
    error InvalidCardBack(uint256 cardBackId);
    error ParallelPackSoldOut(uint256 parallelId);

    event PackPriceSet(uint256 packPrice);
    event PackSet(
        StarterPackPurchaseLib.Parallel indexed parallelId,
        uint256[] cardIds,
        uint256[] cardAmounts
    );
    event IsDisabledSet(bool isDisabled);
    event AllowlistSet(address[] allowlist, bool val);
    event ParallelAlphaSet(address indexed parallelAlpha);
    event PullFromAddressSet(address indexed pullFromAddress);
    event PacksPurchased(
        address indexed user,
        StarterPackPurchaseLib.Parallel[] parallelIds
    );
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.17;

import { Ownable } from "@openzeppelin/contracts/access/Ownable.sol";
import { IERC1155 } from "@openzeppelin/contracts/token/ERC1155/IERC1155.sol";
import { IStarterPackPurchase } from "./interfaces/IStarterPackPurchase.sol";
import { StarterPackPurchaseLib } from "./libraries/StarterPackPurchaseLib.sol";

contract StarterPackPurchase is IStarterPackPurchase, Ownable {
    /// @notice Mapping of parallel to pack
    mapping(StarterPackPurchaseLib.Parallel => StarterPackPurchaseLib.ParallelPack)
        internal parallelPacks;
    /// @notice Mapping of parallel to pack supply
    mapping(StarterPackPurchaseLib.Parallel => uint256)
        public parallelPacksSupply;
    /// @notice Mapping of parallel to packs purchased
    mapping(StarterPackPurchaseLib.Parallel => uint256)
        public parallelPacksPurchased;

    /// @notice Allowlist that bypasses the disabled variable
    mapping(address => bool) public allowlist;
    /// @notice Disabled state
    bool public isDisabled = true;

    /// @notice Pack price
    uint256 public packPrice = 0.01 ether;

    /// @notice Address to get the packs from
    address public pullFromAddress = 0xF61036949E2D584CCAd40Ddad45C37bdf49E9c78;
    /// @notice Parallel Alpha contract
    IERC1155 public parallelAlpha =
        IERC1155(0x206571b68c66E1d112b74d65695043ad2b5F95D5);

    /**
     * @notice Returns the pack for a given parallel
     * @param _parallelId The parallel id
     * @return cardIds The card ids
     */
    function getPack(
        StarterPackPurchaseLib.Parallel _parallelId
    ) external view returns (uint256[] memory, uint256[] memory) {
        return (
            parallelPacks[_parallelId].cardIds,
            parallelPacks[_parallelId].cardAmounts
        );
    }

    /**
     * @notice Allows user to purchase packs
     * @param _parallelIds The parallel ids
     */
    function purchasePack(
        StarterPackPurchaseLib.Parallel[] calldata _parallelIds
    ) external payable {
        if (msg.value != packPrice * _parallelIds.length)
            revert InvalidPayment(msg.value);

        if (isDisabled && !allowlist[_msgSender()]) revert Disabled();

        bool[] memory parallelPackReceived = new bool[](5);
        for (uint256 i = 0; i < _parallelIds.length; i++) {
            StarterPackPurchaseLib.Parallel _parallelId = _parallelIds[i];

            if (parallelPackReceived[uint256(_parallelId)])
                revert ParallelAlreadyReceived(_msgSender());

            if (
                parallelPacksPurchased[_parallelId] >=
                parallelPacksSupply[_parallelId]
            ) revert ParallelPackSoldOut(uint256(_parallelId));

            parallelAlpha.safeBatchTransferFrom(
                pullFromAddress,
                _msgSender(),
                parallelPacks[_parallelId].cardIds,
                parallelPacks[_parallelId].cardAmounts,
                ""
            );

            parallelPackReceived[uint256(_parallelId)] = true;

            parallelPacksPurchased[_parallelId]++;
        }

        emit PacksPurchased(_msgSender(), _parallelIds);
    }

    /**
     * @notice Sets the disabled state
     * @dev Only callable by the owner
     * @param _isDisabled The new disabled state
     */
    function setDisabled(bool _isDisabled) external onlyOwner {
        isDisabled = _isDisabled;

        emit IsDisabledSet(_isDisabled);
    }

    /**
     * @notice Sets the parallel alpha contract
     * @dev Only callable by the owner
     * @param _parallelAlpha The new parallel alpha contract
     */
    function setParallelAlpha(IERC1155 _parallelAlpha) external onlyOwner {
        parallelAlpha = IERC1155(_parallelAlpha);

        emit ParallelAlphaSet(address(_parallelAlpha));
    }

    /**
     * @notice Sets the pull from address
     * @dev Only callable by the owner
     * @param _pullFromAddress The new pull from address
     */
    function setPullFromAddress(address _pullFromAddress) external onlyOwner {
        pullFromAddress = _pullFromAddress;

        emit PullFromAddressSet(_pullFromAddress);
    }

    /**
     * @notice Sets the pack price
     * @dev Only callable by the owner
     * @param _packPrice The new pack price
     */
    function setPackPrice(uint256 _packPrice) external onlyOwner {
        packPrice = _packPrice;

        emit PackPriceSet(_packPrice);
    }

    /**
     * @notice Sets the pack
     * @dev Only callable by the owner
     * @param _parallelId The parallel id
     * @param _cardIds The card ids
     */
    function setPack(
        StarterPackPurchaseLib.Parallel _parallelId,
        uint256[] calldata _cardIds,
        uint256[] calldata _cardAmounts,
        uint256 _maxSupply
    ) external onlyOwner {
        if (_cardIds.length != _cardAmounts.length) revert InvalidLength();

        parallelPacks[_parallelId] = StarterPackPurchaseLib.ParallelPack({
            cardIds: _cardIds,
            cardAmounts: _cardAmounts
        });

        parallelPacksSupply[_parallelId] = _maxSupply;

        emit PackSet(_parallelId, _cardIds, _cardAmounts);
    }

    /**
     * @notice Sets the allowlist
     * @dev Only callable by the owner
     * @param _allowlist The new allowlist
     * @param _val The new value
     */
    function setAllowlist(
        address[] calldata _allowlist,
        bool _val
    ) external onlyOwner {
        for (uint256 i = 0; i < _allowlist.length; i++) {
            allowlist[_allowlist[i]] = _val;
        }

        emit AllowlistSet(_allowlist, _val);
    }

    /**
     * @notice Withdraws the contract balance
     * @dev Only callable by the owner
     */
    function sweep() public onlyOwner {
        (bool sent, ) = msg.sender.call{ value: address(this).balance }("");
        require(sent, "Failed to send Ether");
    }

    /**
     * @notice Withdraws the contract balance to a specific address
     * @dev Only callable by the owner
     * @param _amount The amount to withdraw
     * @param _address The address to withdraw to
     */
    function sweepToAddress(
        uint _amount,
        address payable _address
    ) public onlyOwner {
        (bool sent, ) = _address.call{ value: _amount }("");
        require(sent, "Failed to send Ether");
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.17;

library StarterPackPurchaseLib {
    enum Parallel {
        AUGENCORE,
        EARTHEN,
        KATHARI,
        MARCOLIAN,
        SHROUD
    }

    struct ParallelPack {
        uint256[] cardIds;
        uint256[] cardAmounts;
    }
}

{
  "compilationTarget": {
    "contracts/packdrop/StarterPackPurchase.sol": "StarterPackPurchase"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs",
    "useLiteralContent": true
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}