// SPDX-License-Identifier: MIT
pragma solidity ^0.8.2;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}



/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes calldata data
    ) external;

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {safeTransferFrom} whenever possible.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);
}


/**
 * @title ERC721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be reverted.
     *
     * The selector can be obtained in Solidity with `IERC721Receiver.onERC721Received.selector`.
     */
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}


/**
 * @title ERC-721 Non-Fungible Token Standard, optional metadata extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Metadata is IERC721 {
    /**
     * @dev Returns the token collection name.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the token collection symbol.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
     */
    function tokenURI(uint256 tokenId) external view returns (string memory);
}




/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}




/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}




/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _HEX_SYMBOLS = "0123456789abcdef";

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        // Inspired by OraclizeAPI's implementation - MIT licence
        // https://github.com/oraclize/ethereum-api/blob/b42146b063c7d6ee1358846c198246239e9360e8/oraclizeAPI_0.4.25.sol

        if (value == 0) {
            return "0";
        }
        uint256 temp = value;
        uint256 digits;
        while (temp != 0) {
            digits++;
            temp /= 10;
        }
        bytes memory buffer = new bytes(digits);
        while (value != 0) {
            digits -= 1;
            buffer[digits] = bytes1(uint8(48 + uint256(value % 10)));
            value /= 10;
        }
        return string(buffer);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        if (value == 0) {
            return "0x00";
        }
        uint256 temp = value;
        uint256 length = 0;
        while (temp != 0) {
            length++;
            temp >>= 8;
        }
        return toHexString(value, length);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _HEX_SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }
}



/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}








/**
 * @dev Implementation of https://eips.ethereum.org/EIPS/eip-721[ERC721] Non-Fungible Token Standard, including
 * the Metadata extension, but not including the Enumerable extension, which is available separately as
 * {ERC721Enumerable}.
 */
