// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.0;

import "./IERC20.sol";
import "./extensions/IERC20Metadata.sol";
import "../../utils/Context.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20PresetMinterPauser}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20 is Context, IERC20, IERC20Metadata {
    mapping(address => uint256) private _balances;

    mapping(address => mapping(address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual override returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual override returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual override returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address to, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `amount` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `amount`.
     */
    function transferFrom(address from, address to, uint256 amount) public virtual override returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, amount);
        _transfer(from, to, amount);
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, allowance(owner, spender) + addedValue);
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
        address owner = _msgSender();
        uint256 currentAllowance = allowance(owner, spender);
        require(currentAllowance >= subtractedValue, "ERC20: decreased allowance below zero");
        unchecked {
            _approve(owner, spender, currentAllowance - subtractedValue);
        }

        return true;
    }

    /**
     * @dev Moves `amount` of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     */
    function _transfer(address from, address to, uint256 amount) internal virtual {
        require(from != address(0), "ERC20: transfer from the zero address");
        require(to != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(from, to, amount);

        uint256 fromBalance = _balances[from];
        require(fromBalance >= amount, "ERC20: transfer amount exceeds balance");
        unchecked {
            _balances[from] = fromBalance - amount;
            // Overflow not possible: the sum of all balances is capped by totalSupply, and the sum is preserved by
            // decrementing then incrementing.
            _balances[to] += amount;
        }

        emit Transfer(from, to, amount);

        _afterTokenTransfer(from, to, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply += amount;
        unchecked {
            // Overflow not possible: balance + amount is at most totalSupply + amount, which is checked above.
            _balances[account] += amount;
        }
        emit Transfer(address(0), account, amount);

        _afterTokenTransfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        uint256 accountBalance = _balances[account];
        require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
        unchecked {
            _balances[account] = accountBalance - amount;
            // Overflow not possible: amount <= accountBalance <= totalSupply.
            _totalSupply -= amount;
        }

        emit Transfer(account, address(0), amount);

        _afterTokenTransfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(address owner, address spender, uint256 amount) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `amount`.
     *
     * Does not update the allowance amount in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Might emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 amount) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            require(currentAllowance >= amount, "ERC20: insufficient allowance");
            unchecked {
                _approve(owner, spender, currentAllowance - amount);
            }
        }
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(address from, address to, uint256 amount) internal virtual {}

    /**
     * @dev Hook that is called after any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * has been transferred to `to`.
     * - when `from` is zero, `amount` tokens have been minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens have been burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(address from, address to, uint256 amount) internal virtual {}
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/math/SafeMath.sol)

pragma solidity ^0.8.0;

// CAUTION
// This version of SafeMath should only be used with Solidity 0.8 or later,
// because it relies on the compiler's built in overflow checks.

/**
 * @dev Wrappers over Solidity's arithmetic operations.
 *
 * NOTE: `SafeMath` is generally not needed starting with Solidity 0.8, since the compiler
 * now has built in overflow checking.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryAdd(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            uint256 c = a + b;
            if (c < a) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function trySub(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b > a) return (false, 0);
            return (true, a - b);
        }
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryMul(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
            // benefit is lost if 'b' is also tested.
            // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
            if (a == 0) return (true, 0);
            uint256 c = a * b;
            if (c / a != b) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the division of two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryDiv(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a / b);
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryMod(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a % b);
        }
    }

    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     *
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        return a + b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        return a - b;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     *
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        return a * b;
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator.
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        return a / b;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        return a % b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {trySub}.
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        unchecked {
            require(b <= a, errorMessage);
            return a - b;
        }
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        unchecked {
            require(b > 0, errorMessage);
            return a / b;
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting with custom message when dividing by zero.
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {tryMod}.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        unchecked {
            require(b > 0, errorMessage);
            return a % b;
        }
    }
}

// SPDX-License-Identifier: MIT 
pragma solidity ^0.8.20;
//
//          _______                   _____                _____          
//         /::\    \                 /\    \              /\    \         
//        /::::\    \               /::\    \            /::\    \        
//       /::::::\    \              \:::\    \           \:::\    \       
//      /::::::::\    \              \:::\    \           \:::\    \      
//     /:::/~~\:::\    \              \:::\    \           \:::\    \     
//    /:::/    \:::\    \              \:::\    \           \:::\    \    
//   /:::/    / \:::\    \             /::::\    \          /::::\    \   
//  /:::/____/   \:::\____\   ____    /::::::\    \        /::::::\    \  
// |:::|    |     |:::|    | /\   \  /:::/\:::\    \      /:::/\:::\    \ 
// |:::|____|     |:::|    |/::\   \/:::/  \:::\____\    /:::/  \:::\____\
//  \:::\    \   /:::/    / \:::\  /:::/    \::/    /   /:::/    \::/    /
//   \:::\    \ /:::/    /   \:::\/:::/    / \/____/   /:::/    / \/____/ 
//    \:::\    /:::/    /     \::::::/    /           /:::/    /          
//     \:::\__/:::/    /       \::::/____/           /:::/    /           
//      \::::::::/    /         \:::\    \           \::/    /            
//       \::::::/    /           \:::\    \           \/____/             
//        \::::/    /             \:::\    \                              
//         \::/____/               \:::\____\                             
//          ~~                      \::/    /                             
//                                   \/____/                              
//
import {ERC20} from "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
import {SafeMath} from "@openzeppelin/contracts/utils/math/SafeMath.sol";

interface IUniswapV2Factory {
    function createPair(address tokenA, address tokenB)
        external
        returns (address pair);
}

interface IUniswapV2Router02 {
    function factory() external pure returns (address);

    function WETH() external pure returns (address);

    function addLiquidityETH(
        address token,
        uint256 amountTokenDesired,
        uint256 amountTokenMin,
        uint256 amountETHMin,
        address to,
        uint256 deadline
    )
        external
        payable
        returns (
            uint256 amountToken,
            uint256 amountETH,
            uint256 liquidity
        );



    function swapExactTokensForETHSupportingFeeOnTransferTokens(
        uint256 amountIn,
        uint256 amountOutMin,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external;
}

/**
 * @title OpenInfoToken
 * @author Prozeb & Werner
 * @notice This contract is used for the Open Info Token (OIT) ERC20 token.
 * The contract inherits from the ERC20 and Ownable contracts.
 * The token has a maximum supply of 1 million tokens.
 * The contract uses the Uniswap V2 Router for swapping tokens and adding liquidity.
 */
contract OpenInfoToken is ERC20("Open Info Token", "OIT"), Ownable{
    using SafeMath for uint256;


    //======== Variables ========
    IUniswapV2Router02 public immutable uniswapV2Router;

    uint256 public constant MAX_SUPPLY  = 1*1e6*1e9; // 1m
    address public immutable uniswapV2Pair;
    address public constant deadAddress = address(0xdead);

    bool private isTradingEnabled = false;
    bool public swapEnabled = true;
    bool private swapping;

    address public utilityAddress;
    uint256 public enableTradingBlock;
    uint256 public maxHoldLimit = MAX_SUPPLY*2/100;

    uint256 public maxBuyLimitRate = 10; // 1% max buy
    uint256 public maxSellLimitRate = 5; // 0.5% max sell amount forever
    uint256 public maxWarmupBlocks = 15; // total numbers of blocks for warmup period
    uint256 public swapTokensAtAmount;

    uint256 public normalBuyFee =50; //5%
    uint256 public normalSellFee =50; //5%

    mapping(address => bool) private isExcludedFromFees;
    mapping(address => bool) public isExcludedMaxTransactionLimit;
    mapping(address => bool) public isExcludedMaxHoldLimit;

    mapping(address => bool) public automatedMarketMakerPairs;

    //======== Events ========
    event onTradingEnabled();
    event onExcludeFromFees(address indexed account, bool isExcluded);
    event onExcludeFromMaxHoldLimit(address indexed account, bool isExcluded);
    event onExcludeFromMaxTransactionLimit(address indexed account, bool isExcluded);

    event onSetAutomatedMarketMakerPair(address indexed pair, bool indexed value);
    event onUtilityWalletUpdated( address indexed newWallet,address indexed oldWallet);
    event onSwapAndLiquify(
        uint256 initialBalance,
        uint256 liquidityShareInETH,
        uint256 utilityShareInETH
    );
    event onFeeChanged(uint256 preBuyFee,uint256 newBuyFee,uint256 preSellFee,uint256 newSellFee);


    constructor(address _utilityAddress, address _routerAddress, address _kolSeedAddress)  {
        utilityAddress = _utilityAddress;
       
        IUniswapV2Router02 _uniswapV2Router = IUniswapV2Router02(_routerAddress);
        uniswapV2Router = _uniswapV2Router;
        uniswapV2Pair = IUniswapV2Factory(_uniswapV2Router.factory())
            .createPair(address(this), _uniswapV2Router.WETH());
        setAutomatedMarketMakerPair(address(uniswapV2Pair), true);

        excludeFromFees(owner(),true);
        excludeFromFees(address(this), true);
        excludeFromFees(deadAddress, true);
        excludeFromFees(_utilityAddress,true);

        excludeFromMaxTransactionLimit(address(uniswapV2Pair), true);
        excludeFromMaxTransactionLimit(owner(), true);
        excludeFromMaxTransactionLimit(address(this), true);
        excludeFromMaxTransactionLimit(deadAddress, true);
        excludeFromMaxTransactionLimit(_utilityAddress, true);

        excludeFromMaxHoldLimit(address(uniswapV2Pair), true);
        excludeFromMaxHoldLimit(owner(), true);
        excludeFromMaxHoldLimit(address(this), true);
        excludeFromMaxHoldLimit(deadAddress, true);
        excludeFromMaxHoldLimit(_utilityAddress, true);
        excludeFromMaxHoldLimit(_kolSeedAddress, true); // KOLs funds distributed from this address

        uint256 kolShare = MAX_SUPPLY*6/100; // 6% for KOLs
        _mint(_kolSeedAddress,kolShare);

        uint256 utilityShare = MAX_SUPPLY*14/100; // 8% rewards, 6% team. both locked
        _mint(_utilityAddress,utilityShare);

        _mint(msg.sender,MAX_SUPPLY-utilityShare-kolShare); // 80% for liquidity + airdrop
        swapTokensAtAmount = (totalSupply()*1)/1000; // 0.1% of total supply
    }


    modifier lockTheSwap {
        swapping = true;
        _;
        swapping = false;
    }


    receive() external payable {}


    /**
     * @dev This function is used to register/unregister lp addresses in order to find out if transfer is buy or sell.
     * @param pair The address of the LP pair to register/unregister.
     * @param isAdd A boolean indicating whether to register or unregister the LP pair.
     */
    function setAutomatedMarketMakerPair(address pair, bool isAdd) public onlyOwner{
        automatedMarketMakerPairs[pair] = isAdd;
        emit onSetAutomatedMarketMakerPair(pair, isAdd);
    }


    /**
     * @dev This function is used to disable contract sales if absolutely necessary (emergency use only).
     * @param enabled A boolean indicating whether to enable or disable swapping of the token.
     */
    function updateSwapEnabled(bool enabled) external onlyOwner {
        swapEnabled = enabled;
    }


    /**
     * @dev This function is used to exclude/include wallet addresses from max transaction limit.
     * @param account The address of the wallet to exclude/include.
     * @param excluded A boolean indicating whether to exclude or include the wallet.
     */
    function excludeFromMaxTransactionLimit(address account, bool excluded) public onlyOwner {
        isExcludedMaxTransactionLimit[account] = excluded;
        emit onExcludeFromMaxTransactionLimit(account, excluded);
    }


    /**
     * @dev This function is used to exclude/include wallet addresses from max hold limit.
     * @param account The address of the wallet to exclude/include.
     * @param excluded A boolean indicating whether to exclude or include the wallet.
     */
    function excludeFromMaxHoldLimit(address account, bool excluded) public onlyOwner {
        isExcludedMaxHoldLimit[account] = excluded;
        emit onExcludeFromMaxHoldLimit(account, excluded);
    }


    /**
     * @dev This function is used to update the utility wallet address.
     * @param newUtilityAddress The new utility wallet address.
     */
    function updateUtilityWallet(address newUtilityAddress) external onlyOwner {
        emit onUtilityWalletUpdated(utilityAddress, newUtilityAddress);
        utilityAddress = newUtilityAddress;
    }


    /**
     * @dev This function is used to remove the buy transaction and hold limits.
     */
    function removeLimits() external onlyOwner{
        maxHoldLimit =totalSupply();
        maxBuyLimitRate = 1000; //100%
    }


    /**
     * @dev This function is used to change the buy transaction and hold limits.
     * @param maxBuyLimitInPercent The new maximum transaction limit, expressed in tenths of a percent.
     * @param maxHoldLimitInPercent The new maximum hold limit, expressed in tenths of a percent.
     */
    function changeLimits(uint256 maxBuyLimitInPercent,uint256 maxHoldLimitInPercent) external onlyOwner{
        if(!(maxBuyLimitInPercent  >= 10)){
            revert("cant set buy limit less than 1%");
        }
        if(!(maxHoldLimitInPercent  >= 20)){
            revert("cant set hold limit less than 2%");
        }
        
        maxBuyLimitRate = maxBuyLimitInPercent;
        maxHoldLimitInPercent = maxHoldLimitInPercent;
    }


    /**
     * @dev This function is used to change the buy and sell fees.
     * @param buyFee The new buy fee, expressed in tenths of a percent.
     * @param sellFee The new sell fee, expressed in tenths of a percent.
     */
    function changeBuyAndSellFee(uint256 buyFee,uint256 sellFee) external onlyOwner{
        if(!(buyFee  <= 50)){
            revert("cant set buy fee more than 5%");
        }

        if(!(sellFee  <= 50)){
            revert("cant set sell fee more than 5%");
        }

        emit onFeeChanged(normalBuyFee,buyFee,normalSellFee,sellFee);

        normalBuyFee = buyFee;
        normalSellFee = sellFee;
    }


    /**
     * @dev This function is used to exclude/include wallet addresses from fees.
     * @param account The address of the wallet to exclude/include.
     * @param excluded A boolean indicating whether to exclude or include the wallet.
     */
    function excludeFromFees(address account, bool excluded) public onlyOwner {
        isExcludedFromFees[account] = excluded;
        emit onExcludeFromFees(account, excluded);
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * @return The number of decimals in the token's smallest unit.
     */
    function decimals() public view virtual override returns (uint8) {
        return 9;
    }


    /**
     * @dev Returns whether the warmup time is active or not.
     * @return A boolean indicating whether the warmup time is active or not.
     */
    function isWarmupTime() public view returns(bool){
        if(isTradingEnabled == true){
            return enableTradingBlock+maxWarmupBlocks > block.number;
        }
        return true;
    }


    /**
     * @dev Updates the maximum swap token threshold.
     * @param newAmount The new maximum swap token threshold.
     */
    function updateSwapTokensAtAmount(uint256 newAmount) external onlyOwner {
        if(!(newAmount >= (totalSupply() * 1) / 100000)){
            revert("Swap amount cannot be lower than 0.001% total supply.");
        }

        if(!( newAmount <= (totalSupply() * 5) / 1000)){
            revert("Swap amount cannot be higher than 0.5% total supply.");
        }
        swapTokensAtAmount = newAmount;
    }


    /**
     * @dev Returns the transaction fee for a given amount of tokens.
     * @return buyFee the current buy fee, expressed as tenths of a percent.
     * @return sellFee the current sell fee, expressed as tenths of a percent.
     */
    function getTxnFee() private  view returns(uint256 buyFee,uint256 sellFee){
        if(isWarmupTime()){
            uint256 passedBlocks =  block.number - enableTradingBlock;
            if(passedBlocks < 7){
                buyFee = 500; //50%
                sellFee = 500; //50%
            }else {
                buyFee = 250; //25%
                sellFee = 250; //25%
            }
        }else{
            buyFee = normalBuyFee;
            sellFee = normalSellFee;
        }
    } 


    /**
     * @dev Used to enable trading after the pre-specified specified number of warmup blocks.
     */
    function goBokke() external onlyOwner {
        isTradingEnabled = true;
        enableTradingBlock = block.number;
        emit onTradingEnabled();
    }


    /**
     * @dev Swaps given tokens for ETH.
     * @param tokenAmount The amount of tokens to swap.
     */
    function swapTokensForEth(uint256 tokenAmount) private {
        // generate the uniswap pair path of token -> weth
        address[] memory path = new address[](2);
        path[0] = address(this);
        path[1] = uniswapV2Router.WETH();

        _approve(address(this), address(uniswapV2Router), tokenAmount);

        // make the swap
        uniswapV2Router.swapExactTokensForETHSupportingFeeOnTransferTokens(
            tokenAmount,
            0, // accept any amount of ETH
            path,
            address(this),
            block.timestamp
        );
    }


    /**
     * @dev Swaps nine tenths of the given tokens for ETH and adds a tenth of the tokens to the liquidity in the Uniswap pool.
     * @param balance The balance of tokens to be swapped and liquified.
     */
    function swapAndLiquify(uint256 balance) private lockTheSwap {
        uint256 initialBalance = address(this).balance;
        uint256 convertingToETH = balance*90/100;
        uint256 liquidityShareInTokens = balance*10/100;
        swapTokensForEth(convertingToETH); 
        uint256 newBalance = address(this).balance.sub(initialBalance);
        uint256 utilityShareInETH  = newBalance*80/100;
        uint256 liquidityShareInETH  = newBalance*20/100;
        payable(utilityAddress).transfer(utilityShareInETH);
        addLiquidity(liquidityShareInTokens, liquidityShareInETH);
        emit onSwapAndLiquify(initialBalance, liquidityShareInETH, utilityShareInETH);
    }


    /**
     * @dev Used to add tokens liquidity to the Uniswap pool.
     * @param tokenAmount The amount of tokens to be added as liquidity.
     * @param ethAmount The amount of ETH to be added as liquidity.
     */
    function addLiquidity(uint256 tokenAmount, uint256 ethAmount) private {
        _approve(address(this), address(uniswapV2Router), tokenAmount);
        uniswapV2Router.addLiquidityETH{value: ethAmount}(
            address(this),
            tokenAmount,
            0, 
            0, 
            deadAddress,
            block.timestamp
        );
    }


    /**
     * @dev Internal transfer function. Overridden to meet tokenomics of the token, see https://vrfd.info/token.
     * @param from Address of the sender.
     * @param to Address of the recipient.
     * @param amount Amount to be transferred.
     */
    function _transfer(address from, address to, uint256 amount) internal  override virtual {
        if(owner() == from || owner() == to){
            super._transfer(from,to,amount);
            return;
        }

        if(!isTradingEnabled){
            revert("Trading not enabled");
        }
        bool isBuy = automatedMarketMakerPairs[from];
        bool isSell = automatedMarketMakerPairs[to];

        uint256 contractTokenBalance = balanceOf(address(this));
        bool canSwap = contractTokenBalance >= swapTokensAtAmount;

        if (
            canSwap &&
            swapEnabled &&
            !swapping &&
            !automatedMarketMakerPairs[from]) {
            swapAndLiquify(swapTokensAtAmount);
        }
        if(!isExcludedMaxTransactionLimit[from]){
            if(isBuy){
                if(!(amount <= maxBuyLimitRate*totalSupply()/1000)){
                    revert("Limit Reached");
                }
            }else if(isSell){
                if(!(amount <= maxSellLimitRate*totalSupply()/1000)){
                    revert("Limit Reached");
                }
            }
        }

        if(!isExcludedMaxHoldLimit[to]){
            if(!(amount+balanceOf(to)<= maxHoldLimit)){
                revert("Max Hold Limit Reached");
            }
        }

        bool isTakeFee = !isExcludedFromFees[from] && (isBuy || isSell);

        if(isTakeFee){
            (uint256 buyFee,uint256 sellFee) = getTxnFee();
            if(isBuy){
                uint256 buyFeeAmount = amount * buyFee /1000;
                if(buyFeeAmount >0){
                    super._transfer(from,address(this),buyFeeAmount);
                }
                super._transfer(from,to,amount-buyFeeAmount);
            }else if(isSell){
                uint256 sellFeeAmount = amount * sellFee /1000;
                if(sellFeeAmount >0){
                    super._transfer(from,address(this),sellFeeAmount);
                }
                super._transfer(from,to,amount-sellFeeAmount);
            }
        }else{
            super._transfer(from,to,amount);
        }
    }

    /**
     * @dev Used to transfer the contract's ETH balance to the contract owner.
     */
    function takeETH() external onlyOwner{
        (bool success,) = msg.sender.call{value:address(this).balance}("");
        if(!success) revert("Can't Withdraw");
    }
}

{
  "compilationTarget": {
    "contracts/Token.sol": "OpenInfoToken"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}