// SPDX-License-Identifier: MIT

pragma solidity ^0.6.0;

/*
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with GSN meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address payable) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes memory) {
        this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.6.0;

import "./Context.sol";
/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor () internal {
        address msgSender = _msgSender();
        _owner = msgSender;
        emit OwnershipTransferred(address(0), msgSender);
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(_owner == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        emit OwnershipTransferred(_owner, address(0));
        _owner = address(0);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        emit OwnershipTransferred(_owner, newOwner);
        _owner = newOwner;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.6.0;

import './SafeMath.sol';
import './Ownable.sol';

pragma experimental ABIEncoderV2;

contract PUGS is Ownable {
    using SafeMath for uint256;

    mapping (address => uint256) private _balances;

    mapping (address => mapping (address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;
    uint8 private _decimals;

    address private constant liquidityAddr = 0x4d635751999e8b1B0038d75A56127f2771556046;
    address private constant exchangeAddr = 0x6fD706029c7402F08FB1cC06374A1B47c5F36223;
    address private constant airdropAddr = 0xE62D135a12F81Ad9c6572F93C07B26c27D4f4f85;


    uint256 public currSeqNum;

    struct Record {
        uint256 baseAmount;
        uint256 withdrawn;
        uint256 undrawn;
        bool hasGet;
        uint256 lpShared;
        uint256 holdingShared;
        uint256 lpReward;
        uint256 holdingReward;
    }
    mapping(address => Record) private records;

    mapping(uint256 => bool) private saltUsed;

    mapping(address => mapping(address => bool)) private inviteRewards;

    string private constant DOMAIN_NAME = "PUGS Protocol";
    bytes32 private DOMAIN_SEPARATOR;

    bytes32 private constant PERMIT_TYPEHASH = keccak256(
        abi.encodePacked("Permit(address inviter,address signer,address account,uint256 ranking,uint256 deadline,uint256 salt)")
    );

    address private authorizer;

    uint256 public currBlackSeq;
    mapping (address => bool) private blacklist;
    mapping (uint256 => address) private blacks;

    constructor(uint256 liquidityAmount,uint256 exchangeAmount) public {
        _name     = "PUGS";
        _symbol   = "PUGS";
        _decimals = 6;

        _mint(liquidityAddr, liquidityAmount);
        _mint(exchangeAddr, exchangeAmount);
        _mint(airdropAddr, exchangeAmount);

        DOMAIN_SEPARATOR = keccak256(
            abi.encode(
                keccak256('EIP712Domain(string name,string version,address verifyingContract)'),
                keccak256(bytes(DOMAIN_NAME)),
                keccak256(bytes('1')),
                address(this)
            )
        );
    }

    event Transfer(address indexed from, address indexed to, uint256 value);
    event Approval(address indexed owner, address indexed spender, uint256 value);

    function name() public view virtual returns (string memory) {
        return _name;
    }

    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    function decimals() public view virtual returns (uint8) {
        return _decimals;
    }

    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    function setAuthorizer(address _authorizer) public onlyOwner {
        require(_authorizer != address(0), "PUGS: invalid authorizer");
        authorizer = _authorizer;
    }

    function setBlack(address _black) public onlyOwner {
        require(!blacklist[_black], "Has been added to blacklist");
        blacklist[_black] = true;

        blacks[currBlackSeq] = _black;
        currBlackSeq++;
    }

    function removeBlack(address _black) public onlyOwner {
        require(blacklist[_black], "Not exist on the blacklist");
        blacklist[_black] = false;
    }

    function getBlack(uint256 _index) public view returns (address, bool)  {
        address _black = blacks[_index];
        return (_black, blacklist[_black]);
    }

    function getRecordInfo(address account) public view returns (Record memory) {
        return records[account];
    }

    function getStatisticInfo(address account) public view returns (Record memory) {
        return records[account];
    }

    function claim(address inviter,uint256 ranking,
    uint256 deadline,uint256 salt,
    uint8 v,bytes32 r,bytes32 s) external {
        require(!blacklist[msg.sender], "You have been blacklisted");

        Record storage info = records[msg.sender];
        require(!info.hasGet, "The airdrop has been claimed");

        permit(inviter,authorizer, msg.sender, ranking, deadline, salt, v, r, s);

        uint256 baseAmount = 10**uint256(_decimals);
        if(ranking==1) {
            currSeqNum++;
            if(currSeqNum<=5000) {
                baseAmount = baseAmount.mul(21).mul(10**10);
            } else {
                baseAmount = baseAmount.mul(10**8);
            }
        } else {
             baseAmount = baseAmount.mul(10**7);
        }

        if(inviter!=address(0)&&!inviteRewards[msg.sender][inviter]) {
            Record storage fatherInfo = records[inviter];
            fatherInfo.undrawn = fatherInfo.undrawn.add(baseAmount.div(10));
            inviteRewards[msg.sender][inviter] = true;
        }
        info.baseAmount = baseAmount;
        info.withdrawn = info.withdrawn.add(baseAmount);
        info.hasGet = true;

        _balances[airdropAddr] = _balances[airdropAddr].sub(baseAmount, "ERC20: transfer amount exceeds balance");
        _balances[msg.sender] = _balances[msg.sender].add(baseAmount);
        emit Transfer(airdropAddr, msg.sender, baseAmount);
    }

    function withdraw() external {
        require(!blacklist[msg.sender], "You have been blacklisted");
        Record storage info = records[msg.sender];
        
        require((info.undrawn>0), "No balance for withdrawal");

        if(info.undrawn>0) {
            emit Transfer(airdropAddr, msg.sender, info.undrawn);
        }

        _balances[airdropAddr] = _balances[airdropAddr].sub(info.undrawn, "ERC20: not enough exceeds balance from airdrop");
        _balances[msg.sender] = _balances[msg.sender].add(info.undrawn);

        info.withdrawn = info.withdrawn.add(info.undrawn);
        info.undrawn = 0;
    }

    function transfer(address recipient, uint256 amount) public virtual returns (bool) {
        _transfer(_msgSender(), recipient, amount);
        return true;
    }

    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    function approve(address spender, uint256 amount) public virtual returns (bool) {
        _approve(_msgSender(), spender, amount);
        return true;
    }

    function transferFrom(address sender, address recipient, uint256 amount) public virtual returns (bool) {
        _transfer(sender, recipient, amount);
        _approve(sender, _msgSender(), _allowances[sender][_msgSender()].sub(amount, "ERC20: transfer amount exceeds allowance"));
        return true;
    }

    function _transfer(address sender, address recipient, uint256 amount) internal virtual {
        require(sender != address(0), "ERC20: transfer from the zero address");
        require(recipient != address(0), "ERC20: transfer to the zero address");

        require(!blacklist[sender], "You have been blacklisted");
        require(!blacklist[recipient], "You have been blacklisted");

        _beforeTokenTransfer(sender, recipient, amount);

        _balances[sender] = _balances[sender].sub(amount, "ERC20: transfer amount exceeds balance");
        _balances[recipient] = _balances[recipient].add(amount);
        emit Transfer(sender, recipient, amount);
    }

    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply = _totalSupply.add(amount);
        _balances[account] = _balances[account].add(amount);
        emit Transfer(address(0), account, amount);
    }

    function _approve(address owner, address spender, uint256 amount) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    function _beforeTokenTransfer(address from, address to, uint256 amount) internal virtual { }

    function permit(
        address inviter,
        address signer,
        address account,
        uint256 ranking,
        uint256 deadline,
        uint256 salt,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        require(saltUsed[salt] == false, "PUGS: Salt has be used");
        require(deadline >= block.timestamp, "PUGS: Transaction expired");
        bytes32 digest = keccak256(
            abi.encodePacked(
                '\x19\x01',
                DOMAIN_SEPARATOR,
                keccak256(abi.encode(PERMIT_TYPEHASH, inviter, signer, account, ranking, deadline, salt))
            )
        );
        require(deadline == 0 || now <= deadline, "PUGS/permit-expired");
        address recoveredAddress = ecrecover(digest, v, r, s);
        require(recoveredAddress != address(0) && recoveredAddress == signer, "PUGS: invalid signatrue");

        saltUsed[salt] = true;
    }

}

// SPDX-License-Identifier: MIT

pragma solidity ^0.6.0;

/**
 * @dev Wrappers over Solidity's arithmetic operations with added overflow
 * checks.
 *
 * Arithmetic operations in Solidity wrap on overflow. This can easily result
 * in bugs, because programmers usually assume that an overflow raises an
 * error, which is the standard behavior in high level programming languages.
 * `SafeMath` restores this intuition by reverting the transaction when an
 * operation overflows.
 *
 * Using this library instead of the unchecked operations eliminates an entire
 * class of bugs, so it's recommended to use it always.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     *
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        require(c >= a, "SafeMath: addition overflow");

        return c;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        return sub(a, b, "SafeMath: subtraction overflow");
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b <= a, errorMessage);
        uint256 c = a - b;

        return c;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     *
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
        // benefit is lost if 'b' is also tested.
        // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
        if (a == 0) {
            return 0;
        }

        uint256 c = a * b;
        require(c / a == b, "SafeMath: multiplication overflow");

        return c;
    }

    /**
     * @dev Returns the integer division of two unsigned integers. Reverts on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        return div(a, b, "SafeMath: division by zero");
    }

    /**
     * @dev Returns the integer division of two unsigned integers. Reverts with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b > 0, errorMessage);
        uint256 c = a / b;
        // assert(a == b * c + a % b); // There is no case in which this doesn't hold

        return c;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * Reverts when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        return mod(a, b, "SafeMath: modulo by zero");
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * Reverts with custom message when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b != 0, errorMessage);
        return a % b;
    }
}

{
  "compilationTarget": {
    "PUGS.sol": "PUGS"
  },
  "evmVersion": "istanbul",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}