contract ERC721 is Context, ERC165, IERC721, IERC721Metadata {
    using Address for address;
    using Strings for uint256;

    // Token name
    string private _name;

    // Token symbol
    string private _symbol;

    // Mapping from token ID to owner address
    mapping(uint256 => address) private _owners;

    // Mapping owner address to token count
    mapping(address => uint256) private _balances;

    // Mapping from token ID to approved address
    mapping(uint256 => address) private _tokenApprovals;

    // Mapping from owner to operator approvals
    mapping(address => mapping(address => bool)) private _operatorApprovals;

    /**
     * @dev Initializes the contract by setting a `name` and a `symbol` to the token collection.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(ERC165, IERC165) returns (bool) {
        return
            interfaceId == type(IERC721).interfaceId ||
            interfaceId == type(IERC721Metadata).interfaceId ||
            super.supportsInterface(interfaceId);
    }

    /**
     * @dev See {IERC721-balanceOf}.
     */
    function balanceOf(address owner) public view virtual override returns (uint256) {
        require(owner != address(0), "ERC721: balance query for the zero address");
        return _balances[owner];
    }

    /**
     * @dev See {IERC721-ownerOf}.
     */
    function ownerOf(uint256 tokenId) public view virtual override returns (address) {
        address owner = _owners[tokenId];
        require(owner != address(0), "ERC721: owner query for nonexistent token");
        return owner;
    }

    /**
     * @dev See {IERC721Metadata-name}.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev See {IERC721Metadata-symbol}.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev See {IERC721Metadata-tokenURI}.
     */
    function tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
        require(_exists(tokenId), "ERC721Metadata: URI query for nonexistent token");

        string memory baseURI = _baseURI();
        return bytes(baseURI).length > 0 ? string(abi.encodePacked(baseURI, tokenId.toString())) : "";
    }

    /**
     * @dev Base URI for computing {tokenURI}. If set, the resulting URI for each
     * token will be the concatenation of the `baseURI` and the `tokenId`. Empty
     * by default, can be overridden in child contracts.
     */
    function _baseURI() internal view virtual returns (string memory) {
        return "";
    }

    /**
     * @dev See {IERC721-approve}.
     */
    function approve(address to, uint256 tokenId) public virtual override {
        address owner = ERC721.ownerOf(tokenId);
        require(to != owner, "ERC721: approval to current owner");

        require(
            _msgSender() == owner || isApprovedForAll(owner, _msgSender()),
            "ERC721: approve caller is not owner nor approved for all"
        );

        _approve(to, tokenId);
    }

    /**
     * @dev See {IERC721-getApproved}.
     */
    function getApproved(uint256 tokenId) public view virtual override returns (address) {
        require(_exists(tokenId), "ERC721: approved query for nonexistent token");

        return _tokenApprovals[tokenId];
    }

    /**
     * @dev See {IERC721-setApprovalForAll}.
     */
    function setApprovalForAll(address operator, bool approved) public virtual override {
        _setApprovalForAll(_msgSender(), operator, approved);
    }

    /**
     * @dev See {IERC721-isApprovedForAll}.
     */
    function isApprovedForAll(address owner, address operator) public view virtual override returns (bool) {
        return _operatorApprovals[owner][operator];
    }

    /**
     * @dev See {IERC721-transferFrom}.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        //solhint-disable-next-line max-line-length
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");

        _transfer(from, to, tokenId);
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        safeTransferFrom(from, to, tokenId, "");
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) public virtual override {
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");
        _safeTransfer(from, to, tokenId, _data);
    }

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * `_data` is additional data, it has no specified format and it is sent in call to `to`.
     *
     * This internal function is equivalent to {safeTransferFrom}, and can be used to e.g.
     * implement alternative mechanisms to perform token transfer, such as signature-based.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeTransfer(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) internal virtual {
        _transfer(from, to, tokenId);
        require(_checkOnERC721Received(from, to, tokenId, _data), "ERC721: transfer to non ERC721Receiver implementer");
    }

    /**
     * @dev Returns whether `tokenId` exists.
     *
     * Tokens can be managed by their owner or approved accounts via {approve} or {setApprovalForAll}.
     *
     * Tokens start existing when they are minted (`_mint`),
     * and stop existing when they are burned (`_burn`).
     */
    function _exists(uint256 tokenId) internal view virtual returns (bool) {
        return _owners[tokenId] != address(0);
    }

    /**
     * @dev Returns whether `spender` is allowed to manage `tokenId`.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function _isApprovedOrOwner(address spender, uint256 tokenId) internal view virtual returns (bool) {
        require(_exists(tokenId), "ERC721: operator query for nonexistent token");
        address owner = ERC721.ownerOf(tokenId);
        return (spender == owner || isApprovedForAll(owner, spender) || getApproved(tokenId) == spender);
    }

    /**
     * @dev Safely mints `tokenId` and transfers it to `to`.
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeMint(address to, uint256 tokenId) internal virtual {
        _safeMint(to, tokenId, "");
    }

    /**
     * @dev Same as {xref-ERC721-_safeMint-address-uint256-}[`_safeMint`], with an additional `data` parameter which is
     * forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
     */
    function _safeMint(
        address to,
        uint256 tokenId,
        bytes memory _data
    ) internal virtual {
        _mint(to, tokenId);
        require(
            _checkOnERC721Received(address(0), to, tokenId, _data),
            "ERC721: transfer to non ERC721Receiver implementer"
        );
    }

    /**
     * @dev Mints `tokenId` and transfers it to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {_safeMint} whenever possible
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - `to` cannot be the zero address.
     *
     * Emits a {Transfer} event.
     */
    function _mint(address to, uint256 tokenId) internal virtual {
        require(to != address(0), "ERC721: mint to the zero address");
        require(!_exists(tokenId), "ERC721: token already minted");

        _beforeTokenTransfer(address(0), to, tokenId);

        _balances[to] += 1;
        _owners[tokenId] = to;

        emit Transfer(address(0), to, tokenId);

        _afterTokenTransfer(address(0), to, tokenId);
    }

    /**
     * @dev Destroys `tokenId`.
     * The approval is cleared when the token is burned.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     *
     * Emits a {Transfer} event.
     */
    function _burn(uint256 tokenId) internal virtual {
        address owner = ERC721.ownerOf(tokenId);

        _beforeTokenTransfer(owner, address(0), tokenId);

        // Clear approvals
        _approve(address(0), tokenId);

        _balances[owner] -= 1;
        delete _owners[tokenId];

        emit Transfer(owner, address(0), tokenId);

        _afterTokenTransfer(owner, address(0), tokenId);
    }

    /**
     * @dev Transfers `tokenId` from `from` to `to`.
     *  As opposed to {transferFrom}, this imposes no restrictions on msg.sender.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     *
     * Emits a {Transfer} event.
     */
    function _transfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {
        require(ERC721.ownerOf(tokenId) == from, "ERC721: transfer from incorrect owner");
        require(to != address(0), "ERC721: transfer to the zero address");

        _beforeTokenTransfer(from, to, tokenId);

        // Clear approvals from the previous owner
        _approve(address(0), tokenId);

        _balances[from] -= 1;
        _balances[to] += 1;
        _owners[tokenId] = to;

        emit Transfer(from, to, tokenId);

        _afterTokenTransfer(from, to, tokenId);
    }

    /**
     * @dev Approve `to` to operate on `tokenId`
     *
     * Emits a {Approval} event.
     */
    function _approve(address to, uint256 tokenId) internal virtual {
        _tokenApprovals[tokenId] = to;
        emit Approval(ERC721.ownerOf(tokenId), to, tokenId);
    }

    /**
     * @dev Approve `operator` to operate on all of `owner` tokens
     *
     * Emits a {ApprovalForAll} event.
     */
    function _setApprovalForAll(
        address owner,
        address operator,
        bool approved
    ) internal virtual {
        require(owner != operator, "ERC721: approve to caller");
        _operatorApprovals[owner][operator] = approved;
        emit ApprovalForAll(owner, operator, approved);
    }

    /**
     * @dev Internal function to invoke {IERC721Receiver-onERC721Received} on a target address.
     * The call is not executed if the target address is not a contract.
     *
     * @param from address representing the previous owner of the given token ID
     * @param to target address that will receive the tokens
     * @param tokenId uint256 ID of the token to be transferred
     * @param _data bytes optional data to send along with the call
     * @return bool whether the call correctly returned the expected magic value
     */
    function _checkOnERC721Received(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) private returns (bool) {
        if (to.isContract()) {
            try IERC721Receiver(to).onERC721Received(_msgSender(), from, tokenId, _data) returns (bytes4 retval) {
                return retval == IERC721Receiver.onERC721Received.selector;
            } catch (bytes memory reason) {
                if (reason.length == 0) {
                    revert("ERC721: transfer to non ERC721Receiver implementer");
                } else {
                    assembly {
                        revert(add(32, reason), mload(reason))
                    }
                }
            }
        } else {
            return true;
        }
    }

    /**
     * @dev Hook that is called before any token transfer. This includes minting
     * and burning.
     *
     * Calling conditions:
     *
     * - When `from` and `to` are both non-zero, ``from``'s `tokenId` will be
     * transferred to `to`.
     * - When `from` is zero, `tokenId` will be minted for `to`.
     * - When `to` is zero, ``from``'s `tokenId` will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {}

    /**
     * @dev Hook that is called after any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {}
}


/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}


/**
 * @title Counters
 * @author Matt Condon (@shrugs)
 * @dev Provides counters that can only be incremented, decremented or reset. This can be used e.g. to track the number
 * of elements in a mapping, issuing ERC721 ids, or counting request ids.
 *
 * Include with `using Counters for Counters.Counter;`
 */
