// SPDX-License-Identifier: GPL-3.0
pragma solidity >=0.5.0;

interface ISCRYERC20 {
    // event Approval(address indexed owner, address indexed spender, uint value);
    // event Transfer(address indexed from, address indexed to, uint value);

    function name() external view returns (string memory);
    function symbol() external view returns (string memory);
    function decimals() external view returns (uint8);
    function totalSupply() external view returns (uint);
    function balanceOf(address owner) external view returns (uint);
    function allowance(address owner, address spender) external view returns (uint);

    function approve(address spender, uint value) external returns (bool);
    function transfer(address to, uint value) external returns (bool);
    function transferFrom(address from, address to, uint value) external returns (bool);
}

// SPDX-License-Identifier: GPL-3.0
pragma solidity >=0.5.0;

import './ISCRYERC20.sol';

interface ISCRYERC20Permit is ISCRYERC20 {
    function DOMAIN_SEPARATOR() external view returns (bytes32);
    function PERMIT_TYPEHASH() external pure returns (bytes32);
    function nonces(address owner) external view returns (uint);

    function permit(address owner, address spender, uint value, uint deadline, uint8 v, bytes32 r, bytes32 s) external;
}

// SPDX-License-Identifier: GPL-3.0
pragma solidity >=0.5.0;

interface ISCRYFactory {
    event PairCreated(address indexed token0, address indexed token1, address pair, uint);

    function getPair(address tokenA, address tokenB) external view returns (address pair);
    function allPairs(uint) external view returns (address pair);
    function allPairsLength() external view returns (uint);
    function lpTokens(address) external view returns (bool);

    function createPair(address tokenA, address tokenB) external returns (address pair, address stashTokenA, address stashTokenB);
    function oldMajor() external view returns (address);
    function tokenFactory() external view returns (address);
    function stashETH() external view returns (address);
}

// SPDX-License-Identifier: GPL-3.0
pragma solidity >=0.5.0;

import './ISCRYERC20Permit.sol';

interface ISCRYPair is ISCRYERC20Permit {
    // event Mint(address indexed sender, uint amount0, uint amount1);
    // event Burn(address indexed sender, uint amount0, uint amount1, address indexed to);
    // event Swap(
    //     address indexed sender,
    //     uint amount0In,
    //     uint amount1In,
    //     uint amount0Out,
    //     uint amount1Out,
    //     address indexed to
    // );
    // event Sync(uint128 reserve0, uint128 reserve1);

    function MINIMUM_LIQUIDITY() external pure returns (uint);
    function factory() external view returns (address);
    function token0() external view returns (address);
    function token1() external view returns (address);
    function getReserves() external view returns (uint128 reserve0, uint128 reserve1);

    function mint(address to) external returns (uint liquidity);
    function burn(address to) external returns (uint amount0, uint amount1);
    function burnUnbalanced(address to, uint token0Min, uint token1Min) external returns (uint amount0, uint amount1);
    function burnUnbalancedForExactToken(address to, address exactToken, uint amountExactOut) external returns (uint, uint);
    function swap(uint amount0Out, uint amount1Out, address to, bytes calldata data) external;
    function sync() external;

    function setIsFlashSwapEnabled(bool _isFlashSwapEnabled) external;
    function setFeeToAddresses(address _feeTo0, address _feeTo1) external;
    function setRouter(address _router) external;
    function getBurnFee() external view returns (uint256);
}

// SPDX-License-Identifier: GPL-3.0
pragma solidity >=0.5.0;

interface ISCRYPairTransferable {
    function transferFromPool(address to, uint value) external returns (bool);
    // function balanceOf(address owner) external returns (uint);
}

// SPDX-License-Identifier: GPL-3.0
pragma solidity >=0.6.2;

interface ISCRYRouter {
    function factory() external view returns (address);
    function WETH() external view returns (address);
    function liquidityRouter() external returns (address);

