// SPDX-License-Identifier: MIT
pragma solidity ^0.8.26;

import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import "@openzeppelin/contracts/token/ERC20/extensions/ERC20Burnable.sol";
import "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import "@openzeppelin/contracts/access/Ownable.sol";

interface ITotalSupplyAdjuster {
    function increaseTotalSupply() external;
    function decreaseTotalSupply() external;
}

contract BrainCredits is ERC20, Ownable, ReentrancyGuard {
    ERC20Burnable public pepecoin;

    // Pricing 
    uint256 public basePricePerThousand = 1000 * 1e18; 
    uint256 public priceIncrementPerThousand = 200 * 1e18; 
    
    uint256 public brainCreditsPerTier = 1000 * 10 ** decimals(); 
    
    uint256 public SUPPLY = 1024000 * 10 ** decimals(); 
    uint256 public SUPPLY_HARD_CAP = 1024000 * 10 ** decimals(); 
    
    bool public mintingFrozen = true;
    
    address public totalSupplyAdjuster;
    uint256 constant MAX_ITERATIONS = 100; 

    mapping(address => uint256) public pepecoinBurnedBy; // Kek rank 
    mapping(address => uint256) public addressBurnOrder; // bonus 
    uint256 public totalBurners = 0; 
    
    event MintingFrozen();
    event MintingUnfrozen();
    event TotalSupplyAdjusterChanged(address adjuster);
    event TotalSupplyIncreased(uint256 amount);
    event TotalSupplyDecreased(uint256 amount);
    event TokensMinted(address indexed minter, uint256 tokenAmount, uint256 pepecoinsSpent);
    event PepecoinsBurned(address indexed burner, uint256 amountBurned, uint256 totalBurnedByAddress, uint256 burnOrder);
    
    constructor() ERC20("BRAIN CREDITS", "BCRED") Ownable(msg.sender) {
        pepecoin = ERC20Burnable(0xA9E8aCf069C58aEc8825542845Fd754e41a9489A);
    }

    function getCurrentTier() public view returns (uint256) {
        return totalSupply() / brainCreditsPerTier;
    }

    function getTierPricePerThousand(uint256 tier) public view returns (uint256) {
        return basePricePerThousand + (tier * priceIncrementPerThousand);
    }

    function estimateTokenAmount(uint256 pepecoinsToSpend) public view returns (uint256 totalTokensToMint) {
        require(pepecoinsToSpend > 0, "Must provide Pepecoins to spend");
    
        uint256 remainingPepecoins = pepecoinsToSpend;
        uint256 currentSupply = totalSupply(); 
        uint256 currentTier = currentSupply / brainCreditsPerTier;
        uint256 tokensInCurrentTier = brainCreditsPerTier - (currentSupply % brainCreditsPerTier);
    
        uint256 iterations = 0;
        totalTokensToMint = 0;
    
        while (remainingPepecoins > 0 && currentSupply < SUPPLY && iterations < MAX_ITERATIONS) {
            uint256 tierPricePerThousand = getTierPricePerThousand(currentTier);
    
            uint256 pricePerBrainCredit = (tierPricePerThousand * 1e18) / brainCreditsPerTier;
    
            uint256 costForTokensInCurrentTier = (tokensInCurrentTier * pricePerBrainCredit) / 1e18;
    
            uint256 tokensAffordable;
    
            if (remainingPepecoins >= costForTokensInCurrentTier) {
                tokensAffordable = tokensInCurrentTier;
                remainingPepecoins -= costForTokensInCurrentTier;
            } else {
                // Can only afford part of the tokens in current tier
                tokensAffordable = (remainingPepecoins * 1e18) / pricePerBrainCredit;
                remainingPepecoins = 0;
            }
    
            totalTokensToMint += tokensAffordable;
            currentSupply += tokensAffordable;
    
            // next tier
            currentTier += 1;
            tokensInCurrentTier = brainCreditsPerTier;
    
            iterations++;
        }
    
        // Adjust for supply cap if necessary
        if (currentSupply > SUPPLY) {
            uint256 excessTokens = currentSupply - SUPPLY;
            totalTokensToMint -= excessTokens;
        }
    
        return totalTokensToMint;
    }
    
    // Function to estimate the amount of Pepecoins required to mint a given number of tokens
    function estimatePrice(uint256 tokenAmount) public view returns (uint256 totalPepecoinsRequired) {
        require(tokenAmount > 0, "Must provide token amount");
    
        uint256 remainingTokens = tokenAmount;
        uint256 currentSupply = totalSupply();
        uint256 currentTier = currentSupply / brainCreditsPerTier;
        uint256 tokensInCurrentTier = brainCreditsPerTier - (currentSupply % brainCreditsPerTier);
    
        uint256 iterations = 0;
        totalPepecoinsRequired = 0;
    
        while (remainingTokens > 0 && currentSupply < SUPPLY && iterations < MAX_ITERATIONS) {
            uint256 tierPricePerThousand = getTierPricePerThousand(currentTier);
    
            // Calculate price per Brain Credit in Pepecoins with 18 decimals
            uint256 pricePerBrainCredit = (tierPricePerThousand * 1e18) / brainCreditsPerTier;
    
            uint256 tokensToBuy = tokensInCurrentTier;
    
            if (remainingTokens <= tokensInCurrentTier) {
                tokensToBuy = remainingTokens;
            }
    
            uint256 costForTokens = (tokensToBuy * pricePerBrainCredit) / 1e18;
    
            totalPepecoinsRequired += costForTokens;
            remainingTokens -= tokensToBuy;
            currentSupply += tokensToBuy;
    
            // Move to next tier
            currentTier += 1;
            tokensInCurrentTier = brainCreditsPerTier;
    
            iterations++;
        }
    
        // Adjust for supply cap if necessary
        if (currentSupply > SUPPLY && remainingTokens > 0) {
            // Can't mint more than the supply cap
            // Remaining tokens cannot be purchased
            remainingTokens = 0;
        }
    
        return totalPepecoinsRequired;
    }
    
    function mint(uint256 pepecoinsToSpend, uint256 maxPricePerThousandTokens) public nonReentrant {
        require(!mintingFrozen, "Minting is frozen");
        require(pepecoinsToSpend > 0, "Must specify Pepecoins to spend");
    
        uint256 remainingPepecoins = pepecoinsToSpend;
        uint256 totalTokensToMint = 0;
    
        uint256 currentSupply = totalSupply(); // Fetch the up-to-date total supply
    
        uint256 currentTier = currentSupply / brainCreditsPerTier;
        uint256 tokensInCurrentTier = brainCreditsPerTier - (currentSupply % brainCreditsPerTier);
    
        uint256 iterations = 0;
    
        while (remainingPepecoins > 0 && currentSupply < SUPPLY && iterations < MAX_ITERATIONS) {
            uint256 tierPricePerThousand = getTierPricePerThousand(currentTier);
    
            require(
                maxPricePerThousandTokens == 0 || tierPricePerThousand <= maxPricePerThousandTokens,
                "Price exceeds max price per 1,000 tokens"
            );
    
            uint256 pricePerBrainCredit = (tierPricePerThousand * 1e18) / brainCreditsPerTier;
            uint256 costForTokensInCurrentTier = (tokensInCurrentTier * pricePerBrainCredit) / 1e18;
            uint256 tokensAffordable;
    
            if (remainingPepecoins >= costForTokensInCurrentTier) {
                // Can buy all tokens in tier
                tokensAffordable = tokensInCurrentTier;
                remainingPepecoins -= costForTokensInCurrentTier;
            } else {
                // Can partial buy 
                tokensAffordable = (remainingPepecoins * 1e18) / pricePerBrainCredit;
                remainingPepecoins = 0;
            }
    
            totalTokensToMint += tokensAffordable;
            currentSupply += tokensAffordable;
    
            currentTier += 1;
            tokensInCurrentTier = brainCreditsPerTier;
    
            iterations++;
        }
    
        require(totalTokensToMint > 0, "Insufficient Pepecoins to mint any tokens");
    
        // Adjust for supply cap if necessary
        if (currentSupply > SUPPLY) {
            uint256 excessTokens = currentSupply - SUPPLY;
            totalTokensToMint -= excessTokens;
            currentSupply = SUPPLY;
    
            // Refund Pepecoins for excess tokens
            uint256 tierPricePerThousand = getTierPricePerThousand(currentTier - 1); // Use the last tier
            uint256 pricePerBrainCredit = (tierPricePerThousand * 1e18) / brainCreditsPerTier;
            uint256 pepecoinsToRefund = (excessTokens * pricePerBrainCredit) / 1e18;
            remainingPepecoins += pepecoinsToRefund;
        }
    
        uint256 pepecoinsSpent = pepecoinsToSpend - remainingPepecoins;
    
        require(pepecoinsSpent > 0, "No Pepecoins spent");
    
        // Transfer Pepecoins from user
        require(pepecoin.transferFrom(msg.sender, address(0x000000000000000000000000000000000000dEaD), pepecoinsSpent), "Pepecoin transfer failed");
    
        pepecoinBurnedBy[msg.sender] += pepecoinsSpent;

        if (addressBurnOrder[msg.sender] == 0) {
            totalBurners += 1;
            // Set kek rank
            addressBurnOrder[msg.sender] = totalBurners;
        }

        // Emit event for Pepecoins burned
        emit PepecoinsBurned(msg.sender, pepecoinsSpent, pepecoinBurnedBy[msg.sender], addressBurnOrder[msg.sender]);

        // Mint Brain Credits to user
        _mint(msg.sender, totalTokensToMint);
    
        if (remainingPepecoins > 0) {
            require(pepecoin.transfer(msg.sender, remainingPepecoins), "Refund failed");
        }
    
        emit TokensMinted(msg.sender, totalTokensToMint, pepecoinsSpent);
    
    }
    
    function setPepecoinAddress(address _pepecoinAddress) public onlyOwner {
        pepecoin = ERC20Burnable(_pepecoinAddress);
    }
    
    function checkPepecoinBalanceAndAllowance(address account) public view returns (uint256 balance, uint256 allowance) {
        balance = pepecoin.balanceOf(account);
        allowance = pepecoin.allowance(account, address(this));
    }
    
    function emergencyRefund(address refundAddress) public onlyOwner {
        require(refundAddress != address(0), "Invalid refund address");
        uint256 balance = pepecoin.balanceOf(address(this));
        require(balance > 0, "No Pepecoin to refund");
        require(pepecoin.transfer(refundAddress, balance), "Emergency refund failed");
    }
    
    // Functions to adjust total supply
    function setTotalSupplyAdjuster(address _adjuster) public onlyOwner {
        totalSupplyAdjuster = _adjuster;
        emit TotalSupplyAdjusterChanged(_adjuster);
    }
    
    function increaseTotalSupply() external {
        require(msg.sender == totalSupplyAdjuster, "Unauthorized");
        require(SUPPLY + (1000 * 10 ** decimals()) <= SUPPLY_HARD_CAP, "Total supply cannot exceed hard cap.");
        SUPPLY += (1000 * 10 ** decimals());
        emit TotalSupplyIncreased(SUPPLY);
    }
    
    function decreaseTotalSupply() external {
        require(msg.sender == totalSupplyAdjuster, "Unauthorized");
        require(SUPPLY >= (1000 * 10 ** decimals()), "There must be a minimum supply.");
        SUPPLY -= (1000 * 10 ** decimals());
        emit TotalSupplyDecreased(SUPPLY);
    }
    
    // Functions to control minting
    
    function freezeMinting() public onlyOwner {
        mintingFrozen = true;
        emit MintingFrozen();
    }
    
    function unfreezeMinting() public onlyOwner {
        mintingFrozen = false;
        emit MintingUnfrozen();
    }

    function getBurnStats(address _address) public view returns (uint256 amountBurned, uint256 burnOrder) {
        amountBurned = pepecoinBurnedBy[_address];
        burnOrder = addressBurnOrder[_address];
    }
    
    // Override totalSupply function to ensure visibility
    function totalSupply() public view override returns (uint256) {
        return super.totalSupply();
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC20Metadata} from "./extensions/IERC20Metadata.sol";
import {Context} from "../../utils/Context.sol";
import {IERC20Errors} from "../../interfaces/draft-IERC6093.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 */
abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
    mapping(address account => uint256) private _balances;

    mapping(address account => mapping(address spender => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `value`.
     */
    function transfer(address to, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, value);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, value);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `value`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `value`.
     */
    function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _transfer(from, to, value);
        return true;
    }

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _transfer(address from, address to, uint256 value) internal {
        if (from == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(from, to, value);
    }

    /**
     * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
     * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
     * this function.
     *
     * Emits a {Transfer} event.
     */
    function _update(address from, address to, uint256 value) internal virtual {
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= value;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                _balances[to] += value;
            }
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
     * Relies on the `_update` mechanism
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _mint(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(address(0), account, value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
     * Relies on the `_update` mechanism.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead
     */
    function _burn(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        _update(account, address(0), value);
    }

    /**
     * @dev Sets `value` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        _approve(owner, spender, value, true);
    }

    /**
     * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
     *
     * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
     * `_spendAllowance` during the `transferFrom` operation set the flag to false. This saves gas by not emitting any
     * `Approval` event during `transferFrom` operations.
     *
     * Anyone who wishes to continue emitting `Approval` events on the`transferFrom` operation can force the flag to
     * true using the following override:
     * ```
     * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
     *     super._approve(owner, spender, value, true);
     * }
     * ```
     *
     * Requirements are the same as {_approve}.
     */
    function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
        if (owner == address(0)) {
            revert ERC20InvalidApprover(address(0));
        }
        if (spender == address(0)) {
            revert ERC20InvalidSpender(address(0));
        }
        _allowances[owner][spender] = value;
        if (emitEvent) {
            emit Approval(owner, spender, value);
        }
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `value`.
     *
     * Does not update the allowance value in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Does not emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            if (currentAllowance < value) {
                revert ERC20InsufficientAllowance(spender, currentAllowance, value);
            }
            unchecked {
                _approve(owner, spender, currentAllowance - value, false);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/ERC20Burnable.sol)

pragma solidity ^0.8.20;

import {ERC20} from "../ERC20.sol";
import {Context} from "../../../utils/Context.sol";

/**
 * @dev Extension of {ERC20} that allows token holders to destroy both their own
 * tokens and those that they have an allowance for, in a way that can be
 * recognized off-chain (via event analysis).
 */
abstract contract ERC20Burnable is Context, ERC20 {
    /**
     * @dev Destroys a `value` amount of tokens from the caller.
     *
     * See {ERC20-_burn}.
     */
    function burn(uint256 value) public virtual {
        _burn(_msgSender(), value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, deducting from
     * the caller's allowance.
     *
     * See {ERC20-_burn} and {ERC20-allowance}.
     *
     * Requirements:
     *
     * - the caller must have allowance for ``accounts``'s tokens of at least
     * `value`.
     */
    function burnFrom(address account, uint256 value) public virtual {
        _spendAllowance(account, _msgSender(), value);
        _burn(account, value);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/draft-IERC6093.sol)
pragma solidity ^0.8.20;

/**
 * @dev Standard ERC20 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC20 tokens.
 */
interface IERC20Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientBalance(address sender, uint256 balance, uint256 needed);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC20InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC20InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `spender`’s `allowance`. Used in transfers.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     * @param allowance Amount of tokens a `spender` is allowed to operate with.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 needed);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC20InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `spender` to be approved. Used in approvals.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC20InvalidSpender(address spender);
}

/**
 * @dev Standard ERC721 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC721 tokens.
 */
interface IERC721Errors {
    /**
     * @dev Indicates that an address can't be an owner. For example, `address(0)` is a forbidden owner in EIP-20.
     * Used in balance queries.
     * @param owner Address of the current owner of a token.
     */
    error ERC721InvalidOwner(address owner);

    /**
     * @dev Indicates a `tokenId` whose `owner` is the zero address.
     * @param tokenId Identifier number of a token.
     */
    error ERC721NonexistentToken(uint256 tokenId);

    /**
     * @dev Indicates an error related to the ownership over a particular token. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param tokenId Identifier number of a token.
     * @param owner Address of the current owner of a token.
     */
    error ERC721IncorrectOwner(address sender, uint256 tokenId, address owner);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC721InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC721InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param tokenId Identifier number of a token.
     */
    error ERC721InsufficientApproval(address operator, uint256 tokenId);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC721InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC721InvalidOperator(address operator);
}

/**
 * @dev Standard ERC1155 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC1155 tokens.
 */
interface IERC1155Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     * @param tokenId Identifier number of a token.
     */
    error ERC1155InsufficientBalance(address sender, uint256 balance, uint256 needed, uint256 tokenId);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC1155InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC1155InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param owner Address of the current owner of a token.
     */
    error ERC1155MissingApprovalForAll(address operator, address owner);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC1155InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC1155InvalidOperator(address operator);

    /**
     * @dev Indicates an array length mismatch between ids and values in a safeBatchTransferFrom operation.
     * Used in batch transfers.
     * @param idsLength Length of the array of token identifiers
     * @param valuesLength Length of the array of token amounts
     */
    error ERC1155InvalidArrayLength(uint256 idsLength, uint256 valuesLength);
}

{
  "compilationTarget": {
    "contracts/BrainCreditX.sol": "BrainCredits"
  },
  "evmVersion": "cancun",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}