// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: BSD-3-Clause

pragma solidity ^0.8.0;

/***********************
* @author: squeebo_nft *
************************/

import "@openzeppelin/contracts/access/Ownable.sol";

contract Delegated is Ownable{
  mapping(address => bool) internal _delegates;

  constructor(){
    _delegates[owner()] = true;
  }

  modifier onlyDelegates {
    require(_delegates[msg.sender], "Invalid delegate" );
    _;
  }

  //onlyOwner
  function isDelegate( address addr ) external view onlyOwner returns ( bool ){
    return _delegates[addr];
  }

  function setDelegate( address addr, bool isDelegate_ ) external onlyOwner{
    _delegates[addr] = isDelegate_;
  }

  function transferOwnership(address newOwner) public virtual override onlyOwner {
    _delegates[newOwner] = true;
    super.transferOwnership( newOwner );
  }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/structs/EnumerableSet.sol)

pragma solidity ^0.8.0;

/**
 * @dev Library for managing
 * https://en.wikipedia.org/wiki/Set_(abstract_data_type)[sets] of primitive
 * types.
 *
 * Sets have the following properties:
 *
 * - Elements are added, removed, and checked for existence in constant time
 * (O(1)).
 * - Elements are enumerated in O(n). No guarantees are made on the ordering.
 *
 * ```
 * contract Example {
 *     // Add the library methods
 *     using EnumerableSet for EnumerableSet.AddressSet;
 *
 *     // Declare a set state variable
 *     EnumerableSet.AddressSet private mySet;
 * }
 * ```
 *
 * As of v3.3.0, sets of type `bytes32` (`Bytes32Set`), `address` (`AddressSet`)
 * and `uint256` (`UintSet`) are supported.
 */
