// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// Author: A.P
// Organization: Rare Art
// Development: Kibernacia
// Product: RareDrop
// Version: 1.0.0
// Link: https://linktr.ee/rareuniverse
pragma solidity ^0.8.24;

// OpenZeppelin
import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {ReentrancyGuard} from "@openzeppelin/contracts/utils/ReentrancyGuard.sol";

contract RareDrop is Ownable, ReentrancyGuard {
    /// @notice Stores contract name.
    /// @dev Stores constant string.
    string private constant _name = "RareDrop";

    /// @notice Stores contract symbol.
    /// @dev Stores constant string.
    string private constant _symbol = "RAREDROP";

    /// @notice Mapping to store balances of tokens assigned to recipients.
    /// @dev Nested mapping where the first key is the token address and the second key is the recipient address.
    mapping(address => mapping(address => uint256)) private _balances;

    /// @notice Enum to define the operation types.
    /// @dev The enum values represent the operations: Add (0), Subtract (1), and Assign (2).
    enum Operation {
        Add,
        Subtract,
        Assign
    }

    // Events
    /**
     * @notice Emitted when an airdrop is assigned to a recipient.
     * @param token The address of the ERC20 token being airdropped.
     * @param recipient The address of the recipient receiving the airdrop.
     * @param amount The amount of tokens assigned to the recipient.
     */
    event AirdropAssigned(
        address indexed token,
        address indexed recipient,
        uint256 amount
    );

    /**
     * @notice Emitted when an airdrop is triggered for a specific token.
     * @param token The address of the ERC20 token being airdropped.
     */
    event AirdropTriggered(address indexed token);

    /**
     * @notice Emitted when a recipient claims their airdropped tokens.
     * @param token The address of the ERC20 token being claimed.
     * @param recipient The address of the recipient claiming the airdrop.
     * @param amount The amount of tokens claimed by the recipient.
     */
    event AirdropClaimed(
        address indexed token,
        address indexed recipient,
        uint256 amount
    );

    // Errors
    /// @notice Error thrown when the recipients and amounts arrays have different lengths.
    error RecipientsAndAmountsMismatch();

    /// @notice Error thrown when there are no tokens available to claim.
    error InsufficientBalanceToClaim();

    /// @notice Error thrown when a token transfer fails.
    error TokenTransferFailed();

    /**
     * @notice Constructor that sets the owner of the contract.
     * @dev The Ownable constructor is called with the deployer's address.
     */
    constructor() Ownable(_msgSender()) {}

    /**
     * @notice Returns the balance of a specific token assigned to an account.
     * @param token The address of the ERC20 token.
     * @param account The address of the account.
     * @return The balance of the specified token assigned to the account.
     */
    function balanceOf(
        address token,
        address account
    ) public view returns (uint256) {
        return _balances[token][account];
    }

    /**
     * @notice Assigns or adjusts token balances for multiple recipients.
     * @dev This function allows adding to, subtracting from, or directly setting the balance of each recipient.
     * @param token The address of the ERC20 token.
     * @param recipients The array of recipient addresses.
     * @param amounts The array of token amounts to be assigned to the recipients.
     * @param operation The operation type to perform:
     * - 0 = Add to existing balance,
     * - 1 = Subtract from existing balance,
     * - 2 = Assign directly (overwrite) the balance.
     * @dev Emits an `AirdropAssigned` event for each recipient.
     * @dev Reverts with `RecipientsAndAmountsMismatch` if the lengths of `recipients` and `amounts` are not equal.
     */
    function assign(
        address token,
        address[] calldata recipients,
        uint256[] calldata amounts,
        Operation operation
    ) external onlyOwner nonReentrant {
        // Validation
        if (recipients.length != amounts.length) {
            revert RecipientsAndAmountsMismatch();
        }

        if (operation == Operation.Add) {
            for (uint256 i = 0; i < recipients.length; i++) {
                // Update
                _balances[token][recipients[i]] += amounts[i];

                // Event
                emit AirdropAssigned(token, recipients[i], amounts[i]);
            }
        }

        if (operation == Operation.Subtract) {
            for (uint256 i = 0; i < recipients.length; i++) {
                // Update
                _balances[token][recipients[i]] -= amounts[i];

                // Event
                emit AirdropAssigned(token, recipients[i], amounts[i]);
            }
        }

        if (operation == Operation.Assign) {
            for (uint256 i = 0; i < recipients.length; i++) {
                // Update
                _balances[token][recipients[i]] = amounts[i];

                // Event
                emit AirdropAssigned(token, recipients[i], amounts[i]);
            }
        }
    }

    /**
     * @notice Trigger the airdrop transaction to distribute tokens to all assigned recipients for a specific token.
     * @dev Only the contract owner can call this function.
     * @param token The address of the ERC20 token.
     * @param recipients The array of recipient addresses who have a balance to claim.
     * @dev Emits an `AirdropTriggered` event after the airdrop is completed.
     * @dev Reverts with `TokenTransferFailed` if any of the token transfers fail.
     */
    function airdrop(
        address token,
        address[] calldata recipients
    ) external onlyOwner nonReentrant {
        // Object
        IERC20 _contract = IERC20(token);

        for (uint256 i = 0; i < recipients.length; i++) {
            // Parameters
            address recipient = recipients[i];
            uint256 amount = _balances[token][recipient];

            // Validation
            if (amount > 0) {
                // Transfer
                bool status = _contract.transfer(recipient, amount);

                // Validation
                if (!status) {
                    revert TokenTransferFailed();
                }

                // Update
                _balances[token][recipient] = 0;
            }
        }

        emit AirdropTriggered(token);
    }

    /**
     * @notice Allows a user to claim their assigned tokens for a specific token.
     * @dev Only the recipient of the airdrop can call this function.
     * @param token The address of the ERC20 token.
     * @dev Emits an `AirdropClaimed` event after the claim is successful.
     * @dev Reverts with `InsufficientBalanceToClaim` if the caller has no tokens to claim.
     * @dev Reverts with `TokenTransferFailed` if the token transfer fails.
     */
    function claim(address token) external nonReentrant {
        // Parameters
        uint256 amount = _balances[token][_msgSender()];

        // Validation
        if (amount == 0) {
            revert InsufficientBalanceToClaim();
        }

        // Object
        IERC20 _contract = IERC20(token);

        // Transfer
        bool status = _contract.transfer(_msgSender(), amount);

        // Validation
        if (!status) {
            revert TokenTransferFailed();
        }

        // Update
        _balances[token][_msgSender()] = 0;

        // Event
        emit AirdropClaimed(token, _msgSender(), amount);
    }

    /**
     * @notice Allows the contract owner to withdraw any leftover tokens from the contract.
     * @dev Only the contract owner can call this function.
     * @param token The address of the ERC20 token to withdraw.
     * @param amount The amount of tokens to withdraw.
     * @dev Reverts with `TokenTransferFailed` if the token transfer fails.
     */
    function withdraw(
        address token,
        uint256 amount
    ) external onlyOwner nonReentrant {
        // Object
        IERC20 _contract = IERC20(token);

        // Transfer
        bool status = _contract.transfer(owner(), amount);

        // Validation
        if (!status) {
            revert TokenTransferFailed();
        }
    }

    /**
     * @dev Returns the name of the contract.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the contract, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @notice Fallback function to receive ETH.
     * @dev This function allows the contract to receive ETH.
     */
    receive() external payable {}

    /**
     * @notice Fallback function to receive ETH.
     * @dev This function allows the contract to receive ETH.
     */
    fallback() external payable {}
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

{
  "compilationTarget": {
    "contracts/RareDrop.sol": "RareDrop"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 1000
  },
  "remappings": [],
  "viaIR": true
}