// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.19;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/access/Ownable.sol";

/**
 * @title Staking
 * @dev A contract for staking ERC20 tokens for a specific duration.
 */
contract Staking is Ownable {
    struct Stake {
        uint256 amount;
        uint256 unlocksAt;
    }

    event Staked(
        address staker,
        uint256 amount
    );
    event Unstaked(
        address staker,
        uint256 amount
    );

	IERC20 public token;
    uint256 public minStakingAmount;
    uint256 public stakingDuration;

    mapping(address => Stake) public stakes;

    /**
     * @dev Initializes the contract with the specified token address.
     * @param _tokenAddress The address of the ERC20 token to be staked.
     */
    constructor(address _tokenAddress) Ownable(msg.sender) {
        token = IERC20(_tokenAddress);
        minStakingAmount = 0;
        stakingDuration = 0;
    }

    /**
     * @notice Sets the staking parameters.
     * @dev Only the contract owner can call this function.
     * @param _amount The amount of tokens to be staked.
     * @param _duration The duration for which the tokens will be locked in seconds.
     */
    function setStakingParameters(
        uint256 _amount,
        uint256 _duration
    ) external onlyOwner {
        require(_amount > 0, "Amount must be greater than 0");
        require(_duration > 0, "Duration must be greater than 0");

        minStakingAmount = _amount;
        stakingDuration = _duration;
    }

    /**
     * @notice Stakes the specified amount of tokens for the specified duration.
     * @dev The staker must have approved the contract to transfer the specified amount of tokens.
	 * @param _amount The total amount of tokens to be staked.
     */
    function stake(uint256 _amount) external {
        require(minStakingAmount > 0, "Staking amount not set");
        require(stakingDuration > 0, "Staking duration not set");
		require(_amount >= minStakingAmount, "Amount must be greater than or equal to the minimum staking amount");

		Stake memory existingStake = stakes[msg.sender];

		if (existingStake.amount > 0) {
			require(block.timestamp >= existingStake.unlocksAt, "Existing stake has not expired");
			stakes[msg.sender] = Stake({
				amount: _amount,
				unlocksAt: block.timestamp + stakingDuration
			});
			if (_amount > existingStake.amount) {
				token.transferFrom(msg.sender, address(this), _amount - existingStake.amount);
			} else {
				token.transfer(msg.sender, existingStake.amount - _amount);
			}
			emit Unstaked(msg.sender, existingStake.amount);
		} else {
			stakes[msg.sender] = Stake({
				amount: _amount,
				unlocksAt: block.timestamp + stakingDuration
			});
			token.transferFrom(msg.sender, address(this), _amount);
		}

		emit Staked(msg.sender, _amount);
    }

	/**
	 * @notice Unstakes the specified stake.
	 * @dev Only the staker can call this function.
	 * @param _amount The amount of tokens to be unstaked.
	 */
	function unstake(uint256 _amount) external {
		require(stakes[msg.sender].unlocksAt <= block.timestamp, "Stake has not expired");
		require(stakes[msg.sender].amount > 0, "Stake does not exist");
		require(stakes[msg.sender].amount >= _amount, "Amount must be less than or equal to the stake amount");

		if (stakes[msg.sender].amount == _amount) {
			delete stakes[msg.sender];
		} else {
			stakes[msg.sender].amount -= _amount;
		}
		token.transfer(msg.sender, _amount);

		emit Unstaked(msg.sender, _amount);
	}
}

{
  "compilationTarget": {
    "Staking.sol": "Staking"
  },
  "evmVersion": "shanghai",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}