// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.22;

import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";

/// @custom:security-contact contact@alertfriend.com
contract FredRewards is Ownable {
    IERC20 public claimAgent; // Token used for claim rewards
    mapping(address => uint256) public claimableAmounts; // Tokens available for each user
    mapping(address => bool) public hasClaimed; // Tracks if the user has already claimed
    mapping(address => uint256) public claimedAmounts; // Tracks the total claimed amount per user
    uint256 public claimStartTimestamp; // Start timestamp for the claim period
    uint256 public claimEndTimestamp; // End timestamp for the claim period
    bool public isActive; // Contract status (active/inactive)

    // Events
    event ClaimSet(address indexed user, uint256 amount);
    event Claimed(address indexed user, uint256 amount);
    event TokenSet(address indexed token);
    event ClaimPeriodSet(uint256 startTimestamp, uint256 endTimestamp);
    event TokensWithdrawn(address indexed owner, uint256 amount);
    event ContractStatusChanged(bool isActive);

    // Modifiers
    modifier claimActive() {
        require(isClaimActive(), "Claim period not active");
        _;
    }

    constructor(address initialOwner, address _tokenAddress, uint256 _claimStartTimestamp, uint256 _claimEndTimestamp) Ownable(initialOwner) {
        claimAgent = IERC20(_tokenAddress);
        claimStartTimestamp = _claimStartTimestamp;
        claimEndTimestamp = _claimEndTimestamp;
        isActive = false; // Default to active
    }

    /// @notice Activate or deactivate the contract
    function setContractStatus(bool _isActive) external onlyOwner {
        isActive = _isActive;
        emit ContractStatusChanged(_isActive);
    }

    /// @notice Configure the token used for claims
    function setClaimAgent(address _tokenAddress) external onlyOwner {
        claimAgent = IERC20(_tokenAddress);
        emit TokenSet(_tokenAddress);
    }

    /// @notice Configure the end timestamp for the claim period
    function setClaimPeriod(uint256 _startTimestamp, uint256 _endTimestamp) external onlyOwner {
        require(_endTimestamp > _startTimestamp, "End timestamp must be after start timestamp");
        require(_endTimestamp > block.timestamp, "Timestamp must be in the future");
        claimStartTimestamp = _startTimestamp;
        claimEndTimestamp = _endTimestamp;
        emit ClaimPeriodSet(_startTimestamp, _endTimestamp);
    }

    /// @notice Set claimable amounts for multiple users
    function setClaimableAmounts(address[] memory users, uint256[] memory amounts) external onlyOwner {
        require(users.length == amounts.length, "Length mismatch");
        for (uint256 i = 0; i < users.length; i++) {
            claimableAmounts[users[i]] = amounts[i];
            emit ClaimSet(users[i], amounts[i]);
        }
    }

    /// @notice Allow users to claim their rewards
    function claim() external claimActive {
        uint256 amount = claimableAmounts[msg.sender];

        require(amount > 0, "No tokens to claim");
        require(!hasClaimed[msg.sender], "Already claimed");
        require(claimAgent.balanceOf(address(this)) >= amount, "Insufficient token supply");
        require(claimAgent.transfer(msg.sender, amount), "Token transfer failed");

        hasClaimed[msg.sender] = true;
        claimableAmounts[msg.sender] = 0;
        claimedAmounts[msg.sender] += amount;
        emit Claimed(msg.sender, amount);
    }

    /// @param amount Amount of tokens to withdraw (set to 0 to withdraw full balance)
    function withdraw(uint256 amount) external onlyOwner {
        uint256 balance = claimAgent.balanceOf(address(this));
        uint256 withdrawAmount = (amount == 0) ? balance : amount;
        require(balance >= withdrawAmount, "Insufficient contract balance");
        require(claimAgent.transfer(msg.sender, withdrawAmount), "Token transfer failed");
        emit TokensWithdrawn(msg.sender, withdrawAmount);
    }

    /// @notice Check if the claim period is active and the contract is active
    function isClaimActive() public view returns (bool) {
        return isActive && block.timestamp >= claimStartTimestamp && block.timestamp <= claimEndTimestamp;
    }

    /// @notice Check if a wallet is eligible for claiming tokens
    function isWalletEligible(address user) external view returns (bool) {
        return claimableAmounts[user] > 0 && !hasClaimed[user];
    }
}

{
  "compilationTarget": {
    "fredRewards.sol": "FredRewards"
  },
  "evmVersion": "cancun",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}