// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value, string memory errorMessage) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data, string memory errorMessage) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(bool success, bytes memory returndata, string memory errorMessage) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.9;

error LengthNotMatch();
error EmptyTokenClaim();
error AlreadyRegist();
error NotInvestor();
error AlreadyClaimed();
error WholeClaimed();
error OutofRange();
error Faild();
error NotYet();
error ExceedAmount();
error NotMatchedAmount();
error ExceedTime();
error MoreTimeDelay();
error NotAirdropUser();
error TimeNotSet();

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.17;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.17;
import "./libraries/SafeERC20.sol";
import "@openzeppelin/contracts/security/Pausable.sol";
import {LengthNotMatch, AlreadyRegist, NotInvestor, AlreadyClaimed, WholeClaimed, EmptyTokenClaim, OutofRange, Faild, NotYet, ExceedAmount, NotMatchedAmount, ExceedTime, MoreTimeDelay, NotAirdropUser, TimeNotSet} from "./Errors.sol";

interface OldAirdrop {
    struct AirdropUser {
        uint256 airdropUserTotalClaimable;
        uint256 airdropUserTotalClaimed;
        uint256 airdropUpdateLastClaimTime;
    }
}

interface IPlexusIDO_202311 {
    struct User {
        uint256 userTotalClaimableAmount;
        uint256 updateLastClaimTimestamp;
        uint256 userTotalClaimed;
    }

    function AirdropUserInfo(address user) external view returns (User memory);

    function oldAirdropInfo(address user) external view returns (OldAirdrop.AirdropUser memory);

    function TGETimestamp() external view returns (uint256);
}

