// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[ERC].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[ERC section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC721/IERC721.sol)

pragma solidity ^0.8.20;

import {IERC165} from "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC-721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon
     *   a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId, bytes calldata data) external;

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC-721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must have been allowed to move this token by either {approve} or
     *   {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon
     *   a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Note that the caller is responsible to confirm that the recipient is capable of receiving ERC-721
     * or else they may be permanently lost. Usage of {safeTransferFrom} prevents loss, though the caller must
     * understand this adds an external call which potentially creates a reentrancy vulnerability.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the address zero.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool approved) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC721/IERC721Receiver.sol)

pragma solidity ^0.8.20;

/**
 * @title ERC-721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC-721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be
     * reverted.
     *
     * The selector can be obtained in Solidity with `IERC721Receiver.onERC721Received.selector`.
     */
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

/*
@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@@      @@@,    @@@@@(     @@@    @/   &#       @        .@@@@@@  *@@@@@@@@@@* %@@@
@@        V.    @@@@@      @@@     /    @       @         %@@@        @@,        @@
@@   @>   @.    @@@@@       @@          @    @@@@@@,    @@@@@@@    @@@     /@*  *@@
@@        ^.    @@@@        (@          @      /@@@,    @&     #&       %@@@@@@@@@@
@@       (@,    @@@@    %   (@          @      /@@@,    @      @&      .@@@@@@@@@@@
@@   ,@@@@@,    @@@#         @          @    @@@@@@,    @@@@@@@*    @      @@@  @@@
@@   ,@@@@@,       #   #%    @    @     @       @@@,    @@@@@@      /@@&         @@
@@   ,@@@@@,       #   #@,   @    @/    @       @@@,    @@@@@@@     @@@@@@@(    *@@
@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

Planet-X Staking V1
playplanetx.com
PLAY PLANET X LIMITED © 2024 | All rights reserved
*/

// SPDX-License-Identifier: UNLICENCED

pragma solidity ^0.8.20;

import "@openzeppelin/contracts/interfaces/IERC721Receiver.sol";
import "@openzeppelin/contracts/interfaces/IERC721.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import "@openzeppelin/contracts/access/Ownable.sol";

struct StakedToken {
    address owner; // 20 bytes
    uint64 stakedAt; // 8 bytes
}

struct UserStakedTokens {
    mapping(address contractAddress => uint256[] tokenIds) tokens;
    address[] contracts;
}

error TokenAlreadyStaked();
error TokenNotStaked();
error NotTokenOwner();
error UnsupportedStakingContract();

interface StakingEvents {
    event TokensStaked(
        address indexed contractAddress,
        address indexed owner,
        uint256[] tokenIds,
        uint256 timestamp
    );
    event TokensUnstaked(
        address indexed contractAddress,
        address indexed owner,
        uint256[] tokenIds,
        uint256 timestamp
    );
}