    function createPairAndAddLiquidity(
        address tokenA,
        address tokenB,
        uint amountADesired,
        uint amountBDesired,
        address to,
        uint deadline
    ) external returns (uint, uint, uint);
    function createETHPairAndAddLiquidity(
        address token,
        uint amountTokenDesired,
        address to,
        uint deadline
    ) external payable returns (uint, uint, uint);
    function addLiquidity(
        address tokenA,
        address tokenB,
        uint amountADesired,
        uint amountBDesired,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external returns (uint amountA, uint amountB, uint liquidity);
    function addLiquidityETH(
        address token,
        uint amountTokenDesired,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external payable returns (uint amountToken, uint amountETH, uint liquidity);
    function addUnbalancedLiquidity(
        address tokenA,
        address tokenB,
        uint amountADesired,
        uint amountBDesired,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external returns (uint amountA, uint amountB, uint liquidity);
    function addUnbalancedLiquidityETH(
        address token,
        uint amountTokenDesired,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external payable returns (uint amountToken, uint amountETH, uint liquidity);
    function swapExactTokensForTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);
    function swapTokensForExactTokens(
        uint amountOut,
        uint amountInMax,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);

    function quote(uint amountA, uint reserveA, uint reserveB) external pure returns (uint amountB);
    function getAmountOut(uint amountIn, uint reserveIn, uint reserveOut) external pure returns (uint amountOut);
    function getAmountIn(uint amountOut, uint reserveIn, uint reserveOut) external pure returns (uint amountIn);
    function getAmountsOut(uint amountIn, address[] calldata path) external view returns (uint[] memory amounts);
    function getAmountsIn(uint amountOut, address[] calldata path) external view returns (uint[] memory amounts);
}

// SPDX-License-Identifier: GPL-3.0
import './ISCRYRouter.sol';

pragma solidity >=0.6.2;

interface ISCRYStashRouter is ISCRYRouter{
    function addLiquidityETHWithPermit(
        address token,
        uint amountTokenDesired,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external payable returns (uint amountToken, uint amountETH, uint liquidity);
    function addUnbalancedLiquidityETHWithPermit(
        address token,
        uint amountTokenDesired,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external payable returns (uint amountToken, uint amountETH, uint liquidity);

    function removeLiquidity(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external returns (uint amountA, uint amountB);
    function removeLiquidityWithPermit(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint amountA, uint amountB);
    function removeUnbalancedLiquidity(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAExact,
        uint amountBMin,
        address to,
        uint deadline
    ) external returns (uint, uint);
    function removeUnbalancedLiquidityWithPermit(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAExact,
        uint amountBMin,        
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint, uint);

    function swapExactTokensForTokensWithPermit(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint[] memory amounts);
    function swapTokensForExactTokensWithPermit(
        uint amountOut,
        uint amountInMax,
        address[] calldata path,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint[] memory amounts);
}

// SPDX-License-Identifier: GPL-3.0
pragma solidity >=0.5.0;

import './ISCRYPairTransferable.sol';

interface IStashETH is ISCRYPairTransferable {
    function deposit() external payable returns (uint256);
    function depositFor(address to) external payable returns (bool);
    function withdraw(uint amount) external returns (bool);
    function withdrawTo(address account, uint amount) external returns (bool);
}

pragma solidity >=0.5.0;

interface IWETH {
    function deposit() external payable;
    function transfer(address to, uint value) external returns (bool);
    function withdraw(uint) external;
}

// SPDX-License-Identifier: GPL-3.0
pragma solidity =0.6.12;

import '../core/interfaces/ISCRYERC20Permit.sol';
import '../core/interfaces/ISCRYERC20.sol';
import '../core/interfaces/ISCRYFactory.sol';
import '../core/interfaces/IStashETH.sol';
import '../solidity-lib/libraries/TransferHelper.sol';

import './interfaces/ISCRYRouter.sol';
import './libraries/SCRYLibrary.sol';
import '../core/libraries/SafeMath.sol';

contract LiquidityRouter {
    using SafeMath for uint;

    address public immutable factory;
    address public immutable WETH;

    modifier ensure(uint deadline) {
        require(deadline >= block.timestamp, 'LiquidityRouter: EXPIRED');
        _;
    }

    constructor(address _factory, address _WETH) public {
        factory = _factory;
        WETH = _WETH;
    }

    // **** ADD LIQUIDITY ****
     function createPairAndAddLiquidity(
        address tokenA,
        address tokenB,
        uint amountADesired,
        uint amountBDesired,
        address to,
        uint deadline
    ) public virtual ensure(deadline) returns (uint, uint, uint) {
        (address pair, address stashTokenA, address stashTokenB) = ISCRYFactory(factory).createPair(tokenA, tokenB);
        TransferHelper.safeTransferFrom(stashTokenA, msg.sender, pair, amountADesired);
        TransferHelper.safeTransferFrom(stashTokenB, msg.sender, pair, amountBDesired);
        return (amountADesired, amountBDesired, ISCRYPair(pair).mint(to));
    }
    function createETHPairAndAddLiquidity(
        address token,
        uint amountTokenDesired,
        address to,
        uint deadline
    ) public virtual payable ensure(deadline) returns (uint, uint, uint) {
        (address pair, address stashToken, ) = ISCRYFactory(factory).createPair(token, WETH);
        TransferHelper.safeTransferFrom(stashToken, msg.sender, pair, amountTokenDesired);
        assert(IStashETH(WETH).depositFor{value: msg.value}(pair));

        return (amountTokenDesired, msg.value, ISCRYPair(pair).mint(to));
    }

    function _addLiquidity(
        address tokenA,
        address tokenB,
        uint amountADesired,
        uint amountBDesired,
        uint amountAMin,
        uint amountBMin
    ) internal virtual view returns (uint amountA, uint amountB, address pair) {
        uint reserveA;
        uint reserveB;
        (reserveA, reserveB, pair) = SCRYLibrary.getReserves(factory, tokenA, tokenB);
        if (reserveA == 0 && reserveB == 0) {
            (amountA, amountB) = (amountADesired, amountBDesired);
        } else {
            uint amountBOptimal = SCRYLibrary.quote(amountADesired, reserveA, reserveB);
            if (amountBOptimal <= amountBDesired) {
                // swap A for B
                require(amountBOptimal >= amountBMin, 'LiquidityRouter: INSUFFICIENT_B_AMOUNT');
                (amountA, amountB) = (amountADesired, amountBOptimal);
                require(amountA >= amountAMin, 'LiquidityRouter: INSUFFICIENT_A_AMOUNT');
            } else {
                // swap B for A
                uint amountAOptimal = SCRYLibrary.quote(amountBDesired, reserveB, reserveA);
                assert(amountAOptimal <= amountADesired);
                require(amountAOptimal >= amountAMin, 'LiquidityRouter: INSUFFICIENT_A_AMOUNT');
                (amountA, amountB) = (amountAOptimal, amountBDesired);
                require(amountB >= amountBMin, 'LiquidityRouter: INSUFFICIENT_B_AMOUNT');
            }
        }
    }
    function addLiquidity(
        address tokenA,
        address tokenB,
        uint amountADesired,
        uint amountBDesired,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external virtual ensure(deadline) returns (uint amountA, uint amountB, uint liquidity) {
        address pair;
        (amountA, amountB, pair) = _addLiquidity(tokenA, tokenB, amountADesired, amountBDesired, amountAMin, amountBMin);
        TransferHelper.safeTransferFrom(tokenA, msg.sender, pair, amountA);
        TransferHelper.safeTransferFrom(tokenB, msg.sender, pair, amountB);
        liquidity = ISCRYPair(pair).mint(to);
    }

    function addLiquidityETH(
        address token,
        uint amountTokenDesired,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external virtual payable ensure(deadline) returns (uint amountToken, uint amountETH, uint liquidity) {
        address pair;
        (amountToken, amountETH, pair) = _addLiquidity(
            token,
            WETH,
            amountTokenDesired,
            msg.value,
            amountTokenMin,
            amountETHMin
        );
        TransferHelper.safeTransferFrom(token, msg.sender, pair, amountToken);

        assert(IStashETH(WETH).depositFor{value: amountETH}(pair));
        liquidity = ISCRYPair(pair).mint(to);
        // refund dust eth, if any
        if (msg.value > amountETH) TransferHelper.safeTransferETH(msg.sender, msg.value - amountETH);
    }

    // amountAMin and amountBMin represent minimum amounts if liquidity were withdrawn equally
    function addUnbalancedLiquidity(
        address tokenA,
        address tokenB,
        uint amountADesired,
        uint amountBDesired,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external virtual ensure(deadline) returns (uint amountA, uint amountB, uint liquidity) {
        if (ISCRYFactory(factory).getPair(tokenA, tokenB) == address(0)) {
            ISCRYFactory(factory).createPair(tokenA, tokenB);
        }
        address pair = ISCRYFactory(factory).getPair(tokenA, tokenB);
        TransferHelper.safeTransferFrom(tokenA, msg.sender, pair, amountADesired);
        TransferHelper.safeTransferFrom(tokenB, msg.sender, pair, amountBDesired);
        liquidity = ISCRYPair(pair).mint(to);
        (amountA, amountB) = checkMintedAmount(liquidity, pair, tokenA, tokenB, amountAMin, amountBMin);
    }
    
    // ensure if you burned the liquidity you could get at least amountAMin and amountBMin back
    function checkMintedAmount(uint liquidity, address pair, address tokenA, address tokenB, uint amountAMin, uint amountBMin) private view returns (uint amountA, uint amountB) {
        uint balanceA = ISCRYERC20(tokenA).balanceOf(pair);
        uint balanceB = ISCRYERC20(tokenB).balanceOf(pair);
        uint totalSupply = ISCRYERC20(pair).totalSupply();
        amountA = liquidity.mul(balanceA) / totalSupply; 
        amountB = liquidity.mul(balanceB) / totalSupply;
        require(amountA >= amountAMin, 'LiquidityRouter: INSUFFICIENT_A');
        require(amountB >= amountBMin, 'LiquidityRouter: INSUFFICIENT_B');
    }

    function addUnbalancedLiquidityETH(
        address token,
        uint amountTokenDesired,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external virtual payable ensure(deadline) returns (uint amountToken, uint amountETH, uint liquidity) {
        if (ISCRYFactory(factory).getPair(token, WETH) == address(0)) {
            ISCRYFactory(factory).createPair(token, WETH);
        }
        address pair = ISCRYFactory(factory).getPair(token, WETH);
        TransferHelper.safeTransferFrom(token, msg.sender, pair, amountTokenDesired); 
        assert(IStashETH(WETH).depositFor{value: msg.value}(pair));
        liquidity = ISCRYPair(pair).mint(to);
        (amountToken, amountETH) = checkMintedAmount(liquidity, pair, token, WETH, amountTokenMin, amountETHMin);
    }

    // **** REMOVE LIQUIDITY ****
    function removeLiquidity(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) public virtual ensure(deadline) returns (uint amountA, uint amountB) {
        address pair = SCRYLibrary.pairFor(factory, tokenA, tokenB);
        ISCRYERC20(pair).transferFrom(msg.sender, pair, liquidity); // send liquidity to pair
        (uint amount0, uint amount1) = ISCRYPair(pair).burn(to);
        (address token0,) = SCRYLibrary.sortTokens(tokenA, tokenB);
        (amountA, amountB) = tokenA == token0 ? (amount0, amount1) : (amount1, amount0);
        require(amountA >= amountAMin, 'LiquidityRouter: INSUFFICIENT_A_AMOUNT');
        require(amountB >= amountBMin, 'LiquidityRouter: INSUFFICIENT_B_AMOUNT');
    }
    function removeUnbalancedLiquidity(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAExact,
        uint amountBMin,
        address to,
        uint deadline
    ) public virtual ensure(deadline) returns (uint, uint) {
        address pair = SCRYLibrary.pairFor(factory, tokenA, tokenB);
        ISCRYERC20(pair).transferFrom(msg.sender, pair, liquidity); // send liquidity to pair
        (uint amount0, uint amount1) = ISCRYPair(pair).burnUnbalancedForExactToken(to, tokenA, amountAExact);

        (address token0,) = SCRYLibrary.sortTokens(tokenA, tokenB);
        if (token0 == tokenA) {
            // require(amount0 >= amountAExact, 'LiquidityRouter: INSUFFICIENT_A');
            require(amount1 >= amountBMin, 'LiquidityRouter: INSUFFICIENT_B');
            return (amount0, amount1);
        } else {
            require(amount0 >= amountBMin, 'LiquidityRouter: INSUFFICIENT_B');
            // require(amount1 >= amountAExact, 'LiquidityRouter: INSUFFICIENT_A');
            return (amount1, amount0);
        }
    }
}

// SPDX-License-Identifier: GPL-3.0
pragma solidity >=0.5.0 <0.8.0;

import '../../core/interfaces/ISCRYPair.sol';
import '../../core/interfaces/ISCRYFactory.sol';

import "../../core/libraries/SafeMath.sol";

library SCRYLibrary {
    using SafeMath for uint;

    uint256 private constant MAX_FEE = 10000;

    // returns sorted token addresses, used to handle return values from pairs sorted in this order
    function sortTokens(address tokenA, address tokenB) internal pure returns (address token0, address token1) {
        require(tokenA != tokenB, 'SCRYLibrary: IDENTICAL_ADDRESSES');
        (token0, token1) = tokenA < tokenB ? (tokenA, tokenB) : (tokenB, tokenA);
        require(token0 != address(0), 'SCRYLibrary: ZERO_ADDRESS');
    }

    // calculates the CREATE2 address for a pair without making any external calls
    function pairFor(address factory, address tokenA, address tokenB) internal view returns (address pair) {
        // (address token0, address token1) = sortTokens(tokenA, tokenB);
        // pair = address(uint(keccak256(abi.encodePacked(
        //         hex'ff',
        //         factory,
        //         keccak256(abi.encodePacked(token0, token1)),
        //         hex'7839beac2ac0020a3a02011b7ba701c900dd2c735ec5f5acfcde63d845ce6517' // hardhat
        //         // hex'f2b57fa1700ce1fa58cc33bd5169a52d4fee4581fe629136551e37fe91552963' // init code hash
        //     ))));
        pair = ISCRYFactory(factory).getPair(tokenA, tokenB);
    }

    function getReserves(address factory, address tokenA, address tokenB) internal view returns (uint reserveA, uint reserveB, address pair) {
        (address token0,) = sortTokens(tokenA, tokenB);
        pair = pairFor(factory, tokenA, tokenB);
        (uint reserve0, uint reserve1) = ISCRYPair(pair).getReserves();
        (reserveA, reserveB) = tokenA == token0 ? (reserve0, reserve1) : (reserve1, reserve0);
    }

    // given some amount of an asset and pair reserves, returns an equivalent amount of the other asset
    function quote(uint amountA, uint reserveA, uint reserveB) internal pure returns (uint amountB) {
        require(amountA > 0, 'SCRYLibrary: INSUFFICIENT_AMOUNT');
        require(reserveA > 0 && reserveB > 0, 'SCRYLibrary: INSUFFICIENT_LIQUIDITYQ');
        // amount * price
        amountB = amountA.mul(reserveB) / reserveA;
    }

    // given an input amount of an asset and pair reserves, returns the maximum output amount of the other asset
    function getAmountOut(uint amountIn, uint reserveIn, uint reserveOut) internal pure returns (uint amountOut) {
        require(amountIn > 0, 'SCRYLibrary: INSUFFICIENT_INPUT_AMOUNT');
        require(reserveIn > 0 && reserveOut > 0, 'SCRYLibrary: INSUFFICIENT_LIQUIDITY1');
        uint numerator = amountIn.mul(reserveOut);
        uint denominator = reserveIn.add(amountIn.mul(2));
        amountOut = numerator / denominator;
    }

    // given an output amount of an asset and pair reserves, returns a required input amount of the other asset
    function getAmountIn(uint amountOut, uint reserveIn, uint reserveOut) internal pure returns (uint amountIn) {
        require(amountOut > 0, 'SCRYLibrary: INSUFFICIENT_OUTPUT_AMOUNT');
        require(reserveIn > 0 && reserveOut > 0, 'SCRYLibrary: INSUFFICIENT_LIQUIDITY2');
        uint numerator = reserveIn.mul(amountOut);
        uint denominator = reserveOut.sub(amountOut.mul(2));
        amountIn = (numerator / denominator).add(1);
    }

    // performs chained getAmountOut calculations on any number of pairs
    function getAmountsOut(address factory, uint amountIn, address[] memory path) internal view returns (uint[] memory amounts) {
        require(path.length >= 2, 'SCRYLibrary: INVALID_PATH');
        amounts = new uint[](path.length);
        amounts[0] = amountIn;
        for (uint i; i < path.length - 1; i++) {
            (uint reserveIn, uint reserveOut,) = getReserves(factory, path[i], path[i + 1]);
            amounts[i + 1] = getAmountOut(amounts[i], reserveIn, reserveOut);
        }
    }

    // performs chained getAmountIn calculations on any number of pairs
    function getAmountsIn(address factory, uint amountOut, address[] memory path) internal view returns (uint[] memory amounts) {
        require(path.length >= 2, 'SCRYLibrary: INVALID_PATH');
        amounts = new uint[](path.length);
        amounts[amounts.length - 1] = amountOut;
        for (uint i = path.length - 1; i > 0; i--) {
            (uint reserveIn, uint reserveOut,) = getReserves(factory, path[i - 1], path[i]);
            amounts[i - 1] = getAmountIn(amounts[i], reserveIn, reserveOut);
        }
    }
}

// SPDX-License-Identifier: GPL-3.0
pragma solidity =0.6.12;

import '../core/interfaces/ISCRYERC20Permit.sol';
import '../solidity-lib/libraries/TransferHelper.sol';

import './interfaces/ISCRYStashRouter.sol';
import './interfaces/IWETH.sol';
import './libraries/SCRYLibrary.sol';
import '../core/libraries/SafeMath.sol';
import './LiquidityRouter.sol';

contract SCRYRouter is ISCRYStashRouter {
    using SafeMath for uint;

    address public immutable override factory;
    address public immutable override WETH;
    address public immutable override liquidityRouter;

    modifier ensure(uint deadline) {
        require(deadline >= block.timestamp, 'EXPIRED');
        // EOA only
        require(tx.origin == msg.sender, 'INVALID SENDER');
        _;
    }

    constructor(address _factory) public {
        factory = _factory;
        address _WETH = ISCRYFactory(_factory).stashETH();
        liquidityRouter = address(new LiquidityRouter(_factory, _WETH));
        WETH = _WETH;
    }

    receive() external payable {
        assert(msg.sender == WETH);
    }

    // **** ADD LIQUIDITY ****
    function createPairAndAddLiquidity(
        address tokenA,
        address tokenB,
        uint amountADesired,
        uint amountBDesired,
        address to,
        uint deadline
    ) external virtual override returns (uint, uint, uint) {
        (bool success, bytes memory result) = liquidityRouter.delegatecall(
            abi.encodeWithSelector(LiquidityRouter.createPairAndAddLiquidity.selector, 
            tokenA, tokenB, amountADesired, amountBDesired, to, deadline));
        require(success);
        return abi.decode(result, (uint, uint, uint));
    }

    function createETHPairAndAddLiquidity(
        address token,
        uint amountTokenDesired,
        address to,
        uint deadline
    ) external virtual override payable returns (uint, uint, uint) {
        (bool success, bytes memory result) = liquidityRouter.delegatecall(
            abi.encodeWithSelector(LiquidityRouter.createETHPairAndAddLiquidity.selector, 
            token, amountTokenDesired, to, deadline));
        require(success);
        return abi.decode(result, (uint, uint, uint));
    }

    function addLiquidity(
        address tokenA,
        address tokenB,
        uint amountADesired,
        uint amountBDesired,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external virtual override returns (uint amountA, uint amountB, uint liquidity) {
        (bool success, bytes memory result) = liquidityRouter.delegatecall(
            abi.encodeWithSelector(LiquidityRouter.addLiquidity.selector, 
            tokenA, tokenB, amountADesired, amountBDesired, amountAMin, amountBMin, to, deadline));
        require(success);
        return abi.decode(result, (uint, uint, uint));
    }
    function addUnbalancedLiquidity(
        address tokenA,
        address tokenB,
        uint amountADesired,
        uint amountBDesired,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external virtual override returns (uint amountA, uint amountB, uint liquidity) {
        (bool success, bytes memory result) = liquidityRouter.delegatecall(
            abi.encodeWithSelector(LiquidityRouter.addUnbalancedLiquidity.selector, 
            tokenA, tokenB, amountADesired, amountBDesired, amountAMin, amountBMin, to, deadline));
        require(success);
        return abi.decode(result, (uint, uint, uint));
    }
    function addLiquidityETH(
        address token,
        uint amountTokenDesired,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) public virtual override payable returns (uint amountToken, uint amountETH, uint liquidity) {
        (bool success, bytes memory result) = liquidityRouter.delegatecall(
            abi.encodeWithSelector(LiquidityRouter.addLiquidityETH.selector, 
            token, amountTokenDesired, amountTokenMin, amountETHMin, to, deadline));
        require(success);
        return abi.decode(result, (uint, uint, uint));
    }
    function addLiquidityETHWithPermit(
        address token,
        uint amountTokenDesired,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external virtual override payable returns (uint amountToken, uint amountETH, uint liquidity) {
      _permit(token, amountTokenDesired, deadline, approveMax, v, r, s);
      return addLiquidityETH(token, amountTokenDesired, amountTokenMin, amountETHMin, to, deadline);
    }

    function addUnbalancedLiquidityETH(
        address token,
        uint amountTokenDesired,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) public virtual override payable returns (uint amountToken, uint amountETH, uint liquidity) {
        (bool success, bytes memory result) = liquidityRouter.delegatecall(
            abi.encodeWithSelector(LiquidityRouter.addUnbalancedLiquidityETH.selector, 
            token, amountTokenDesired, amountTokenMin, amountETHMin, to, deadline));
        require(success);
        return abi.decode(result, (uint, uint, uint));
    }

    function addUnbalancedLiquidityETHWithPermit(
        address token,
        uint amountTokenDesired,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external virtual override payable returns (uint amountToken, uint amountETH, uint liquidity) {
      _permit(token, amountTokenDesired, deadline, approveMax, v, r, s);
      return addUnbalancedLiquidityETH(token, amountTokenDesired, amountTokenMin, amountETHMin, to, deadline);
    }

    // **** REMOVE LIQUIDITY ****
    function removeLiquidity(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) public virtual override returns (uint amountA, uint amountB) {
        (bool success, bytes memory result) = liquidityRouter.delegatecall(
            abi.encodeWithSelector(LiquidityRouter.removeLiquidity.selector, 
            tokenA, tokenB, liquidity, amountAMin, amountBMin, to, deadline));
        require(success);
        return abi.decode(result, (uint, uint));
    } 
    function removeLiquidityWithPermit(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external virtual override returns (uint, uint) {
        _permit(SCRYLibrary.pairFor(factory, tokenA, tokenB), liquidity, deadline, approveMax, v, r, s);
        return removeLiquidity(tokenA, tokenB, liquidity, amountAMin, amountBMin, to, deadline);
    }
    function removeUnbalancedLiquidity(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAExact,
        uint amountBMin,
        address to,
        uint deadline
    ) public virtual override returns (uint, uint) {
        (bool success, bytes memory result) = liquidityRouter.delegatecall(
            abi.encodeWithSelector(LiquidityRouter.removeUnbalancedLiquidity.selector, 
            tokenA, tokenB, liquidity, amountAExact, amountBMin, to, deadline));
        require(success);
        return abi.decode(result, (uint, uint));
    }
    function removeUnbalancedLiquidityWithPermit(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAExact,
        uint amountBMin,       
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external virtual override returns (uint, uint) {
        _permit(SCRYLibrary.pairFor(factory, tokenA, tokenB), liquidity, deadline, approveMax, v, r, s);
        return removeUnbalancedLiquidity(tokenA, tokenB, liquidity, amountAExact, amountBMin, to, deadline);
    }
    function _permit(
        address token, uint amount, uint deadline, 
        bool approveMax, uint8 v, bytes32 r, bytes32 s) internal {
        ISCRYERC20Permit(token)
            .permit(msg.sender, address(this), approveMax ? uint(-1) : amount, deadline, v, r, s);
    }

    // **** SWAP ****
    function _swap(uint[] memory amounts, address[] memory path, address _to) internal virtual {
        for (uint i; i < path.length - 1; i++) {
            (address input, address output) = (path[i], path[i + 1]);
            (address token0,) = SCRYLibrary.sortTokens(input, output);
            uint amountOut = amounts[i + 1];
            (uint amount0Out, uint amount1Out) = input == token0 ? (uint(0), amountOut) : (amountOut, uint(0));
            address to = i < path.length - 2 ? SCRYLibrary.pairFor(factory, output, path[i + 2]) : _to;
            ISCRYPair(SCRYLibrary.pairFor(factory, input, output)).swap(
                amount0Out, amount1Out, to, new bytes(0)
            );
        }
    }
    function swapExactTokensForTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) public virtual override ensure(deadline) returns (uint[] memory amounts) {
        amounts = SCRYLibrary.getAmountsOut(factory, amountIn, path);
        require(amounts[amounts.length - 1] >= amountOutMin, 'OUTPUT');
        TransferHelper.safeTransferFrom(
            path[0], msg.sender, SCRYLibrary.pairFor(factory, path[0], path[1]), amounts[0]
        );
        _swap(amounts, path, to);
    }
    function swapTokensForExactTokens(
        uint amountOut,
        uint amountInMax,
        address[] calldata path,
        address to,
        uint deadline
    ) public virtual override ensure(deadline) returns (uint[] memory amounts) {
        amounts = SCRYLibrary.getAmountsIn(factory, amountOut, path);
        require(amounts[0] <= amountInMax, 'INPUT');
        TransferHelper.safeTransferFrom(
            path[0], msg.sender, SCRYLibrary.pairFor(factory, path[0], path[1]), amounts[0]
        );
        _swap(amounts, path, to);
    }

    // **** SWAP (supporting fee-on-transfer tokens) ****
    // stashed tokens are not feeOnTransfer so not required

    function swapExactTokensForTokensWithPermit(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) public virtual override ensure(deadline) returns (uint[] memory amounts) {
        _permit(path[0], amountIn, deadline, approveMax, v, r, s);
        return swapExactTokensForTokens(amountIn, amountOutMin, path, to, deadline);
    }
    function swapTokensForExactTokensWithPermit(
        uint amountOut,
        uint amountInMax,
        address[] calldata path,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) public virtual override ensure(deadline) returns (uint[] memory amounts) {
        _permit(path[0], amountInMax, deadline, approveMax, v, r, s);
        return swapTokensForExactTokens(amountOut, amountInMax, path, to, deadline);
    }

    // **** LIBRARY FUNCTIONS ****
    function quote(uint amountA, uint reserveA, uint reserveB) external pure virtual override returns (uint amountB) {
        return SCRYLibrary.quote(amountA, reserveA, reserveB);
    }
    function getAmountOut(uint amountIn, uint reserveIn, uint reserveOut)
        external
        pure
        virtual
        override
        returns (uint amountOut)
    {
        return SCRYLibrary.getAmountOut(amountIn, reserveIn, reserveOut);
    }
    function getAmountIn(uint amountOut, uint reserveIn, uint reserveOut)
        external
        pure
        virtual
        override
        returns (uint amountIn)
    {
        return SCRYLibrary.getAmountIn(amountOut, reserveIn, reserveOut);
    }
    function getAmountsOut(uint amountIn, address[] calldata path)
        external
        view
        virtual
        override
        returns (uint[] memory amounts)
    {
        return SCRYLibrary.getAmountsOut(factory, amountIn, path);
    }
    function getAmountsIn(uint amountOut, address[] calldata path)
        external
        view
        virtual
        override
        returns (uint[] memory amounts)
    {
        return SCRYLibrary.getAmountsIn(factory, amountOut, path);
    }
}

pragma solidity >=0.5.0;

// a library for performing overflow-safe math, courtesy of DappHub (https://github.com/dapphub/ds-math)

library SafeMath {
    function add(uint x, uint y) internal pure returns (uint z) {
        require((z = x + y) >= x, 'ds-math-add-overflow');
    }

    function sub(uint x, uint y) internal pure returns (uint z) {
        require((z = x - y) <= x, 'ds-math-sub-underflow');
    }

    function mul(uint x, uint y) internal pure returns (uint z) {
        require(y == 0 || (z = x * y) / y == x, 'ds-math-mul-overflow');
    }
}

// SPDX-License-Identifier: GPL-3.0-or-later

pragma solidity >=0.6.0;

// helper methods for interacting with ERC20 tokens and sending ETH that do not consistently return true/false
library TransferHelper {
    function safeApprove(
        address token,
        address to,
        uint256 value
    ) internal {
        // bytes4(keccak256(bytes('approve(address,uint256)')));
        (bool success, bytes memory data) = token.call(abi.encodeWithSelector(0x095ea7b3, to, value));
        require(
            success && (data.length == 0 || abi.decode(data, (bool))),
            'TransferHelper::safeApprove: approve failed'
        );
    }

    function safeTransfer(
        address token,
        address to,
        uint256 value
    ) internal {
        // bytes4(keccak256(bytes('transfer(address,uint256)')));
        (bool success, bytes memory data) = token.call(abi.encodeWithSelector(0xa9059cbb, to, value));
        require(
            success && (data.length == 0 || abi.decode(data, (bool))),
            'TransferHelper::safeTransfer: transfer failed'
        );
    }

    function safeTransferFrom(
        address token,
        address from,
        address to,
        uint256 value
    ) internal {
        // bytes4(keccak256(bytes('transferFrom(address,address,uint256)')));
        (bool success, bytes memory data) = token.call(abi.encodeWithSelector(0x23b872dd, from, to, value));
        require(
            success && (data.length == 0 || abi.decode(data, (bool))),
            'TransferHelper::transferFrom: transferFrom failed'
        );
    }

    function safeTransferETH(address to, uint256 value) internal {
        (bool success, ) = to.call{value: value}(new bytes(0));
        require(success, 'TransferHelper::safeTransferETH: ETH transfer failed');
    }
}

{
  "compilationTarget": {
    "contracts/periphery/SCRYRouter.sol": "SCRYRouter"
  },
  "evmVersion": "istanbul",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 999999
  },
  "remappings": []
}