// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Counters.sol)

pragma solidity ^0.8.0;

/**
 * @title Counters
 * @author Matt Condon (@shrugs)
 * @dev Provides counters that can only be incremented, decremented or reset. This can be used e.g. to track the number
 * of elements in a mapping, issuing ERC721 ids, or counting request ids.
 *
 * Include with `using Counters for Counters.Counter;`
 */
library Counters {
    struct Counter {
        // This variable should never be directly accessed by users of the library: interactions must be restricted to
        // the library's function. As of Solidity v0.5.2, this cannot be enforced, though there is a proposal to add
        // this feature: see https://github.com/ethereum/solidity/issues/4637
        uint256 _value; // default: 0
    }

    function current(Counter storage counter) internal view returns (uint256) {
        return counter._value;
    }

    function increment(Counter storage counter) internal {
        unchecked {
            counter._value += 1;
        }
    }

    function decrement(Counter storage counter) internal {
        uint256 value = counter._value;
        require(value > 0, "Counter: decrement overflow");
        unchecked {
            counter._value = value - 1;
        }
    }

    function reset(Counter storage counter) internal {
        counter._value = 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/cryptography/ECDSA.sol)

pragma solidity ^0.8.0;

import "../Strings.sol";

/**
 * @dev Elliptic Curve Digital Signature Algorithm (ECDSA) operations.
 *
 * These functions can be used to verify that a message was signed by the holder
 * of the private keys of a given address.
 */
library ECDSA {
    enum RecoverError {
        NoError,
        InvalidSignature,
        InvalidSignatureLength,
        InvalidSignatureS,
        InvalidSignatureV // Deprecated in v4.8
    }

    function _throwError(RecoverError error) private pure {
        if (error == RecoverError.NoError) {
            return; // no error: do nothing
        } else if (error == RecoverError.InvalidSignature) {
            revert("ECDSA: invalid signature");
        } else if (error == RecoverError.InvalidSignatureLength) {
            revert("ECDSA: invalid signature length");
        } else if (error == RecoverError.InvalidSignatureS) {
            revert("ECDSA: invalid signature 's' value");
        }
    }

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with
     * `signature` or error string. This address can then be used for verification purposes.
     *
     * The `ecrecover` EVM opcode allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {toEthSignedMessageHash} on it.
     *
     * Documentation for signature generation:
     * - with https://web3js.readthedocs.io/en/v1.3.4/web3-eth-accounts.html#sign[Web3.js]
     * - with https://docs.ethers.io/v5/api/signer/#Signer-signMessage[ethers]
     *
     * _Available since v4.3._
     */
    function tryRecover(bytes32 hash, bytes memory signature) internal pure returns (address, RecoverError) {
        if (signature.length == 65) {
            bytes32 r;
            bytes32 s;
            uint8 v;
            // ecrecover takes the signature parameters, and the only way to get them
            // currently is to use assembly.
            /// @solidity memory-safe-assembly
            assembly {
                r := mload(add(signature, 0x20))
                s := mload(add(signature, 0x40))
                v := byte(0, mload(add(signature, 0x60)))
            }
            return tryRecover(hash, v, r, s);
        } else {
            return (address(0), RecoverError.InvalidSignatureLength);
        }
    }

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with
     * `signature`. This address can then be used for verification purposes.
     *
     * The `ecrecover` EVM opcode allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {toEthSignedMessageHash} on it.
     */
    function recover(bytes32 hash, bytes memory signature) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, signature);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `r` and `vs` short-signature fields separately.
     *
     * See https://eips.ethereum.org/EIPS/eip-2098[EIP-2098 short signatures]
     *
     * _Available since v4.3._
     */
    function tryRecover(bytes32 hash, bytes32 r, bytes32 vs) internal pure returns (address, RecoverError) {
        bytes32 s = vs & bytes32(0x7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff);
        uint8 v = uint8((uint256(vs) >> 255) + 27);
        return tryRecover(hash, v, r, s);
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `r and `vs` short-signature fields separately.
     *
     * _Available since v4.2._
     */
    function recover(bytes32 hash, bytes32 r, bytes32 vs) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, r, vs);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `v`,
     * `r` and `s` signature fields separately.
     *
     * _Available since v4.3._
     */
    function tryRecover(bytes32 hash, uint8 v, bytes32 r, bytes32 s) internal pure returns (address, RecoverError) {
        // EIP-2 still allows signature malleability for ecrecover(). Remove this possibility and make the signature
        // unique. Appendix F in the Ethereum Yellow paper (https://ethereum.github.io/yellowpaper/paper.pdf), defines
        // the valid range for s in (301): 0 < s < secp256k1n ÷ 2 + 1, and for v in (302): v ∈ {27, 28}. Most
        // signatures from current libraries generate a unique signature with an s-value in the lower half order.
        //
        // If your library generates malleable signatures, such as s-values in the upper range, calculate a new s-value
        // with 0xFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFEBAAEDCE6AF48A03BBFD25E8CD0364141 - s1 and flip v from 27 to 28 or
        // vice versa. If your library also generates signatures with 0/1 for v instead 27/28, add 27 to v to accept
        // these malleable signatures as well.
        if (uint256(s) > 0x7FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF5D576E7357A4501DDFE92F46681B20A0) {
            return (address(0), RecoverError.InvalidSignatureS);
        }

        // If the signature is valid (and not malleable), return the signer address
        address signer = ecrecover(hash, v, r, s);
        if (signer == address(0)) {
            return (address(0), RecoverError.InvalidSignature);
        }

        return (signer, RecoverError.NoError);
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `v`,
     * `r` and `s` signature fields separately.
     */
    function recover(bytes32 hash, uint8 v, bytes32 r, bytes32 s) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, v, r, s);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Returns an Ethereum Signed Message, created from a `hash`. This
     * produces hash corresponding to the one signed with the
     * https://eth.wiki/json-rpc/API#eth_sign[`eth_sign`]
     * JSON-RPC method as part of EIP-191.
     *
     * See {recover}.
     */
    function toEthSignedMessageHash(bytes32 hash) internal pure returns (bytes32 message) {
        // 32 is the length in bytes of hash,
        // enforced by the type signature above
        /// @solidity memory-safe-assembly
        assembly {
            mstore(0x00, "\x19Ethereum Signed Message:\n32")
            mstore(0x1c, hash)
            message := keccak256(0x00, 0x3c)
        }
    }

    /**
     * @dev Returns an Ethereum Signed Message, created from `s`. This
     * produces hash corresponding to the one signed with the
     * https://eth.wiki/json-rpc/API#eth_sign[`eth_sign`]
     * JSON-RPC method as part of EIP-191.
     *
     * See {recover}.
     */
    function toEthSignedMessageHash(bytes memory s) internal pure returns (bytes32) {
        return keccak256(abi.encodePacked("\x19Ethereum Signed Message:\n", Strings.toString(s.length), s));
    }

    /**
     * @dev Returns an Ethereum Signed Typed Data, created from a
     * `domainSeparator` and a `structHash`. This produces hash corresponding
     * to the one signed with the
     * https://eips.ethereum.org/EIPS/eip-712[`eth_signTypedData`]
     * JSON-RPC method as part of EIP-712.
     *
     * See {recover}.
     */
    function toTypedDataHash(bytes32 domainSeparator, bytes32 structHash) internal pure returns (bytes32 data) {
        /// @solidity memory-safe-assembly
        assembly {
            let ptr := mload(0x40)
            mstore(ptr, "\x19\x01")
            mstore(add(ptr, 0x02), domainSeparator)
            mstore(add(ptr, 0x22), structHash)
            data := keccak256(ptr, 0x42)
        }
    }

    /**
     * @dev Returns an Ethereum Signed Data with intended validator, created from a
     * `validator` and `data` according to the version 0 of EIP-191.
     *
     * See {recover}.
     */
    function toDataWithIntendedValidatorHash(address validator, bytes memory data) internal pure returns (bytes32) {
        return keccak256(abi.encodePacked("\x19\x00", validator, data));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/cryptography/EIP712.sol)

pragma solidity ^0.8.8;

import "./ECDSA.sol";
import "../ShortStrings.sol";
import "../../interfaces/IERC5267.sol";

/**
 * @dev https://eips.ethereum.org/EIPS/eip-712[EIP 712] is a standard for hashing and signing of typed structured data.
 *
 * The encoding specified in the EIP is very generic, and such a generic implementation in Solidity is not feasible,
 * thus this contract does not implement the encoding itself. Protocols need to implement the type-specific encoding
 * they need in their contracts using a combination of `abi.encode` and `keccak256`.
 *
 * This contract implements the EIP 712 domain separator ({_domainSeparatorV4}) that is used as part of the encoding
 * scheme, and the final step of the encoding to obtain the message digest that is then signed via ECDSA
 * ({_hashTypedDataV4}).
 *
 * The implementation of the domain separator was designed to be as efficient as possible while still properly updating
 * the chain id to protect against replay attacks on an eventual fork of the chain.
 *
 * NOTE: This contract implements the version of the encoding known as "v4", as implemented by the JSON RPC method
 * https://docs.metamask.io/guide/signing-data.html[`eth_signTypedDataV4` in MetaMask].
 *
 * NOTE: In the upgradeable version of this contract, the cached values will correspond to the address, and the domain
 * separator of the implementation contract. This will cause the `_domainSeparatorV4` function to always rebuild the
 * separator from the immutable values, which is cheaper than accessing a cached version in cold storage.
 *
 * _Available since v3.4._
 *
 * @custom:oz-upgrades-unsafe-allow state-variable-immutable state-variable-assignment
 */
abstract contract EIP712 is IERC5267 {
    using ShortStrings for *;

    bytes32 private constant _TYPE_HASH =
        keccak256("EIP712Domain(string name,string version,uint256 chainId,address verifyingContract)");

    // Cache the domain separator as an immutable value, but also store the chain id that it corresponds to, in order to
    // invalidate the cached domain separator if the chain id changes.
    bytes32 private immutable _cachedDomainSeparator;
    uint256 private immutable _cachedChainId;
    address private immutable _cachedThis;

    bytes32 private immutable _hashedName;
    bytes32 private immutable _hashedVersion;

    ShortString private immutable _name;
    ShortString private immutable _version;
    string private _nameFallback;
    string private _versionFallback;

    /**
     * @dev Initializes the domain separator and parameter caches.
     *
     * The meaning of `name` and `version` is specified in
     * https://eips.ethereum.org/EIPS/eip-712#definition-of-domainseparator[EIP 712]:
     *
     * - `name`: the user readable name of the signing domain, i.e. the name of the DApp or the protocol.
     * - `version`: the current major version of the signing domain.
     *
     * NOTE: These parameters cannot be changed except through a xref:learn::upgrading-smart-contracts.adoc[smart
     * contract upgrade].
     */
    constructor(string memory name, string memory version) {
        _name = name.toShortStringWithFallback(_nameFallback);
        _version = version.toShortStringWithFallback(_versionFallback);
        _hashedName = keccak256(bytes(name));
        _hashedVersion = keccak256(bytes(version));

        _cachedChainId = block.chainid;
        _cachedDomainSeparator = _buildDomainSeparator();
        _cachedThis = address(this);
    }

    /**
     * @dev Returns the domain separator for the current chain.
     */
    function _domainSeparatorV4() internal view returns (bytes32) {
        if (address(this) == _cachedThis && block.chainid == _cachedChainId) {
            return _cachedDomainSeparator;
        } else {
            return _buildDomainSeparator();
        }
    }

    function _buildDomainSeparator() private view returns (bytes32) {
        return keccak256(abi.encode(_TYPE_HASH, _hashedName, _hashedVersion, block.chainid, address(this)));
    }

    /**
     * @dev Given an already https://eips.ethereum.org/EIPS/eip-712#definition-of-hashstruct[hashed struct], this
     * function returns the hash of the fully encoded EIP712 message for this domain.
     *
     * This hash can be used together with {ECDSA-recover} to obtain the signer of a message. For example:
     *
     * ```solidity
     * bytes32 digest = _hashTypedDataV4(keccak256(abi.encode(
     *     keccak256("Mail(address to,string contents)"),
     *     mailTo,
     *     keccak256(bytes(mailContents))
     * )));
     * address signer = ECDSA.recover(digest, signature);
     * ```
     */
    function _hashTypedDataV4(bytes32 structHash) internal view virtual returns (bytes32) {
        return ECDSA.toTypedDataHash(_domainSeparatorV4(), structHash);
    }

    /**
     * @dev See {EIP-5267}.
     *
     * _Available since v4.9._
     */
    function eip712Domain()
        public
        view
        virtual
        override
        returns (
            bytes1 fields,
            string memory name,
            string memory version,
            uint256 chainId,
            address verifyingContract,
            bytes32 salt,
            uint256[] memory extensions
        )
    {
        return (
            hex"0f", // 01111
            _name.toStringWithFallback(_nameFallback),
            _version.toStringWithFallback(_versionFallback),
            block.chainid,
            address(this),
            bytes32(0),
            new uint256[](0)
        );
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (interfaces/IERC5267.sol)

pragma solidity ^0.8.0;

interface IERC5267 {
    /**
     * @dev MAY be emitted to signal that the domain could have changed.
     */
    event EIP712DomainChanged();

    /**
     * @dev returns the fields and values that describe the domain separator used by this contract for EIP-712
     * signature.
     */
    function eip712Domain()
        external
        view
        returns (
            bytes1 fields,
            string memory name,
            string memory version,
            uint256 chainId,
            address verifyingContract,
            bytes32 salt,
            uint256[] memory extensions
        );
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC721/IERC721.sol)

pragma solidity ^0.8.0;

import "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId, bytes calldata data) external;

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Note that the caller is responsible to confirm that the recipient is capable of receiving ERC721
     * or else they may be permanently lost. Usage of {safeTransferFrom} prevents loss, though the caller must
     * understand this adds an external call which potentially creates a reentrancy vulnerability.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool approved) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

interface IIQNftStaking {
    /**
     * @dev Thrown when the address for proof verification is invalid.
     */
    error InvalidProofSourceAddress();

    /**
     * @dev Thrown when a staker attempts to claim rewards before the next claimable timestamp.
     * The staker must wait until the current block timestamp is greater than or equal to the nextClaimTimestamp.
     */
    error ClaimDelayNotPassed();

    /**
     * @dev Thrown when caller of stake function is not Staking Manager.
     */
    error CallerIsNotStakingManager();

    /**
     * @dev Thrown when the pool size is insufficient for a new staking action.
     */
    error InsufficientPoolSize();

    /**
     * @dev Thrown when trying to stake a token that is already staked.
     */
    error TokenAlreadyStaked();

    /**
     * @dev Thrown when the caller is not the owner of the NFT they are trying to stake.
     */
    error NotTheOwnerOfNft();

    /**
     * @dev Thrown when an attempt is made to withdraw a token that is not staked.
     */
    error NftNotStaked();

    /**
     * @dev Thrown when a user attempts to claim zero tokens.
     */
    error CantClaimZero();

    /**
     * @dev Thrown when a user attempts to withdraw zero tokens.
     */
    error CantWithdrawZero();

    /**
     * @dev Thrown when deployer tries to withdraw reward tokens when pool still active.
     */
    error StakingShouldBeDeactivated();

    /**
     * @dev Thrown when a staking-related action is attempted while staking is not active.
     */
    error StakingNotActive();

    /**
     * @notice Thrown when an attempt is made to deposit tokens into the staking pool after tokens have already been deposited.
     */
    error PoolAlreadyFunded();

    /**
     * @notice Thrown when an attempt is made to deposit zero tokens.
     */
    error PoolSizeMustBePositive();

    /**
     * @notice Thrown when an attempt is made to setup reward rate = 0.
     */
    error RewardRateMustBePositive();

    /**
     * @notice Thrown when an attempt is made to setup reward frequency = 0.
     */
    error RewardFrequencyMustBePositive();

    /**
     * @notice Thrown when an attempt is made to withdraw more than once.
     */
    error TokensAlreadyWithdrawn();

    /**
     * @notice Thrown when an attempt is made to withdraw more than the total accrued value.
     */
    error ZeroTotalAccruedValue();

    /**
     * @notice Thrown when an attempt is made to withdraw more than the total accrued value.
     */
    error TotalAccruedIsBiggerThanPoolSize();

    /**
     * @notice Thrown when an attempt is made to withdraw more than the total accrued value.
     */
    error InvalidWithdrawAmountIsBiggerThanLeft();

    /**
     * @dev Thrown when an unauthorized address attempts to claim tokens for a staker.
     */
    error UnauthorizedClaimAttempt();

    /**
     * @notice Emitted when a staker claims their reward tokens.
     * @param staker The address of the staker claiming tokens.
     * @param amount The amount of tokens claimed.
     * @param timestamp The timestamp when the claim occurred.
     * @param claimDetails Detailed information for each claim.
     */
    event TokensClaimed(address indexed staker, uint256 amount, uint256 timestamp, string claimDetails);

    /**
     * @notice Emitted when a staker stakes their NFTs.
     * @param staker The address of the staker.
     * @param tokenIds The array of token IDs that were staked.
     * @param timestamp The timestamp when the staking occurred.
     */
    event Staked(address indexed staker, uint256[] tokenIds, uint256 timestamp);

    /**
     * @notice Emitted when a staker withdraws their staked NFTs.
     * @param staker The address of the staker withdrawing tokens.
     * @param tokenIds The array of token IDs that were withdrawn.
     * @param timestamp The timestamp when the withdrawal occurred.
     */
    event WithdrawStakedTokens(address indexed staker, uint256[] tokenIds, uint256 timestamp);

    /**
     * @notice Emitted when tokens are deposited into the reward pool.
     * @param rewardTokenAddress The adress of reward token.
     * @param amount The amount of tokens deposited.
     * @param rewardRate Amount of reward tokens earned for each time interval specified in @rewardFrequency.
     * @param rewardFrequency Time interval in seconds between reward distributions.
     * @param timestamp The timestamp when the deposit occurred.
     */
    event TokensDeposited(address rewardTokenAddress, uint256 amount, uint256 rewardRate, uint256 rewardFrequency, uint256 timestamp);

    /**
     * @notice Emitted when staking is deactivated.
     * @param timestamp The timestamp when staking was deactivated.
     * @param totalRewardAccrued Quantity of tokens that users have earned and cannot be withdrawn by staking owner.
     */
    event StakingDeactivated(uint256 timestamp, uint256 totalRewardAccrued);

    /**
     * @notice Emitted when reward tokens was withdrawed by staking pool owner.
     * @param amount The amount of tokens withdrawed.
     */
    event TokensWithdrawedByOwner(uint256 amount);

    /**
     * @notice Emitted when a new staking manager is set for the staking contract.
     * @param stakingManager The address of the new staking manager.
     */
    event NewStakingManagerSet(address stakingManager);

    /**
     * @dev Stake NFTs by providing an array of token IDs.
     * @param tokenIds The array of token IDs to stake.
     * @param staker The address of staker.
     */
    function stake(uint256[] calldata tokenIds, address staker) external;

    /**
     * @dev Allows a staker to claim their reward tokens.
     * @param staker The address of the staker claiming tokens.
     * @param amount The amount of tokens to be claimed.
     * @param claimDetails detailed information for each claim.
     * @param signature The signature verifying the claim.
     */
    function claimTokens(address staker, uint256 amount, string memory claimDetails, bytes calldata signature) external;

    /**
     * @dev Withdraw staked NFTs by providing an array of token IDs.
     * @param tokenIds The array of token IDs to withdraw.
     * @param signature The signature verifying the withdrawal.
     */
    function withdraw(uint256[] calldata tokenIds, bytes calldata signature) external;

    /**
     * @dev Set reward pool address, pool size and deposit rewards tokens.
     * @param rewardTokenAddress Address of ERC20 reward token.
     * @param tokensPoolSize Quantity of reward tokens in staking pool.
     * @param rewardRate Amount of reward tokens earned for each time interval specified in @rewardFrequency.
     * @param rewardFrequency Time interval in seconds between reward distributions.
     * @notice Full amount should be deposited in 1 transaction.
     */
    function depositRewardTokens(address rewardTokenAddress, uint256 tokensPoolSize, uint256 rewardRate,
        uint256 rewardFrequency) external;

    /**
     * @dev Withdrawal of reward tokens from the pool.
     * @param amount The amount of reward tokens to withdraw.
     * @param signature The signature verifying the claim.
     * @notice Pool should be deactivated to perform, only for staking pool owner.
     */
    function withdrawRewardTokens(uint256 amount, bytes calldata signature) external;

    /**
     * @dev Deactivates staking, preventing any new stakes.
     * @notice Can be called only by staking owner.
     * @param totalRewardAccrued Quantity of tokens that users have earned and cannot be withdrawn.
     * @param signature The signature verifying the deactivation.
     */
    function deactivateStaking(uint256 totalRewardAccrued, bytes calldata signature) external;

    /**
     * @dev Set new staking manager for staking contract.
     * @param stakingManager New staking manager address.
     */
    function setStakingManager(address stakingManager) external;

    /**
     * @dev Returns the owner address of the specified staked token ID.
     * @param tokenId The token ID being queried.
     * @return The address of the owner of the specified staked token.
     */
    function getOwnerOfStakedTokenId(uint256 tokenId) external view returns (address);

    /**
     * @dev Returns an array of token IDs staked by a specified address.
     * @param staker The address of the staker.
     * @return An array of token IDs staked by the specified address.
     */
    function getStakedNftsByAddress(address staker) external view returns (uint256[] memory);

    /**
     * @dev Returns the total amount of tokens claimed by a specified address.
     * @param staker The address of the staker.
     * @return The total amount of tokens claimed by the specified address.
     */
    function getClaimedTokensByAddress(address staker) external view returns (uint256);

    /**
     * @dev Checks if the specified address has claimed their tokens before.
     * @param staker The address to check.
     * @return True if the specified address has claimed their tokens, false otherwise.
     */
    function hasClaimed(address staker) external view returns (bool);

    /**
     * @dev Returns the maximum size of the reward pool.
     * @return The maximum size of the reward pool in tokens.
     */
    function showMaxPoolSize() external view returns (uint256);

    /**
     * @dev Returns the total amount of tokens claimed from the pool.
     * @return The total amount of tokens that have been claimed.
     */
    function totalTokensClaimed() external view returns (uint256);

    /**
     * @dev Returns the total amount of tokens left in the reward pool.
     * @return The total amount of unclaimed tokens left in the pool.
     */
    function totalTokensLeft() external view returns (uint256);

    /**
     * @dev Returns the reward rate for staking.
     * @return The rate at which rewards are generated for staking.
     */
    function getRewardRate() external view returns (uint256);

    /**
     * @dev Returns the frequency at which rewards are calculated and can be claimed.
     * @return The frequency (in seconds) of reward calculation and availability.
     */
    function getRewardFrequency() external view returns (uint256);

    /**
     * @dev Returns the address of the reward token contract.
     * @return The contract address of the reward token.
     */
    function getRewardTokenAddress() external view returns (address);

    /**
     * @dev Returns the address of the NFT collection associated with this staking contract.
     * @return The contract address of the NFT collection.
     */
    function getNftCollectionAddress() external view returns (address);

    /**
     * @dev Get the Staking Manager address.
     * @return Staking Manager address.
     */
    function getStakingManagerAddress() external view returns (address);

    /**
     * @dev Get the proof source address.
     * @return Proof source address.
     */
    function getProofSourceAddress() external view returns (address);

    /**
     * @dev Get the next claimable timestamp for the specified staker.
     * @param claimer The address to check.
     * @return Timestamp when next claim will be available.
     */
    function getNextClaimTimestamp(address claimer) external view returns (uint256);

    /**
     * @dev Checks if staking is currently active.
     * @return True if staking is active, false otherwise.
     */
    function isStakingActive() external view returns (bool);

    /**
     * @dev Checks the delay between claims.
     * @return True claimed delay in seconds.
     */
    function getClaimedDelay() external view returns (uint256);

    /**
     * @dev Indicates total amount of accrued rewards for staked tokens.
     * Used for scenario, when pool owner terminates staking.
     */
    function getTotalAccruedReward() external view returns (uint256);

    /**
     * @dev Returns the nonce counter for a given address, which can be used to prevent replay attacks.
     * @param reserver The address for which the nonce counter is being queried.
     * @return The current nonce for the given address.
     */
    function nonceCounter(address reserver) external view returns (uint256);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "@openzeppelin/contracts/utils/Multicall.sol";
import "@openzeppelin/contracts/utils/cryptography/draft-EIP712.sol";
import "@openzeppelin/contracts/utils/Counters.sol";
import "@openzeppelin/contracts/utils/cryptography/ECDSA.sol";
import "@openzeppelin/contracts/access/Ownable2Step.sol";
import "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import "@openzeppelin/contracts/token/ERC721/IERC721.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "./IIQNftStaking.sol";


contract IQNftStaking is IIQNftStaking, EIP712, Multicall, Ownable2Step, ReentrancyGuard {
    using Counters for Counters.Counter;
    using SafeERC20 for IERC20;

     /**
     * @dev EIP-712 type hash for claiming tokens. Used in the claimTokens function to securely claim staking rewards.
     * This type hash includes the address of the staker, a nonce for replay protection, and the amount of tokens to claim.
     */
    bytes32 private constant CLAIM_TOKENS_TYPEHASH = keccak256(
        "ClaimTokens(address staker,uint256 nonce,uint256 amount,string claimDetails)"
    );

    /**
     * @dev EIP-712 type hash for withdrawing tokens. Used in the withdraw function to securely withdraw staked tokens.
     * This type hash includes the address of the staker, a nonce for replay protection, and the token IDs to withdraw.
    */
    bytes32 private constant WITHDRAW_TOKENS_TYPEHASH = keccak256(
        "Withdraw(address staker,uint256 nonce,uint256[] tokenIds)"
    );

    /**
     * @dev EIP-712 type hash for withdrawing reward tokens by the owner. Used in the withdrawRewardTokens function to securely withdraw tokens from the contract.
     * This type hash includes the address of the withdrawer, the amount of tokens to withdraw, and a nonce for replay protection.
     */
    bytes32 private constant WITHDRAW_REWARD_TOKENS_TYPEHASH = keccak256(
        "WithdrawRewardTokens(address withdrawer,uint256 amount,uint256 nonce)"
    );

    /**
     * @dev EIP-712 type hash for withdrawing reward tokens by the owner. Used in the deactivateStaking function to securely deactivate staking.
     * This type hash includes the address of the deactivator, the quantity of reward tokens accrued, and a nonce for replay protection.
     */
    bytes32 private constant DEACTIVATE_STAKING_TYPEHASH = keccak256(
        "DeactivateStaking(address deactivator,uint256 totalRewardAccrued,uint256 nonce)"
    );

    /**
     * @dev Nonce counters for each reserver.
     * Used to prevent replay attacks.
    */
    mapping(address => Counters.Counter) private _nonceCounters;

    /**
     * @dev NFT collection for staking.
     */
    IERC721 immutable _nftCollection;

    /**
     * @dev ERC20 reward token, that use for reward distribution.
     */
    IERC20 private _rewardToken;

    /**
     * @dev Indicates IQ signer account.
     */
    address immutable _proofSource;

    /**
     * @dev Indicates IQ Staking Manager address.
     */
    address private _stakingManager;

    /**
     * @dev Indicates maximum pool size.
     */
    uint256 private _poolSize;

    /**
     * @dev Indicates quantity of tokens, that staker get for 1 NFT in staking per 1 tic.
     */
    uint256 private _rewardRate;

    /**
     * @dev Indicates frequency of reward discribution (tics).
     */
    uint256 private _rewardFrequency;

    /**
     * @dev Indicates total amount of accrued rewards for staked tokens.
     * Used for scenario, when pool owner terminates staking.
     */
    uint256 private _totalRewardAccrued;

    /**
     * @dev Indicates total quantity of claimed tokens.
     */
    uint256 private _totalTokensClaimed;

    /**
     * @dev Indicates total quantity of tokens withdrawed by owner.
     */
    uint256 private _tokensWithdrawedByOwner;

    /**
     * @dev Indicates total quantity of tokens left in the pool.
     */
    uint256 private _totalTokensLeft;

    /**
     * @dev Indicates delay in seconds for claim transaction.
     */
    uint256 constant _claimDelay = 3600;

    /**
     * @dev Indicates next claim timestamp for each user.
     */
    mapping(address => uint256) private _nextClaimTimestamp;

    /**
     * @dev Indicates the status of staking pool.
     */
    bool private _stakingActive;

    /**
     * @dev Indicates the status of tokens withdrawed by owner.
     */
    bool private _tokensWithdrawn;

    /**
     * @dev Indicates staked tokens by address.
     */
    mapping(address => uint256[]) private _stakedTokens;

    /**
     * @dev Indicates indexes of staked tokens.
    */
    mapping(uint256 => uint256) private _stakedTokenIndexes;

    /**
     * @dev Indicates owners of staked tokens.
     */
    mapping(uint256 => address) private _tokenOwners;

    /**
     * @dev Indicates quantity of claimed tokens per address.
     */
    mapping(address => uint256) private _claimedTokens;

    /**
     * @dev Constructor for the IQStaking contract.
     * @param proofSource Address of the backend that will provide the signature for the reservation.
     * @param nftCollectionAddress ERC721 collection eligible for staking.
    */
    constructor(
        address proofSource,
        address stakingManager,
        address nftCollectionAddress,
        address owner
    ) payable EIP712("IQNftStaking", "1") {
        if (proofSource == address(0)) revert InvalidProofSourceAddress();
        _proofSource = proofSource;
        _stakingManager = stakingManager;
        _nftCollection = IERC721(nftCollectionAddress);
        _transferOwnership(owner);
    }

    /**
     * @inheritdoc IIQNftStaking
     */
    function stake(
        uint256[] calldata tokenIds,
        address staker
    ) external nonReentrant {
        if (msg.sender != _stakingManager) revert CallerIsNotStakingManager();
        if (!_stakingActive) revert StakingNotActive();

        bool hasNoStakedTokens = _stakedTokens[staker].length == 0;

        // execute staking logic
        for (uint i = 0; i < tokenIds.length; ++i) {
            unchecked {
                if (_nftCollection.ownerOf(tokenIds[i]) != staker) revert NotTheOwnerOfNft();

                _nftCollection.transferFrom(staker, address(this), tokenIds[i]);

                // Add the token to the staked array and map its index
                _stakedTokens[staker].push(tokenIds[i]);
                _stakedTokenIndexes[tokenIds[i]] = _stakedTokens[staker].length - 1;
                _tokenOwners[tokenIds[i]] = staker;
            }
        }

        if (hasNoStakedTokens) {
            _nextClaimTimestamp[staker] = block.timestamp + _claimDelay;
        }

        // emit event
        emit Staked(staker, tokenIds, block.timestamp);
    }

    /**
     * @inheritdoc IIQNftStaking
     */
    function claimTokens(
        address staker,
        uint256 amount,
        string memory claimDetails,
        bytes calldata signature
    ) external nonReentrant {
        // basic checks
        if (msg.sender != staker) revert UnauthorizedClaimAttempt();
        if (amount == 0) revert CantClaimZero();
        if (_nextClaimTimestamp[staker] > block.timestamp) revert ClaimDelayNotPassed();
        if (_totalTokensClaimed + amount > _poolSize) revert InsufficientPoolSize();

        // verify nonce
        uint256 nonce = _useNonce(staker);

        // generate typed data signature for verification
        bytes32 digest = _hashTypedDataV4(keccak256(abi.encode(
            CLAIM_TOKENS_TYPEHASH,
            staker,
            nonce,
            amount,
            keccak256(abi.encodePacked(claimDetails))
        )));

        // verify that signature from backend is correct
        require(_verifySignature(_proofSource, digest, signature));

        // execute claim logic
        _claimedTokens[staker] = _claimedTokens[staker] + amount;
        _totalTokensClaimed = _totalTokensClaimed + amount;
        _totalTokensLeft = _totalTokensLeft - amount;
        _nextClaimTimestamp[staker] = block.timestamp + _claimDelay;

        // safe transfer tokens to staker
        _rewardToken.safeTransfer(staker, amount);

        // emit event
        emit TokensClaimed(staker, amount, block.timestamp, claimDetails);
    }

    /**
     * @inheritdoc IIQNftStaking
     */
    function withdraw(
        uint256[] calldata tokenIds,
        bytes calldata signature
    ) external nonReentrant {
        uint256 length = tokenIds.length;
        address staker = msg.sender;

        // check that staker is the owner of the NFTs
        for (uint i = 0; i < length; ++i) {
            uint256 tokenId = tokenIds[i];

            // check that NFT is owned by this contract currently
            if (_nftCollection.ownerOf(tokenId) != address(this)) revert NftNotStaked();

            // check that staker is the owner of the NFT
            if (_tokenOwners[tokenId] != staker) revert NotTheOwnerOfNft();
        }

        // verify nonce
        uint256 nonce = _useNonce(staker);

        // generate typed data signature for verification
        bytes32 digest = _hashTypedDataV4(keccak256(abi.encode(
            WITHDRAW_TOKENS_TYPEHASH,
            staker,
            nonce,
            keccak256(abi.encodePacked(tokenIds))
        )));

        // verify that signature from backend is correct
        require(_verifySignature(_proofSource, digest, signature));

            for (uint i = 0; i < length; ++i) {
            uint256 tokenId = tokenIds[i];

            _nftCollection.transferFrom(address(this), staker, tokenId);

            _removeNftFromStaking(staker, tokenId);
        }

        emit WithdrawStakedTokens(msg.sender, tokenIds, block.timestamp);
    }

    function _removeNftFromStaking(address user, uint256 tokenId) private {
        uint256 lastTokenIndex = _stakedTokens[user].length - 1;
        uint256 tokenIndex = _stakedTokenIndexes[tokenId];

        // Move the last token to the place of the one to be removed
        if (tokenIndex != lastTokenIndex) {
            uint256 lastTokenId = _stakedTokens[user][lastTokenIndex];
            _stakedTokens[user][tokenIndex] = lastTokenId;
            _stakedTokenIndexes[lastTokenId] = tokenIndex;
        }

        // Remove the last element (now duplicated)
        _stakedTokens[user].pop();
        delete _stakedTokenIndexes[tokenId]; // Remove the index tracking
        delete _tokenOwners[tokenId]; // Update ownership mapping
    }

    /**
     * @inheritdoc IIQNftStaking
     */
    function depositRewardTokens(address rewardTokenAddress, uint256 tokensPoolSize, uint256 rewardRate,
        uint256 rewardFrequency) external onlyOwner {
        if (_poolSize != 0) revert PoolAlreadyFunded();
        if (tokensPoolSize == 0) revert PoolSizeMustBePositive();
        if (rewardRate == 0) revert RewardRateMustBePositive();
        if (rewardFrequency == 0) revert RewardFrequencyMustBePositive();


        _rewardToken = IERC20(rewardTokenAddress);
        _poolSize = tokensPoolSize;
        _totalTokensLeft = tokensPoolSize;
        _rewardRate = rewardRate;
        _rewardFrequency = rewardFrequency;

        _rewardToken.safeTransferFrom(msg.sender, address(this), _poolSize);
        _stakingActive = true;
        emit TokensDeposited(rewardTokenAddress, _poolSize, _rewardRate, _rewardFrequency, block.timestamp);
    }

    /**
     * @inheritdoc IIQNftStaking
     */
    function withdrawRewardTokens(uint256 amount, bytes calldata signature) external onlyOwner {
        if (_stakingActive) revert StakingShouldBeDeactivated();
        if (amount == 0) revert CantWithdrawZero();
        if (_tokensWithdrawn) revert TokensAlreadyWithdrawn();
        if (amount > _poolSize - _totalTokensClaimed) revert InvalidWithdrawAmountIsBiggerThanLeft();

        uint256 nonce = _useNonce(msg.sender);

        bytes32 digest = _hashTypedDataV4(keccak256(abi.encode(
            WITHDRAW_REWARD_TOKENS_TYPEHASH,
            msg.sender,
            amount,
            nonce
        )));

        require(_verifySignature(_proofSource, digest, signature));

        _rewardToken.safeTransfer(msg.sender, amount);

        _tokensWithdrawedByOwner = amount;
        _totalTokensLeft = _totalTokensLeft - amount;
        _tokensWithdrawn = true;

        emit TokensWithdrawedByOwner(amount);
    }

    /**
     * @inheritdoc IIQNftStaking
     */
    function deactivateStaking(uint256 totalRewardAccrued, bytes calldata signature) external onlyOwner {
        if (!_stakingActive) revert StakingNotActive();
        if (totalRewardAccrued == 0) revert ZeroTotalAccruedValue();
        if (totalRewardAccrued > _poolSize) revert TotalAccruedIsBiggerThanPoolSize();

        uint256 nonce = _useNonce(msg.sender);

        bytes32 digest = _hashTypedDataV4(keccak256(abi.encode(
            DEACTIVATE_STAKING_TYPEHASH,
            msg.sender,
            totalRewardAccrued,
            nonce
        )));

        require(_verifySignature(_proofSource, digest, signature));

        _stakingActive = false;
        _totalRewardAccrued = totalRewardAccrued;

        emit StakingDeactivated(block.timestamp, _totalRewardAccrued);
    }

    /**
     * @inheritdoc IIQNftStaking
     */
    function setStakingManager(address stakingManager) external {
        if (msg.sender != _stakingManager) revert CallerIsNotStakingManager();

        _stakingManager = stakingManager;

        emit NewStakingManagerSet(stakingManager);
    }

    /**
     * @inheritdoc IIQNftStaking
     */
    function getNextClaimTimestamp(address claimer) external view returns (uint256) {
        return _nextClaimTimestamp[claimer];
    }

    /**
     * @inheritdoc IIQNftStaking
     */
    function getOwnerOfStakedTokenId(uint256 tokenId) external view returns (address) {
        return _tokenOwners[tokenId];
    }

    /**
     * @inheritdoc IIQNftStaking
     */
    function getStakedNftsByAddress(address staker) external view returns (uint256[] memory) {
        return _stakedTokens[staker];
    }

    /**
     * @inheritdoc IIQNftStaking
     */
    function getClaimedTokensByAddress(address staker) external view returns (uint256) {
        return _claimedTokens[staker];
    }

    /**
     * @inheritdoc IIQNftStaking
     */
    function hasClaimed(address staker) external view returns (bool) {
        return _claimedTokens[staker] != 0;
    }

    /**
     * @inheritdoc IIQNftStaking
     */
    function showMaxPoolSize() external view returns (uint256) {
        return _poolSize;
    }

    /**
     * @inheritdoc IIQNftStaking
     */
    function totalTokensClaimed() external view returns (uint256) {
        return _totalTokensClaimed;
    }

    /**
     * @inheritdoc IIQNftStaking
     */
    function totalTokensLeft() external view returns (uint256) {
        return _totalTokensLeft;
    }

    /**
     * @inheritdoc IIQNftStaking
     */
    function getRewardRate() external view returns (uint256) {
        return _rewardRate;
    }

    /**
     * @inheritdoc IIQNftStaking
     */
    function getRewardFrequency() external view returns (uint256) {
        return _rewardFrequency;
    }

    /**
     * @inheritdoc IIQNftStaking
     */
    function getRewardTokenAddress() external view returns (address) {
        return address(_rewardToken);
    }

    /**
     * @inheritdoc IIQNftStaking
     */
    function getNftCollectionAddress() external view returns (address) {
        return address(_nftCollection);
    }

    /**
     * @inheritdoc IIQNftStaking
     */
     function getProofSourceAddress() external view returns (address) {
        return _proofSource;
    }

    /**
     * @inheritdoc IIQNftStaking
     */
     function getStakingManagerAddress() external view returns (address) {
        return _stakingManager;
    }

    /**
     * @inheritdoc IIQNftStaking
     */
    function isStakingActive() external view returns (bool) {
        return _stakingActive;
    }

    /**
     * @inheritdoc IIQNftStaking
     */
    function getClaimedDelay() external pure returns (uint256) {
        return _claimDelay;
    }

    /**
     * @inheritdoc IIQNftStaking
     */
    function getTotalAccruedReward() external view returns (uint256) {
        return _totalRewardAccrued;
    }

    /**
     * @inheritdoc IIQNftStaking
     */
    function nonceCounter(address reserver) external view returns (uint256) {
        return _nonceCounters[reserver].current();
    }

    /**
     * @dev Increments the nonce for the reserver and returns the used nonce.
     * @param reserver The address for which the nonce is being incremented.
     * @return The used nonce.
     */
    function _useNonce(address reserver) internal returns (uint256) {
        _nonceCounters[reserver].increment();
        return _nonceCounters[reserver].current() - 1; // Return the used nonce
    }

    /**
     * @dev Verifies the signature for the reservation.
     * @param signer The address that signed the reservation.
     * @param digest The hash of the reservation details.
     * @param signature The signature to verify.
     * @return True if the signature is valid, false otherwise.
     */
    function _verifySignature(
        address signer,
        bytes32 digest,
        bytes memory signature
    ) internal pure returns (bool) {
        return ECDSA.recover(digest, signature) == signer;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "./IQNftStaking.sol";

interface IStakingManager {

    /**
     * @notice Thrown when an attempt is made to withdraw funds from empty contract.
     */
    error CantWithdrawZero();

    /**
     * @notice Thrown when an attempt is made to send incorrect amount of ether to cover the fees.
     */
    error IncorrectEtherSent();

    /**
     * @notice Thrown when the address for proof verification is invalid.
     */
    error InvalidProofSourceAddress();

    /**
     * @notice Thrown when attemp to withdraw ether from contract failed.
     */
    error FailedToSendEther();

    /**
     * @notice Emitted when user deploy IQ NFT Staking.
     */
    event NftStakingDeployed(address indexed stakingContract, address indexed owner, address proofSource, address nftCollectionAddress);

    /**
     * @dev Emitted when the deployment price is set.
     * @param newDeploymentPrice Deployment price.
     */
    event DeploymentPriceSet(uint256 newDeploymentPrice);

    /**
     * @dev Emitted when the batch transaction fee is set.
     * @param newBatchTransactionFee Batch transaction fee.
     */
    event BatchTransactionFeeSet(uint256 newBatchTransactionFee);

    /**
     * @dev Emitted when the individual contract batch transaction fee is set.
     * @param stakingContract The address of the staking contract.
     * @param newBatchTransactionFee The new batch transaction fee.
     */
    event IndividualContractBatchTransactionFeeSet(address indexed stakingContract, uint256 newBatchTransactionFee);

    /**
     * @dev Emitted when the new StakingManager is set for existing IQNftStaking contract.
     * @param stakingContract The address of the staking contract.
     * @param newStakingManager The new StakingManager address.
     */
    event StakingManagerUpdated(address indexed stakingContract, address newStakingManager);

    /**
     * @dev Emitted when funds are withdrawn from the contract.
     * @param to The address to which the funds were sent.
     * @param amount Withdrawn amount.
     */
    event FundsWithdrawn(address indexed to, uint256 amount);

    /**
     * @dev Emitted when the individual contract batch transaction fee is deactivated.
     * @param stakingContract The address of the staking contract.
     */
    event IndividualContractBatchTransactionFeeDeactivated(address indexed stakingContract);

    /**
     * @dev Deploy IQNftStaking contract.
     * @param proofSource Backend address.
     * @param nftCollectionAddress ERC721 collection address.
     * @param signature eip712 signature.
     * @return Deployed contract address.
     */
    function deployNftStaking(address proofSource, address nftCollectionAddress, bytes calldata signature) payable external returns (address);

    /**
     * @dev Stake tokens in a specified staking contract.
     * @param stakingContract Address of the staking contract.
     * @param tokenIds Array of token IDs.
     * @param signature Backend signature.
     */
    function stake(address stakingContract, uint256[] calldata tokenIds, bytes calldata signature) payable external;

    /**
     * @dev Withdraw contract funds to a specified address.
     * @param _to Address to withdraw funds to.
     */
    function withdrawFunds(address payable _to) external;

    /**
     * @dev Set the deployment fee.
     * @param deploymentFee New deployment fee.
     */
    function setDeploymentPrice(uint256 deploymentFee) external;

    /**
     * @dev Set the batch transaction fee.
     * @param batchTransactionFee New batch transaction fee.
     */
    function setBatchTransactionFee(uint256 batchTransactionFee) external;

    /**
     * @dev Set new staking manager for staking contract.
     * @param stakingContract Address of the staking contract.
     * @param stakingManager New staking manager address.
     */
    function setStakingManager(address stakingContract, address stakingManager) external;

    /**
     * @dev Sets and activates the individual batch transaction fee for the specified staking contract.
     * @param stakingContract The address of the staking contract.
     * @param batchTransactionFee The individual batch transaction fee to be set for the specified staking contract.
     */
    function setIndividualContractBatchTransactionFee(address stakingContract, uint256 batchTransactionFee) external;

    /**
     * @dev Deactivates the individual batch transaction fee for the specified staking contract.
     * @param stakingContract The address of the staking contract.
     */
    function deactivateIndividualContractBatchTransactionFee(address stakingContract) external;

    /**
     * @dev Returns whether the individual batch transaction fee is active for the specified contract.
     * @param stakingContract The address of the staking contract.
     * @return True if the individual batch transaction fee is active, false otherwise.
     */
    function isIndividualBatchTransactionFeeActive(address stakingContract) external view returns (bool);

    /**
     * @dev Returns the individual batch transaction fee for the specified contract.
     * @param stakingContract The address of the staking contract.
     * @return The individual batch transaction fee.
     */
    function getIndividualBatchTransactionFee(address stakingContract) external view returns (uint256);

    /**
     * @dev Get the current deployment price.
     * @return Deployment price.
     */
    function getDeploymentPrice() external view returns (uint256);

    /**
     * @dev Get the current batch transaction fee.
     * @return Batch transaction fee.
     */
    function getBatchTransactionFee() external view returns (uint256);

    /**
     * @dev Get the proof source address.
     * @return Proof source address.
     */
    function getProofSourceAddress() external view returns (address);

    /**
     * @dev Get contract Balance.
     * @return Actual contract balance.
     */
    function getBalance() external view returns (uint256);

    /**
     * @dev Get the current nonce for a user.
     * @param user User address.
     * @return Current nonce.
     */
    function nonceCounter(address user) external view returns (uint256);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/math/Math.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library Math {
    enum Rounding {
        Down, // Toward negative infinity
        Up, // Toward infinity
        Zero // Toward zero
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds up instead
     * of rounding down.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv)
     * with further edits by Uniswap Labs also under MIT license.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod0 := mul(x, y)
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                // Solidity will revert if denominator == 0, unlike the div opcode on its own.
                // The surrounding unchecked block does not change this fact.
                // See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            require(denominator > prod1, "Math: mulDiv overflow");

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator. Always >= 1.
            // See https://cs.stackexchange.com/q/138556/92363.

            // Does not overflow because the denominator cannot be zero at this stage in the function.
            uint256 twos = denominator & (~denominator + 1);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also works
            // in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (rounding == Rounding.Up && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded down.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (rounding == Rounding.Up && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (rounding == Rounding.Up && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10 ** 64) {
                value /= 10 ** 64;
                result += 64;
            }
            if (value >= 10 ** 32) {
                value /= 10 ** 32;
                result += 32;
            }
            if (value >= 10 ** 16) {
                value /= 10 ** 16;
                result += 16;
            }
            if (value >= 10 ** 8) {
                value /= 10 ** 8;
                result += 8;
            }
            if (value >= 10 ** 4) {
                value /= 10 ** 4;
                result += 4;
            }
            if (value >= 10 ** 2) {
                value /= 10 ** 2;
                result += 2;
            }
            if (value >= 10 ** 1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (rounding == Rounding.Up && 10 ** result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256, rounded down, of a positive value.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 256, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (rounding == Rounding.Up && 1 << (result << 3) < value ? 1 : 0);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.5) (utils/Multicall.sol)

pragma solidity ^0.8.0;

import "./Address.sol";
import "./Context.sol";

/**
 * @dev Provides a function to batch together multiple calls in a single external call.
 *
 * Consider any assumption about calldata validation performed by the sender may be violated if it's not especially
 * careful about sending transactions invoking {multicall}. For example, a relay address that filters function
 * selectors won't filter calls nested within a {multicall} operation.
 *
 * NOTE: Since 5.0.1 and 4.9.4, this contract identifies non-canonical contexts (i.e. `msg.sender` is not {_msgSender}).
 * If a non-canonical context is identified, the following self `delegatecall` appends the last bytes of `msg.data`
 * to the subcall. This makes it safe to use with {ERC2771Context}. Contexts that don't affect the resolution of
 * {_msgSender} are not propagated to subcalls.
 *
 * _Available since v4.1._
 */
abstract contract Multicall is Context {
    /**
     * @dev Receives and executes a batch of function calls on this contract.
     * @custom:oz-upgrades-unsafe-allow-reachable delegatecall
     */
    function multicall(bytes[] calldata data) external virtual returns (bytes[] memory results) {
        bytes memory context = msg.sender == _msgSender()
            ? new bytes(0)
            : msg.data[msg.data.length - _contextSuffixLength():];

        results = new bytes[](data.length);
        for (uint256 i = 0; i < data.length; i++) {
            results[i] = Address.functionDelegateCall(address(this), bytes.concat(data[i], context));
        }
        return results;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable2Step.sol)

pragma solidity ^0.8.0;

import "./Ownable.sol";

/**
 * @dev Contract module which provides access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership} and {acceptOwnership}.
 *
 * This module is used through inheritance. It will make available all functions
 * from parent (Ownable).
 */
abstract contract Ownable2Step is Ownable {
    address private _pendingOwner;

    event OwnershipTransferStarted(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Returns the address of the pending owner.
     */
    function pendingOwner() public view virtual returns (address) {
        return _pendingOwner;
    }

    /**
     * @dev Starts the ownership transfer of the contract to a new account. Replaces the pending transfer if there is one.
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual override onlyOwner {
        _pendingOwner = newOwner;
        emit OwnershipTransferStarted(owner(), newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`) and deletes any pending owner.
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual override {
        delete _pendingOwner;
        super._transferOwnership(newOwner);
    }

    /**
     * @dev The new owner accepts the ownership transfer.
     */
    function acceptOwnership() public virtual {
        address sender = _msgSender();
        require(pendingOwner() == sender, "Ownable2Step: caller is not the new owner");
        _transferOwnership(sender);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.3) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/ShortStrings.sol)

