// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/AccessControl.sol)

pragma solidity ^0.8.20;

import {IAccessControl} from "./IAccessControl.sol";
import {Context} from "../utils/Context.sol";
import {ERC165} from "../utils/introspection/ERC165.sol";

/**
 * @dev Contract module that allows children to implement role-based access
 * control mechanisms. This is a lightweight version that doesn't allow enumerating role
 * members except through off-chain means by accessing the contract event logs. Some
 * applications may benefit from on-chain enumerability, for those cases see
 * {AccessControlEnumerable}.
 *
 * Roles are referred to by their `bytes32` identifier. These should be exposed
 * in the external API and be unique. The best way to achieve this is by
 * using `public constant` hash digests:
 *
 * ```solidity
 * bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
 * ```
 *
 * Roles can be used to represent a set of permissions. To restrict access to a
 * function call, use {hasRole}:
 *
 * ```solidity
 * function foo() public {
 *     require(hasRole(MY_ROLE, msg.sender));
 *     ...
 * }
 * ```
 *
 * Roles can be granted and revoked dynamically via the {grantRole} and
 * {revokeRole} functions. Each role has an associated admin role, and only
 * accounts that have a role's admin role can call {grantRole} and {revokeRole}.
 *
 * By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
 * that only accounts with this role will be able to grant or revoke other
 * roles. More complex role relationships can be created by using
 * {_setRoleAdmin}.
 *
 * WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
 * grant and revoke this role. Extra precautions should be taken to secure
 * accounts that have been granted it. We recommend using {AccessControlDefaultAdminRules}
 * to enforce additional security measures for this role.
 */