contract NewPlexusIDO_202311 is Pausable {
    using SafeERC20 for IERC20;

    event Claim(address user, uint256 claimAmount, uint256 claimTime);
    event ChangeOwner(address oldOwner, address newOwner);
    event ChangeTGEtime(uint256 oldTime, uint256 newTime);

    IERC20 private immutable PLEXUS;

    address public owner;
    address public plexusIDO;
    address public plexusIDO_202311;
    address public plexusIDO_202311_old;
    uint256 public plexusTotalAmount;
    uint256 public TGETimestamp;
    uint256 public claimStartTime;

    uint256 public constant PLX_ACC_PRECISION = 1e18;
    uint256 public constant AIRDROP_TOTAL_SUPPLY = 9_750_500;

    uint256 public airdropTotalClaimed;

    address[] internal signerList;
    mapping(address => uint256) confirmTime;

    // =============

    struct User {
        uint256 userTotalClaimableAmount;
        uint256 updateLastClaimTimestamp;
        uint256 userTotalClaimed;
    }

    modifier onlyOwner() {
        require(msg.sender == owner, "No permission");
        _;
    }

    constructor(address _plxAddress, address _plexusIDO, address _plexusIDO_202311, address _plexusIDO_202311_old) {
        PLEXUS = IERC20(_plxAddress);
        plexusIDO = _plexusIDO;
        plexusIDO_202311 = _plexusIDO_202311;
        plexusIDO_202311_old = _plexusIDO_202311_old;
        owner = msg.sender;
        TGETimestamp = IPlexusIDO_202311(plexusIDO_202311).TGETimestamp();
    }

    function setClaimStartTime(uint256 _claimStartTime) external onlyOwner {
        claimStartTime = _claimStartTime;
    }

    function setOwner(address _newOwner) public onlyOwner {
        require(_newOwner != address(0));
        owner = _newOwner;
        emit ChangeOwner(msg.sender, _newOwner);
    }

    function pauseOnOff() external onlyOwner {
        if (!paused()) {
            _pause();
        } else {
            _unpause();
        }
    }

    function _calculmonth(uint256 _num) internal pure returns (uint256) {
        return _num * 30 days;
    }

    function _mulPrecision(uint256 _num) internal pure returns (uint256) {
        return _num * PLX_ACC_PRECISION;
    }

    function callPlxBalance() public view returns (uint256) {
        return PLEXUS.balanceOf(address(this));
    }

    // ========
    // airdrop section

    mapping(address => User) public AirdropUserInfo;

    function airdropUserClaimablePlx(address _user) public view returns (uint256) {
        User memory airdropUser = AirdropUserInfo[_user];

        uint256 userTotalClaimableAmount;
        uint256 userTotalClaimed;

        if (airdropUser.updateLastClaimTimestamp == 0) {
            userTotalClaimableAmount = IPlexusIDO_202311(plexusIDO).AirdropUserInfo(_user).userTotalClaimableAmount;
            userTotalClaimed = IPlexusIDO_202311(plexusIDO).AirdropUserInfo(_user).userTotalClaimed;

            if (userTotalClaimableAmount == 0) {
                userTotalClaimableAmount = IPlexusIDO_202311(plexusIDO_202311).AirdropUserInfo(_user).userTotalClaimableAmount;
                userTotalClaimed = IPlexusIDO_202311(plexusIDO_202311).AirdropUserInfo(_user).userTotalClaimed;

                if (userTotalClaimableAmount == 0) {
                    userTotalClaimableAmount = IPlexusIDO_202311(plexusIDO_202311_old).AirdropUserInfo(_user).userTotalClaimableAmount;
                    userTotalClaimed = IPlexusIDO_202311(plexusIDO_202311_old).AirdropUserInfo(_user).userTotalClaimed;
                }
            }
        } else {
            if (airdropUser.userTotalClaimed >= airdropUser.userTotalClaimableAmount) revert WholeClaimed();
            userTotalClaimableAmount = airdropUser.userTotalClaimableAmount;
            userTotalClaimed = airdropUser.userTotalClaimed;
        }

        uint256 tgeDateClaimbleAmount;
        uint256 airdropEndTime;
        if (userTotalClaimableAmount <= (5000 * PLX_ACC_PRECISION)) {
            tgeDateClaimbleAmount = (userTotalClaimableAmount * 125) / 1000; // TGE 12.5% release
            airdropEndTime = _calculmonth(8);
        } else if (userTotalClaimableAmount > (5000 * PLX_ACC_PRECISION) && userTotalClaimableAmount <= (50000 * PLX_ACC_PRECISION)) {
            tgeDateClaimbleAmount = (userTotalClaimableAmount * 100) / 1000; // TGE 10% release
            airdropEndTime = _calculmonth(10);
        } else if (userTotalClaimableAmount > (50000 * PLX_ACC_PRECISION)) {
            tgeDateClaimbleAmount = (userTotalClaimableAmount * 75) / 1000; // TGE 7.5% release
            airdropEndTime = _calculmonth(12);
        }

        uint256 remainClaimableAmount = userTotalClaimableAmount - tgeDateClaimbleAmount;

        uint256 perSecondClaimableToken = remainClaimableAmount / airdropEndTime;
        uint256 claimableAmount;

        if (block.timestamp >= TGETimestamp && block.timestamp < TGETimestamp + airdropEndTime) {
            if (airdropUser.updateLastClaimTimestamp == 0) {
                claimableAmount = tgeDateClaimbleAmount + ((block.timestamp - TGETimestamp) * perSecondClaimableToken) - userTotalClaimed;
            } else {
                claimableAmount = (block.timestamp - airdropUser.updateLastClaimTimestamp) * perSecondClaimableToken;
            }
        } else if (block.timestamp >= TGETimestamp + airdropEndTime) {
            claimableAmount = userTotalClaimableAmount - userTotalClaimed;
        } else {
            revert OutofRange();
        }

        return claimableAmount;
    }

    function airdropUserClaimPlx() public whenNotPaused {
        if (block.timestamp < claimStartTime) revert NotYet();
        if (block.timestamp < TGETimestamp) revert NotYet();

        User storage airdropUser = AirdropUserInfo[msg.sender];
        if (airdropUser.updateLastClaimTimestamp == 0) {
            airdropUser.userTotalClaimableAmount = IPlexusIDO_202311(plexusIDO).AirdropUserInfo(msg.sender).userTotalClaimableAmount;
            airdropUser.userTotalClaimed = IPlexusIDO_202311(plexusIDO).AirdropUserInfo(msg.sender).userTotalClaimed;

            if (airdropUser.userTotalClaimableAmount == 0) {
                airdropUser.userTotalClaimableAmount = IPlexusIDO_202311(plexusIDO_202311).AirdropUserInfo(msg.sender).userTotalClaimableAmount;
                airdropUser.userTotalClaimed = IPlexusIDO_202311(plexusIDO_202311).AirdropUserInfo(msg.sender).userTotalClaimed;
                if (airdropUser.userTotalClaimableAmount == 0) {
                    airdropUser.userTotalClaimableAmount = IPlexusIDO_202311(plexusIDO_202311_old)
                        .AirdropUserInfo(msg.sender)
                        .userTotalClaimableAmount;
                    airdropUser.userTotalClaimed = IPlexusIDO_202311(plexusIDO_202311_old).AirdropUserInfo(msg.sender).userTotalClaimed;
                }
            }
        }
        uint256 claimableAmount = airdropUserClaimablePlx(msg.sender);

        if (claimableAmount == 0) revert EmptyTokenClaim();
        PLEXUS.safeTransfer(msg.sender, claimableAmount);
        airdropUser.updateLastClaimTimestamp = block.timestamp;
        airdropUser.userTotalClaimed += claimableAmount;
        airdropTotalClaimed += claimableAmount;
    }

    function oldAirdropInfo(address user) public view returns (OldAirdrop.AirdropUser memory) {
        return IPlexusIDO_202311(plexusIDO_202311).oldAirdropInfo(user);
    }

    function airdropUserInfo(address user) external view returns (uint256 total, uint256 claimable, uint256 claimed) {
        User memory airdropUser = AirdropUserInfo[user];

        if (airdropUser.updateLastClaimTimestamp == 0) {
            claimed = IPlexusIDO_202311(plexusIDO).AirdropUserInfo(user).userTotalClaimed;
            total = IPlexusIDO_202311(plexusIDO).AirdropUserInfo(user).userTotalClaimableAmount;

            if (total == 0) {
                claimed = IPlexusIDO_202311(plexusIDO_202311).AirdropUserInfo(user).userTotalClaimed;
                total = IPlexusIDO_202311(plexusIDO_202311).AirdropUserInfo(user).userTotalClaimableAmount;
                if (total == 0) {
                    claimed = IPlexusIDO_202311(plexusIDO_202311_old).AirdropUserInfo(user).userTotalClaimed;
                    total = IPlexusIDO_202311(plexusIDO_202311_old).AirdropUserInfo(user).userTotalClaimableAmount;
                }
            }
        } else {
            total = airdropUser.userTotalClaimableAmount;
            claimed = airdropUser.userTotalClaimed;
        }
        claimable = airdropUserClaimablePlx(user);
    }

    // ===== emergencyWithdraw
    function emergencyWithdraw() external onlyOwner {
        uint256 length = signerList.length;
        for (uint256 i; i < length; i++) {
            if (confirmTime[signerList[i]] + 600 < block.timestamp) revert ExceedTime();
        }
        PLEXUS.safeTransfer(owner, callPlxBalance());
    }

    function setSigner(address[] memory _signer) external onlyOwner {
        require(_signer.length >= 3);
        for (uint256 i = 0; i < _signer.length; i++) {
            signerList.push(_signer[i]);
        }
    }

    function viewSigner() external view returns (address[] memory) {
        return signerList;
    }

    function signerConfirm() external {
        bool check;
        uint256 length = signerList.length;
        for (uint256 i; i < length; i++) {
            if (msg.sender == signerList[i]) {
                check = true;
                break;
            }
        }
        require(check);
        confirmTime[msg.sender] = block.timestamp;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (security/Pausable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    bool private _paused;

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        require(!paused(), "Pausable: paused");
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        require(paused(), "Pausable: not paused");
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

import "../interfaces/IERC20.sol";
import "./Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require((value == 0) || (token.allowance(address(this), spender) == 0), "SafeERC20: approve from non-zero to non-zero allowance");
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 newAllowance = token.allowance(address(this), spender) + value;
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            uint256 newAllowance = oldAllowance - value;
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address.functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        if (returndata.length > 0) {
            // Return data is optional
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}

{
  "compilationTarget": {
    "contracts/NewPlexusIDO_202311.sol": "NewPlexusIDO_202311"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}