contract PlanetXStakingV1 is IERC721Receiver, Ownable, ReentrancyGuard, StakingEvents {
    mapping(address contractAddress => bool) public isContractSupported;

    mapping(address contractAddress => uint256 totalStaked) public stakeCountsPerContract;

    mapping(address contractAddress => mapping(uint256 tokenId => StakedToken))
        public vaults;

    mapping(address user => UserStakedTokens) userStakedTokens;

    constructor() Ownable(msg.sender) {}

    /// @notice allows a user to stake their tokens
    /// @param contractAddress address of the NFT contract
    /// @param tokenIds array of token ids to stake
    function stake(
        address contractAddress,
        uint256[] calldata tokenIds
    ) external nonReentrant {
        // check that we accept stakes for this contract
        if (!isContractSupported[contractAddress]) {
            revert UnsupportedStakingContract();
        }

        uint256[] storage userTokens = userStakedTokens[msg.sender].tokens[
            contractAddress
        ];
        bool userHadPreviousStakedInContract = userTokens.length > 0;

        uint256 stakedCount = tokenIds.length;
        IERC721 nftContract = IERC721(contractAddress);

        for (uint256 i; i < stakedCount; ) {
            uint256 tokenId = tokenIds[i];

            // check that the token is not already staked
            if (vaults[contractAddress][tokenId].owner != address(0)) {
                revert TokenAlreadyStaked();
            }

            // check that the sender is the owner of the token
            if (nftContract.ownerOf(tokenId) != msg.sender) {
                revert NotTokenOwner();
            }

            // save the staking information
            vaults[contractAddress][tokenId] = StakedToken({
                owner: msg.sender,
                stakedAt: uint64(block.timestamp)
            });

            // add the token to the user's staked tokens
            userTokens.push(tokenId);

            // transfer the nft to this contract
            nftContract.safeTransferFrom(msg.sender, address(this), tokenId);

            unchecked {
                ++i;
            }
        }

        // if contract is not in the user's contracts, add it
        if (!userHadPreviousStakedInContract) {
            userStakedTokens[msg.sender].contracts.push(contractAddress);
        }

        // update the total staked count
        stakeCountsPerContract[contractAddress] += stakedCount;

        // emit final event after for loop to save gas
        emit TokensStaked(contractAddress, msg.sender, tokenIds, block.timestamp);
    }

    /// @notice allows a user to unstake their tokens
    /// @param contractAddress address of the NFT contract
    /// @param tokenIds array of token ids to unstake
    function unstake(
        address contractAddress,
        uint256[] calldata tokenIds
    ) external nonReentrant {
        address user = msg.sender;

        IERC721 nftContract = IERC721(contractAddress);
        uint256[] storage userTokens = userStakedTokens[user].tokens[contractAddress];

        for (uint256 i; i < tokenIds.length; ) {
            uint256 tokenId = tokenIds[i];

            // remove the token from the user's staked tokens
            uint256 len = userTokens.length;
            bool tokenFound = false;
            for (uint256 j; j < len; ) {
                if (userTokens[j] == tokenId) {
                    userTokens[j] = userTokens[len - 1];
                    userTokens.pop();
                    tokenFound = true;
                    break;
                }
                unchecked {
                    ++j;
                }
            }

            if (!tokenFound) {
                revert TokenNotStaked();
            }

            delete vaults[contractAddress][tokenId];

            // transfer the token back to the user
            nftContract.safeTransferFrom(address(this), user, tokenId);

            unchecked {
                ++i;
            }
        }

        // remove the contract from the user's staked contracts if they have no more tokens staked in it
        if (userTokens.length == 0) {
            address[] storage userStakedContracts = userStakedTokens[user].contracts;
            uint256 len = userStakedContracts.length;
            for (uint256 i; i < len; ) {
                if (userStakedContracts[i] == contractAddress) {
                    userStakedContracts[i] = userStakedContracts[len - 1];
                    userStakedContracts.pop();
                    break;
                }
                unchecked {
                    ++i;
                }
            }
        }

        stakeCountsPerContract[contractAddress] -= tokenIds.length;

        // emit final event after for loop to save gas
        emit TokensUnstaked(contractAddress, user, tokenIds, block.timestamp);
    }

    function setSupportedContract(
        address contractAddress,
        bool isSupported
    ) external onlyOwner {
        isContractSupported[contractAddress] = isSupported;
    }

    // ********* //
    //  GETTERS  //
    // ********* //

    /// @notice get all staked tokens for a user in a contract
    /// @param user address of user to get staked tokens for
    function getStakedTokens(
        address user,
        address contractAddress
    ) external view returns (uint256[] memory tokenIds) {
        return userStakedTokens[user].tokens[contractAddress];
    }

    /// @notice get all staked tokens for a user
    /// @param user address of user to get staked tokens for
    function getStakedTokens(
        address user
    ) external view returns (address[] memory contracts, uint256[][] memory tokenIds) {
        UserStakedTokens storage userStake = userStakedTokens[user];
        uint256 contractLen = userStake.contracts.length;
        contracts = new address[](contractLen);
        tokenIds = new uint256[][](contractLen);

        for (uint256 i; i < contractLen; ) {
            address contractAddress = userStake.contracts[i];
            contracts[i] = contractAddress;
            tokenIds[i] = userStake.tokens[contractAddress];
            unchecked {
                ++i;
            }
        }

        return (contracts, tokenIds);
    }

    function onERC721Received(
        address /**operator*/,
        address /**from*/,
        uint256 /**amount*/,
        bytes calldata //data
    ) external pure override returns (bytes4) {
        return IERC721Receiver.onERC721Received.selector;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

{
  "compilationTarget": {
    "src/staking/PlanetXStakingV1.sol": "PlanetXStakingV1"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": [
    ":@/=src/",
    ":@chainlink/=lib/chainlink/contracts/src/v0.8/",
    ":@openzeppelin/=lib/openzeppelin-contracts/",
    ":@openzeppelin/contracts/=lib/openzeppelin-contracts/contracts/",
    ":@prb/test/=lib/foundry-random/lib/CramBit/lib/prb-test/src/",
    ":CramBit/=lib/foundry-random/lib/CramBit/",
    ":ERC721A/=lib/ERC721A/contracts/",
    ":chainlink/=lib/chainlink/",
    ":delegate-registry/=lib/delegate-registry/",
    ":delegate.cash/=lib/delegate-registry/src/",
    ":ds-test/=lib/forge-std/lib/ds-test/src/",
    ":erc4626-tests/=lib/operator-filter-registry/lib/openzeppelin-contracts/lib/erc4626-tests/",
    ":erc721a/=lib/ERC721A/",
    ":forge-std/=lib/forge-std/src/",
    ":foundry-random/=lib/foundry-random/src/",
    ":openzeppelin-contracts-upgradeable/=lib/operator-filter-registry/lib/openzeppelin-contracts-upgradeable/",
    ":openzeppelin-contracts/=lib/openzeppelin-contracts/",
    ":operator-filter-registry/=lib/operator-filter-registry/",
    ":prb-test/=lib/foundry-random/lib/prb-test/src/",
    ":solidity-bytes-utils/=lib/foundry-random/lib/solidity-bytes-utils/contracts/"
  ]
}