abstract contract AccessControl is Context, IAccessControl, ERC165 {
    struct RoleData {
        mapping(address account => bool) hasRole;
        bytes32 adminRole;
    }

    mapping(bytes32 role => RoleData) private _roles;

    bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;

    /**
     * @dev Modifier that checks that an account has a specific role. Reverts
     * with an {AccessControlUnauthorizedAccount} error including the required role.
     */
    modifier onlyRole(bytes32 role) {
        _checkRole(role);
        _;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IAccessControl).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) public view virtual returns (bool) {
        return _roles[role].hasRole[account];
    }

    /**
     * @dev Reverts with an {AccessControlUnauthorizedAccount} error if `_msgSender()`
     * is missing `role`. Overriding this function changes the behavior of the {onlyRole} modifier.
     */
    function _checkRole(bytes32 role) internal view virtual {
        _checkRole(role, _msgSender());
    }

    /**
     * @dev Reverts with an {AccessControlUnauthorizedAccount} error if `account`
     * is missing `role`.
     */
    function _checkRole(bytes32 role, address account) internal view virtual {
        if (!hasRole(role, account)) {
            revert AccessControlUnauthorizedAccount(account, role);
        }
    }

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) public view virtual returns (bytes32) {
        return _roles[role].adminRole;
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleGranted} event.
     */
    function grantRole(bytes32 role, address account) public virtual onlyRole(getRoleAdmin(role)) {
        _grantRole(role, account);
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleRevoked} event.
     */
    function revokeRole(bytes32 role, address account) public virtual onlyRole(getRoleAdmin(role)) {
        _revokeRole(role, account);
    }

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been revoked `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `callerConfirmation`.
     *
     * May emit a {RoleRevoked} event.
     */
    function renounceRole(bytes32 role, address callerConfirmation) public virtual {
        if (callerConfirmation != _msgSender()) {
            revert AccessControlBadConfirmation();
        }

        _revokeRole(role, callerConfirmation);
    }

    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.
     */
    function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
        bytes32 previousAdminRole = getRoleAdmin(role);
        _roles[role].adminRole = adminRole;
        emit RoleAdminChanged(role, previousAdminRole, adminRole);
    }

    /**
     * @dev Attempts to grant `role` to `account` and returns a boolean indicating if `role` was granted.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleGranted} event.
     */
    function _grantRole(bytes32 role, address account) internal virtual returns (bool) {
        if (!hasRole(role, account)) {
            _roles[role].hasRole[account] = true;
            emit RoleGranted(role, account, _msgSender());
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Attempts to revoke `role` to `account` and returns a boolean indicating if `role` was revoked.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleRevoked} event.
     */
    function _revokeRole(bytes32 role, address account) internal virtual returns (bool) {
        if (hasRole(role, account)) {
            _roles[role].hasRole[account] = false;
            emit RoleRevoked(role, account, _msgSender());
            return true;
        } else {
            return false;
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/introspection/ERC165.sol)

pragma solidity ^0.8.20;

import {IERC165} from "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC-165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (access/IAccessControl.sol)

pragma solidity ^0.8.20;

/**
 * @dev External interface of AccessControl declared to support ERC-165 detection.
 */
interface IAccessControl {
    /**
     * @dev The `account` is missing a role.
     */
    error AccessControlUnauthorizedAccount(address account, bytes32 neededRole);

    /**
     * @dev The caller of a function is not the expected one.
     *
     * NOTE: Don't confuse with {AccessControlUnauthorizedAccount}.
     */
    error AccessControlBadConfirmation();

    /**
     * @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
     *
     * `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
     * {RoleAdminChanged} not being emitted signaling this.
     */
    event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);

    /**
     * @dev Emitted when `account` is granted `role`.
     *
     * `sender` is the account that originated the contract call. This account bears the admin role (for the granted role).
     * Expected in cases where the role was granted using the internal {AccessControl-_grantRole}.
     */
    event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Emitted when `account` is revoked `role`.
     *
     * `sender` is the account that originated the contract call:
     *   - if using `revokeRole`, it is the admin role bearer
     *   - if using `renounceRole`, it is the role bearer (i.e. `account`)
     */
    event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) external view returns (bool);

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {AccessControl-_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) external view returns (bytes32);

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function grantRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function revokeRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been granted `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `callerConfirmation`.
     */
    function renounceRole(bytes32 role, address callerConfirmation) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (interfaces/IERC1363.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC165} from "./IERC165.sol";

/**
 * @title IERC1363
 * @dev Interface of the ERC-1363 standard as defined in the https://eips.ethereum.org/EIPS/eip-1363[ERC-1363].
 *
 * Defines an extension interface for ERC-20 tokens that supports executing code on a recipient contract
 * after `transfer` or `transferFrom`, or code on a spender contract after `approve`, in a single transaction.
 */
interface IERC1363 is IERC20, IERC165 {
    /*
     * Note: the ERC-165 identifier for this interface is 0xb0202a11.
     * 0xb0202a11 ===
     *   bytes4(keccak256('transferAndCall(address,uint256)')) ^
     *   bytes4(keccak256('transferAndCall(address,uint256,bytes)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256,bytes)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256,bytes)'))
     */

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @param data Additional data with no specified format, sent in call to `spender`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value, bytes calldata data) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC165.sol)

pragma solidity ^0.8.20;

import {IERC165} from "../utils/introspection/IERC165.sol";

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../token/ERC20/IERC20.sol";

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import "@openzeppelin/contracts/access/AccessControl.sol";
import "./WODS_Market.sol";
import "./TokenLocking.sol";

contract Market_Factory is AccessControl {
    address public _platformAddress;
    uint256 public _platformFee;
    uint256 public _creatorFee;

    // mapping of user address - prediction market address
    mapping(address user => address[] markets) private _userPredictions;

    // All Prediction markets deployed
    address[] private _predictions;
    // count of prediction markets
    uint256 public predictionCount;
    bytes32 private constant _MARKET_CREATOR_ROLE = keccak256("MARKET_CREATOR_ROLE");

    // Token Locking Specifications
    TokenLocking private _tokenLockingContract;
    uint256 public lockAmount; // Amount required to lock for market creation

    event MarketDeployed(address tokenAddress);
    event PlatformDetailsUpdated(address platformAddress, uint256 platformFee);
    event UserPredictionsUpdated(address user, address[] markets);

    error InvalidDescription(string error);
    error InvalidOutcomes(string error);
    error InvalidAmount(string error);
    error InvalidResolveTime(string error);

    constructor(
        address platformAddress,
        uint256 platformFee,
        uint256 creatorFee,
        address tokenLockingAddress,
        uint256 requiredLockAmount
    ) {
        _platformAddress = platformAddress;
        _platformFee = platformFee;
        _creatorFee = creatorFee;
        _tokenLockingContract = TokenLocking(tokenLockingAddress);
        lockAmount = requiredLockAmount;

        _grantRole(DEFAULT_ADMIN_ROLE, msg.sender);
        _grantRole(_MARKET_CREATOR_ROLE, msg.sender);
    }

    modifier _checkMarketParams(
        string memory _description,
        string[] memory _outcomes,
        uint256 _endTimestamp,
        uint256 _minPrice,
        uint256 _maxPrice
    ) {
        if (bytes(_description).length == 0) {
            revert InvalidDescription("EMPTY_DESCRIPTION");
        }

        if (_minPrice > _maxPrice) {
            revert InvalidAmount("MIN_PRICE_IS_HIGH");
        }

        if (_outcomes.length < 2) {
            revert InvalidOutcomes("MIN_2_OUTCOMES");
        }

        if (_endTimestamp <= block.timestamp) {
            revert InvalidResolveTime("NOT_FUTURE_RESOLVE_TIME");
        }
        _;
    }

    function deployMarket(
        address _tokenAddress,
        string memory _description,
        string[] memory _outcomes,
        uint256 _tokenDecimals,
        uint256 _endTimestamp,
        uint256 _minPrice,
        uint256 _maxPrice
    )
        public
        onlyRole(_MARKET_CREATOR_ROLE)
        _checkMarketParams(_description, _outcomes, _endTimestamp, _minPrice, _maxPrice)
        returns (address)
    {
        // Deploy the market
        WODS_Market prediction = new WODS_Market(
            _tokenAddress,
            _platformAddress,
            msg.sender, // Market creator
            _description,
            _outcomes,
            _tokenDecimals,
            _endTimestamp,
            _minPrice,
            _maxPrice,
            _platformFee,
            _creatorFee
        );

        // Lock tokens for this specific market after deployment
        _tokenLockingContract.lockTokens(address(prediction), lockAmount, msg.sender);

        // Update the states
        _predictions.push(address(prediction));
        _userPredictions[msg.sender].push(address(prediction));
        predictionCount++;
        emit UserPredictionsUpdated(msg.sender, _userPredictions[msg.sender]);
        emit MarketDeployed(address(prediction));
        return address(prediction);
    }

    function getAllMarkets() public view returns (address[] memory) {
        return _predictions;
    }

    function getAllUserMarkets(address _account) public view returns (address[] memory) {
        return _userPredictions[_account];
    }

    function grantMarketCreatorRole(address _account) public onlyRole(DEFAULT_ADMIN_ROLE) {
        grantRole(_MARKET_CREATOR_ROLE, _account);
    }

    function revokeMarketCreatorRole(address _account) public onlyRole(DEFAULT_ADMIN_ROLE) {
        revokeRole(_MARKET_CREATOR_ROLE, _account);
    }

    function getPlatformDetails() external view onlyRole(_MARKET_CREATOR_ROLE) returns (address, uint256) {
        return (_platformAddress, _platformFee);
    }

    function updateCreatorFee(uint256 _fee) public onlyRole(DEFAULT_ADMIN_ROLE) {
        _creatorFee = _fee;
        emit PlatformDetailsUpdated(_platformAddress, _creatorFee); // Reuse event or create a new one
    }

    function setLockAmount(uint256 amount) external onlyRole(DEFAULT_ADMIN_ROLE) {
        lockAmount = amount;
    }

    // Add this function to Market_Factory

    function MARKET_CREATOR_ROLE() public pure returns (bytes32) {
        return keccak256("MARKET_CREATOR_ROLE");
    }

    function updatePlatformDetails(address _address, uint256 _fee) public onlyRole(DEFAULT_ADMIN_ROLE) {
        _platformAddress = _address;
        _platformFee = _fee;

        emit PlatformDetailsUpdated(_platformAddress, _platformFee);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If EIP-1153 (transient storage) is available on the chain you're deploying at,
 * consider using {ReentrancyGuardTransient} instead.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.2.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC1363} from "../../../interfaces/IERC1363.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC-20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    /**
     * @dev An operation with an ERC-20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     *
     * NOTE: If the token implements ERC-7674, this function will not modify any temporary allowance. This function
     * only sets the "standard" allowance. Any temporary allowance will remain active, in addition to the value being
     * set here.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Performs an {ERC1363} transferAndCall, with a fallback to the simple {ERC20} transfer if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            safeTransfer(token, to, value);
        } else if (!token.transferAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} transferFromAndCall, with a fallback to the simple {ERC20} transferFrom if the target
     * has no code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferFromAndCallRelaxed(
        IERC1363 token,
        address from,
        address to,
        uint256 value,
        bytes memory data
    ) internal {
        if (to.code.length == 0) {
            safeTransferFrom(token, from, to, value);
        } else if (!token.transferFromAndCall(from, to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} approveAndCall, with a fallback to the simple {ERC20} approve if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * NOTE: When the recipient address (`to`) has no code (i.e. is an EOA), this function behaves as {forceApprove}.
     * Opposedly, when the recipient address (`to`) has code, this function only attempts to call {ERC1363-approveAndCall}
     * once without retrying, and relies on the returned value to be true.
     *
     * Reverts if the returned value is other than `true`.
     */
    function approveAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            forceApprove(token, to, value);
        } else if (!token.approveAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturnBool} that reverts if call fails to meet the requirements.
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            let success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            // bubble errors
            if iszero(success) {
                let ptr := mload(0x40)
                returndatacopy(ptr, 0, returndatasize())
                revert(ptr, returndatasize())
            }
            returnSize := returndatasize()
            returnValue := mload(0)
        }

        if (returnSize == 0 ? address(token).code.length == 0 : returnValue != 1) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silently catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        bool success;
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            returnSize := returndatasize()
            returnValue := mload(0)
        }
        return success && (returnSize == 0 ? address(token).code.length > 0 : returnValue == 1);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "./WODS_Market.sol";

contract TokenLocking {
    using SafeERC20 for IERC20;

    IERC20 private immutable _lockToken;

    struct Lock {
        uint256 amount;
        address creator;
        bool claimed;
    }

    mapping(address market => Lock lock) private _locks;

    event TokensLocked(address indexed market, address indexed creator, uint256 amount);
    event TokensUnlocked(address indexed market, address indexed creator, uint256 amount);

    constructor(address tokenAddress) {
        _lockToken = IERC20(tokenAddress);
    }

    function lockTokens(address market, uint256 amount, address creator) external {
        require(_locks[market].amount == 0, "Tokens already locked for this market");
        require(amount > 0, "Amount must be greater than zero");

        _locks[market] = Lock(amount, creator, false);

        _lockToken.safeTransferFrom(creator, address(this), amount);
        emit TokensLocked(market, creator, amount);
    }

    function unlockTokens(address market) external {
        // Check if the market is resolved
        WODS_Market wodsMarket = WODS_Market(market);
        require(wodsMarket.isResolved(), "Market is not resolved yet");

        // Fetch lock details
        Lock storage lock = _locks[market];
        require(lock.amount > 0, "No tokens locked for this market");
        require(!lock.claimed, "Tokens already claimed");
        require(msg.sender == lock.creator, "Only creator can unlock tokens");

        // Unlock the funds
        lock.claimed = true;
        _lockToken.safeTransfer(lock.creator, lock.amount);

        emit TokensUnlocked(market, lock.creator, lock.amount);
    }

    function getLockedTokens(address market) external view returns (uint256) {
        return _locks[market].amount;
    }

    function isClaimed(address market) external view returns (bool) {
        return _locks[market].claimed;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/access/Ownable.sol";

contract WODS_Market is Ownable, ReentrancyGuard {
    using SafeERC20 for IERC20;

    IERC20 private _rewardToken;
    address private _platformAddress;
    address private _creatorAddress;
    uint256 private _platformFee;
    uint256 private _creatorFee;

    struct Market {
        address admin;
        address tokenAddress;
        string description;
        uint256 tokenDecimals;
        uint256 minPrice;
        uint256 maxPrice;
        uint256 fee;
        uint256 totalRewards;
        uint256 totalBets;
        uint256 totalSponsors;
        uint256 endTimestamp;
        uint256 outcomes;
        uint256 finalOutcome;
        bool resolved;
        bool cancelled;
    }

    struct Outcome {
        string name;
        // total Bet amount
        uint256 totalAmount;
        // total Bet count
        uint256 totalBets;
        address[] users;
    }

    Market public market;
    mapping(uint256 index => Outcome outcome) public outcomes;
    mapping(uint256 index => address sponsor) public sponsors;

    mapping(address user => uint256 amount) public userWithdrawals;
    // Track user participation; 0 (default value) - not participated
    mapping(address user => uint256 outcome) public userBets;
    // user addresses - Bet Amount
    mapping(address user => uint256 amount) public userAmounts;
    // Sponsor addresses - Amount sponsored
    mapping(address sponsor => uint256 amount) public sponsorAmounts;

    event BetPlaced(address indexed bettor, uint256 outcome, uint256 amount);
    event MarketUpdated();
    event MarketCancelled();
    event MarketResolved(uint256 outcome);
    event RewardsAmplified(address indexed sponsor, uint256 amount);
    event WinningsWithdrawn(address indexed user, uint256 amount);
    event FundsWithdrawn(address indexed user, uint256 amount);
    event PlatformDetailsUpdated(address platformAddress, uint256 platformFee);

    error InvalidAmount(string error);
    error InvalidMarketState(string error);
    error InvalidAllowance(uint256 amount);
    error InvalidOutcome(uint256 outcome);
    error InvalidUserAction(string error);

    modifier marketNotResolved() {
        if (market.resolved || market.endTimestamp <= block.timestamp) {
            revert InvalidMarketState("MARKET_RESOLVED");
        }
        _;
    }

    modifier marketNotCancelled() {
        if (market.cancelled) {
            revert InvalidMarketState("MARKET_CANCELLED");
        }
        _;
    }

    modifier marketResolved() {
        if (!market.resolved || market.endTimestamp > block.timestamp) {
            revert InvalidMarketState("MARKET_NOT_RESOLVED");
        }
        _;
    }

    modifier onlyParticipants(address _address) {
        if (userBets[_address] == 0) {
            revert InvalidUserAction("NOT_VALID_PARTICIPANT");
        }
        _;
    }

    modifier notAParticipant() {
        if (userBets[msg.sender] > 0) {
            revert InvalidUserAction("VALID_PARTICIPANT");
        }
        _;
    }

    modifier notWithdrawn() {
        if (userWithdrawals[msg.sender] != 0) {
            revert InvalidUserAction("NO_PENDING_REWARDS");
        }
        _;
    }

    modifier hasAllowance(uint256 _amount) {
        if (_rewardToken.allowance(msg.sender, address(this)) < _amount) {
            revert InvalidAllowance(_amount);
        }
        _;
    }

    constructor(
        address _tokenAddress,
        address _pAddress,
        address _marketCreator,
        string memory _description,
        string[] memory _marketOutcomes,
        uint256 _tokenDecimals,
        uint256 _endTimestamp,
        uint256 _minPrice,
        uint256 _maxPrice,
        uint256 platformFee_,
        uint256 creatorFee_
    ) Ownable(_marketCreator) {
        _rewardToken = IERC20(_tokenAddress);
        _platformAddress = _pAddress;
        _creatorAddress = _marketCreator;
        _platformFee = platformFee_;
        _creatorFee = creatorFee_;

        // Initialize market details
        market.admin = _marketCreator;
        market.description = _description;
        market.fee = 0;
        market.minPrice = _minPrice;
        market.maxPrice = _maxPrice;
        market.totalBets = 0;
        market.totalSponsors = 0;
        market.endTimestamp = _endTimestamp;
        market.resolved = false;
        market.cancelled = false;
        market.outcomes = _marketOutcomes.length;
        market.tokenAddress = _tokenAddress;
        market.tokenDecimals = _tokenDecimals;

        for (uint256 i = 0; i < _marketOutcomes.length; i++) {
            Outcome storage outcome = outcomes[i];
            outcome.name = _marketOutcomes[i];
            outcome.totalBets = 0;
            outcome.totalAmount = 0;
        }
    }

    function participate(uint256 _outcome, uint256 _amount)
        external
        notAParticipant
        marketNotResolved
        marketNotCancelled
        hasAllowance(_amount)
    {
        if (_amount < market.minPrice) {
            revert InvalidAmount("LESS_PRICE");
        }

        if (_amount > market.maxPrice) {
            revert InvalidAmount("MORE_PRICE");
        }

        if (market.outcomes <= _outcome) {
            revert InvalidOutcome(_outcome);
        }

        Outcome storage extOutcome = outcomes[_outcome];
        extOutcome.totalBets++;
        extOutcome.totalAmount += _amount;
        extOutcome.users.push(msg.sender);
        userBets[msg.sender] = _outcome + 1;
        userAmounts[msg.sender] = _amount;

        market.totalBets++;
        market.totalRewards += _amount;

        _rewardToken.safeTransferFrom(msg.sender, address(this), _amount);

        emit BetPlaced(msg.sender, _outcome, _amount);
    }

    function getParticipants(uint256 outcome) external view returns (address[] memory) {
        return outcomes[outcome].users;
    }

    function updateMarket(string memory _description, uint256 _endTimestamp, uint256 _minPrice, uint256 _maxPrice)
        external
        onlyOwner
        marketNotCancelled
    {
        if (market.resolved) {
            revert InvalidMarketState("MARKET_RESOLVED");
        }

        market.description = _description;
        market.endTimestamp = _endTimestamp;
        market.minPrice = _minPrice;
        market.maxPrice = _maxPrice;

        emit MarketUpdated();
    }

    function cancelMarket() external onlyOwner nonReentrant marketNotCancelled {
        if (market.resolved) {
            revert InvalidMarketState("MARKET_RESOLVED");
        }

        market.cancelled = true;
        market.endTimestamp = block.timestamp;

        // Transfer back Participants amounts
        for (uint256 index = 0; index < market.outcomes; index++) {
            Outcome memory outcome = outcomes[index];
            for (uint256 uIndex = 0; uIndex < outcome.totalBets; uIndex++) {
                _rewardToken.safeTransfer(outcome.users[uIndex], userAmounts[outcome.users[uIndex]]);
            }
        }

        // Trasfer back Sponsors amount
        for (uint256 index = 0; index < market.totalSponsors; index++) {
            address sponsor = sponsors[index];
            uint256 amount = sponsorAmounts[sponsor];
            if (getContractBalance() >= amount) {
                _rewardToken.safeTransfer(sponsor, amount);
            }
        }

        emit MarketCancelled();
    }

    function resolveMarket(uint256 _outcome) external onlyOwner marketNotCancelled {
        require(!market.resolved, "Market already resolved");
        require(_outcome < market.outcomes, "Invalid outcome");
        require(block.timestamp > market.endTimestamp, "Market need to End First ");

        market.resolved = true;
        market.endTimestamp = block.timestamp;
        market.finalOutcome = _outcome;

        // Calculate fees
        uint256 platformFeeAmount = (market.totalRewards * _platformFee) / 10000;
        uint256 creatorFeeAmount = (market.totalRewards * _creatorFee) / 10000;

        // Update rewards pool
        market.fee = platformFeeAmount + creatorFeeAmount;
        market.totalRewards -= market.fee;

        // Transfer fees
        _rewardToken.safeTransfer(_platformAddress, platformFeeAmount);
        _rewardToken.safeTransfer(_creatorAddress, creatorFeeAmount);

        emit MarketResolved(_outcome);
    }

    function withdrawWinnings() external onlyParticipants(msg.sender) marketResolved notWithdrawn {
        uint256 userBet = userBets[msg.sender];
        if (market.finalOutcome + 1 != userBet) {
            revert InvalidUserAction("NOT_A_WINNER");
        }

        uint256 winnings = calculateWinnings(msg.sender);
        if (winnings == 0) {
            revert InvalidAmount("ZERO_WINNINGS_AMOUNT");
        }

        userWithdrawals[msg.sender] = winnings;

        _rewardToken.safeTransfer(msg.sender, winnings);
        emit WinningsWithdrawn(msg.sender, winnings);
    }

    function calculateWinnings(address userAddress)
        public
        view
        onlyParticipants(userAddress)
        marketResolved
        returns (uint256)
    {
        uint256 outcomeAmount = outcomes[market.finalOutcome].totalAmount;
        if (outcomeAmount == 0) {
            revert InvalidAmount("ZERO_OUTCOME_AMOUNT");
        }

        uint256 multiplier = uint256(10) ** market.tokenDecimals;
        uint256 winPercentage = (userAmounts[userAddress] * multiplier) / outcomeAmount;

        uint256 winnings = (market.totalRewards * winPercentage) / multiplier;
        return winnings;
    }

    function retrieveFunds() external onlyOwner {
        uint256 total_funds = getContractBalance();
        _rewardToken.safeTransfer(msg.sender, total_funds);

        emit FundsWithdrawn(owner(), total_funds);
    }

    function amplifyRewards(uint256 _amount)
        external
        marketNotResolved
        marketNotCancelled
        hasAllowance(_amount)
        returns (uint256)
    {
        market.totalRewards += _amount;

        if (sponsorAmounts[msg.sender] == 0) {
            sponsors[market.totalSponsors] = msg.sender;
            sponsorAmounts[msg.sender] = _amount;
            market.totalSponsors += 1;
        } else {
            sponsorAmounts[msg.sender] += _amount;
        }

        _rewardToken.safeTransferFrom(msg.sender, address(this), _amount);
        emit RewardsAmplified(msg.sender, sponsorAmounts[msg.sender]);

        return getContractBalance();
    }

    function updatePlatformDetails(address _address, uint256 _fee)
        public
        onlyOwner
        marketNotResolved
        marketNotCancelled
    {
        _platformFee = _fee;
        _platformAddress = _address;

        emit PlatformDetailsUpdated(_platformAddress, _fee);
    }

    function getContractBalance() public view returns (uint256) {
        return _rewardToken.balanceOf(address(this));
    }

    function isResolved() external view returns (bool) {
        return market.resolved;
    }
}

{
  "compilationTarget": {
    "src/Market_Factory.sol": "Market_Factory"
  },
  "evmVersion": "cancun",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": [
    ":@openzeppelin/contracts/=lib/openzeppelin-contracts/contracts/",
    ":erc4626-tests/=lib/openzeppelin-contracts/lib/erc4626-tests/",
    ":forge-std/=lib/forge-std/src/",
    ":halmos-cheatcodes/=lib/openzeppelin-contracts/lib/halmos-cheatcodes/src/",
    ":openzeppelin-contracts/=lib/openzeppelin-contracts/"
  ],
  "viaIR": true
}