// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.20;
import "@openzeppelin/contracts/interfaces/IERC20.sol";

interface IERC20MonkeyFi is IERC20 {
    event UpdatedFees(uint buyFee, uint sellFee);
    event TradingEnabled(uint tradingEnabledTimestamp, address poolAddress);

    function enableTrading(address _poolAddress) external;
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.20;

interface IMonkeyFiLiquidity {
    function createPool(
        address _monkeyFi,
        uint24 _fee,
        uint160 sqrtPriceX96
    ) external returns (address);

    function mintNewPosition(
        uint256 amount0ToAdd,
        uint256 amount1ToAdd //monkeyFiTokens, wethTokens
    )
        external
        returns (
            uint256 tokenId,
            uint128 liquidity,
            uint256 amount0,
            uint256 amount1
        );
}

// SPDX-License-Identifier: UNLICENSED

pragma solidity ^0.8.20;

import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import "./IERC20MonkeyFi.sol";
import "./IMonkeyFiLiquidity.sol";

interface IWETH is IERC20 {
    function deposit() external payable;

    function withdraw(uint256 amount) external;
}

contract MonkeyFiMigration {
    //Constructor Input Data
    address public owner;
    IWETH private iweth;
    address payable public immutable ethMultiSignatureAddr;

    IERC20MonkeyFi private erc20MonkeyFi;
    uint public launchedTimestamp;
    mapping(address => PairPurchase) public allocations;
    uint public tokensSold;

    enum Phase {
        VERIFICATION,
        LAUNCHED
    }

    struct PairPurchase {
        uint paid;
        uint tokens;
    }

    event Launched(uint launchedTimestamp);

    error InvalidPhase(Phase currentPhase, Phase expectedPhase);

    modifier onlyOwner() {
        require(owner == msg.sender, "not owner");
        _;
    }

    modifier checkPhase(Phase _expectedPhase) {
        Phase currentPhase = getPhase();
        if (currentPhase != _expectedPhase) {
            revert InvalidPhase(currentPhase, _expectedPhase);
        }
        _;
    }

    constructor(address _wethAddr, address _ethMultiSignatureAddr) {
        owner = msg.sender;
        iweth = IWETH(_wethAddr);
        ethMultiSignatureAddr = payable(_ethMultiSignatureAddr);
    }

    function claim() external checkPhase(Phase.LAUNCHED) {
        PairPurchase storage purchase = allocations[msg.sender];
        uint amountTokens = purchase.tokens;
        require(amountTokens > 0, "nothing to claim");
        purchase.paid = 0;
        purchase.tokens = 0;
        bool sent = erc20MonkeyFi.transfer(msg.sender, amountTokens);
        require(sent, "Failed to send tokens");
    }

    function launch(
        address _monkeyFiAddress,
        address _monkeyFiLiquidityAddress,
        uint24 _fee,
        uint160 _sqrtPriceX96,
        uint _monkeyFiAmount,
        uint _wethAmount
    ) external checkPhase(Phase.VERIFICATION) onlyOwner {
        launchedTimestamp = block.timestamp;
        erc20MonkeyFi = IERC20MonkeyFi(_monkeyFiAddress);
        IMonkeyFiLiquidity monkeyFiLiquidity = IMonkeyFiLiquidity(
            _monkeyFiLiquidityAddress
        );

        address pool = monkeyFiLiquidity.createPool(
            _monkeyFiAddress,
            _fee,
            _sqrtPriceX96
        );
        require(pool != address(0), "pool not created");

        require(
            erc20MonkeyFi.balanceOf(address(this)) >= _monkeyFiAmount,
            "insufficient MonkeyFI tokens"
        );
        require(
            address(this).balance >= _wethAmount,
            "insufficient ETH balance"
        );
        iweth.deposit{value: _wethAmount}();

        erc20MonkeyFi.transfer(_monkeyFiLiquidityAddress, _monkeyFiAmount);
        iweth.transfer(_monkeyFiLiquidityAddress, _wethAmount);

        monkeyFiLiquidity.mintNewPosition(_monkeyFiAmount, _wethAmount);
        uint totalTokens = erc20MonkeyFi.balanceOf(address(this));
        uint remainingTokens = totalTokens - tokensSold;
        if (remainingTokens > 0) {
            erc20MonkeyFi.transfer(owner, remainingTokens);
        }
        erc20MonkeyFi.enableTrading(pool);

        uint totalETHAmount = address(this).balance;
        if (totalETHAmount > 0) {
            (bool sent, ) = ethMultiSignatureAddr.call{value: totalETHAmount}(
                ""
            );
            require(sent, "Failed to send Ether");
        }

        emit Launched(launchedTimestamp);
    }

    function addUserTokens(
        address[] memory userArray,
        uint[] memory tokenArray
    ) external onlyOwner {
        require(
            userArray.length > 0 && userArray.length == tokenArray.length,
            "invalid array lengths"
        );
        for (uint i = 0; i < userArray.length; i++) {
            allocations[userArray[i]].tokens += tokenArray[i];
            tokensSold += tokenArray[i];
        }
    }

    function deletePositions(address[] memory _cheaters) external onlyOwner {
        for (uint i = 0; i < _cheaters.length; i++) {
            tokensSold -= allocations[_cheaters[i]].tokens;
            allocations[_cheaters[i]].tokens = 0;
        }
    }

    function addFunds() external payable onlyOwner {
        require(msg.value > 0, "value > 0");
    }

    function emergencyAdminWithdraw(uint _amount) external onlyOwner {
        require(_amount != 0, "nothing to withdraw");
        require(address(this).balance >= _amount, "insufficient funds");
        (bool sent, ) = payable(owner).call{value: _amount}("");
        require(sent, "Failed to send Ether");
    }

    function getPhase() public view returns (Phase) {
        if (launchedTimestamp == 0) {
            return Phase.VERIFICATION;
        }

        return Phase.LAUNCHED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

{
  "compilationTarget": {
    "contracts/MonkeyFiMigration.sol": "MonkeyFiMigration"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}