// File: @openzeppelin/contracts/utils/Context.sol


// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// File: @openzeppelin/contracts/access/Ownable.sol


// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;


/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// File: @openzeppelin/contracts/utils/Pausable.sol


// OpenZeppelin Contracts (last updated v5.0.0) (utils/Pausable.sol)

pragma solidity ^0.8.20;


/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    bool private _paused;

    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    /**
     * @dev The operation failed because the contract is paused.
     */
    error EnforcedPause();

    /**
     * @dev The operation failed because the contract is not paused.
     */
    error ExpectedPause();

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        if (paused()) {
            revert EnforcedPause();
        }
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        if (!paused()) {
            revert ExpectedPause();
        }
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

// File: contracts/QBXVipClubReward.sol


pragma solidity ^0.8.0;




contract QBXVIPClubReward is Context, Ownable, Pausable {
    mapping(address => uint256) public rewards;
    mapping(address => uint256) public transactionCount;
    mapping(address => bool) public blacklist;
    uint256 public withdrawalThreshold;
    uint256 private nonce = 0;
    bool public emergencyMode = false;

    uint256 lowerLimit = 0.0000037 ether;
    uint256 upperLimit = 0.00018 ether;

    uint256 public firstTxGas = 67400;
    uint256 public secondTxGas = 47200;

    event Accrue(address indexed user, uint256 amount);
    event Withdraw(address indexed user, uint256 amount);
    event BlacklistUpdated(address indexed user, bool isBlacklisted);

    constructor(uint256 _threshold, address _owner) Ownable(_owner) {
        withdrawalThreshold = _threshold;
    }

    receive() external payable {}

    modifier notBlacklisted() {
        require(
            !blacklist[msg.sender],
            "Address is not allowed to make transactions"
        );
        _;
    }

    function _generateRandomReward() internal returns (uint256) {
        nonce++;
        return
            (uint256(
                keccak256(abi.encodePacked(block.timestamp, msg.sender, nonce))
            ) % upperLimit) + lowerLimit;
    }

    function setLimits(
        uint256 _lowerLimit,
        uint256 _upperLimit
    ) external onlyOwner {
        lowerLimit = _lowerLimit;
        upperLimit = _upperLimit;
    }

    function setWithdrawalThreshold(uint256 _newThreshold) external onlyOwner {
        withdrawalThreshold = _newThreshold;
    }

    function setPaused(bool flag) external onlyOwner {
        if (flag) {
            _pause();
        } else {
            _unpause();
        }
    }

    function setEmergencyMode(
        bool _emergencyMode
    ) external onlyOwner whenPaused {
        emergencyMode = _emergencyMode;
    }

    function accrue() external whenNotPaused {
        require(tx.origin == msg.sender, "Not EOA");
        uint256 txCost;
        if (transactionCount[msg.sender] == 0) {
            txCost = firstTxGas * tx.gasprice;
        } else {
            txCost = secondTxGas * tx.gasprice;
        }

        uint256 randomReward = _generateRandomReward();
        rewards[msg.sender] += txCost + randomReward;
        transactionCount[msg.sender]++;
        emit Accrue(msg.sender, txCost + randomReward);
    }

    function withdraw() external notBlacklisted {
        uint256 userReward = rewards[msg.sender];
        require(
            userReward >= withdrawalThreshold,
            "Reward is below the withdrawal threshold"
        );
        rewards[msg.sender] = 0;
        payable(msg.sender).transfer(userReward);
        emit Withdraw(msg.sender, userReward);
    }

    function emergencyOwnerWithdraw(
        address payable _to
    ) external onlyOwner whenPaused {
        payable(_to).transfer(address(this).balance);
    }

    function emergencyUserWithdraw() external notBlacklisted {
        require(
            emergencyMode == true,
            "Can only be called when Emergency mode is activated"
        );

        uint256 userReward = rewards[msg.sender];
        rewards[msg.sender] = 0;
        payable(msg.sender).transfer(userReward);
        emit Withdraw(msg.sender, userReward);
    }

    function addToBlacklist(address[] calldata _users) external onlyOwner {
        for (uint256 i = 0; i < _users.length; i++) {
            blacklist[_users[i]] = true;
            emit BlacklistUpdated(_users[i], true);
        }
    }

    function removeFromBlacklist(address[] calldata _users) external onlyOwner {
        for (uint256 i = 0; i < _users.length; i++) {
            blacklist[_users[i]] = false;
            emit BlacklistUpdated(_users[i], false);
        }
    }

    function getContractBalance() external view returns (uint256) {
        return address(this).balance;
    }
}

{
  "compilationTarget": {
    "QBXVIPClubReward.sol": "QBXVIPClubReward"
  },
  "evmVersion": "cancun",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}