// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

pragma solidity 0.8.16;

import {IStaking} from "../interfaces/IStaking.sol";
import {IERC20} from "@openzeppelin/contracts/interfaces/IERC20.sol";
import {IVirtualRebaseViewer} from "../Token/VirtualRebaseViewer.sol";

interface IBalancerVault {
    enum SwapKind {
        GIVEN_IN,
        GIVEN_OUT
    }

    struct FundManagement {
        address sender;
        bool fromInternalBalance;
        address payable recipient;
        bool toInternalBalance;
    }

    struct SingleSwap {
        bytes32 poolId;
        SwapKind kind;
        address assetIn;
        address assetOut;
        uint256 amount;
        bytes userData;
    }

    function getPool(bytes32 poolId) external view returns (address, bytes memory);
    function getPoolTokens(bytes32 poolId)
        external
        view
        returns (address[] memory tokens, uint256[] memory balances, uint256 lastChangeBlock);

    function swap(SingleSwap memory singleSwap, FundManagement memory funds, uint256 limit, uint256 deadline)
        external
        payable
        returns (uint256);
}

interface IBalancerPool {
    function getNormalizedWeights() external view returns (uint256[] memory);
    function getSwapFeePercentage() external view returns (uint256);
}

interface ICurveZap {
    function get_dy(address, uint256, uint256, uint256) external view returns (uint256);
    function exchange(address, uint256, uint256, uint256, uint256) external payable returns (uint256);
}

interface ICurvePool {
    function get_dy(uint256, uint256, uint256) external view returns (uint256);
    function coins(uint256) external view returns (address);
}

interface IMaverickPool {
    function swap(
        address recipient,
        uint256 amount,
        bool tokenAIn,
        bool exactOutput,
        uint256 sqrtPriceLimit,
        bytes calldata data
    ) external returns (uint256 amountIn, uint256 amountOut);

    struct SwapCallbackData {
        bytes path;
        address payer;
        bool exactOutput;
    }
}

interface IMaverickFactory {
    function isFactoryPool(address) external view returns (bool);
}

library RouterConstants {
    IERC20 internal constant usdc = IERC20(0xA0b86991c6218b36c1d19D4a2e9Eb0cE3606eB48);
    IERC20 internal constant coil = IERC20(0x823E1B82cE1Dc147Bbdb25a203f046aFab1CE918);
    IERC20 internal constant spiral = IERC20(0x85b6ACaBa696B9E4247175274F8263F99b4B9180);
    IStaking internal constant staking = IStaking(0x6701E792b7CD344BaE763F27099eEb314A4b4943);
    ICurveZap internal constant curveZap = ICurveZap(0x5De4EF4879F4fe3bBADF2227D2aC5d0E2D76C895);
    address internal constant curvePool = 0xAF4264916B467e2c9C8aCF07Acc22b9EDdDaDF33;

    IBalancerVault internal constant balVault = IBalancerVault(0xBA12222222228d8Ba445958a75a0704d566BF2C8);
    IBalancerPool internal constant balancerPool = IBalancerPool(0x42FBD9F666AaCC0026ca1B88C94259519e03dd67);
    bytes32 internal constant balancerPoolId = 0x42fbd9f666aacc0026ca1b88c94259519e03dd67000200000000000000000507;

    IVirtualRebaseViewer internal constant virtualRebaseViewer =
        IVirtualRebaseViewer(0xab1789b0A1830d897F55e7aDAE87612264271309);
    IMaverickPool internal constant maverickPool = IMaverickPool(0xF04984FDc904F310D3ca0B7B105453E14129CDa2);
    IMaverickFactory internal constant maverickFactory = IMaverickFactory(0xEb6625D65a0553c9dBc64449e56abFe519bd9c9B);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

interface IStaking {
    function rebase() external;
    function stake(uint256) external;
    function unstake(uint256) external;
    function index() external view returns (uint256);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Compatible with tokens that require the approval to be set to
     * 0 before setting it to a non-zero value.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
    }
}

// SPDX-License-Identifier: GPL-3.0-or-later.
// Copyright (C) 2023 Spiral DAO, info@RouterConstants.spiral.farm
// Full Notice is available in the root folder.
pragma solidity 0.8.16;

import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";

import {
    IStaking,
    IERC20,
    IVirtualRebaseViewer,
    IBalancerVault,
    IBalancerPool,
    ICurveZap,
    ICurvePool,
    IMaverickPool,
    IMaverickFactory,
    RouterConstants
} from "./Helper.sol";