library Counters {
    struct Counter {
        // This variable should never be directly accessed by users of the library: interactions must be restricted to
        // the library's function. As of Solidity v0.5.2, this cannot be enforced, though there is a proposal to add
        // this feature: see https://github.com/ethereum/solidity/issues/4637
        uint256 _value; // default: 0
    }

    function current(Counter storage counter) internal view returns (uint256) {
        return counter._value;
    }

    function increment(Counter storage counter) internal {
        unchecked {
            counter._value += 1;
        }
    }

    function decrement(Counter storage counter) internal {
        uint256 value = counter._value;
        require(value > 0, "Counter: decrement overflow");
        unchecked {
            counter._value = value - 1;
        }
    }

    function reset(Counter storage counter) internal {
        counter._value = 0;
    }
}




contract BIG3 is ERC721, Ownable {
    using Counters for Counters.Counter;
    Counters.Counter private _tokenIdCounter;
    string public baseURI = "https://ownership.big3.com/apis/pages/getnft/";
    


    // mix=====================
    address payable public fundsTo; // Where funds should be sent to
    address payable public fundsToDev; // Where funds should be sent to
    // end mix=================

    mapping(uint256 => string) public _teamTierTokenURIs;

    mapping(uint256 => bool) public _paymentIds;

    mapping(uint256 => mapping(uint256=>uint256)) public _paymentIdLogs;
    // sale bools =============
    bool public vipSale = false;
    bool public sale = false;
    bool public whiteListSale = false;
    // end sale bools==========


    //whitelists and max wallets
        uint256 public maxWallet = 5;
        uint256 public maxWhiteListLimit = 3;
    // end whitelists and max wallets    

    // prices =================
    uint256 public FirePriceWhiteList = 9 ether;
    uint256 public FirePrice = 9 ether;

    uint256 public GoldPriceWhiteList = 1.6 ether;
    uint256 public GoldPrice = 1.85 ether;
    // end prices==============

    enum Teams {
        Team1,
        Team2,
        Team3,
        Team4,
        Team5,
        Team6,
        Team7,
        Team8,
        Team9,
        Team10,
        Team11,
        Team12
    }
    uint256 public FireTier = 1;
    uint256 public GoldTier = 2;

    //struct TeamTierInfo {
      //  uint256 Tiers;
    //    uint256 maxSupply;
   // }

    //mappings ==============
    mapping (Teams => mapping (uint256 => uint256)) teamTierLimits;

    uint256 public goldTierLimit;
    uint256 public goldTierMintCounts;
   // mapping (uint256 => uint256) public mintTeam;
   // mapping (uint256 => uint256) public mintTier;
    mapping (Teams => uint256) teamIDS;
    mapping (address => bool) whiteLists;
    mapping (Teams => mapping (uint256 => mapping (address => uint256))) whiteListsVip;
    mapping (address => uint256) whiteListsVipGold;
    mapping (Teams => mapping (uint256 => uint256)) teamTierMintCounts;
    
    mapping(address => uint256) public minted; // To check how many tokens an address has minted
    //end mappings
    

    constructor(address payable fundsTo_,address payable fundsToDev_) ERC721("BIG3 Ownership", "BIG3") {
        fundsTo = fundsTo_;
        fundsToDev = fundsToDev_;
        teamTierLimits[Teams.Team1][FireTier] = 25;
        teamTierLimits[Teams.Team2][FireTier] = 25;
        teamTierLimits[Teams.Team3][FireTier] = 25;
        teamTierLimits[Teams.Team4][FireTier] = 25;
        teamTierLimits[Teams.Team5][FireTier] = 25;
        teamTierLimits[Teams.Team6][FireTier] = 25;
        teamTierLimits[Teams.Team7][FireTier] = 25;
        teamTierLimits[Teams.Team8][FireTier] = 25;
        teamTierLimits[Teams.Team9][FireTier] = 25;
        teamTierLimits[Teams.Team10][FireTier] = 25;
        teamTierLimits[Teams.Team11][FireTier] = 25;
        teamTierLimits[Teams.Team12][FireTier] = 25;

        teamIDS[Teams.Team1] = 1;
        teamIDS[Teams.Team2] = 2;
        teamIDS[Teams.Team3] = 3;
        teamIDS[Teams.Team4] = 4;
        teamIDS[Teams.Team5] = 5;
        teamIDS[Teams.Team6] = 6;
        teamIDS[Teams.Team7] = 7;
        teamIDS[Teams.Team8] = 8;
        teamIDS[Teams.Team9] = 9;
        teamIDS[Teams.Team10] = 10;
        teamIDS[Teams.Team11] = 11;
        teamIDS[Teams.Team12] = 12;


        goldTierLimit = 11700;
     
    }


    function updateFundsTo(address payable newFundsTo) public onlyOwner {
        fundsTo = newFundsTo;
    }
    function updateFundsToDev(address payable newFundsToDev) public onlyOwner {
        fundsToDev = newFundsToDev;
    }
  
    
    function claimBalance() public onlyOwner {
        uint256 contractBalance = address(this).balance;
        (bool success2, ) = fundsToDev.call{value: (contractBalance/ 1000) * 150}("");
        (bool success, ) = fundsTo.call{value: (contractBalance/ 1000) * 850}("");
        require(success, "transfer failed");require(success2, "transfer failed");
    }


    function setMaxWallet(uint _newMaxWallet) external onlyOwner {
        maxWallet = _newMaxWallet;
    }

    function setMaxWhiteListLimit(uint _newMaxWhiteListLimit) external onlyOwner {
        maxWhiteListLimit = _newMaxWhiteListLimit;
    }

    function setFirePriceWhiteList(uint256 FirePriceWhiteList_) external onlyOwner {
        FirePriceWhiteList = FirePriceWhiteList_;
    }


    function setGoldPriceWhiteList(uint256 GoldPriceWhiteList_) external onlyOwner {
        GoldPriceWhiteList = GoldPriceWhiteList_;
    }

    function setGoldPrice(uint256 GoldPrice_) external onlyOwner {
        GoldPrice = GoldPrice_;
    }

    function setFirePrice(uint256 FirePrice_) external onlyOwner {
        FirePrice = FirePrice_;
    }

    function flipVipSaleState() public onlyOwner {
        vipSale = !vipSale;
    }
    function flipSaleState() public onlyOwner {
        sale = !sale;
    }

    function flipWhiteListSaleState() public onlyOwner {
        whiteListSale = !whiteListSale;
    }
    
    // wallet functions

    function isVipWallet(address wallet,Teams team,uint256 tier) public view returns (uint256) {
        return whiteListsVip[team][tier][wallet];
    }
    function isVipWalletGold(address wallet) public view returns (uint256) {
        return whiteListsVipGold[wallet];
    }
    function whitelistVipAddresses(address[] calldata wallets,uint256[] calldata quantities,Teams[] calldata team,uint256[] calldata tiers) public onlyOwner
    {
        for (uint256 i; i < wallets.length; i++) {
            whiteListsVip[team[i]][tiers[i]][wallets[i]] = quantities[i];
        }
    }
    function whitelistVipGoldAddresses(address[] calldata wallets,uint256[] calldata quantities) public onlyOwner
    {
        for (uint256 i; i < wallets.length; i++) {
            whiteListsVipGold[wallets[i]] = quantities[i];
        }
    }
    function whitelistAddresses(address[] calldata wallets,bool[] calldata enableDisables) public onlyOwner
    {
        for (uint256 i; i < wallets.length; i++) {
            whiteLists[wallets[i]] = enableDisables[i];
        }
    }
    function reduceLimit(address wallet, uint256 quantity,Teams team, uint256 tier) internal {
        whiteListsVip[team][tier][wallet] = whiteListsVip[team][tier][wallet] - quantity;
    }
    function reduceLimitGold(address wallet, uint256 quantity) internal {
        whiteListsVipGold[wallet] = whiteListsVipGold[wallet] - quantity;
    }
    function incrementTeamTierMintCount(Teams team,uint256 tier) internal {
        teamTierMintCounts[team][tier] = teamTierMintCounts[team][tier]+1;
    }
        
    function getTeamTierMintCount(Teams team,uint256 tier) public view returns (uint256) {
        return teamTierMintCounts[team][tier];
    }
    
    function getTeamTierSupply(Teams team,uint256 tier) public view returns (uint256) {

        return teamTierLimits[team][tier];
    } 

    function checkTeamTierAvailableSupply(Teams team, uint256 tier) public view returns(uint256) {
        return getTeamTierSupply(team,tier) - getTeamTierMintCount(team,tier);
    }
 

    // contract functions
    
    function setBaseURI(string memory __baseURI) external onlyOwner {
        baseURI = __baseURI;
    }
    

    
    function _baseURI() internal view override returns (string memory) {
        return baseURI;
    }
    
  
    function tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
        require(_exists(tokenId), "ERC721Metadata: Nonexistent token");

        string memory _tokenURI = _teamTierTokenURIs[tokenId];
        string memory base = _baseURI();

        // If there is no base URI, return the token URI.
        if (bytes(base).length == 0) {
            return _tokenURI;
        }
        // If both are set, concatenate the baseURI and tokenURI (via abi.encodePacked).
        if (bytes(_tokenURI).length > 0) {
            return string(abi.encodePacked(base, _tokenURI));
        }

        return super.tokenURI(tokenId);
    }

    function _isWhitelistAddress (address wallet) public view returns (bool) {
        return whiteLists[wallet];
    }
    function totalSupplyMinted() public view  returns (uint256) { 
        return _tokenIdCounter.current(); 
    }
    
    // end setting functions 

    //mint functions

    function _safeMintLoop(address wallet, Teams team, uint256 tier, uint256 quantity,uint256 _paymentId) internal
    {
        
        for (uint256 i = 0; i < quantity; i++) {
           // mintTeam[_tokenIdCounter.current()] = teamIDS[team];
            //mintTier[_tokenIdCounter.current()] = tier;
            incrementTeamTierMintCount(team,tier);
            _mint(wallet, _tokenIdCounter.current());
            _setTokenURI(_tokenIdCounter.current(), string(abi.encodePacked(Strings.toString(_tokenIdCounter.current()),"/",Strings.toString(teamIDS[team]),"/", Strings.toString(tier))));
            _paymentIdLogs[_paymentId][_tokenIdCounter.current()] = _tokenIdCounter.current();
            _tokenIdCounter.increment();
        }
        
    }
    function _safeMintLoopGold(address wallet, uint256 tier, uint256 quantity,uint256 _paymentId) internal
    {

        for (uint256 i = 0; i < quantity; i++) {
            _mint(wallet, _tokenIdCounter.current());
            _setTokenURI(_tokenIdCounter.current(), string(abi.encodePacked(Strings.toString(_tokenIdCounter.current()),"/13/", Strings.toString(tier))));
            _paymentIdLogs[_paymentId][_tokenIdCounter.current()] = _tokenIdCounter.current();
            _tokenIdCounter.increment();
        }
        
    }
    function _setTokenURI(uint256 tokenId, string memory _tokenURI) internal 
    {
        require(_exists(tokenId), "ERC721URIStorage: URI set of nonexistent token");
        _teamTierTokenURIs[tokenId] = _tokenURI;
    }
    function mintVipFire(address wallet, uint256 quantity,Teams team) payable public {
        require(vipSale, "VIP Sale disabled");
        require(quantity != 0, "Requested quantity cannot be zero");
        require(quantity * FirePriceWhiteList <= msg.value, "Not enough ether sent");
        require(isVipWallet(wallet,team,FireTier)>=quantity,"Wallet Not WhiteListed Or No Mint Quantity Available");
        require(getTeamTierMintCount(team,FireTier)+quantity<=teamTierLimits[team][FireTier],"Low Mint Supply for Whitelist");        
        reduceLimit(wallet,quantity, team, FireTier);
        _safeMintLoop(wallet, team, FireTier, quantity,0);

    }

    function mintVipFireOwner(address wallet, uint256 quantity,Teams team,uint256 _paymentId) external onlyOwner {
        require(quantity != 0, "Requested quantity cannot be zero");
        require(!_paymentIds[_paymentId], "Mint Already Sent");
        require(isVipWallet(wallet,team,FireTier)>=quantity,"Wallet Not WhiteListed Or No Mint Quantity Available");
        require(getTeamTierMintCount(team,FireTier)+quantity<=teamTierLimits[team][FireTier],"Low Mint Supply for Whitelist");        
        reduceLimit(wallet,quantity, team, FireTier);
        _paymentIds[_paymentId] = true;
        _safeMintLoop(wallet, team, FireTier, quantity,_paymentId);

    }

    function mintWhitelistFire(address wallet, uint256 quantity,Teams team) payable public {
        require(whiteListSale, "Whitelist Sale disabled");
        require(quantity != 0, "Requested quantity cannot be zero");
        require(quantity * FirePriceWhiteList <= msg.value, "Not enough ether sent");
        require(_isWhitelistAddress(wallet),"Wallet Not WhiteListed Or No Mint Quantity Available");
        require(getTeamTierMintCount(team,FireTier)+quantity<=teamTierLimits[team][FireTier],"Low Mint Supply for Whitelist");
        require(minted[wallet]+quantity<=maxWhiteListLimit,"Wallet Mint limit rached");
        _safeMintLoop(wallet, team, FireTier, quantity,0);

    }

    function mintWhitelistFireOwner(address wallet, uint256 quantity,Teams team,uint256 _paymentId) external onlyOwner {
        require(whiteListSale, "Whitelist Sale disabled");
        require(quantity != 0, "Requested quantity cannot be zero");
        require(_isWhitelistAddress(wallet),"Wallet Not WhiteListed Or No Mint Quantity Available");
        require(getTeamTierMintCount(team,FireTier)+quantity<=teamTierLimits[team][FireTier],"Low Mint Supply for Whitelist");
        require(minted[wallet]+quantity<=maxWhiteListLimit,"Wallet Mint limit rached");
        require(!_paymentIds[_paymentId], "Mint Already Sent");
        _paymentIds[_paymentId] = true;
        _safeMintLoop(wallet, team, FireTier, quantity,_paymentId);

    }


    function mintFireNormal(address wallet, uint256 quantity,Teams team) payable public {
        require(sale, "Sale disabled");
        require(!Address.isContract(msg.sender), "Contracts are not allowed to mint");
        require(quantity != 0, "Requested quantity cannot be zero");
        require(quantity * FirePrice <= msg.value, "Not enough ether sent");
        require(getTeamTierMintCount(team,FireTier)+quantity<=teamTierLimits[team][FireTier],"Low Mint Supply for Whitelist");
        require(minted[wallet]+quantity<=maxWallet,"Wallet Mint limit rached");
        minted[wallet] += quantity;
        _safeMintLoop(wallet, team, FireTier, quantity,0);
    }


    function mintFireNormalOwner(address wallet, uint256 quantity,Teams team,uint256 _paymentId) external onlyOwner{
        require(sale, "Sale disabled");
        require(quantity != 0, "Requested quantity cannot be zero");
        require(getTeamTierMintCount(team,FireTier)+quantity<=teamTierLimits[team][FireTier],"Low Mint Supply for Whitelist");
        require(minted[wallet]+quantity<=maxWallet,"Wallet Mint limit rached");
        require(!_paymentIds[_paymentId], "Mint Already Sent");
        _paymentIds[_paymentId] = true;
        minted[wallet] += quantity;
        _safeMintLoop(wallet, team, FireTier, quantity,_paymentId);
    }

    function mintVipGold(address wallet, uint256 quantity) payable public {
        require(vipSale, "VIP Sale disabled");
        require(quantity != 0, "Requested quantity cannot be zero");
        require(quantity * GoldPriceWhiteList <= msg.value, "Not enough ether sent");
        require(isVipWalletGold(wallet)>=quantity,"Wallet Not WhiteListed Or No Mint Quantity Available");
        require(goldTierMintCounts+quantity<=goldTierLimit,"Low Mint Supply for Whitelist");        
        reduceLimitGold(wallet,quantity);
        goldTierMintCounts += quantity;
        _safeMintLoopGold(wallet,  GoldTier, quantity,0);

    }

    function mintVipGoldOwner(address wallet, uint256 quantity,uint256 _paymentId) external onlyOwner {
        require(quantity != 0, "Requested quantity cannot be zero");
        require(isVipWalletGold(wallet)>=quantity,"Wallet Not WhiteListed Or No Mint Quantity Available");
        require(goldTierMintCounts+quantity<=goldTierLimit,"Low Mint Supply for Whitelist"); 
        require(!_paymentIds[_paymentId], "Mint Already Sent");
        _paymentIds[_paymentId] = true;          
        reduceLimitGold(wallet,quantity);
        goldTierMintCounts += quantity;
        _safeMintLoopGold(wallet,  GoldTier, quantity,_paymentId);

    }
    

    function mintWhitelistGold(address wallet, uint256 quantity) payable public {
        require(whiteListSale, "Whitelist Sale disabled");
        require(quantity != 0, "Requested quantity cannot be zero");
        require(quantity * GoldPriceWhiteList <= msg.value, "Not enough ether sent");
        require(_isWhitelistAddress(wallet),"Wallet Not WhiteListed Or No Mint Quantity Available");
        require(goldTierMintCounts+quantity<=goldTierLimit,"Low Mint Supply for Whitelist");
        require(minted[wallet]+quantity<=maxWhiteListLimit,"Wallet Mint limit rached");
        goldTierMintCounts += quantity;
        _safeMintLoopGold(wallet,  GoldTier, quantity,0);

    }

    function mintWhitelistGoldOwner(address wallet, uint256 quantity,uint256 _paymentId) external onlyOwner {
        require(whiteListSale, "Whitelist Sale disabled");
        require(quantity != 0, "Requested quantity cannot be zero");
        require(_isWhitelistAddress(wallet),"Wallet Not WhiteListed Or No Mint Quantity Available");
        require(goldTierMintCounts+quantity<=goldTierLimit,"Low Mint Supply for Whitelist");
        require(minted[wallet]+quantity<=maxWhiteListLimit,"Wallet Mint limit rached");
        require(!_paymentIds[_paymentId], "Mint Already Sent");
        goldTierMintCounts += quantity;
        _paymentIds[_paymentId] = true;
        _safeMintLoopGold(wallet,  GoldTier, quantity,_paymentId);

    }


    function mintGoldNormal(address wallet, uint256 quantity) payable public {
        require(sale, "Sale disabled");
        require(!Address.isContract(msg.sender), "Contracts are not allowed to mint");
        require(quantity != 0, "Requested quantity cannot be zero");
        require(quantity * GoldPrice <= msg.value, "Not enough ether sent");
        require(goldTierMintCounts+quantity<=goldTierLimit,"Low Mint Supply for Whitelist");
        require(minted[wallet]+quantity<=maxWallet,"Wallet Mint limit rached");
        goldTierMintCounts += quantity;
        minted[wallet] += quantity;
        _safeMintLoopGold(wallet,  GoldTier, quantity,0);
    }
    
    function mintGoldNormalOwner(address wallet, uint256 quantity,uint256 _paymentId) external onlyOwner{
        require(sale, "Sale disabled");
        require(quantity != 0, "Requested quantity cannot be zero");
        require(goldTierMintCounts+quantity<=goldTierLimit,"Low Mint Supply for Whitelist");
        require(minted[wallet]+quantity<=maxWallet,"Wallet Mint limit rached");
        require(!_paymentIds[_paymentId], "Mint Already Sent");
        _paymentIds[_paymentId] = true;
        goldTierMintCounts += quantity;
        minted[wallet] += quantity;
        _safeMintLoopGold(wallet,  GoldTier, quantity,_paymentId);
    }
    function checkTokenExists(uint256 tokenId) public view returns(bool) 
    {
        require(_exists(tokenId), "ERC721Metadata: URI query for nonexistent token");
        return true;
    }
    function totalSupply() public view virtual  returns (uint256) {
        return _tokenIdCounter.current();
    }
}

{
  "compilationTarget": {
    "BIG3.sol": "BIG3"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}