NeoAudit AI

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC20Metadata} from "./extensions/IERC20Metadata.sol";
import {Context} from "../../utils/Context.sol";
import {IERC20Errors} from "../../interfaces/draft-IERC6093.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 */
abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
    mapping(address account => uint256) private _balances;

    mapping(address account => mapping(address spender => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `value`.
     */
    function transfer(address to, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, value);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, value);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `value`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `value`.
     */
    function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _transfer(from, to, value);
        return true;
    }

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _transfer(address from, address to, uint256 value) internal {
        if (from == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(from, to, value);
    }

    /**
     * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
     * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
     * this function.
     *
     * Emits a {Transfer} event.
     */
    function _update(address from, address to, uint256 value) internal virtual {
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= value;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                _balances[to] += value;
            }
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
     * Relies on the `_update` mechanism
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _mint(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(address(0), account, value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
     * Relies on the `_update` mechanism.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead
     */
    function _burn(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        _update(account, address(0), value);
    }

    /**
     * @dev Sets `value` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        _approve(owner, spender, value, true);
    }

    /**
     * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
     *
     * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
     * `_spendAllowance` during the `transferFrom` operation set the flag to false. This saves gas by not emitting any
     * `Approval` event during `transferFrom` operations.
     *
     * Anyone who wishes to continue emitting `Approval` events on the`transferFrom` operation can force the flag to
     * true using the following override:
     * ```
     * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
     *     super._approve(owner, spender, value, true);
     * }
     * ```
     *
     * Requirements are the same as {_approve}.
     */
    function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
        if (owner == address(0)) {
            revert ERC20InvalidApprover(address(0));
        }
        if (spender == address(0)) {
            revert ERC20InvalidSpender(address(0));
        }
        _allowances[owner][spender] = value;
        if (emitEvent) {
            emit Approval(owner, spender, value);
        }
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `value`.
     *
     * Does not update the allowance value in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Does not emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            if (currentAllowance < value) {
                revert ERC20InsufficientAllowance(spender, currentAllowance, value);
            }
            unchecked {
                _approve(owner, spender, currentAllowance - value, false);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

pragma solidity >=0.5.0;

interface IUniswapV2Factory {
    event PairCreated(address indexed token0, address indexed token1, address pair, uint);

    function feeTo() external view returns (address);
    function feeToSetter() external view returns (address);

    function getPair(address tokenA, address tokenB) external view returns (address pair);
    function allPairs(uint) external view returns (address pair);
    function allPairsLength() external view returns (uint);

    function createPair(address tokenA, address tokenB) external returns (address pair);

    function setFeeTo(address) external;
    function setFeeToSetter(address) external;
}

pragma solidity >=0.5.0;

interface IUniswapV2Pair {
    event Approval(address indexed owner, address indexed spender, uint value);
    event Transfer(address indexed from, address indexed to, uint value);

    function name() external pure returns (string memory);
    function symbol() external pure returns (string memory);
    function decimals() external pure returns (uint8);
    function totalSupply() external view returns (uint);
    function balanceOf(address owner) external view returns (uint);
    function allowance(address owner, address spender) external view returns (uint);

    function approve(address spender, uint value) external returns (bool);
    function transfer(address to, uint value) external returns (bool);
    function transferFrom(address from, address to, uint value) external returns (bool);

    function DOMAIN_SEPARATOR() external view returns (bytes32);
    function PERMIT_TYPEHASH() external pure returns (bytes32);
    function nonces(address owner) external view returns (uint);

    function permit(address owner, address spender, uint value, uint deadline, uint8 v, bytes32 r, bytes32 s) external;

    event Mint(address indexed sender, uint amount0, uint amount1);
    event Burn(address indexed sender, uint amount0, uint amount1, address indexed to);
    event Swap(
        address indexed sender,
        uint amount0In,
        uint amount1In,
        uint amount0Out,
        uint amount1Out,
        address indexed to
    );
    event Sync(uint112 reserve0, uint112 reserve1);

    function MINIMUM_LIQUIDITY() external pure returns (uint);
    function factory() external view returns (address);
    function token0() external view returns (address);
    function token1() external view returns (address);
    function getReserves() external view returns (uint112 reserve0, uint112 reserve1, uint32 blockTimestampLast);
    function price0CumulativeLast() external view returns (uint);
    function price1CumulativeLast() external view returns (uint);
    function kLast() external view returns (uint);

    function mint(address to) external returns (uint liquidity);
    function burn(address to) external returns (uint amount0, uint amount1);
    function swap(uint amount0Out, uint amount1Out, address to, bytes calldata data) external;
    function skim(address to) external;
    function sync() external;

    function initialize(address, address) external;
}

pragma solidity >=0.6.2;

interface IUniswapV2Router01 {
    function factory() external pure returns (address);
    function WETH() external pure returns (address);

    function addLiquidity(
        address tokenA,
        address tokenB,
        uint amountADesired,
        uint amountBDesired,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external returns (uint amountA, uint amountB, uint liquidity);
    function addLiquidityETH(
        address token,
        uint amountTokenDesired,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external payable returns (uint amountToken, uint amountETH, uint liquidity);
    function removeLiquidity(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external returns (uint amountA, uint amountB);
    function removeLiquidityETH(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external returns (uint amountToken, uint amountETH);
    function removeLiquidityWithPermit(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint amountA, uint amountB);
    function removeLiquidityETHWithPermit(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint amountToken, uint amountETH);
    function swapExactTokensForTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);
    function swapTokensForExactTokens(
        uint amountOut,
        uint amountInMax,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);
    function swapExactETHForTokens(uint amountOutMin, address[] calldata path, address to, uint deadline)
        external
        payable
        returns (uint[] memory amounts);
    function swapTokensForExactETH(uint amountOut, uint amountInMax, address[] calldata path, address to, uint deadline)
        external
        returns (uint[] memory amounts);
    function swapExactTokensForETH(uint amountIn, uint amountOutMin, address[] calldata path, address to, uint deadline)
        external
        returns (uint[] memory amounts);
    function swapETHForExactTokens(uint amountOut, address[] calldata path, address to, uint deadline)
        external
        payable
        returns (uint[] memory amounts);

    function quote(uint amountA, uint reserveA, uint reserveB) external pure returns (uint amountB);
    function getAmountOut(uint amountIn, uint reserveIn, uint reserveOut) external pure returns (uint amountOut);
    function getAmountIn(uint amountOut, uint reserveIn, uint reserveOut) external pure returns (uint amountIn);
    function getAmountsOut(uint amountIn, address[] calldata path) external view returns (uint[] memory amounts);
    function getAmountsIn(uint amountOut, address[] calldata path) external view returns (uint[] memory amounts);
}

pragma solidity >=0.6.2;

import './IUniswapV2Router01.sol';

interface IUniswapV2Router02 is IUniswapV2Router01 {
    function removeLiquidityETHSupportingFeeOnTransferTokens(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external returns (uint amountETH);
    function removeLiquidityETHWithPermitSupportingFeeOnTransferTokens(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint amountETH);

    function swapExactTokensForTokensSupportingFeeOnTransferTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external;
    function swapExactETHForTokensSupportingFeeOnTransferTokens(
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external payable;
    function swapExactTokensForETHSupportingFeeOnTransferTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external;
}

// SPDX-License-Identifier: MIT
pragma solidity =0.8.20;

import {ERC20, IERC20} from "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
import {IUniswapV2Router02} from "@uniswap/v2-periphery/contracts/interfaces/IUniswapV2Router02.sol";
import {IUniswapV2Factory} from "@uniswap/v2-core/contracts/interfaces/IUniswapV2Factory.sol";
import {IUniswapV2Pair} from "@uniswap/v2-core/contracts/interfaces/IUniswapV2Pair.sol";

contract Main is IERC20Metadata, ERC20, Ownable {

    /**
     * The contract ensures via the '_update' function that a transaction amount does not exceed `maxTxAmount`.
     * For transactions involving addresses not included in `whitelistedAddresses`,
     * the function will throw an error if the amount surpasses the `maxTxAmount`.
     *
     * The value of `maxTxAmount` can be changed using the `maxTxAmountChange` function.
     */
    uint256 public maxTxAmount;

    /**
     * This limit is enforced in the '_update' function of the contract: after executing a transaction, a non-whitelisted address
     * should still hold a number of tokens not exceeding `maxWalletAmount`. If the limit were to be surpassed as a result
     * of the transaction, the function would throw an error, thereby preventing the transaction.
     *
     * The `maxWalletAmount` value can be updated by calling the `maxWalletChange` function and it applies only to non-whitelisted addresses.
     */
    uint256 public maxWalletAmount;

    /**
    * @dev The wallet that receives operation taxes and has the ability to withdraw them.
    *
    * It is responsible for receiving operation taxes from buy and sell transactions in `operationsTaxBuy` and `operationsTaxSell` respectively.
    *
    * Furthermore, `operationsWallet` is the recipient of any ETH or tokens accidentally sent to the contract and it can withdraw these
    * via the `withdrawETH` and `withdrawTokens` functions respectively.
    */
    address public operationsWallet;

    /**
     * Prevent admin to change critical addresses to this address:
     */
    address public DEAD = 0x000000000000000000000000000000000000dEaD;

    /**
     * Determines if transaction fees apply for a specific address.
     *
     * This mapping stores a boolean value for each address. If the boolean is true,
     * the address is exempted from transaction fees, otherwise transaction fees will apply.
     *
     * Fees can either be for buying or selling operations and are calculated in the '_update' function.
     * The exemption status of an address can be changed using the '' method.
     */
    mapping(address => bool) public hasFee;

    /**
    * @dev Maintains the whitelist of addresses exempt from transaction limits and fees.
    *
    * Addresses in this mapping are not bound by `maxTxAmount` and `maxWalletAmount` restrictions and do not incur tax
    * from buy/sell transactions.
    * They are set at contract initialisation and can be modified using `emergencyTaxRemoval`.
    */
    mapping(address => bool) public whitelistedAddresses;

    /**
    * @dev The tax rate applied to buy transactions not involving whitelisted addresses.
    *
    * This tax, as a percentage, is deducted from buy transactions between non-whitelisted addresses.
    * The tax is transferred to the operations wallet, thereby reducing the amount of tokens received on purchase.
    */
    uint256 public operationsTaxBuy;

    /**
     * @dev The tax rate applied to sell transactions not involving whitelisted addresses.
     *
     * This tax, as a percentage, is deducted from sell transactions between non-whitelisted addresses.
     * The tax is transferred to the operations wallet, therefore reducing the amount of tokens converted back on selling.
     */
    uint256 public operationsTaxSell;

    /**
     * @dev An instance of Uniswap V2 router to execute token swaps and liquidity provision.
     *
     * This is required for facilitating token swaps on the Uniswap exchange. It's initially set in the constructor
     * and is used in the `swapAndLiquify` and `_swapTokensForEth` functions to swap tokens for ETH and add liquidity to the pool.
     */
    IUniswapV2Router02 public router;

    /**
     * @dev The address of the Uniswap V2 pair for this contract's token and WETH.
     *
     * This address represents the Uniswap liquidity pool for this token and Wrapped Ether (WETH).
     * It's used during buy and sell operations to check if tokens are being bought from or sold into the pair.
     * It's initially set in the constructor and can be updated using the `updatePair` function.
     */
    address public uniswapV2Pair;

    /**
    * @dev A flag indicating if a token swap operation is in progress.
    *
    * This boolean is used to prevent reentrancy in the token swapping process. During a sell operation,
    * it's set to true in the '_update' function just before calling 'swapAndLiquify', and reset to false afterward.
    */
    bool private _progressSwap = false;

    /**
    * @dev Thrown when a token transfer amount exceeds the maximum transaction amount (`maxTxAmount`).
    */
    error ERC20TransferExceedsMaxTx(uint256 amount, uint256 maxTxAmount);

    /**
    * @dev Thrown when a token transfer would cause the receiver's balance to exceed the maximum wallet amount (`maxWalletAmount`).
    */
    error ERC20TransferExceedsMaxWallet(uint256 amount, uint256 maxWalletAmount);

    /**
    * @dev Thrown when an operation is attempted by someone other than the owner or the operations wallet.
    */
    error NotOwnerOrOperations();

    /**
    * @dev Thrown when a token transfer amount exceeds the maximum transaction amount (`maxTxAmount`) allowed.
    */
    error ERC20ExceedsMaxTxAmount(uint256 amount, uint256 maxTxAmount);

    /**
    * @dev Thrown when a specified address is invalid (equivalent to the `DEAD` address or the zero address).
    */
    error InvalidAddress(address addr);

    /**
    * @dev Thrown when attempting to set `maxTxAmount` to more than 10% of the total supply.
    */
    error CannotSetMaxTxAmountToMoreThan10Percent();

    /**
    * @dev Thrown when attempting to set `maxTxAmount` to less than 0.5% of the total supply.
    */
    error CannotSetMaxTxAmountToLessThanHalfPercent();

    /**
    * @dev Thrown when a eth transfer fails.
    */
    error CallFailed();

    /**
     * @dev Emitted when the operations wallet change process has been finalized
     *
     * Event Parameters:
     * _newWallet {address} - Holds the address of the new operations wallet after the change process
     */
    event SetOperationsWallet(address _newWallet);

    /**
     * @dev Emitted when an address is added or removed from the whitelist
     *
     * Event Parameters:
     * addy {address} - Holds the address that is being whitelisted or removed from the whitelist
     * changer {bool} - Holds the new whitelist status of the address. True if whitelisted, false if removed from whitelist
     */
    event WhitelistAddress(address indexed addy, bool changer);

    /**
     * @dev Emitted when ETH is withdrawn from the contract
     *
     * Event Parameters:
     * amount {uint256} - Holds the amount of ETH that was withdrawn
     */
    event WithdrawETH(uint256 amount);

    /**
     * @dev Emitted when tokens are withdrawn from the contract
     *
     * Event Parameters:
     * token {address} - Holds the address of the token that was withdrawn
     * amount {uint256} - Holds the amount of tokens that was withdrawn
     */
    event WithdrawTokens(address token, uint256 amount);

    /**
     * @dev Emitted when the maximum transaction amount is changed
     *
     * Event Parameters:
     * from {uint256} - Holds the previous maximum transaction amount
     * to {uint256} - Holds the new maximum transaction amount
     */
    event MaxWalletChange(uint from, uint to);

    /**
     * @dev Emitted when the maximum wallet amount is changed
     *
     * Event Parameters:
     * from {uint256} - Holds the previous maximum wallet amount
     * to {uint256} - Holds the new maximum wallet amount
     */
    event MaxTxAmountChange(uint from, uint to);

    /**
    * @dev Emitted when the Uniswap pair is changed
    *
    * Event Parameters:
    * from {address} - Holds the previous Uniswap pair address
    * to {address} - Holds the new Uniswap pair address
    */
    event PoolChanged(address indexed from, address indexed to);

    /**
     * @dev Emitted when tokens are swapped for ETH
     *
     * Event Parameters:
     * tokensSwapped {uint256} - Holds the amount of tokens that were swapped
     * ethReceived {uint256} - Holds the amount of ETH that was received
     */
    event SwapAndLiquify(
        uint256 tokensSwapped,
        uint256 ethReceived
    );

    /**
     * @dev Ensures that the caller is either the contract owner or the operations wallet.
     *
     * This modifier restricts access to certain functions to only the owner of the contract or the operations
     * wallet. It prevents any other account from executing the function the modifier is attached to.
     */
    modifier onlyOwnerOrOperations() {
        if (owner() != _msgSender() && operationsWallet != _msgSender()) {
            revert NotOwnerOrOperations();
        }
        _;
    }

    /**
    * @dev Constructs a new instance of the Main contract.
    *
    * Sets up the contract with initial supply, treasury, owner, router, operations wallet, tax percentages,
    * maximum transaction amount, and maximum wallet amount.
    * Also, it creates a new Uniswap pair for the contract's token and WETH and whitelists critical addresses
    * including the treasury, the contract owner, the router, and the operations wallet.
    *
    * @param _symbol The symbol of the token.
    * @param _name The name of the token.
    * @param _totalSupply The total initial supply of tokens.
    * @param _treasure The treasury to hold all supply.
    * @param _owner The owner of the contract.
    * @param _router The Uniswap router to use for token swaps.
    * @param _operationsWalletAddress The operations wallet to receive fees.
    * @param _operationsTaxBuyPercentage The tax to be deducted on token buy transactions.
    * @param _operationsTaxSellPercentage The tax to be deducted on token sell transactions.
    * @param _maxTxAmount The maximum token amount that can be transferred in a single transaction.
    * @param _maxWalletAmount The maximum token amount that a non-whitelisted address can hold.
    */

    constructor(
        string memory _symbol,
        string memory _name,
        uint _totalSupply,
        address _treasure,
        address _owner,
        address _router,
        address _operationsWalletAddress,
        uint _operationsTaxBuyPercentage,
        uint _operationsTaxSellPercentage,
        uint _maxTxAmount,
        uint _maxWalletAmount
    )
    ERC20(_name, _symbol)
        /// @dev on OZ 5, we need to inform the contract admin:
    Ownable(_owner)
    {
        maxTxAmount = _maxTxAmount;
        maxWalletAmount = _maxWalletAmount;
        operationsTaxBuy = _operationsTaxBuyPercentage;
        operationsTaxSell = _operationsTaxSellPercentage;

        router = IUniswapV2Router02(_router);
        operationsWallet = _operationsWalletAddress;

        /// @dev: full whitelist treasure as it has all supply:
        whitelistedAddresses[_treasure] = true;
        hasFee[_treasure] = true;

        /// @dev whitelist other important addresses:
        whitelistedAddresses[owner()] = true;
        whitelistedAddresses[operationsWallet] = true;
        whitelistedAddresses[address(this)] = true;
        whitelistedAddresses[_owner] = true;
        whitelistedAddresses[msg.sender] = true; // to be able to add liquidity
        hasFee[address(router)] = true;
        hasFee[msg.sender] = true;
        hasFee[operationsWallet] = true;
        hasFee[address(this)] = true;

        /// @dev: supply is minted to treasure:

        _mint(_treasure, _totalSupply);

        uniswapV2Pair = IUniswapV2Factory(router.factory()).createPair(
            address(this),
            router.WETH()
        );
    }

    /**
    * @dev Overrides the OpenZeppelin `_update` function with added functionality.
    *
    * Implements additional checks for non-whitelisted addresses - transactions must not exceed `maxTxAmount`
    * and a non-whitelisted receiver's balance after the transaction must not exceed `maxWalletAmount`.
    * Also, implements tax deductions for transactions made by non-whitelisted addresses - a `operationsTaxBuy`
    * for purchases and `operationsTaxSell` for sales. If the transaction amount surpasses these conditions or
    * the receiver's balance including the new amount does surpass `maxWalletAmount`, operations involving the Uniswap pair,
    * the function throws an error preventing the transaction.
    *
    * @param from The sender address.
    * @param to The recipient address.
    * @param amount The amount of tokens to be transferred.
    */
    function _update(
        address from,
        address to,
        uint256 amount
    ) internal override {
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }

        if (!whitelistedAddresses[from] && !whitelistedAddresses[to]) {
            if (to != uniswapV2Pair) {
                if (amount > maxTxAmount) {
                    revert ERC20TransferExceedsMaxTx(amount, maxTxAmount);
                }

                if ((amount + balanceOf(to)) > maxWalletAmount) {
                    revert ERC20TransferExceedsMaxWallet(
                        amount,
                        maxWalletAmount
                    );
                }
            }
        }

        uint256 transferAmount = amount;
        if (!hasFee[from] && !hasFee[to]) {
            if ((from == uniswapV2Pair || to == uniswapV2Pair)) {

                if (amount > maxTxAmount) {
                    revert ERC20ExceedsMaxTxAmount(amount, maxTxAmount);
                }
                // Buy
                if (
                    operationsTaxBuy > 0 &&
                    uniswapV2Pair == from &&
                    !whitelistedAddresses[to] &&
                    from != address(this)
                ) {
                    uint256 feeTokens = (amount * operationsTaxBuy) / 100;
                    super._transfer(from, address(this), feeTokens);
                    transferAmount = amount - feeTokens;
                }

                // Sell
                if (
                    uniswapV2Pair == to &&
                    !whitelistedAddresses[from] &&
                    to != address(this) &&
                    !_progressSwap
                ) {
                    uint256 taxSell = operationsTaxSell;
                    _progressSwap = true;
                    swapAndLiquify();
                    _progressSwap = false;

                    uint256 feeTokens = (amount * taxSell) / 100;
                    super._transfer(from, address(this), feeTokens);
                    transferAmount = amount - feeTokens;
                }
            }
        }
        super._update(from, to, transferAmount);
    }

    /**
     * @dev Swaps tokens stored in the contract to ether (ETH)
     *
     * This function is used to convert tokens in the contract (collected as fees)
     * to ETH. It is called during a sell operation when the `_progressSwap` flag
     * is true, indicating that a token swap operation is in progress.
     *
     * If the balance of tokens in the contract is greater than 0, the function
     * calls `_swapTokensForEth` function passing the total token balance of the contract.
     */
    function swapAndLiquify() internal {
        if (balanceOf(address(this)) == 0) {
            return;
        }
        uint256 contractTokenBalance = balanceOf(address(this));
        if (contractTokenBalance > 0) {
            _swapTokensForEth(contractTokenBalance, 0);
        }
    }

    /**
     * @dev Swaps a specified amount of tokens for ETH.
     * 
     * This function is an intermediary called by `swapAndLiquify` when the contract's balance is not empty.
     * It uses the Uniswap router to perform the swap, trading the contract's tokens for ETH. 
     * The function sets the necessary approvals for the router, formulates the swap path from the contract's token to WETH,
     * and then initiates the swap with Uniswap. The ETH is then held by the contract and can be withdrawn by the operations wallet.
     *
     * @param tokenAmount The amount of tokens to be swapped.
     * @param tokenAmountOut Expected minimum amount of ETH to receive from swap.
     */
    function _swapTokensForEth(
        uint256 tokenAmount,
        uint256 tokenAmountOut
    ) internal {
        address[] memory path = new address[](2);
        path[0] = address(this);
        path[1] = router.WETH();

        IERC20(address(this)).approve(address(router), type(uint256).max);

        router.swapExactTokensForETHSupportingFeeOnTransferTokens(
            tokenAmount,
            tokenAmountOut,
            path,
            address(this),
            block.timestamp
        );

        emit SwapAndLiquify(tokenAmount, address(this).balance);

    }

    /**
     * @dev Updates the contract's Uniswap pair
     *
     * This function allows the contract owner or the operations wallet to update
     * the contract's Uniswap pair. This can be useful to change the liquidity pool in which the token is trading.
     *
     * To prevent misuse, it verifies the new pair address is non-zero and not equivalent to the DEAD address.
     * Reverts with 'InvalidAddress' error if the address is invalid.
     *
     * @param _pair The address of the new Uniswap pair.
     */
    function updatePair(address _pair) external onlyOwnerOrOperations {
        if (_pair == DEAD || _pair == address(0)) {
            revert InvalidAddress(_pair);
        }
        if( _pair.code.length == 0 ) {
            revert InvalidAddress(_pair);
        }

        IUniswapV2Pair pair = IUniswapV2Pair(_pair);
        // @dev: check if the pair is valid:
        address token0 = pair.token0();
        address token1 = pair.token1();
        if (token0 != address(this) && token1 != address(this)) {
            revert InvalidAddress(_pair);
        }

        emit PoolChanged(uniswapV2Pair, _pair);

        uniswapV2Pair = _pair;
    }

    /**
    * @dev Updates the operations wallet address
    *
    * This function allows the contract owner or the operations wallet to update
    * the operations wallet address. This can be useful to change the wallet that receives
    * the operations tax.
    *
    * To prevent misuse, it verifies the new wallet address is non-zero and not equivalent to the DEAD address.
    * Reverts with 'InvalidAddress' error if the address is invalid.
    *
    * @param _newWallet The address of the new operations wallet.
    */
    function setOperationsWallet( address _newWallet ) external onlyOwnerOrOperations {

        // @dev: set new wallet:
        operationsWallet = _newWallet;

        // @dev: add new wallet to whitelist:
        whitelistedAddresses[operationsWallet] = true;
        hasFee[operationsWallet] = true;

        emit SetOperationsWallet(_newWallet);
    }

    /**
    * @dev Calculates the upper limit for the number of tokens that can be transferred
    * in a single transaction.
    *
    * The upper limit is defined as 10% of the total token supply. The value can be used
    * as an argument to set the `maxTxAmount` and `maxWalletAmount` in the contract.
    *
    * @return {uint256} - Returns the upper limit value for the maximum transaction amount.
    */
    function getUpperTxValue() public view returns (uint256) {
        return (totalSupply() * 10) / 100;
    }

    /**
    * @dev Calculates the lower limit for the number of tokens that can be transferred
    * in a single transaction.
    *
    * The lower limit is defined as 0.5% of the total token supply. The value can be used
    * as an argument to verify the `maxTxAmount` and `maxWalletAmount` in the contract.
    *
    * @return {uint256} - Returns the lower limit value for the maximum transaction amount.
    */
    function getLowerTxValue() public view returns (uint256) {
        return (totalSupply() * 1) / 200;
    }

    /**
     * @dev Updates the maximum number of tokens that can be transferred in a single transaction (`maxTxAmount`).
     *
     * This function is accessible only to the contract owner. It allows the modification of `maxTxAmount`,
     * thereby changing the upper limit for the number of tokens that can be transferred in a single transaction
     * by non-whitelisted addresses. The new `maxTxAmount` needs to be within the range of 0.5% to 10%
     * of the total token supply. If out of this range, the function will revert.
     *
     * @param _maxTxAmount {uint256} - The new maximum number of tokens that can be transferred in a single transaction.
     */
    function maxTxAmountChange(
        uint256 _maxTxAmount
    ) external onlyOwner {

        if (_maxTxAmount > getUpperTxValue() ) {
            revert CannotSetMaxTxAmountToMoreThan10Percent();
        }

        if (_maxTxAmount < getLowerTxValue() ) {
            revert CannotSetMaxTxAmountToLessThanHalfPercent();
        }

        emit MaxTxAmountChange(maxTxAmount, _maxTxAmount);

        maxTxAmount = _maxTxAmount;

    }

    /**
     * @dev Updates the maximum number of tokens that a non-whitelisted address can hold (`maxWalletAmount`).
     *
     * This function is accessible only to the contract owner. It allows the modification of `maxWalletAmount`,
     * thereby changing the upper limit for the number of tokens that a non-whitelisted address can hold.
     * The new `maxWalletAmount` needs to be within the range of 0.5% to 10% of the total token supply.
     * If out of this range, the function will revert.
     *
     * @param _maxWalletAmount {uint256} - The new maximum number of tokens that any non-whitelisted address can hold.
     */
    function maxWalletChange(
        uint256 _maxWalletAmount
    ) external onlyOwner {

        if (_maxWalletAmount > getUpperTxValue() ) {
            revert CannotSetMaxTxAmountToMoreThan10Percent();
        }

        if (_maxWalletAmount < getLowerTxValue() ) {
            revert CannotSetMaxTxAmountToLessThanHalfPercent();
        }

        emit MaxWalletChange(maxWalletAmount, _maxWalletAmount);

        maxWalletAmount = _maxWalletAmount;
    }

    /**
    * @dev Transfers any ERC20 tokens sent by mistake to this contract, to the operations wallet.
    *
    * This function is accessible only to the contract owner or the operations wallet.
    * It allows the recovery of ERC20 tokens sent by mistake to this contract.
    *
    * @param token {address} - The contract address of the ER20 token to be withdrawn.
    */
    function withdrawTokens(address token) external onlyOwnerOrOperations {
        uint amount = IERC20(token).balanceOf(address(this));
        IERC20(token).transfer(operationsWallet, amount);
        emit WithdrawTokens(token, amount);
    }

    /**
    * @dev Transfers any ether sent by mistake to this contract or collected, to the operations wallet.
    *
    * This function is accessible only to the contract owner or the operations wallet.
    * It allows the recovery of ether sent by mistake to this contract or collect any fee accumulated in the contract.
    */
    function withdrawETH() external onlyOwnerOrOperations {
        uint amount = address(this).balance;
        (bool success,) = address(operationsWallet).call{value: amount}("");
        if (!success) {
            revert CallFailed();
        }
        emit WithdrawETH(amount);
    }

    /**
    * @dev Modifies the whitelist status of an address for transactions limits and fees exemption.
    *
    * This function is accessible only to the contract owner or the operations wallet. It allows the modification of
    * the `whitelistedAddresses` mapping for a specific address which determines whether transactions involving
    * that address are exempt from the `maxTxAmount` and `maxWalletAmount` restrictions and transaction fees.
    *
    * @param addy {address} - The address whose whitelist status is to be modified.
    * @param changer {bool} - The new whitelist status. If true, the address will be whitelisted, otherwise, it will lose its whitelist status.
    */

    function emergencyTaxRemoval(
        address addy,
        bool changer
    ) external onlyOwnerOrOperations {
        whitelistedAddresses[addy] = changer;
        emit WhitelistAddress(addy, changer);
    }

    /**
    * @dev callback to receive ethers from uniswapV2Router when swaping
    */
    receive() external payable {}
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/draft-IERC6093.sol)
pragma solidity ^0.8.20;

/**
 * @dev Standard ERC20 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC20 tokens.
 */
interface IERC20Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientBalance(address sender, uint256 balance, uint256 needed);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC20InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC20InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `spender`’s `allowance`. Used in transfers.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     * @param allowance Amount of tokens a `spender` is allowed to operate with.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 needed);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC20InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `spender` to be approved. Used in approvals.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC20InvalidSpender(address spender);
}

/**
 * @dev Standard ERC721 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC721 tokens.
 */
interface IERC721Errors {
    /**
     * @dev Indicates that an address can't be an owner. For example, `address(0)` is a forbidden owner in EIP-20.
     * Used in balance queries.
     * @param owner Address of the current owner of a token.
     */
    error ERC721InvalidOwner(address owner);

    /**
     * @dev Indicates a `tokenId` whose `owner` is the zero address.
     * @param tokenId Identifier number of a token.
     */
    error ERC721NonexistentToken(uint256 tokenId);

    /**
     * @dev Indicates an error related to the ownership over a particular token. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param tokenId Identifier number of a token.
     * @param owner Address of the current owner of a token.
     */
    error ERC721IncorrectOwner(address sender, uint256 tokenId, address owner);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC721InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC721InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param tokenId Identifier number of a token.
     */
    error ERC721InsufficientApproval(address operator, uint256 tokenId);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC721InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC721InvalidOperator(address operator);
}

/**
 * @dev Standard ERC1155 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC1155 tokens.
 */
interface IERC1155Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     * @param tokenId Identifier number of a token.
     */
    error ERC1155InsufficientBalance(address sender, uint256 balance, uint256 needed, uint256 tokenId);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC1155InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC1155InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param owner Address of the current owner of a token.
     */
    error ERC1155MissingApprovalForAll(address operator, address owner);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC1155InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC1155InvalidOperator(address operator);

    /**
     * @dev Indicates an array length mismatch between ids and values in a safeBatchTransferFrom operation.
     * Used in batch transfers.
     * @param idsLength Length of the array of token identifiers
     * @param valuesLength Length of the array of token amounts
     */
    error ERC1155InvalidArrayLength(uint256 idsLength, uint256 valuesLength);
}

{
  "compilationTarget": {
    "contracts/Main.sol": "Main"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}