pragma solidity ^0.8.8;

import "./StorageSlot.sol";

// | string  | 0xAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA   |
// | length  | 0x                                                              BB |
type ShortString is bytes32;

/**
 * @dev This library provides functions to convert short memory strings
 * into a `ShortString` type that can be used as an immutable variable.
 *
 * Strings of arbitrary length can be optimized using this library if
 * they are short enough (up to 31 bytes) by packing them with their
 * length (1 byte) in a single EVM word (32 bytes). Additionally, a
 * fallback mechanism can be used for every other case.
 *
 * Usage example:
 *
 * ```solidity
 * contract Named {
 *     using ShortStrings for *;
 *
 *     ShortString private immutable _name;
 *     string private _nameFallback;
 *
 *     constructor(string memory contractName) {
 *         _name = contractName.toShortStringWithFallback(_nameFallback);
 *     }
 *
 *     function name() external view returns (string memory) {
 *         return _name.toStringWithFallback(_nameFallback);
 *     }
 * }
 * ```
 */
library ShortStrings {
    // Used as an identifier for strings longer than 31 bytes.
    bytes32 private constant _FALLBACK_SENTINEL = 0x00000000000000000000000000000000000000000000000000000000000000FF;

    error StringTooLong(string str);
    error InvalidShortString();

    /**
     * @dev Encode a string of at most 31 chars into a `ShortString`.
     *
     * This will trigger a `StringTooLong` error is the input string is too long.
     */
    function toShortString(string memory str) internal pure returns (ShortString) {
        bytes memory bstr = bytes(str);
        if (bstr.length > 31) {
            revert StringTooLong(str);
        }
        return ShortString.wrap(bytes32(uint256(bytes32(bstr)) | bstr.length));
    }

    /**
     * @dev Decode a `ShortString` back to a "normal" string.
     */
    function toString(ShortString sstr) internal pure returns (string memory) {
        uint256 len = byteLength(sstr);
        // using `new string(len)` would work locally but is not memory safe.
        string memory str = new string(32);
        /// @solidity memory-safe-assembly
        assembly {
            mstore(str, len)
            mstore(add(str, 0x20), sstr)
        }
        return str;
    }

    /**
     * @dev Return the length of a `ShortString`.
     */
    function byteLength(ShortString sstr) internal pure returns (uint256) {
        uint256 result = uint256(ShortString.unwrap(sstr)) & 0xFF;
        if (result > 31) {
            revert InvalidShortString();
        }
        return result;
    }

    /**
     * @dev Encode a string into a `ShortString`, or write it to storage if it is too long.
     */
    function toShortStringWithFallback(string memory value, string storage store) internal returns (ShortString) {
        if (bytes(value).length < 32) {
            return toShortString(value);
        } else {
            StorageSlot.getStringSlot(store).value = value;
            return ShortString.wrap(_FALLBACK_SENTINEL);
        }
    }

    /**
     * @dev Decode a string that was encoded to `ShortString` or written to storage using {setWithFallback}.
     */
    function toStringWithFallback(ShortString value, string storage store) internal pure returns (string memory) {
        if (ShortString.unwrap(value) != _FALLBACK_SENTINEL) {
            return toString(value);
        } else {
            return store;
        }
    }

    /**
     * @dev Return the length of a string that was encoded to `ShortString` or written to storage using {setWithFallback}.
     *
     * WARNING: This will return the "byte length" of the string. This may not reflect the actual length in terms of
     * actual characters as the UTF-8 encoding of a single character can span over multiple bytes.
     */
    function byteLengthWithFallback(ShortString value, string storage store) internal view returns (uint256) {
        if (ShortString.unwrap(value) != _FALLBACK_SENTINEL) {
            return byteLength(value);
        } else {
            return bytes(store).length;
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/math/SignedMath.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard signed math utilities missing in the Solidity language.
 */
library SignedMath {
    /**
     * @dev Returns the largest of two signed numbers.
     */
    function max(int256 a, int256 b) internal pure returns (int256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two signed numbers.
     */
    function min(int256 a, int256 b) internal pure returns (int256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two signed numbers without overflow.
     * The result is rounded towards zero.
     */
    function average(int256 a, int256 b) internal pure returns (int256) {
        // Formula from the book "Hacker's Delight"
        int256 x = (a & b) + ((a ^ b) >> 1);
        return x + (int256(uint256(x) >> 255) & (a ^ b));
    }

    /**
     * @dev Returns the absolute unsigned value of a signed value.
     */
    function abs(int256 n) internal pure returns (uint256) {
        unchecked {
            // must be unchecked in order to support `n = type(int256).min`
            return uint256(n >= 0 ? n : -n);
        }
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "@openzeppelin/contracts/access/Ownable2Step.sol";
import "@openzeppelin/contracts/utils/cryptography/draft-EIP712.sol";
import "@openzeppelin/contracts/utils/Counters.sol";
import "@openzeppelin/contracts/utils/cryptography/ECDSA.sol";
import "./IIQNftStaking.sol";
import "./IStakingManager.sol";


contract StakingManager is IStakingManager, EIP712, Ownable2Step {
    using Counters for Counters.Counter;

    /**
     * @dev EIP-712 type hash for securely IQNFTStaking deployment.
     * This type hash includes the proofSource address, the nft collection address, msg.sender address and a nonce for replay protection.
     */
    bytes32 private constant DEPLOY_IQ_NFT_STAKING_TYPEHASH = keccak256(
        "DeployNftStaking(address proofSource,address nftCollectionAddress,address deployer,uint256 nonce)"
    );

    /**
     * @dev EIP-712 type hash for securely tokens staking.
     * This type hash includes the address of the staking contract, the array of tokens to stake, and a nonce for replay protection.
     */
    bytes32 private constant STAKE_TOKENS_TYPEHASH = keccak256(
        "StakeTokens(address stakingContract,uint256[] tokenIds,uint256 nonce)"
    );

    /**
     * @dev Nonce counters for eip712 verification.
     * Used to prevent replay attacks.
    */
    mapping(address => Counters.Counter) private _nonceCounters;

    /**
     * @dev Indicates deployment price of IQ Staking.
     */
    uint256 private _deploymentPrice;

    /**
     * @dev Indicates transaction fee for each staked subsequent NFT in a batch.
     */
    uint256 private _batchTransactionFee;

    /**
     * @dev Stores the individual batch transaction fee for each specific contract.
     */
    mapping(address => uint256) private _individualBatchTransactionFee;

    /**
     * @dev Indicates whether the individual batch transaction fee is active for each specific contract.
     */
    mapping(address => bool) private _isIndividualBatchTransactionFeeActive;

    /**
     * @dev Stores backend address that will provide the signatures.
     */
    address immutable _proofSource;

    /**
     * @dev Constructor for the StakingManager contract.
     * @param proofSource Address of the backend that will provide the signature for transaction verifications.
     * @param deploymentPrice Amount of fee for IQ Staking deployment.
     * @param batchTransactionFee Amount of fee for each staked subsequent NFT in a batch.
    */
    constructor(
        address proofSource,
        uint256 deploymentPrice,
        uint256 batchTransactionFee
    ) payable EIP712("StakingManager", "1") {
        if (proofSource == address(0)) revert InvalidProofSourceAddress();
        _proofSource = proofSource;
        _deploymentPrice = deploymentPrice;
        _batchTransactionFee = batchTransactionFee;
    }

    /**
     * @inheritdoc IStakingManager
     */
    function deployNftStaking(address proofSource, address nftCollectionAddress, bytes calldata signature) payable external returns (address) {
        // check msg.value is enough to cover deployment fee
        if (msg.value != _deploymentPrice) revert IncorrectEtherSent();

        uint256 nonce = _useNonce(msg.sender);
        address deployer = msg.sender;

        bytes32 digest = _hashTypedDataV4(keccak256(abi.encode(
            DEPLOY_IQ_NFT_STAKING_TYPEHASH,
            proofSource,
            nftCollectionAddress,
            deployer,
            nonce
        )));

        require(_verifySignature(_proofSource, digest, signature));

        IIQNftStaking stakingContract = new IQNftStaking(proofSource, address(this), nftCollectionAddress, deployer);
        emit NftStakingDeployed(address(stakingContract), deployer, proofSource, nftCollectionAddress);
        return address(stakingContract);
    }

    /**
     * @inheritdoc IStakingManager
     */
    function stake(address stakingContract, uint256[] calldata tokenIds, bytes calldata signature) payable external {
        // check msg.value is enough to cover transaction fee
        uint256 batchTransactionFee = _isIndividualBatchTransactionFeeActive[stakingContract] ? _individualBatchTransactionFee[stakingContract] : _batchTransactionFee;
        uint256 requiredFee = (tokenIds.length - 1) * batchTransactionFee;
        if (msg.value < requiredFee) revert IncorrectEtherSent();

        // verify nonce
        uint256 nonce = _useNonce(msg.sender);

        // generate typed data signature for verification
        bytes32 digest = _hashTypedDataV4(keccak256(abi.encode(
            STAKE_TOKENS_TYPEHASH,
            stakingContract,
            keccak256(abi.encodePacked(tokenIds)),
            nonce
        )));

        // verify that signature from backend is correct
        require(_verifySignature(_proofSource, digest, signature));

        IIQNftStaking(stakingContract).stake(tokenIds, msg.sender);
    }

    /**
     * @inheritdoc IStakingManager
     */
    function withdrawFunds(address payable _to) external onlyOwner {
        uint amount = address(this).balance;
        if(amount == 0) revert CantWithdrawZero();
        (bool sent, ) = _to.call{value: amount}("");
        if (!sent) revert FailedToSendEther();
        emit FundsWithdrawn(_to, amount);
    }

    /**
     * @inheritdoc IStakingManager
     */
    function setDeploymentPrice(uint256 deploymentFee) external onlyOwner {
        _deploymentPrice = deploymentFee;
        emit DeploymentPriceSet(deploymentFee);
    }

    /**
     * @inheritdoc IStakingManager
     */
    function setBatchTransactionFee(uint256 batchTransactionFee) external onlyOwner {
        _batchTransactionFee = batchTransactionFee;
        emit BatchTransactionFeeSet(batchTransactionFee);
    }

    /**
     * @inheritdoc IStakingManager
     */
    function setIndividualContractBatchTransactionFee(address stakingContract, uint256 batchTransactionFee) external onlyOwner {
        _individualBatchTransactionFee[stakingContract] = batchTransactionFee;
        _isIndividualBatchTransactionFeeActive[stakingContract] = true;
        emit IndividualContractBatchTransactionFeeSet(stakingContract, batchTransactionFee);
    }

    /**
     * @inheritdoc IStakingManager
     */
    function deactivateIndividualContractBatchTransactionFee(address stakingContract) external onlyOwner {
        _isIndividualBatchTransactionFeeActive[stakingContract] = false;
        emit IndividualContractBatchTransactionFeeDeactivated(stakingContract);
    }

    /**
     * @inheritdoc IStakingManager
     */
    function setStakingManager(address stakingContract, address stakingManager) external onlyOwner {
        IIQNftStaking(stakingContract).setStakingManager(stakingManager);
        emit StakingManagerUpdated(stakingContract, stakingManager);
    }

    /**
     * @inheritdoc IStakingManager
     */
    function getDeploymentPrice() external view returns (uint256) {
        return _deploymentPrice;
    }

    /**
     * @inheritdoc IStakingManager
     */
     function getBatchTransactionFee() external view returns (uint256) {
        return _batchTransactionFee;
    }

    /**
     * @inheritdoc IStakingManager
     */
    function isIndividualBatchTransactionFeeActive(address stakingContract) external view returns (bool) {
        return _isIndividualBatchTransactionFeeActive[stakingContract];
    }

    /**
     * @inheritdoc IStakingManager
     */
    function getIndividualBatchTransactionFee(address stakingContract) external view returns (uint256) {
        return _individualBatchTransactionFee[stakingContract];
    }

    /**
     * @inheritdoc IStakingManager
     */
     function getProofSourceAddress() external view returns (address) {
        return _proofSource;
    }

    /**
     * @inheritdoc IStakingManager
     */
    function getBalance() external view returns (uint) {
        return address(this).balance;
    }

     /**
     * @inheritdoc IStakingManager
     */
    function nonceCounter(address user) external view returns (uint256) {
        return _nonceCounters[user].current();
    }

    /**
     * @dev Increments the nonce for the user and returns the used nonce.
     * @param user The address for which the nonce is being incremented.
     * @return The used nonce.
     */
    function _useNonce(address user) internal returns (uint256) {
        _nonceCounters[user].increment();
        return _nonceCounters[user].current() - 1; // Return the used nonce
    }

    /**
     * @dev Verifies the signature for the reservation.
     * @param signer The address that signed the reservation.
     * @param digest The hash of the reservation details.
     * @param signature The signature to verify.
     * @return True if the signature is valid, false otherwise.
     */
    function _verifySignature(
        address signer,
        bytes32 digest,
        bytes memory signature
    ) internal pure returns (bool) {
        return ECDSA.recover(digest, signature) == signer;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/StorageSlot.sol)
// This file was procedurally generated from scripts/generate/templates/StorageSlot.js.

pragma solidity ^0.8.0;

/**
 * @dev Library for reading and writing primitive types to specific storage slots.
 *
 * Storage slots are often used to avoid storage conflict when dealing with upgradeable contracts.
 * This library helps with reading and writing to such slots without the need for inline assembly.
 *
 * The functions in this library return Slot structs that contain a `value` member that can be used to read or write.
 *
 * Example usage to set ERC1967 implementation slot:
 * ```solidity
 * contract ERC1967 {
 *     bytes32 internal constant _IMPLEMENTATION_SLOT = 0x360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc;
 *
 *     function _getImplementation() internal view returns (address) {
 *         return StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value;
 *     }
 *
 *     function _setImplementation(address newImplementation) internal {
 *         require(Address.isContract(newImplementation), "ERC1967: new implementation is not a contract");
 *         StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value = newImplementation;
 *     }
 * }
 * ```
 *
 * _Available since v4.1 for `address`, `bool`, `bytes32`, `uint256`._
 * _Available since v4.9 for `string`, `bytes`._
 */
library StorageSlot {
    struct AddressSlot {
        address value;
    }

    struct BooleanSlot {
        bool value;
    }

    struct Bytes32Slot {
        bytes32 value;
    }

    struct Uint256Slot {
        uint256 value;
    }

    struct StringSlot {
        string value;
    }

    struct BytesSlot {
        bytes value;
    }

    /**
     * @dev Returns an `AddressSlot` with member `value` located at `slot`.
     */
    function getAddressSlot(bytes32 slot) internal pure returns (AddressSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `BooleanSlot` with member `value` located at `slot`.
     */
    function getBooleanSlot(bytes32 slot) internal pure returns (BooleanSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `Bytes32Slot` with member `value` located at `slot`.
     */
    function getBytes32Slot(bytes32 slot) internal pure returns (Bytes32Slot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `Uint256Slot` with member `value` located at `slot`.
     */
    function getUint256Slot(bytes32 slot) internal pure returns (Uint256Slot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `StringSlot` with member `value` located at `slot`.
     */
    function getStringSlot(bytes32 slot) internal pure returns (StringSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `StringSlot` representation of the string storage pointer `store`.
     */
    function getStringSlot(string storage store) internal pure returns (StringSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := store.slot
        }
    }

    /**
     * @dev Returns an `BytesSlot` with member `value` located at `slot`.
     */
    function getBytesSlot(bytes32 slot) internal pure returns (BytesSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `BytesSlot` representation of the bytes storage pointer `store`.
     */
    function getBytesSlot(bytes storage store) internal pure returns (BytesSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := store.slot
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Strings.sol)

pragma solidity ^0.8.0;

import "./math/Math.sol";
import "./math/SignedMath.sol";

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _SYMBOLS = "0123456789abcdef";
    uint8 private constant _ADDRESS_LENGTH = 20;

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        unchecked {
            uint256 length = Math.log10(value) + 1;
            string memory buffer = new string(length);
            uint256 ptr;
            /// @solidity memory-safe-assembly
            assembly {
                ptr := add(buffer, add(32, length))
            }
            while (true) {
                ptr--;
                /// @solidity memory-safe-assembly
                assembly {
                    mstore8(ptr, byte(mod(value, 10), _SYMBOLS))
                }
                value /= 10;
                if (value == 0) break;
            }
            return buffer;
        }
    }

    /**
     * @dev Converts a `int256` to its ASCII `string` decimal representation.
     */
    function toString(int256 value) internal pure returns (string memory) {
        return string(abi.encodePacked(value < 0 ? "-" : "", toString(SignedMath.abs(value))));
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        unchecked {
            return toHexString(value, Math.log256(value) + 1);
        }
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }

    /**
     * @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal representation.
     */
    function toHexString(address addr) internal pure returns (string memory) {
        return toHexString(uint256(uint160(addr)), _ADDRESS_LENGTH);
    }

    /**
     * @dev Returns true if the two strings are equal.
     */
    function equal(string memory a, string memory b) internal pure returns (bool) {
        return keccak256(bytes(a)) == keccak256(bytes(b));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/cryptography/draft-EIP712.sol)

pragma solidity ^0.8.0;

// EIP-712 is Final as of 2022-08-11. This file is deprecated.

import "./EIP712.sol";

{
  "compilationTarget": {
    "contracts/staking/StakingManager.sol": "StakingManager"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs",
    "useLiteralContent": true
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}