contract SpiralRouterV2 {
    using SafeERC20 for IERC20;

    constructor() {
        _refreshAllowances();
    }

    function refreshAllowances() external {
        _refreshAllowances();
    }

    function _refreshAllowances() internal {
        IERC20(RouterConstants.coil).forceApprove(address(RouterConstants.staking), type(uint256).max);
        IERC20(RouterConstants.spiral).forceApprove(address(RouterConstants.staking), type(uint256).max);

        IERC20(RouterConstants.coil).forceApprove(address(RouterConstants.balVault), type(uint256).max);
        IERC20(RouterConstants.usdc).forceApprove(address(RouterConstants.balVault), type(uint256).max);

        IERC20(RouterConstants.coil).forceApprove(address(RouterConstants.curvePool), type(uint256).max);
        IERC20(RouterConstants.usdc).forceApprove(address(RouterConstants.curvePool), type(uint256).max);

        IERC20(RouterConstants.coil).forceApprove(address(RouterConstants.curveZap), type(uint256).max);
        IERC20(RouterConstants.usdc).forceApprove(address(RouterConstants.curveZap), type(uint256).max);

        IERC20(RouterConstants.coil).forceApprove(address(RouterConstants.maverickPool), type(uint256).max);
        IERC20(RouterConstants.usdc).forceApprove(address(RouterConstants.maverickPool), type(uint256).max);
    }

    function swap(address tokenIn, address tokenOut, uint256[3] calldata amounts, uint256 minAmountOut) external {
        uint256 amountIn = amounts[0] + amounts[1] + amounts[2];
        uint256 amountCurve = amounts[0];
        uint256 amountBalancer = amounts[1];
        uint256 amountMaverick = amounts[2];
        IERC20(tokenIn).safeTransferFrom(msg.sender, address(this), amountIn);
        if (tokenIn == address(RouterConstants.spiral)) {
            RouterConstants.staking.unstake(amountIn);
            uint256 index_ = RouterConstants.staking.index();
            tokenIn = address(RouterConstants.coil);
            amountIn = RouterConstants.coil.balanceOf(address(this));
            amountCurve = amountCurve * index_ / 1e18;
            amountBalancer = amountBalancer * index_ / 1e18;
            amountMaverick = amountMaverick * index_ / 1e18;
        }
        address tokenOut_ = tokenOut;
        if (tokenOut == address(RouterConstants.spiral)) {
            tokenOut_ = address(RouterConstants.coil);
        }
        uint256 balanceBefore = IERC20(tokenOut_).balanceOf(address(this));
        if (amountCurve > 0) {
            curveSwap(IERC20(tokenIn), IERC20(tokenOut_), amountCurve);
        }
        if (amountBalancer > 0) {
            balancerSwap(tokenIn, tokenOut_, amountBalancer);
        }
        if (amountMaverick > 0) {
            maverickSwap(tokenIn, tokenOut_, IERC20(tokenIn).balanceOf(address(this)));
        }
        uint256 actualOut = IERC20(tokenOut_).balanceOf(address(this)) - balanceBefore;
        if (tokenOut == address(RouterConstants.spiral)) {
            RouterConstants.staking.stake(actualOut);
            require(RouterConstants.spiral.balanceOf(address(this)) >= minAmountOut, "slippage");
            RouterConstants.spiral.safeTransfer(msg.sender, RouterConstants.spiral.balanceOf(address(this)));
        } else {
            require(actualOut >= minAmountOut, "slippage");
            IERC20(tokenOut).safeTransfer(msg.sender, actualOut);
        }
    }

    function curveSwap(IERC20 tokenIn, IERC20 tokenOut, uint256 amountIn) internal {
        ICurvePool pool = ICurvePool(RouterConstants.curvePool);
        uint256 i;
        uint256 j;
        if (address(tokenIn) == address(RouterConstants.coil)) {
            i = 0;
            j = 2;
        } else {
            i = 2;
            j = 0;
        }
        RouterConstants.curveZap.exchange(address(pool), i, j, amountIn, 0);
    }

    function balancerSwap(address tokenIn, address tokenOut, uint256 amountIn) internal {
        RouterConstants.balVault.swap(
            IBalancerVault.SingleSwap(
                RouterConstants.balancerPoolId,
                IBalancerVault.SwapKind.GIVEN_IN,
                tokenIn,
                tokenOut,
                amountIn,
                new bytes(0)
            ),
            IBalancerVault.FundManagement(address(this), false, payable(address(this)), false),
            0,
            block.timestamp
        );
    }

    function maverickSwap(address tokenIn, address tokenOut, uint256 amount) internal {
        IMaverickPool pool = RouterConstants.maverickPool;

        pool.swap(
            address(this),
            amount,
            tokenIn < tokenOut,
            false,
            0,
            abi.encode(
                IMaverickPool.SwapCallbackData({
                    path: abi.encodePacked(tokenIn, address(pool), tokenOut),
                    payer: address(this),
                    exactOutput: false
                })
            )
        );
    }

    /**
     * @dev required to perform maverick swap
     */
    function swapCallback(uint256 amountToPay, uint256 amountOut, bytes calldata _data) external {
        require(amountToPay > 0 && amountOut > 0);
        require(RouterConstants.maverickFactory.isFactoryPool(msg.sender));

        IMaverickPool.SwapCallbackData memory data = abi.decode(_data, (IMaverickPool.SwapCallbackData));

        bytes memory path = data.path;
        address tokenToPay;
        address pool;
        assembly ("memory-safe") {
            tokenToPay := div(mload(add(add(path, 0x20), 0)), 0x1000000000000000000000000)
            pool := div(mload(add(add(path, 0x34), 0)), 0x1000000000000000000000000)
        }
        require(msg.sender == pool);

        IERC20(tokenToPay).safeTransfer(pool, amountToPay);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.16;

import {IERC20} from "@openzeppelin/contracts/interfaces/IERC20.sol";

interface IStaking {
    struct Epoch {
        uint256 length;
        uint256 number;
        uint256 endBlock;
        uint256 apr;
    }

    function epoch() external view returns (Epoch memory);
    function index() external view returns (uint256);
    /* function stakedCoil() external view returns(uint256); */
}

interface IVirtualRebaseViewer {
    function epoch() external view returns (IStaking.Epoch memory);
    function nextRebaseAt() external view returns (uint256);
    function pendingIndex() external view returns (uint256, uint256);
    function pendingCoil() external view returns (uint256);
    function allInOne() external view returns (uint256, uint256, uint256, uint256);
}

contract VirtualRebaseViewer is IVirtualRebaseViewer {
    address private constant staking = address(0x6701E792b7CD344BaE763F27099eEb314A4b4943);
    address private constant spiral = address(0x85b6ACaBa696B9E4247175274F8263F99b4B9180);
    address private constant coil = address(0x823E1B82cE1Dc147Bbdb25a203f046aFab1CE918);
    uint256 private constant initialIndex = 10 ** 18;
    uint256 private constant blocksPerYear = 2628000;
    uint256 private constant aprBase = 10000;

    constructor() {}

    function epoch() external view returns (IStaking.Epoch memory) {
        return IStaking(staking).epoch();
    }

    function nextRebaseAt() external view returns (uint256) {
        (,, uint256 endBlock,) = _virtualRebase();
        return endBlock;
    }

    function pendingIndex() external view returns (uint256, uint256) {
        (uint256 pendingRebasesCount, uint256 futureIndex,,) = _virtualRebase();
        return (pendingRebasesCount, futureIndex);
    }

    function pendingCoil() external view returns (uint256) {
        (,,, uint256 stakedCoil) = _virtualRebase();
        return stakedCoil;
    }

    function allInOne() external view returns (uint256, uint256, uint256, uint256) {
        return _virtualRebase();
    }

    function _virtualRebase()
        internal
        view
        returns (uint256 pendingRebasesCount, uint256 futureIndex, uint256 endBlock, uint256 stakedCoil)
    {
        IStaking.Epoch memory epoch = IStaking(staking).epoch();
        futureIndex = IStaking(staking).index();
        /* stakedCoil = IStaking(staking).stakedCoil(); */
        stakedCoil = IERC20(coil).balanceOf(staking);
        uint256 totalSpiral = IERC20(spiral).totalSupply();

        while (epoch.endBlock <= block.number) {
            pendingRebasesCount++;
            futureIndex = futureIndex + ((epoch.apr * futureIndex * epoch.length) / blocksPerYear / aprBase);
            epoch.endBlock = epoch.endBlock + epoch.length;
            epoch.number++;
            if (totalSpiral > 0 && stakedCoil > 0 && epoch.apr > 0) {
                uint256 mintAmount = (totalSpiral * futureIndex / initialIndex) - stakedCoil;
                stakedCoil += mintAmount;
            }
        }

        return (pendingRebasesCount, futureIndex, epoch.endBlock, stakedCoil);
    }
}

{
  "compilationTarget": {
    "src/Contracts/SpiralRouter/SpiralRouter.sol": "SpiralRouterV2"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "none"
  },
  "optimizer": {
    "enabled": true,
    "runs": 999999
  },
  "remappings": [
    ":@/=lib/forge-std/src/",
    ":@openzeppelin/=lib/openzeppelin-contracts/",
    ":ds-test/=lib/forge-std/lib/ds-test/src/",
    ":erc4626-tests/=lib/openzeppelin-contracts/lib/erc4626-tests/",
    ":forge-std/=lib/forge-std/src/",
    ":openzeppelin-contracts/=lib/openzeppelin-contracts/",
    ":openzeppelin/=lib/openzeppelin-contracts/contracts/"
  ]
}