// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: GPL-3.0

pragma solidity 0.8.17;

import "../interfaces/IFeeWallet.sol";
import "../interfaces/IWstETH.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/access/Ownable.sol";

// Wallet to hold protocol fees or redemption fees (stETH) from the Vault.
// Once called by the fee distributor, converts stETH to wstETH and sends to the fee distributor.
// Note: deploy two instances of this contract, one for protocol fees and one for redemption fees.
contract FeeWallet is IFeeWallet, Ownable {
  
  address public wstETH;
  address public stETH;
  mapping(address => bool) public feeDistributors;

  // for conveniency: a human readable name to distinguish between protocol fees and redemption fees wallet
  string public walletName;


  constructor(address _wstETH, string memory _walletName) {
    wstETH = _wstETH;
    stETH = IWstETH(_wstETH).stETH();
    walletName = _walletName;
  }

  function withdraw() external override onlyFeeDistributor returns (uint256) {
    // wrap stETH to wstETH and send to fee distributor
    uint256 stETHAmount = IERC20(stETH).balanceOf(address(this));
    if (stETHAmount == 0) {
      return 0;
    }
    IERC20(stETH).approve(wstETH, stETHAmount);
    uint256 wstETHAmount = IWstETH(wstETH).wrap(stETHAmount);

    IWstETH(wstETH).transfer(msg.sender, wstETHAmount);

    return wstETHAmount;
  }

  // in case of bugs from wstETH or other usecases, allow fee distributor to withdraw stETH without wrapping
  function withdrawRaw() external override onlyFeeDistributor returns (uint256) {
    uint256 stETHAmountBefore = IERC20(stETH).balanceOf(address(this));
    if (stETHAmountBefore == 0) {
      return 0;
    }
    IWstETH(stETH).transfer(msg.sender, stETHAmountBefore);
    uint256 stETHAmountAfter = IERC20(stETH).balanceOf(address(this));

    return stETHAmountBefore - stETHAmountAfter;
  }

  function feeToken() external view override returns (address) {
    return wstETH;
  }

  function feeTokenRaw() external view override returns (address) {
    return stETH;
  }

  function setFeeDistributor(address _feeDistributor, bool _isFeeDistributor) external onlyOwner {
    feeDistributors[_feeDistributor] = _isFeeDistributor;
  }

  modifier onlyFeeDistributor() {
    require(feeDistributors[msg.sender], "!fee distributor");
    _;
  }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: GPL-3.0

pragma solidity 0.8.17;

interface IFeeWallet {
    function withdraw() external returns (uint);
    function withdrawRaw() external returns (uint);
    function feeToken() external view returns (address);
    function feeTokenRaw() external view returns (address);
}

// SPDX-License-Identifier: GPL-3.0

pragma solidity 0.8.17;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";

interface IWstETH is IERC20 {
    function getWstETHByStETH(uint _stETHAmount) external view returns (uint _wstETHAmount);
    function getStETHByWstETH(uint _wstETHAmount) external view returns (uint _stETHAmount);
    function stETH() external view returns (address);
    
    function wrap(uint256 _stETHAmount) external returns (uint _receivedWstETHAmount);
    function unwrap(uint256 _wstETHAmount) external returns (uint _receivedStETHAmount);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

{
  "compilationTarget": {
    "contracts/earn/FeeWallet.sol": "FeeWallet"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}