library EnumerableSet {
    // To implement this library for multiple types with as little code
    // repetition as possible, we write it in terms of a generic Set type with
    // bytes32 values.
    // The Set implementation uses private functions, and user-facing
    // implementations (such as AddressSet) are just wrappers around the
    // underlying Set.
    // This means that we can only create new EnumerableSets for types that fit
    // in bytes32.

    struct Set {
        // Storage of set values
        bytes32[] _values;
        // Position of the value in the `values` array, plus 1 because index 0
        // means a value is not in the set.
        mapping(bytes32 => uint256) _indexes;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function _add(Set storage set, bytes32 value) private returns (bool) {
        if (!_contains(set, value)) {
            set._values.push(value);
            // The value is stored at length-1, but we add 1 to all indexes
            // and use 0 as a sentinel value
            set._indexes[value] = set._values.length;
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function _remove(Set storage set, bytes32 value) private returns (bool) {
        // We read and store the value's index to prevent multiple reads from the same storage slot
        uint256 valueIndex = set._indexes[value];

        if (valueIndex != 0) {
            // Equivalent to contains(set, value)
            // To delete an element from the _values array in O(1), we swap the element to delete with the last one in
            // the array, and then remove the last element (sometimes called as 'swap and pop').
            // This modifies the order of the array, as noted in {at}.

            uint256 toDeleteIndex = valueIndex - 1;
            uint256 lastIndex = set._values.length - 1;

            if (lastIndex != toDeleteIndex) {
                bytes32 lastvalue = set._values[lastIndex];

                // Move the last value to the index where the value to delete is
                set._values[toDeleteIndex] = lastvalue;
                // Update the index for the moved value
                set._indexes[lastvalue] = valueIndex; // Replace lastvalue's index to valueIndex
            }

            // Delete the slot where the moved value was stored
            set._values.pop();

            // Delete the index for the deleted slot
            delete set._indexes[value];

            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function _contains(Set storage set, bytes32 value) private view returns (bool) {
        return set._indexes[value] != 0;
    }

    /**
     * @dev Returns the number of values on the set. O(1).
     */
    function _length(Set storage set) private view returns (uint256) {
        return set._values.length;
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function _at(Set storage set, uint256 index) private view returns (bytes32) {
        return set._values[index];
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function _values(Set storage set) private view returns (bytes32[] memory) {
        return set._values;
    }

    // Bytes32Set

    struct Bytes32Set {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _add(set._inner, value);
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _remove(set._inner, value);
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(Bytes32Set storage set, bytes32 value) internal view returns (bool) {
        return _contains(set._inner, value);
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(Bytes32Set storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(Bytes32Set storage set, uint256 index) internal view returns (bytes32) {
        return _at(set._inner, index);
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(Bytes32Set storage set) internal view returns (bytes32[] memory) {
        return _values(set._inner);
    }

    // AddressSet

    struct AddressSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(AddressSet storage set, address value) internal returns (bool) {
        return _add(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(AddressSet storage set, address value) internal returns (bool) {
        return _remove(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(AddressSet storage set, address value) internal view returns (bool) {
        return _contains(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(AddressSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(AddressSet storage set, uint256 index) internal view returns (address) {
        return address(uint160(uint256(_at(set._inner, index))));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(AddressSet storage set) internal view returns (address[] memory) {
        bytes32[] memory store = _values(set._inner);
        address[] memory result;

        assembly {
            result := store
        }

        return result;
    }

    // UintSet

    struct UintSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(UintSet storage set, uint256 value) internal returns (bool) {
        return _add(set._inner, bytes32(value));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(UintSet storage set, uint256 value) internal returns (bool) {
        return _remove(set._inner, bytes32(value));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(UintSet storage set, uint256 value) internal view returns (bool) {
        return _contains(set._inner, bytes32(value));
    }

    /**
     * @dev Returns the number of values on the set. O(1).
     */
    function length(UintSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(UintSet storage set, uint256 index) internal view returns (uint256) {
        return uint256(_at(set._inner, index));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(UintSet storage set) internal view returns (uint256[] memory) {
        bytes32[] memory store = _values(set._inner);
        uint256[] memory result;

        assembly {
            result := store
        }

        return result;
    }
}

// SPDX-License-Identifier: BSD-3-Clause
pragma solidity ^0.8.0;
import "@openzeppelin/contracts/interfaces/IERC20.sol";

interface IAeon is IERC20 {
    function mint(address to, uint256 qty) external;

    function burn(uint256 qty) external;

    function burnFrom(address from, uint256 qty) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (interfaces/IERC721.sol)

pragma solidity ^0.8.0;

import "../token/ERC721/IERC721.sol";

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC721/IERC721Receiver.sol)

pragma solidity ^0.8.0;

/**
 * @title ERC721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be reverted.
     *
     * The selector can be obtained in Solidity with `IERC721.onERC721Received.selector`.
     */
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}

// SPDX-License-Identifier: BSD-3-Clause
pragma solidity ^0.8.9;

import "@openzeppelin/contracts/interfaces/IERC721.sol";

interface ISanctum is IERC721 {
    function mint(address _to, address _for) external;

    function totalSupply() external returns (uint256);

    function getDistributionLimit(address _address) external view returns (uint256);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: BSD-3-Clause
pragma solidity ^0.8.9;
import "@openzeppelin/contracts/interfaces/IERC20.sol";
import "@openzeppelin/contracts/interfaces/IERC721.sol";
import "@openzeppelin/contracts/interfaces/IERC721Receiver.sol";
import "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";

import "./Delegated.sol";
import "../Interfaces/ISanctum.sol";
import "../Interfaces/IAeon.sol";

contract RirisuStaking is IERC721Receiver, Delegated {
    using EnumerableSet for EnumerableSet.UintSet;

    uint256 private LORE_COST = 100 ether; // 100 AEON

    uint256 private NAME_COST = 100 ether; // 100 AEON

    uint128 public immutable MAX_RIRI_LEVEL = 80;

    uint128[] public MODIFIERS = [uint128(100), 125, 150, 225];

    uint128[][] public RARITIES = [[uint128(6301), 9001, 9901, 10_001], [uint128(6301), 9001, 9801, 10_001]];

    uint256[] public ENCHANT_COST = [
        uint256(5 ether),
        44 ether,
        86 ether,
        130 ether,
        130 ether,
        172 ether,
        172 ether,
        172 ether,
        172 ether
    ];

    // maps token id to staking info
    mapping(uint256 => Riri) internal riris;
    // maps token id to staking info
    mapping(uint256 => Sanctum) internal sanctums;

    mapping(uint256 => uint128[]) internal rooms;

    mapping(address => EnumerableSet.UintSet) private stkdRiris;

    mapping(address => EnumerableSet.UintSet) private stkdSanctums;

    mapping(uint256 => bool) private legendaries;

    IERC721 internal riri;

    ISanctum internal sanctum;

    IAeon internal aeon;

    bytes32 internal entropySauce;

    enum Actions {
        UNSTAKE,
        STAKE,
        CHANNEL
    }

    enum RoomRarity {
        COMMON,
        UNCOMMON,
        RARE,
        MYTHIC
    }

    struct Sanctum {
        address owner;
        uint128 totalStaked;
        uint128 level;
        Actions action;
    }

    struct Riri {
        address owner;
        uint256 sanctum; // should this be int?
        uint256 timestamp;
        uint128 level;
        uint128 rerolls;
        Actions action;
        string name;
        string description;
    }

    struct StakeMeta {
        uint256 rewardMultiplier;
    }

    constructor(
        address ririAddress,
        address sanctumAddress,
        address aeonAddress
    ) {
        riri = IERC721(ririAddress);
        sanctum = ISanctum(sanctumAddress);
        aeon = IAeon(aeonAddress);
    }

    modifier noCheaters() {
        uint256 size = 0;
        address acc = msg.sender;
        assembly {
            size := extcodesize(acc)
        }

        require(msg.sender == tx.origin && size == 0, "you're trying to cheat!");
        _;

        // We'll use the last caller hash to add entropy to next caller
        entropySauce = keccak256(abi.encodePacked(acc, block.coinbase));
    }

    function setLegendaries(uint256[] calldata _legendaries) external onlyDelegates {
        for (uint256 i = 0; i < _legendaries.length; i++) {
            legendaries[_legendaries[i]] = true;
        }
    }

    function removeLegendaries(uint256[] calldata _legendaries) external onlyDelegates {
        for (uint256 i = 0; i < _legendaries.length; i++) {
            legendaries[_legendaries[i]] = false;
        }
    }

    // claim sanctum token
    function claimSanctum(bool autoStake) public noCheaters {
        uint256 tokenId = sanctum.totalSupply();
        if (autoStake) {
            sanctum.mint(address(this), msg.sender);
            sanctums[tokenId] = Sanctum(msg.sender, 0, 0, Actions.STAKE);
            stkdSanctums[msg.sender].add(tokenId);
        } else {
            sanctum.mint(msg.sender, msg.sender);
        }
        _generateNewRoom(tokenId);
    }

    function claimAllSanctums(bool autoStake) external noCheaters {
        uint256 limit = sanctum.getDistributionLimit(msg.sender);
        if (limit > 7) {
            limit = 7;
        }

        for (uint256 i = 0; i < limit; i++) {
            claimSanctum(autoStake);
        }
    }

    // claim from riri ID
    function claimForRiri(uint256 id) public noCheaters {
        Riri memory currentRiri = riris[id];
        // TODO: events
        if (block.timestamp <= currentRiri.timestamp) return;
        uint256 timediff = block.timestamp - currentRiri.timestamp;
        if (currentRiri.action == Actions.STAKE) {
            uint256 mod = _aggregateRarity(currentRiri.sanctum, currentRiri.level);
            aeon.mint(currentRiri.owner, _claimableAeon(timediff, mod, legendaries[id]));
            currentRiri.timestamp = block.timestamp; // reset timestamp
        }
        if (currentRiri.action == Actions.CHANNEL) {
            uint128 claimableLevels = _claimableLevels(timediff);

            currentRiri.level = (currentRiri.level + claimableLevels > MAX_RIRI_LEVEL)
                ? (MAX_RIRI_LEVEL)
                : (currentRiri.level + claimableLevels);

            currentRiri.timestamp = block.timestamp; // reset timestamp
            riris[id] = currentRiri;
        }
    }

    function claimAll(uint256[] calldata ririIds) external {
        for (uint256 i = 0; i < ririIds.length; i++) {
            claimForRiri(ririIds[i]);
        }
    }

    function doActionsWithSanctums(uint256[] calldata ids, Actions[] calldata actions) external {
        require(ids.length == actions.length, "ids and actions must be the same length");
        for (uint256 i = 0; i < ids.length; i++) {
            Sanctum memory s = sanctums[ids[i]];
            require(ownerOfSanctum(ids[i]) == msg.sender, "You are not the owner of this Sanctum! uwu");
            require(actions[i] < Actions.CHANNEL, "sanctum: invalid action");
            if (actions[i] == Actions.UNSTAKE) {
                require(s.totalStaked == 0, "Sanctum must not have staked tokens to unstake");

                s.action = Actions.UNSTAKE;
                s.owner = address(0);
                sanctums[ids[i]] = s;
                stkdSanctums[msg.sender].remove(ids[i]);
                sanctum.safeTransferFrom(address(this), msg.sender, ids[i]); // transfer from staking contract to owner
            }
            if (actions[i] == Actions.STAKE) {
                require(sanctum.getApproved(ids[i]) == address(this), "Sanctum must be approved staking");
                s.action = Actions.STAKE;
                s.owner = msg.sender;
                s.totalStaked = 0;
                sanctums[ids[i]] = s;
                stkdSanctums[msg.sender].add(ids[i]);
                sanctum.safeTransferFrom(msg.sender, address(this), ids[i]);
            }
        }
    }

    function doActionsWithRiris(
        uint256[] calldata ids,
        Actions[] calldata actions,
        uint256[] calldata sanctumIds
    ) external noCheaters {
        require(
            ids.length == actions.length && actions.length == sanctumIds.length,
            "ids and actions must be the same length"
        );

        for (uint256 i = 0; i < ids.length; i++) {
            Riri memory r = riris[ids[i]];
            Sanctum memory s = sanctums[sanctumIds[i]];
            require(
                ownerOfRiri(ids[i]) == msg.sender && ownerOfSanctum(sanctumIds[i]) == msg.sender,
                "you do not own one of these tokens! qq"
            );
            if (actions[i] == Actions.UNSTAKE) {
                require(r.action == Actions.STAKE || r.action == Actions.CHANNEL, "Riri must be staked or channelling");
                require(r.sanctum == sanctumIds[i], "Riri must be in this sanctum");

                claimForRiri(ids[i]);

                r.action = Actions.UNSTAKE;
                r.timestamp = block.timestamp;
                r.owner = address(0);
                r.sanctum = 5555;
                s.totalStaked -= 1;

                sanctums[sanctumIds[i]] = s;
                riris[ids[i]] = r;

                stkdRiris[msg.sender].remove(ids[i]);
                riri.safeTransferFrom(address(this), msg.sender, ids[i]); // transfer from staking contract to owner
            }
            if (actions[i] == Actions.STAKE) {
                require(r.action == Actions.UNSTAKE || r.action == Actions.CHANNEL, "Riri must be unstaked");

                if (r.action == Actions.UNSTAKE) {
                    require(s.totalStaked < 5, "Sanctum has reached the maximum Riris staked");
                    require(
                        riri.getApproved(ids[i]) == address(this) || riri.isApprovedForAll(msg.sender, address(this)),
                        "Ririsu must be approved staking"
                    );

                    r.sanctum = sanctumIds[i];
                    riri.safeTransferFrom(msg.sender, address(this), ids[i]); // transfer from staking contract to owner
                    stkdRiris[msg.sender].add(ids[i]);
                } else {
                    require(r.sanctum == sanctumIds[i], "Riri must be in this sanctum");
                }

                r.action = Actions.STAKE;
                r.timestamp = block.timestamp;
                r.owner = address(msg.sender);

                s.totalStaked += 1;

                sanctums[sanctumIds[i]] = s;
                riris[ids[i]] = r;
            }
            if (actions[i] == Actions.CHANNEL) {
                require(
                    riri.getApproved(ids[i]) == address(this) || riri.isApprovedForAll(msg.sender, address(this)),
                    "Ririsu must be approved staking"
                );
                require(r.action == Actions.UNSTAKE || r.action == Actions.STAKE, "Riri must be unstaked or staked");
                // if ririsu is staked, we need to transfer it back to the staking contract
                if (r.action == Actions.UNSTAKE) {
                    require(s.totalStaked < 5, "Sanctum has reached the maximum Riris");
                    require(
                        riri.getApproved(ids[i]) == address(this) || riri.isApprovedForAll(msg.sender, address(this)),
                        "Ririsu must be approved staking"
                    );
                    r.sanctum = sanctumIds[i];
                    riri.safeTransferFrom(msg.sender, address(this), ids[i]); // transfer from staking contract to owner
                    stkdRiris[msg.sender].add(ids[i]);
                } else {
                    require(r.sanctum == sanctumIds[i], "Riri must be in this sanctum");
                }

                r.action = Actions.CHANNEL;
                r.timestamp = block.timestamp;
                r.owner = address(msg.sender);

                s.totalStaked += 1;

                sanctums[sanctumIds[i]] = s;
                riris[ids[i]] = r;
            }
        }
    }

    function _claimableLevels(uint256 timeDiff) internal pure returns (uint128 levels_) {
        levels_ = uint128(timeDiff / 12 hours); // 1 level every 12 hours uwu
    }

    function _aggregateRarity(uint256 id, uint256 ririLevel) internal view returns (uint256) {
        uint256 totalRarity = 0;
        uint128[] memory roomArray = getSanctumRooms(id);

        for (uint256 i = 0; i < roomArray.length && i < ((ririLevel / 10) + 1); i++) {
            totalRarity += uint256(roomArray[i]);
        }

        return totalRarity;
    }

    // claimable AEON
    function _claimableAeon(
        uint256 timeDiff,
        uint256 mod,
        bool isLegendary
    ) internal pure returns (uint256 aeon_) {
        uint256 base = isLegendary ? 525 : 300;
        aeon_ = ((timeDiff * (base + mod) * 1 ether) / 100 / 1 days);
    }

    function _generateNewRoom(uint256 _sanctumId) internal {
        rooms[_sanctumId].push(_pickRarity(_sanctumId, rooms[_sanctumId].length)); // todo generate random room
    }

    function _psued(uint128[] memory args) internal view returns (uint256) {
        bytes32 p1 = keccak256(abi.encodePacked((args)));
        bytes32 p2 = keccak256(
            abi.encodePacked(block.number, block.timestamp, block.difficulty, block.coinbase, entropySauce)
        );
        return uint256((p1 & p2) | (p1 ^ p2)) % 10_000;
    }

    function _pickRarity(uint256 _sanctumId, uint256 _roomNumber) internal view returns (uint128 rarity_) {
        uint256 ps = _psued(getSanctumRooms(_sanctumId));
        uint256 roomNumber = _roomNumber < 2 ? _roomNumber : 1;
        uint128[] memory rarities = RARITIES[roomNumber];
        rarity_ = MODIFIERS[0];
        for (uint256 i = 0; i < rarities.length; i++) {
            if (ps < rarities[i]) {
                rarity_ = MODIFIERS[i];
                return rarity_;
            }
        }
    }

    // claimable view
    function claimable(uint256 id) external view returns (uint256 amount_) {
        require(riris[id].action > Actions.UNSTAKE, "Riri must be staked to claim");
        uint256 mod = _aggregateRarity(riris[id].sanctum, riris[id].level);
        uint256 timeDiff = block.timestamp > riris[id].timestamp ? uint256(block.timestamp - riris[id].timestamp) : 0;
        amount_ = riris[id].action == Actions.STAKE
            ? _claimableAeon(timeDiff, mod, legendaries[id])
            : (timeDiff * 3000) / 1 days;
    }

    // writeLore -- write lore on your NFT, so cool OwO
    function writeLore(uint256 id, string calldata lore) external {
        require(ownerOfRiri(id) == msg.sender, "You are not the owner of this Riri! uwu");
        require(
            aeon.allowance(msg.sender, address(this)) >= LORE_COST,
            "You don't have enough AEON to write lore! uwu"
        );
        require(bytes(riris[id].description).length == 0, "You have already edited the lore once in the past! q.q");

        aeon.burnFrom(msg.sender, LORE_COST);
        riris[id].description = lore;
    }

    // nameRiri -- name your NFT, so cool OwO
    function nameRiri(uint256 _id, string calldata _name) external {
        require(ownerOfRiri(_id) == msg.sender, "You are not the owner of this Riri! uwu");
        require(aeon.allowance(msg.sender, address(this)) >= NAME_COST, "You don't have enough AEON to rename! uwu");
        require(bytes(riris[_id].name).length == 0, "You have already edited the name once in the past! q.q");

        aeon.burnFrom(msg.sender, NAME_COST);
        riris[_id].name = _name;
    }

    function enchantRoom(
        uint256 _ririId,
        uint256 _sanctumId,
        uint256 _roomNumber
    ) external noCheaters {
        require(_sanctumId < sanctum.totalSupply(), "The sanctum is not valid!");
        require(_roomNumber < 9, "The room is not within the sanctum list!");
        require(_roomNumber < rooms[_sanctumId].length + 1, "Cant unlock that one yet!");
        require(riris[_ririId].rerolls < (riris[_ririId].level / 10), "Riri's level is too low to reroll!");

        require(
            aeon.allowance(msg.sender, address(this)) >= ENCHANT_COST[_roomNumber],
            "You don't have enough AEON to reroll!"
        );

        aeon.burnFrom(msg.sender, ENCHANT_COST[_roomNumber]);

        if (_roomNumber < rooms[_sanctumId].length) {
            rooms[_sanctumId][_roomNumber] = _pickRarity(_sanctumId, _roomNumber);
        } else {
            _generateNewRoom(_sanctumId);
        }
    }

    function ownerOfRiri(uint256 id) public view returns (address) {
        if (riri.ownerOf(id) == address(this)) return riris[id].owner;
        return riri.ownerOf(id);
    }

    function ownerOfSanctum(uint256 id) public view returns (address) {
        if (sanctum.ownerOf(id) == address(this)) return sanctums[id].owner;
        return sanctum.ownerOf(id);
    }

    function getSanctumRooms(uint256 _id) public view returns (uint128[] memory) {
        uint128[] memory rooms_ = new uint128[](rooms[_id].length);
        for (uint256 i = 0; i < rooms[_id].length; i++) {
            rooms_[i] = rooms[_id][i];
        }
        return rooms_;
    }

    function roomInfo(uint256 _id, uint256 _roomNumber) public view returns (uint128 roomType_, uint128 rarity_) {
        roomType_ = uint128(_roomNumber);
        rarity_ = rooms[_id][_roomNumber];
    }

    function stakedRiris(address _owner) public view returns (uint256[] memory riris_) {
        riris_ = stkdRiris[_owner].values();
    }

    function stakedSanctums(address _owner) public view returns (uint256[] memory sanctums_) {
        sanctums_ = stkdSanctums[_owner].values();
    }

    function ririMeta(uint256 _id) public view returns (Riri memory riri_) {
        riri_ = riris[_id];
    }

    function sanctumInfo(uint256 id) public view returns (Sanctum memory sanctum_) {
        sanctum_ = sanctums[id];
    }

    function onERC721Received(
        address,
        address,
        uint256,
        bytes memory
    ) public virtual override returns (bytes4) {
        return this.onERC721Received.selector;
    }
}

{
  "compilationTarget": {
    "src/Ririsu/RiriStaking.sol": "RirisuStaking"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs",
    "useLiteralContent": true
  },
  "optimizer": {
    "enabled": true,
    "runs": 2000
  },
  "remappings": []
}