// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}

// SPDX-License-Identifier: Unlicense

pragma solidity ^0.8.0;

import { IERC20 } from "@openzeppelin/contracts/token/ERC20/IERC20.sol";

interface IRWaste is IERC20 {
    function burn(address from, uint256 amount) external;
}

// SPDX-License-Identifier: Unlicense

pragma solidity ^0.8.0;

import { IERC20 } from "@openzeppelin/contracts/token/ERC20/IERC20.sol";

interface IScales is IERC20 {
    function spend(address from, uint256 amount) external;
}

// SPDX-License-Identifier: Unlicense

pragma solidity ^0.8.0;

import { Ownable } from "@openzeppelin/contracts/access/Ownable.sol";

import { IRWaste } from "./interfaces/IRWaste.sol";
import { IScales } from "./interfaces/IScales.sol";

error KaijuTokenVirtualizer_UninitializedDestination();

/**
                        .             :++-
                       *##-          +####*          -##+
                       *####-      :%######%.      -%###*
                       *######:   =##########=   .######*
                       *#######*-#############*-*#######*
                       *################################*
                       *################################*
                       *################################*
                       *################################*
                       *################################*
                       :*******************************+.

                .:.
               *###%*=:
              .##########+-.
              +###############=:
              %##################%+
             =######################
             -######################++++++++++++++++++=-:
              =###########################################*:
               =#############################################.
  +####%#*+=-:. -#############################################:
  %############################################################=
  %##############################################################
  %##############################################################%=----::.
  %#######################################################################%:
  %##########################################+:    :+%#######################:
  *########################################*          *#######################
   -%######################################            %######################
     -%###################################%            #######################
       =###################################-          :#######################
     ....+##################################*.      .+########################
  +###########################################%*++*%##########################
  %#########################################################################*.
  %#######################################################################+
  ########################################################################-
  *#######################################################################-
  .######################################################################%.
     :+#################################################################-
         :=#####################################################:.....
             :--:.:##############################################+
   ::             +###############################################%-
  ####%+-.        %##################################################.
  %#######%*-.   :###################################################%
  %###########%*=*####################################################=
  %####################################################################
  %####################################################################+
  %#####################################################################.
  %#####################################################################%
  %######################################################################-
  .+*********************************************************************.
 * @title Kaiju Token Virtualizer
 * @notice Burn Kaiju ecosystem tokens to virtualize them to a destination
 * @author Augminted Labs, LLC
 */
contract KaijuTokenVirtualizer is Ownable {
    event Virtualize(
        address indexed token,
        address indexed from,
        uint256 indexed destination,
        uint256 amount
    );

    IRWaste public rwaste;
    IScales public scales;
    mapping(uint256 => string) public destinations;

    mapping(address => mapping(uint256 => uint256)) internal _rwasteVirtualized;
    mapping(address => mapping(uint256 => uint256)) internal _scalesVirtualized;

    constructor(
        address _rwaste,
        address _scales,
        address _owner
    ) {
        rwaste = IRWaste(_rwaste);
        scales = IScales(_scales);

        transferOwnership(_owner);
    }

    /**
     * @notice Modifier that ensures the specified destination has been initialized
     * @param _destination Destination to validate
     */
    modifier validateDestination(uint256 _destination) {
        if (bytes(destinations[_destination]).length == 0) revert KaijuTokenVirtualizer_UninitializedDestination();
        _;
    }

    /**
     * @notice Returns the amount of $RWASTE virtualized by a specified address for a specified destination
     * @param _from Address to return the amount of virtualized $RWASTE for
     * @param _destination Destination to return the amount of virtualized $RWASTE for
     * @return uint256 Amount of $RWASTE virtualized by the address to the specified destination
     */
    function rwasteVirtualized(address _from, uint256 _destination) public view returns (uint256) {
        return _rwasteVirtualized[_from][_destination];
    }

    /**
     * @notice Returns the amount of $SCALES virtualized by a specified address for a specified destination
     * @param _from Address to return the amount of virtualized $SCALES for
     * @param _destination Destination to return the amount of virtualized $SCALES for
     * @return uint256 Amount of $SCALES virtualized by the address to the specified destination
     */
    function scalesVirtualized(address _from, uint256 _destination) public view returns (uint256) {
        return _scalesVirtualized[_from][_destination];
    }

    /**
     * @notice Set the $RWASTE token contract
     * @param _rwaste New $RWASTE token contract
     */
    function setRWaste(address _rwaste) public payable onlyOwner {
        rwaste = IRWaste(_rwaste);
    }

    /**
     * @notice Set the $SCALES token contract
     * @param _scales New $SCALES token contract
     */
    function setScales(address _scales) public payable onlyOwner {
        scales = IScales(_scales);
    }

    /**
     * @notice Set the values of a destination
     * @param _id Identifier of the destination
     * @param _name Name of the destination
     */
    function setDestination(uint256 _id, string calldata _name) public payable onlyOwner {
        destinations[_id] = _name;
    }

    /**
     * @notice Virtualize $RWASTE to a specified destination
     * @param _amount Amount of $RWASTE to virtualize
     * @param _destination Destination to virtualize $RWASTE to
     */
    function virtualizeRWaste(uint256 _amount, uint256 _destination) public validateDestination(_destination) {
        rwaste.burn(msg.sender, _amount);

        unchecked { _rwasteVirtualized[msg.sender][_destination] += _amount; }

        emit Virtualize(
            address(rwaste),
            msg.sender,
            _destination,
            _amount
        );
    }

    /**
     * @notice Virtualize $SCALES to a specified destination
     * @param _amount Amount of $SCALES to virtualize
     * @param _destination Destination to virtualize $SCALES to
     */
    function virtualizeScales(uint256 _amount, uint256 _destination) public validateDestination(_destination) {
        scales.spend(msg.sender, _amount);

        unchecked { _scalesVirtualized[msg.sender][_destination] += _amount; }

        emit Virtualize(
            address(scales),
            msg.sender,
            _destination,
            _amount
        );
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

{
  "compilationTarget": {
    "contracts/KaijuTokenVirtualizer.sol": "KaijuTokenVirtualizer"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}