Detective Comics (1937-2011) #58

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

import "../utils/EnumerableSet.sol";
import "../utils/Address.sol";
import "../utils/Context.sol";

/**
 * @dev Contract module that allows children to implement role-based access
 * control mechanisms.
 *
 * Roles are referred to by their `bytes32` identifier. These should be exposed
 * in the external API and be unique. The best way to achieve this is by
 * using `public constant` hash digests:
 *
 * ```
 * bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
 * ```
 *
 * Roles can be used to represent a set of permissions. To restrict access to a
 * function call, use {hasRole}:
 *
 * ```
 * function foo() public {
 *     require(hasRole(MY_ROLE, msg.sender));
 *     ...
 * }
 * ```
 *
 * Roles can be granted and revoked dynamically via the {grantRole} and
 * {revokeRole} functions. Each role has an associated admin role, and only
 * accounts that have a role's admin role can call {grantRole} and {revokeRole}.
 *
 * By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
 * that only accounts with this role will be able to grant or revoke other
 * roles. More complex role relationships can be created by using
 * {_setRoleAdmin}.
 *
 * WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
 * grant and revoke this role. Extra precautions should be taken to secure
 * accounts that have been granted it.
 */
abstract contract AccessControl is Context {
    using EnumerableSet for EnumerableSet.AddressSet;
    using Address for address;

    struct RoleData {
        EnumerableSet.AddressSet members;
        bytes32 adminRole;
    }

    mapping (bytes32 => RoleData) private _roles;

    bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;

    /**
     * @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
     *
     * `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
     * {RoleAdminChanged} not being emitted signaling this.
     *
     * _Available since v3.1._
     */
    event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);

    /**
     * @dev Emitted when `account` is granted `role`.
     *
     * `sender` is the account that originated the contract call, an admin role
     * bearer except when using {_setupRole}.
     */
    event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Emitted when `account` is revoked `role`.
     *
     * `sender` is the account that originated the contract call:
     *   - if using `revokeRole`, it is the admin role bearer
     *   - if using `renounceRole`, it is the role bearer (i.e. `account`)
     */
    event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) public view returns (bool) {
        return _roles[role].members.contains(account);
    }

    /**
     * @dev Returns the number of accounts that have `role`. Can be used
     * together with {getRoleMember} to enumerate all bearers of a role.
     */
    function getRoleMemberCount(bytes32 role) public view returns (uint256) {
        return _roles[role].members.length();
    }

    /**
     * @dev Returns one of the accounts that have `role`. `index` must be a
     * value between 0 and {getRoleMemberCount}, non-inclusive.
     *
     * Role bearers are not sorted in any particular way, and their ordering may
     * change at any point.
     *
     * WARNING: When using {getRoleMember} and {getRoleMemberCount}, make sure
     * you perform all queries on the same block. See the following
     * https://forum.openzeppelin.com/t/iterating-over-elements-on-enumerableset-in-openzeppelin-contracts/2296[forum post]
     * for more information.
     */
    function getRoleMember(bytes32 role, uint256 index) public view returns (address) {
        return _roles[role].members.at(index);
    }

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) public view returns (bytes32) {
        return _roles[role].adminRole;
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function grantRole(bytes32 role, address account) public virtual {
        require(hasRole(_roles[role].adminRole, _msgSender()), "AccessControl: sender must be an admin to grant");

        _grantRole(role, account);
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function revokeRole(bytes32 role, address account) public virtual {
        require(hasRole(_roles[role].adminRole, _msgSender()), "AccessControl: sender must be an admin to revoke");

        _revokeRole(role, account);
    }

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been granted `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `account`.
     */
    function renounceRole(bytes32 role, address account) public virtual {
        require(account == _msgSender(), "AccessControl: can only renounce roles for self");

        _revokeRole(role, account);
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event. Note that unlike {grantRole}, this function doesn't perform any
     * checks on the calling account.
     *
     * [WARNING]
     * ====
     * This function should only be called from the constructor when setting
     * up the initial roles for the system.
     *
     * Using this function in any other way is effectively circumventing the admin
     * system imposed by {AccessControl}.
     * ====
     */
    function _setupRole(bytes32 role, address account) internal virtual {
        _grantRole(role, account);
    }

    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.
     */
    function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
        emit RoleAdminChanged(role, _roles[role].adminRole, adminRole);
        _roles[role].adminRole = adminRole;
    }

    function _grantRole(bytes32 role, address account) private {
        if (_roles[role].members.add(account)) {
            emit RoleGranted(role, account, _msgSender());
        }
    }

    function _revokeRole(bytes32 role, address account) private {
        if (_roles[role].members.remove(account)) {
            emit RoleRevoked(role, account, _msgSender());
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.2 <0.8.0;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        // solhint-disable-next-line no-inline-assembly
        assembly { size := extcodesize(account) }
        return size > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        // solhint-disable-next-line avoid-low-level-calls, avoid-call-value
        (bool success, ) = recipient.call{ value: amount }("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain`call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
      return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value, string memory errorMessage) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.call{ value: value }(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data, string memory errorMessage) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.staticcall(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    function _verifyCallResult(bool success, bytes memory returndata, string memory errorMessage) private pure returns(bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                // solhint-disable-next-line no-inline-assembly
                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.7.5;
pragma experimental ABIEncoderV2;

import "./IAsset.sol";
import "@openzeppelin/contracts/access/AccessControl.sol";

contract Asset is IAsset, AccessControl {

    bytes32 private constant _MANAGER_ROLE = keccak256("MANAGER_ROLE");
    bytes32 private constant _MINTER_ROLE = keccak256("MINTER_ROLE");

    constructor() {
        _setupRole(DEFAULT_ADMIN_ROLE, _msgSender());
    }

    function transferDefaultAdmin(address defaultAdmin) external returns (bool) {
        require(_msgSender() != defaultAdmin, "Must be different admin");
        grantRole(DEFAULT_ADMIN_ROLE, defaultAdmin);
        renounceRole(DEFAULT_ADMIN_ROLE, _msgSender());
        return true;
    }

    function authorizeAssetManager(address manager) external override returns (bool) {
        grantRole(_MANAGER_ROLE, manager);
        emit AssetManagerAuthorized(manager, _msgSender());
        return true;
    }

    function revokeAssetManager(address manager) external override returns (bool) {
        revokeRole(_MANAGER_ROLE, manager);
        emit AssetManagerRevoked(manager, _msgSender());
        return true;
    }

    function authorizeAssetMinter(address minter) external override returns (bool) {
        grantRole(_MINTER_ROLE, minter);
        emit AssetMinterAuthorized(minter, _msgSender());
        return true;
    }

    function revokeAssetMinter(address minter) external override returns (bool) {
        revokeRole(_MINTER_ROLE, minter);
        emit AssetMinterRevoked(minter, _msgSender());
        return true;
    }

    function isAssetManager(address manager) public override view returns (bool) {
        return hasRole(_MANAGER_ROLE, manager);
    }

    function isAssetMinter(address minter) external override view returns (bool) {
        return hasRole(_MINTER_ROLE, minter);
    }

    function _onlyAdmin() internal view {
        require(hasRole(DEFAULT_ADMIN_ROLE, _msgSender()),
            "Not admin"
        );
    }

    function _onlyManager() internal view {
        require(hasRole(_MANAGER_ROLE, _msgSender()) ||
            hasRole(DEFAULT_ADMIN_ROLE, _msgSender()),
            "0x28: must have manager role"
        );
    }

    function _onlyMinter() internal view {
        require(hasRole(_MINTER_ROLE, _msgSender()) ||
            hasRole(DEFAULT_ADMIN_ROLE, _msgSender()),
            "0x28: must have minter role"
        );
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.7.5;
pragma experimental ABIEncoderV2;

import "@openzeppelin/contracts/access/AccessControl.sol";

abstract contract BurnerRole is AccessControl {
    bytes32 private constant _BURNER_ROLE = keccak256("BURNER_ROLE");

    event AssetBurnerAuthorized(address burner, address owner);
    event AssetBurnerRevoked(address burner, address owner);

    function authorizeAssetBurner(address _burner) public virtual returns (bool) {
        grantRole(_BURNER_ROLE, _burner);
        emit AssetBurnerAuthorized(_burner, _msgSender());
        return true;
    }

    function revokeAssetBurner(address _burner) public virtual returns (bool) {
        revokeRole(_BURNER_ROLE, _burner);
        emit AssetBurnerRevoked(_burner, _msgSender());
        return true;
    }

    function isAssetBurner(address _burner) public view returns (bool) {
        return hasRole(_BURNER_ROLE, _burner);
    }
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

/*
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with GSN meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address payable) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes memory) {
        this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

import "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts may inherit from this and call {_registerInterface} to declare
 * their support of an interface.
 */
abstract contract ERC165 is IERC165 {
    /*
     * bytes4(keccak256('supportsInterface(bytes4)')) == 0x01ffc9a7
     */
    bytes4 private constant _INTERFACE_ID_ERC165 = 0x01ffc9a7;

    /**
     * @dev Mapping of interface ids to whether or not it's supported.
     */
    mapping(bytes4 => bool) private _supportedInterfaces;

    constructor () internal {
        // Derived contracts need only register support for their own interfaces,
        // we register support for ERC165 itself here
        _registerInterface(_INTERFACE_ID_ERC165);
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     *
     * Time complexity O(1), guaranteed to always use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return _supportedInterfaces[interfaceId];
    }

    /**
     * @dev Registers the contract as an implementer of the interface defined by
     * `interfaceId`. Support of the actual ERC165 interface is automatic and
     * registering its interface id is not required.
     *
     * See {IERC165-supportsInterface}.
     *
     * Requirements:
     *
     * - `interfaceId` cannot be the ERC165 invalid interface (`0xffffffff`).
     */
    function _registerInterface(bytes4 interfaceId) internal virtual {
        require(interfaceId != 0xffffffff, "ERC165: invalid interface id");
        _supportedInterfaces[interfaceId] = true;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

/**
 * @dev Library for managing
 * https://en.wikipedia.org/wiki/Set_(abstract_data_type)[sets] of primitive
 * types.
 *
 * Sets have the following properties:
 *
 * - Elements are added, removed, and checked for existence in constant time
 * (O(1)).
 * - Elements are enumerated in O(n). No guarantees are made on the ordering.
 *
 * ```
 * contract Example {
 *     // Add the library methods
 *     using EnumerableSet for EnumerableSet.AddressSet;
 *
 *     // Declare a set state variable
 *     EnumerableSet.AddressSet private mySet;
 * }
 * ```
 *
 * As of v3.3.0, sets of type `bytes32` (`Bytes32Set`), `address` (`AddressSet`)
 * and `uint256` (`UintSet`) are supported.
 */
library EnumerableSet {
    // To implement this library for multiple types with as little code
    // repetition as possible, we write it in terms of a generic Set type with
    // bytes32 values.
    // The Set implementation uses private functions, and user-facing
    // implementations (such as AddressSet) are just wrappers around the
    // underlying Set.
    // This means that we can only create new EnumerableSets for types that fit
    // in bytes32.

    struct Set {
        // Storage of set values
        bytes32[] _values;

        // Position of the value in the `values` array, plus 1 because index 0
        // means a value is not in the set.
        mapping (bytes32 => uint256) _indexes;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function _add(Set storage set, bytes32 value) private returns (bool) {
        if (!_contains(set, value)) {
            set._values.push(value);
            // The value is stored at length-1, but we add 1 to all indexes
            // and use 0 as a sentinel value
            set._indexes[value] = set._values.length;
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function _remove(Set storage set, bytes32 value) private returns (bool) {
        // We read and store the value's index to prevent multiple reads from the same storage slot
        uint256 valueIndex = set._indexes[value];

        if (valueIndex != 0) { // Equivalent to contains(set, value)
            // To delete an element from the _values array in O(1), we swap the element to delete with the last one in
            // the array, and then remove the last element (sometimes called as 'swap and pop').
            // This modifies the order of the array, as noted in {at}.

            uint256 toDeleteIndex = valueIndex - 1;
            uint256 lastIndex = set._values.length - 1;

            // When the value to delete is the last one, the swap operation is unnecessary. However, since this occurs
            // so rarely, we still do the swap anyway to avoid the gas cost of adding an 'if' statement.

            bytes32 lastvalue = set._values[lastIndex];

            // Move the last value to the index where the value to delete is
            set._values[toDeleteIndex] = lastvalue;
            // Update the index for the moved value
            set._indexes[lastvalue] = toDeleteIndex + 1; // All indexes are 1-based

            // Delete the slot where the moved value was stored
            set._values.pop();

            // Delete the index for the deleted slot
            delete set._indexes[value];

            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function _contains(Set storage set, bytes32 value) private view returns (bool) {
        return set._indexes[value] != 0;
    }

    /**
     * @dev Returns the number of values on the set. O(1).
     */
    function _length(Set storage set) private view returns (uint256) {
        return set._values.length;
    }

   /**
    * @dev Returns the value stored at position `index` in the set. O(1).
    *
    * Note that there are no guarantees on the ordering of values inside the
    * array, and it may change when more values are added or removed.
    *
    * Requirements:
    *
    * - `index` must be strictly less than {length}.
    */
    function _at(Set storage set, uint256 index) private view returns (bytes32) {
        require(set._values.length > index, "EnumerableSet: index out of bounds");
        return set._values[index];
    }

    // Bytes32Set

    struct Bytes32Set {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _add(set._inner, value);
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _remove(set._inner, value);
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(Bytes32Set storage set, bytes32 value) internal view returns (bool) {
        return _contains(set._inner, value);
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(Bytes32Set storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

   /**
    * @dev Returns the value stored at position `index` in the set. O(1).
    *
    * Note that there are no guarantees on the ordering of values inside the
    * array, and it may change when more values are added or removed.
    *
    * Requirements:
    *
    * - `index` must be strictly less than {length}.
    */
    function at(Bytes32Set storage set, uint256 index) internal view returns (bytes32) {
        return _at(set._inner, index);
    }

    // AddressSet

    struct AddressSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(AddressSet storage set, address value) internal returns (bool) {
        return _add(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(AddressSet storage set, address value) internal returns (bool) {
        return _remove(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(AddressSet storage set, address value) internal view returns (bool) {
        return _contains(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(AddressSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

   /**
    * @dev Returns the value stored at position `index` in the set. O(1).
    *
    * Note that there are no guarantees on the ordering of values inside the
    * array, and it may change when more values are added or removed.
    *
    * Requirements:
    *
    * - `index` must be strictly less than {length}.
    */
    function at(AddressSet storage set, uint256 index) internal view returns (address) {
        return address(uint160(uint256(_at(set._inner, index))));
    }


    // UintSet

    struct UintSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(UintSet storage set, uint256 value) internal returns (bool) {
        return _add(set._inner, bytes32(value));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(UintSet storage set, uint256 value) internal returns (bool) {
        return _remove(set._inner, bytes32(value));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(UintSet storage set, uint256 value) internal view returns (bool) {
        return _contains(set._inner, bytes32(value));
    }

    /**
     * @dev Returns the number of values on the set. O(1).
     */
    function length(UintSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

   /**
    * @dev Returns the value stored at position `index` in the set. O(1).
    *
    * Note that there are no guarantees on the ordering of values inside the
    * array, and it may change when more values are added or removed.
    *
    * Requirements:
    *
    * - `index` must be strictly less than {length}.
    */
    function at(UintSet storage set, uint256 index) internal view returns (uint256) {
        return uint256(_at(set._inner, index));
    }
}

pragma solidity ^0.7.5;
pragma experimental ABIEncoderV2;
// SPDX-License-Identifier: Apache2

interface IAsset {

    function authorizeAssetManager(address manager) external returns (bool);
    function revokeAssetManager(address manager) external returns (bool);
    function isAssetManager(address manager) external view returns (bool);

    function authorizeAssetMinter(address minter) external returns (bool);
    function revokeAssetMinter(address minter) external returns (bool);
    function isAssetMinter(address minter) external view returns (bool);

    event AssetManagerAuthorized(address manager, address owner);
    event AssetManagerRevoked(address manager, address owner);
    
    event AssetMinterAuthorized(address minter, address owner);
    event AssetMinterRevoked(address minter, address owner);
}

// SPDX-License-Identifier: Apache2
pragma solidity ^0.7.5;
pragma experimental ABIEncoderV2;

interface IDATSNFTCollection {
    // ERC165 bytes to add to interface array
    //
    // type(IDATSNFTCollection).interfaceId == 0x14ac1af3

    event Withdraw(
        string operationId,
        address from,
        address to,
        string assetId,
        uint256 tokenId
    );

    struct NFTCollectionWithdrawCommand {
        string operationId;
        address from;
        address to;
        string assetId;
        uint256 tokenId;
    }

    struct NFTAssetBalance {
        string id;
        uint256 balance;
        uint256 weight;
    }

    function assetsInCollection() external view returns (string[] memory);

    // this function is only needed, to force Web3J to create the type NFTAssetBalance needed for the following function
    function assetBalanceOf(string memory _assetId, address _to) external view returns (NFTAssetBalance memory);

    function assetBalanceBatchOf(address _to) external view returns (NFTAssetBalance[] memory);

    function isAutoIncrementalCollection() external view returns (bool);

    function collectionId() external view returns(string memory);

    function mint(
        address _to,
        string memory _assetId,
        uint256 _tokenId,
        bytes memory _data
    ) external returns (uint256 id, uint256 internalId);

    function mint(
        address _to,
        string memory _assetId,
        bytes memory _data
    ) external returns (uint256 id, uint256 internalId);

    function burn(address _account, string memory _assetId, uint256 _tokenId) external;
    function burnBatch(address _account, string memory _assetId, uint256[] memory _tokenIds) external;
    function authorizeAssetBurner(address _burner) external returns (bool);

    function withdraw(NFTCollectionWithdrawCommand calldata withdrawCommand) external;

    function safeTransferFrom(
        address _from,
        address _to,
        string calldata _assetId,
        uint256 _tokenId,
        bytes calldata _data
    )
    external;

    function safeBatchTransferFrom(
        address _from,
        address _to,
        string calldata _assetId,
        uint256 [] calldata _tokenIds,
        bytes calldata _data
    )
    external;

    function assetIdByInternalTokenId(uint256 _internalTokenId) external view returns(string memory);
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.2 <0.8.0;

import "../../introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC1155 compliant contract, as defined in the
 * https://eips.ethereum.org/EIPS/eip-1155[EIP].
 *
 * _Available since v3.1._
 */
interface IERC1155 is IERC165 {
    /**
     * @dev Emitted when `value` tokens of token type `id` are transferred from `from` to `to` by `operator`.
     */
    event TransferSingle(address indexed operator, address indexed from, address indexed to, uint256 id, uint256 value);

    /**
     * @dev Equivalent to multiple {TransferSingle} events, where `operator`, `from` and `to` are the same for all
     * transfers.
     */
    event TransferBatch(address indexed operator, address indexed from, address indexed to, uint256[] ids, uint256[] values);

    /**
     * @dev Emitted when `account` grants or revokes permission to `operator` to transfer their tokens, according to
     * `approved`.
     */
    event ApprovalForAll(address indexed account, address indexed operator, bool approved);

    /**
     * @dev Emitted when the URI for token type `id` changes to `value`, if it is a non-programmatic URI.
     *
     * If an {URI} event was emitted for `id`, the standard
     * https://eips.ethereum.org/EIPS/eip-1155#metadata-extensions[guarantees] that `value` will equal the value
     * returned by {IERC1155MetadataURI-uri}.
     */
    event URI(string value, uint256 indexed id);

    /**
     * @dev Returns the amount of tokens of token type `id` owned by `account`.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function balanceOf(address account, uint256 id) external view returns (uint256);

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {balanceOf}.
     *
     * Requirements:
     *
     * - `accounts` and `ids` must have the same length.
     */
    function balanceOfBatch(address[] calldata accounts, uint256[] calldata ids) external view returns (uint256[] memory);

    /**
     * @dev Grants or revokes permission to `operator` to transfer the caller's tokens, according to `approved`,
     *
     * Emits an {ApprovalForAll} event.
     *
     * Requirements:
     *
     * - `operator` cannot be the caller.
     */
    function setApprovalForAll(address operator, bool approved) external;

    /**
     * @dev Returns true if `operator` is approved to transfer ``account``'s tokens.
     *
     * See {setApprovalForAll}.
     */
    function isApprovedForAll(address account, address operator) external view returns (bool);

    /**
     * @dev Transfers `amount` tokens of token type `id` from `from` to `to`.
     *
     * Emits a {TransferSingle} event.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - If the caller is not `from`, it must be have been approved to spend ``from``'s tokens via {setApprovalForAll}.
     * - `from` must have a balance of tokens of type `id` of at least `amount`.
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155Received} and return the
     * acceptance magic value.
     */
    function safeTransferFrom(address from, address to, uint256 id, uint256 amount, bytes calldata data) external;

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {safeTransferFrom}.
     *
     * Emits a {TransferBatch} event.
     *
     * Requirements:
     *
     * - `ids` and `amounts` must have the same length.
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155BatchReceived} and return the
     * acceptance magic value.
     */
    function safeBatchTransferFrom(address from, address to, uint256[] calldata ids, uint256[] calldata amounts, bytes calldata data) external;
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.2 <0.8.0;

import "./IERC1155.sol";

/**
 * @dev Interface of the optional ERC1155MetadataExtension interface, as defined
 * in the https://eips.ethereum.org/EIPS/eip-1155#metadata-extensions[EIP].
 *
 * _Available since v3.1._
 */
interface IERC1155MetadataURI is IERC1155 {
    /**
     * @dev Returns the URI for token type `id`.
     *
     * If the `\{id\}` substring is present in the URI, it must be replaced by
     * clients with the actual token type ID.
     */
    function uri(uint256 id) external view returns (string memory);
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

import "../../introspection/IERC165.sol";

/**
 * _Available since v3.1._
 */
interface IERC1155Receiver is IERC165 {

    /**
        @dev Handles the receipt of a single ERC1155 token type. This function is
        called at the end of a `safeTransferFrom` after the balance has been updated.
        To accept the transfer, this must return
        `bytes4(keccak256("onERC1155Received(address,address,uint256,uint256,bytes)"))`
        (i.e. 0xf23a6e61, or its own function selector).
        @param operator The address which initiated the transfer (i.e. msg.sender)
        @param from The address which previously owned the token
        @param id The ID of the token being transferred
        @param value The amount of tokens being transferred
        @param data Additional data with no specified format
        @return `bytes4(keccak256("onERC1155Received(address,address,uint256,uint256,bytes)"))` if transfer is allowed
    */
    function onERC1155Received(
        address operator,
        address from,
        uint256 id,
        uint256 value,
        bytes calldata data
    )
        external
        returns(bytes4);

    /**
        @dev Handles the receipt of a multiple ERC1155 token types. This function
        is called at the end of a `safeBatchTransferFrom` after the balances have
        been updated. To accept the transfer(s), this must return
        `bytes4(keccak256("onERC1155BatchReceived(address,address,uint256[],uint256[],bytes)"))`
        (i.e. 0xbc197c81, or its own function selector).
        @param operator The address which initiated the batch transfer (i.e. msg.sender)
        @param from The address which previously owned the token
        @param ids An array containing ids of each token being transferred (order and length must match values array)
        @param values An array containing amounts of each token being transferred (order and length must match ids array)
        @param data Additional data with no specified format
        @return `bytes4(keccak256("onERC1155BatchReceived(address,address,uint256[],uint256[],bytes)"))` if transfer is allowed
    */
    function onERC1155BatchReceived(
        address operator,
        address from,
        uint256[] calldata ids,
        uint256[] calldata values,
        bytes calldata data
    )
        external
        returns(bytes4);
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.7.5;
pragma experimental ABIEncoderV2;

interface IERC2981 {
    /// @notice Called with the sale price to determine how much royalty
    //          is owed and to whom.
    /// @param _tokenId - the NFT asset queried for royalty information
    /// @param _salePrice - the sale price of the NFT asset specified by _tokenId
    /// @return receiver - address of who should be sent the royalty payment
    /// @return royaltyAmount - the royalty payment amount for _salePrice
    function royaltyInfo(
        uint256 _tokenId,
        uint256 _salePrice
    ) external view returns (
        address receiver,
        uint256 royaltyAmount
    );
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.7.5;
pragma experimental ABIEncoderV2;

interface INFTCollection {
    event AssetCreated(
        string id,
        uint256 cap,
        NFTCollectionAssetData assetData,
        uint256 weight,
        address royaltyReceiver,
        uint256 royaltyFee
    );

    event AssetWeightModified(string id, uint256 oldWeight, uint256 newWeight);

    event BaseAssetCollectionURISet(string baseUri);

    event AssetCustomURISet(string baseUri, string assetId);

    event NFTCollectionMint(
        address to,
        string assetId,
        uint256 tokenId,
        uint256 nftCollectionTokenId
    );

    event NFTCollectionMintBatch(
        address to,
        string assetId,
        uint256[] tokenIds,
        uint256[] nftCollectionTokenIds
    );

    event NFTCollectionBurn(
        address account,
        string assetId,
        uint256 tokenId,
        uint256 nftCollectionTokenId
    );

    event NFTCollectionBurnBatch(
        address account,
        string assetId,
        uint256[] tokenIds,
        uint256[] nftCollectionTokenIds
    );

    event NFTCollectionTransfer(
        address from,
        address to,
        string assetId,
        uint256 tokenId,
        uint256 nftCollectionTokenId
    );

    event NFTCollectionTransferBatch(
        address from,
        address to,
        string assetId,
        uint256[] tokenIds,
        uint256[] nftCollectionTokenIds
    );

    struct NFTCollectionData {
        string name;
        string symbol;
        string baseUri;
        string collectionId;
        uint256 collectionCap;
        uint256 collectionMintLimit;
    }

    struct AssetData {
        string name;
        string symbol;
        string uri;
        address royaltyReceiver;
        uint256 royaltyFee;
        uint256 weight;
        uint256 cap;
    }

    struct NFTCollectionAssetData {
        string name;
        string symbol;
        string uri;
    }

    struct CreateAssetCommand {
        string id;
        uint256 cap;
        NFTCollectionAssetData assetData;
        uint256 weight;
        address royaltyReceiver;
        uint256 royaltyFee;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.7.5;
pragma experimental ABIEncoderV2;

interface IRoyaltyFee {
    event RoyaltyModified(
        string assetId,
        address oldRoyaltyReceiver,
        address newRoyaltyReceiver,
        uint256 oldRoyaltyFee,
        uint256 newRoyaltyFee
    );
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.7.5;
pragma experimental ABIEncoderV2;

//import "@openzeppelin/contracts/token/ERC1155/ERC1155.sol";
import "./NFTAssetCollectionBase.sol";
import "./INFTCollection.sol";
import "../../Asset.sol";
import "../../IDATSNFTCollection.sol";

abstract contract NFTAssetCollection is
    Asset,
    NFTAssetCollectionBase,
    INFTCollection,
    IDATSNFTCollection
{
    mapping(string => bool) private _assetExists;
    mapping(string => AssetData) internal _assets;
    mapping(uint256 => string) internal _numericalIdAsset;

    string public name;
    string public symbol;
    string public override collectionId;

    string[] internal _assetIds;
    mapping(string => uint256) internal _assetIdToIndex;

    constructor(NFTCollectionData memory _data)
        NFTAssetCollectionBase(_data.baseUri)
    {
        name = _data.name;
        symbol = _data.symbol;
        collectionId = _data.collectionId;

        _registerInterface(type(IDATSNFTCollection).interfaceId);
    }

    function createAsset(CreateAssetCommand calldata _cmd) public virtual {
        _onlyManager();
        _checkNotZeroAddress(_cmd.royaltyReceiver);
        require(!_assetExists[_cmd.id], "Asset exists");
        if (_assetIds.length > 0) {
            if (_assets[_assetIds[0]].weight == 0) {
                require(_cmd.weight == 0, "No weight");
            } else {
                require(_cmd.weight > 0, "Needs weight");
            }
        }

        _assets[_cmd.id] = AssetData(
            _cmd.assetData.name,
            _cmd.assetData.symbol,
            _cmd.assetData.uri,
            _cmd.royaltyReceiver,
            _cmd.royaltyFee,
            _cmd.weight,
            _cmd.cap
        );
        _assetExists[_cmd.id] = true;

        _numericalIdAsset[calculateAssetNumericalId(_cmd.id)] = _cmd.id;

        _assetIdToIndex[_cmd.id] = _assetIds.length;
        _assetIds.push(_cmd.id);

        emit AssetCreated(
            _cmd.id,
            _cmd.cap,
            _cmd.assetData,
            _cmd.weight,
            _cmd.royaltyReceiver,
            _cmd.royaltyFee
        );
    }

    function modifyWeight(string memory _id, uint256 _newWeight) public {
        _onlyManager();
        _checkAssetExists(_id);
        uint256 oldWeight = _assets[_id].weight;
        
        require(oldWeight != _newWeight, "Same weight");
        _assets[_id].weight = _newWeight;

        emit AssetWeightModified(_id, oldWeight, _newWeight);
    }

    function assetsInCollection()
        external
        view
        override
        returns (string[] memory)
    {
        return _assetIds;
    }

    function cap(string memory _id) public view virtual returns (uint256) {
        return _assets[_id].cap;
    }

    function weight(string memory _id) public view virtual returns (uint256) {
        return _assets[_id].weight;
    }

    function calculateAssetNumericalId(string memory _assetId)
        public
        pure
        returns (uint256)
    {
        return uint256(keccak256(abi.encodePacked(_assetId)));
    }

    function calculateNftCollectionTokenId(
        string memory _assetId,
        uint256 _tokenId
    ) public pure returns (uint256) {
        return uint256(keccak256(abi.encodePacked(_assetId, _tokenId)));
    }

    function setURI(string memory _newURI) public {
        _onlyManager();
        _setURI(_newURI);
        emit BaseAssetCollectionURISet(_newURI);
    }

    function setAssetCustomUri(string memory _assetId, string memory _newURI)
        public
    {
        _onlyManager();
        _checkAssetExists(_assetId);
        _assets[_assetId].uri = _newURI;
        emit AssetCustomURISet(_newURI, _assetId);
    }

    function uriAsset(string calldata _assetId)
        public
        view
        returns (string memory)
    {
        _checkAssetExists(_assetId);
        string memory assetUri = _assets[_assetId].uri;
        if (!_isEmptyString(assetUri)) {
            return assetUri;
        }
        return _uri;
    }

    function _checkAssetExists(string memory _id) internal view {
        require(_assetExists[_id], "Asset not exists");
    }

    function _isEmptyString(string memory _str) internal pure returns (bool) {
        return bytes(_str).length == 0;
    }

    function _checkTransferIsApproved(address _from) internal view {
        require(
            _from == _msgSender() ||
                isApprovedForAll(_from, _msgSender()) ||
                hasRole(DEFAULT_ADMIN_ROLE, _msgSender()) ||
                isAssetManager(_msgSender()),
            "Not approved"
        );
    }

    // solhint-disable no-empty-blocks
    function _beforeAssetTokenTransfer(
        address from,
        address to,
        string memory assetId,
        uint256 amount
    ) internal virtual {}
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.7.5;
pragma experimental ABIEncoderV2;

import "@openzeppelin/contracts/token/ERC1155/IERC1155.sol";
import "@openzeppelin/contracts/token/ERC1155/IERC1155Receiver.sol";
import "@openzeppelin/contracts/token/ERC1155/IERC1155MetadataURI.sol";
import "@openzeppelin/contracts/utils/Address.sol";
import "@openzeppelin/contracts/utils/Context.sol";
import "@openzeppelin/contracts/introspection/ERC165.sol";
import "@openzeppelin/contracts/math/SafeMath.sol";

/**
 *
 * @dev Implementation of the basic standard multi-token.
 * See https://eips.ethereum.org/EIPS/eip-1155
 * Originally based on code by Enjin: https://github.com/enjin/erc-1155
 *
 * _Available since v3.1._
 */
abstract contract NFTAssetCollectionBase is
    Context,
    ERC165,
    IERC1155,
    IERC1155MetadataURI
{
    using SafeMath for uint256;
    using Address for address;

    // Mapping from token ID to account balances
    mapping(uint256 => mapping(address => uint256)) private _balances;

    // Mapping from account to operator approvals
    mapping(address => mapping(address => bool)) private _operatorApprovals;

    // Used as the URI for all token types by relying on ID substitution, e.g. https://token-cdn-domain/{id}.json
    string internal _uri;

    /*
     *     bytes4(keccak256('balanceOf(address,uint256)')) == 0x00fdd58e
     *     bytes4(keccak256('balanceOfBatch(address[],uint256[])')) == 0x4e1273f4
     *     bytes4(keccak256('setApprovalForAll(address,bool)')) == 0xa22cb465
     *     bytes4(keccak256('isApprovedForAll(address,address)')) == 0xe985e9c5
     *     bytes4(keccak256('safeTransferFrom(address,address,uint256,uint256,bytes)')) == 0xf242432a
     *     bytes4(keccak256('safeBatchTransferFrom(address,address,uint256[],uint256[],bytes)')) == 0x2eb2c2d6
     *
     *     => 0x00fdd58e ^ 0x4e1273f4 ^ 0xa22cb465 ^
     *        0xe985e9c5 ^ 0xf242432a ^ 0x2eb2c2d6 == 0xd9b67a26
     */
    bytes4 private constant _INTERFACE_ID_ERC1155 = 0xd9b67a26;

    /*
     *     bytes4(keccak256('uri(uint256)')) == 0x0e89341c
     */
    bytes4 private constant _INTERFACE_ID_ERC1155_METADATA_URI = 0x0e89341c;

    /**
     * @dev See {_setURI}.
     */
    constructor(string memory uri_) {
        _setURI(uri_);

        // register the supported interfaces to conform to ERC1155 via ERC165
        _registerInterface(_INTERFACE_ID_ERC1155);
        // register the supported interfaces to conform to ERC1155MetadataURI via ERC165
        _registerInterface(_INTERFACE_ID_ERC1155_METADATA_URI);
    }

    /**
     * @dev See {IERC1155-balanceOf}.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function balanceOf(address account, uint256 id)
        public
        view
        virtual
        override
        returns (uint256)
    {
        _checkNotZeroAddress(account);
        return _balances[id][account];
    }

    /**
     * @dev See {IERC1155-balanceOfBatch}.
     *
     * Requirements:
     *
     * - `accounts` and `ids` must have the same length.
     */
    function balanceOfBatch(address[] memory accounts, uint256[] memory ids)
        public
        view
        virtual
        override
        returns (uint256[] memory)
    {
        _checkArrayLengths(accounts.length, ids.length);

        uint256[] memory batchBalances = new uint256[](accounts.length);

        for (uint256 i = 0; i < accounts.length; ++i) {
            batchBalances[i] = balanceOf(accounts[i], ids[i]);
        }

        return batchBalances;
    }

    /**
     * @dev See {IERC1155-setApprovalForAll}.
     */
    function setApprovalForAll(address operator, bool approved)
        public
        virtual
        override
    {
        require(_msgSender() != operator, "operator must not be sender");

        _operatorApprovals[_msgSender()][operator] = approved;
        emit ApprovalForAll(_msgSender(), operator, approved);
    }

    /**
     * @dev See {IERC1155-isApprovedForAll}.
     */
    function isApprovedForAll(address account, address operator)
        public
        view
        virtual
        override
        returns (bool)
    {
        return _operatorApprovals[account][operator];
    }

    function _safeTransferFrom(
        address from,
        address to,
        uint256 id,
        uint256 amount,
        bytes memory data
    ) internal {
        _checkNotZeroAddress(to);

        address operator = _msgSender();

        _balances[id][from] = _balances[id][from].sub(
            amount,
            _insufficientBalanceErrorMessage()
        );
        _balances[id][to] = _balances[id][to].add(amount);

        emit TransferSingle(operator, from, to, id, amount);

        _doSafeTransferAcceptanceCheck(
            operator,
            from,
            to,
            id,
            amount,
            data
        );
    }

    /**
     * @dev See {IERC1155-safeBatchTransferFrom}.
     */
    function safeBatchTransferFrom(
        address from,
        address to,
        uint256[] memory ids,
        uint256[] memory amounts,
        bytes memory data
    ) public virtual override {
        _checkArrayLengths(ids.length, amounts.length);
        _checkNotZeroAddress(to);
        // _checkTransferIsApproved(from);

        address operator = _msgSender();

        for (uint256 i = 0; i < ids.length; ++i) {
            uint256 id = ids[i];
            uint256 amount = amounts[i];

            _balances[id][from] = _balances[id][from].sub(
                amount,
                _insufficientBalanceErrorMessage()
            );
            _balances[id][to] = _balances[id][to].add(amount);
        }

        emit TransferBatch(operator, from, to, ids, amounts);

        _doSafeBatchTransferAcceptanceCheck(
            operator,
            from,
            to,
            ids,
            amounts,
            data
        );
    }

    /**
     * @dev Sets a new URI for all token types, by relying on the token type ID
     * substitution mechanism
     * https://eips.ethereum.org/EIPS/eip-1155#metadata[defined in the EIP].
     *
     * By this mechanism, any occurrence of the `\{id\}` substring in either the
     * URI or any of the amounts in the JSON file at said URI will be replaced by
     * clients with the token type ID.
     *
     * For example, the `https://token-cdn-domain/\{id\}.json` URI would be
     * interpreted by clients as
     * `https://token-cdn-domain/000000000000000000000000000000000000000000000000000000000004cce0.json`
     * for token type ID 0x4cce0.
     *
     * See {uri}.
     *
     * Because these URIs cannot be meaningfully represented by the {URI} event,
     * this function emits no events.
     */
    function _setURI(string memory newuri) internal virtual {
        _uri = newuri;
    }

    /**
     * @dev Creates `amount` tokens of token type `id`, and assigns them to `account`.
     *
     * Emits a {TransferSingle} event.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - If `account` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155Received} and return the
     * acceptance magic value.
     */
    function _mint(
        address account,
        uint256 id,
        uint256 amount,
        bytes memory data
    ) internal virtual {
        _checkNotZeroAddress(account);

        address operator = _msgSender();

        _balances[id][account] = _balances[id][account].add(amount);
        emit TransferSingle(operator, address(0), account, id, amount);

        _doSafeTransferAcceptanceCheck(
            operator,
            address(0),
            account,
            id,
            amount,
            data
        );
    }

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {_mint}.
     *
     * Requirements:
     *
     * - `ids` and `amounts` must have the same length.
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155BatchReceived} and return the
     * acceptance magic value.
     */
    function _mintBatch(
        address to,
        uint256[] memory ids,
        uint256[] memory amounts,
        bytes memory data
    ) internal virtual {
        _checkNotZeroAddress(to);
        _checkArrayLengths(ids.length, amounts.length);

        address operator = _msgSender();

        for (uint256 i = 0; i < ids.length; i++) {
            _balances[ids[i]][to] = _balances[ids[i]][to].add(amounts[i]);
        }

        emit TransferBatch(operator, address(0), to, ids, amounts);

        _doSafeBatchTransferAcceptanceCheck(
            operator,
            address(0),
            to,
            ids,
            amounts,
            data
        );
    }

    /**
     * @dev Destroys `amount` tokens of token type `id` from `account`
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens of token type `id`.
     */
    function _burn(
        address account,
        uint256 id,
        uint256 amount
    ) internal virtual {
        _checkNotZeroAddress(account);
        _balances[id][account] = _balances[id][account].sub(
            amount,
            _insufficientBalanceErrorMessage()
        );

        emit TransferSingle(_msgSender(), account, address(0), id, amount);
    }

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {_burn}.
     *
     * Requirements:
     *
     * - `ids` and `amounts` must have the same length.
     */
    function _burnBatch(
        address account,
        uint256[] memory ids,
        uint256[] memory amounts
    ) internal virtual {
        _checkNotZeroAddress(account);
        _checkArrayLengths(ids.length, amounts.length);

        for (uint256 i = 0; i < ids.length; i++) {
            _balances[ids[i]][account] = _balances[ids[i]][account].sub(
                amounts[i],
                _insufficientBalanceErrorMessage()
            );
        }

        emit TransferBatch(_msgSender(), account, address(0), ids, amounts);
    }

    function _doSafeTransferAcceptanceCheck(
        address operator,
        address from,
        address to,
        uint256 id,
        uint256 amount,
        bytes memory data
    ) private {
        if (to.isContract()) {
            try
                IERC1155Receiver(to).onERC1155Received(
                    operator,
                    from,
                    id,
                    amount,
                    data
                )
            returns (bytes4 response) {
                if (
                    response != IERC1155Receiver(to).onERC1155Received.selector
                ) {
                    _revertTokenRejected();
                }
            } catch Error(string memory reason) {
                revert(reason);
            } catch {
                _revertNotERC1155Receiver();
            }
        }
    }

    function _doSafeBatchTransferAcceptanceCheck(
        address operator,
        address from,
        address to,
        uint256[] memory ids,
        uint256[] memory amounts,
        bytes memory data
    ) private {
        if (to.isContract()) {
            try
                IERC1155Receiver(to).onERC1155BatchReceived(
                    operator,
                    from,
                    ids,
                    amounts,
                    data
                )
            returns (bytes4 response) {
                if (
                    response !=
                    IERC1155Receiver(to).onERC1155BatchReceived.selector
                ) {
                    _revertTokenRejected();
                }
            } catch Error(string memory reason) {
                revert(reason);
            } catch {
                _revertNotERC1155Receiver();
            }
        }
    }

    function _checkArrayLengths(uint256 _array1Length, uint256 _array2Length)
        private
        pure
    {
        require(_array1Length == _array2Length, "Array length mismatch");
    }

    function _checkNotZeroAddress(address _adr) internal pure {
        require(_adr != address(0), "Zero address");
    }

    function _revertNotERC1155Receiver() internal pure {
        revert("Transfer to non ERC1155Receiver");
    }

    function _revertTokenRejected() internal pure {
        revert("ERC1155Receiver rejected tokens");
    }

    function _insufficientBalanceErrorMessage()
        internal
        pure
        returns (string memory)
    {
        return "Insufficient balance";
    }

    // s
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.7.5;
pragma experimental ABIEncoderV2;

import "../base/NFTAssetCollection.sol";
import "../../BurnerRole.sol";

abstract contract NFTAssetCollectionBurnable is NFTAssetCollection, BurnerRole {
    function burn(
        address _account,
        string memory _assetId,
        uint256 _tokenId
    ) public virtual override {
        _burn(_account, calculateNftCollectionTokenId(_assetId, _tokenId), 1);
    }

    function burnBatch(
        address _account,
        string memory _assetId,
        uint256[] memory _tokenIds
    ) public virtual override {
        uint256[] memory nftCollectionTokenIds = new uint256[](
            _tokenIds.length
        );
        uint256[] memory amounts = new uint256[](_tokenIds.length);

        for (uint256 i = 0; i < _tokenIds.length; i++) {
            nftCollectionTokenIds[i] = calculateNftCollectionTokenId(
                _assetId,
                _tokenIds[i]
            );
            amounts[i] = 1;
        }

        _burnBatch(_account, nftCollectionTokenIds, amounts);
    }

    function authorizeAssetBurner(address _burner)
        public
        virtual
        override(IDATSNFTCollection, BurnerRole)
        returns (bool)
    {
        _onlyAdmin();
        return super.authorizeAssetBurner(_burner);
    }

    function revokeAssetBurner(address _burner) public override returns (bool) {
        _onlyAdmin();
        return super.revokeAssetBurner(_burner);
    }

    function _beforeAssetTokenTransfer(
        address from,
        address to,
        string memory assetId,
        uint256 amount
    ) internal virtual override {
        super._beforeAssetTokenTransfer(from, to, assetId, amount);
        if (to == address(0)) {
            address operator = _msgSender();
            require(
                (operator == from) || isAssetBurner(operator),
                "Not approved"
            );
        }
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.7.5;
pragma experimental ABIEncoderV2;

import "../base/NFTAssetCollection.sol";

abstract contract NFTAssetCollectionCapped is NFTAssetCollection {
    using SafeMath for uint256;

    uint256 private _collectionCap;

    /**
     * @dev Sets the value of the `cap`. This value is immutable, it can only be
     * set once during construction. If cap is 0, the NFTCollection is not capped.
     */
    constructor(uint256 collectionCap_) {
        _collectionCap = collectionCap_;
    }

    /**
     * @dev Returns the cap of the collection.
     */
    function collectionCap() public view virtual returns (uint256) {
        return _collectionCap;
    }

    /**
     * @dev Overrides NFTAssetCollection.createAsset. Checks if collection cap would be exceeded
     */
    function createAsset(CreateAssetCommand calldata _cmd)
        public
        virtual
        override
    {
        if(_collectionCap != 0) _checkCollectionCap();
        super.createAsset(_cmd);
    }

    /**
     * @dev  Checks if collection cap would be exceeded
     */
    function _checkCollectionCap() internal view {
        require(
            _assetIds.length.add(1) <= _collectionCap,
            "Cap exceeded"
        );
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.7.5;
pragma experimental ABIEncoderV2;

import "./NFTAssetCollectionCapped.sol";

abstract contract NFTAssetCollectionMintable is NFTAssetCollectionCapped {
    using SafeMath for uint256;

    mapping(string => uint256) private _assetSupply;
    mapping(uint256 => bool) internal _tokenAssetExists;
    mapping(string => mapping(address => uint256)) private _assetAmountByUsers;
    mapping(uint256 => uint256) internal _internalTokenIdToAssetIdIndex;
    uint256 public collectionMintLimit;

    constructor(NFTCollectionData memory _data)
        NFTAssetCollectionCapped(_data.collectionCap)
        NFTAssetCollection(_data)
    {
        collectionMintLimit = _data.collectionMintLimit;
    }

    function assetBalanceOf(string memory _assetId, address _to)
        external
        view
        override
        returns (NFTAssetBalance memory)
    {
        NFTAssetBalance memory assetBalance;

        assetBalance.id = _assetId;
        assetBalance.weight = _assets[_assetId].weight;
        assetBalance.balance = _assetAmountByUsers[_assetId][_to];

        return assetBalance;
    }

    function assetBalanceBatchOf(address _to)
        external
        view
        override
        returns (NFTAssetBalance[] memory)
    {
        NFTAssetBalance[] memory assetBalances = new NFTAssetBalance[](
            _assetIds.length
        );

        for (uint256 i = 0; i < _assetIds.length; i++) {
            assetBalances[i].id = _assetIds[i];
            assetBalances[i].balance = _assetAmountByUsers[_assetIds[i]][_to];
            assetBalances[i].weight = _assets[_assetIds[i]].weight;
        }

        return assetBalances;
    }

    function balanceOf(
        address _account,
        string memory _assetId,
        uint256 _tokenId
    ) public view returns (uint256 balance) {
        return
            super.balanceOf(
                _account,
                calculateNftCollectionTokenId(_assetId, _tokenId)
            );
    }

    function balanceOf(address _account, string memory _assetId)
        public
        view
        returns (uint256 balance)
    {
        return _assetAmountByUsers[_assetId][_account];
    }

    function balanceOfBatch(
        address[] memory _accounts,
        string memory _assetId,
        uint256[] memory _tokenIds
    ) public view returns (uint256[] memory balances) {
        uint256[] memory internalTokenIds = new uint256[](_tokenIds.length);

        for (uint256 i = 0; i < _tokenIds.length; i++) {
            internalTokenIds[i] = calculateNftCollectionTokenId(
                _assetId,
                _tokenIds[i]
            );
        }

        return balanceOfBatch(_accounts, internalTokenIds);
    }

    /**
     * @dev Returns the total quantity for a asset ID
     * @param _assetId string ID of the asset to query
     * @return amount of asset in existence
     */
    function totalSupply(string memory _assetId) public view returns (uint256) {
        return _assetSupply[_assetId];
    }

    // TODO: revisar
    function assetsOf(address _account)
        external
        view
        returns (string[] memory)
    {
        uint256 _numberOfAssetsOfAccount;

        // first we need to iterate over all asset ids to calculate how big the resulting array needs to be
        for (uint256 i = 0; i < _assetIds.length; i++) {
            if (balanceOf(_account, _assetIds[i]) > 0) {
                _numberOfAssetsOfAccount = _numberOfAssetsOfAccount.add(1);
            }
        }

        string[] memory _assetsOfAccount = new string[](
            _numberOfAssetsOfAccount
        );
        uint256 _assetsOfAccountIndex;

        // now we iterate again over the asset ids to fill the resulting array
        for (uint256 i = 0; i < _assetIds.length; i++) {
            if (balanceOf(_account, _assetIds[i]) > 0) {
                _assetsOfAccount[_assetsOfAccountIndex] = _assetIds[i];
                _assetsOfAccountIndex = _assetsOfAccountIndex.add(1);
            }
        }

        return _assetsOfAccount;
    }

    function assetIdByInternalTokenId(uint256 _internalTokenId)
        external
        view
        override
        returns (string memory)
    {
        uint256 _assetIdIndex = _internalTokenIdToAssetIdIndex[
            _internalTokenId
        ];
        return _assetIds[_assetIdIndex];
    }

    function _mintAsset(
        address _to,
        string memory _assetId,
        uint256 _tokenId,
        bytes memory _data
    ) internal returns (uint256 id, uint256 internalId) {
        uint256 nftCollectionTokenId = calculateNftCollectionTokenId(
            _assetId,
            _tokenId
        );
        _checkTokenNotExist(nftCollectionTokenId);
        _beforeAssetTokenTransfer(address(0), _to, _assetId, 1);

        _internalTokenIdToAssetIdIndex[nftCollectionTokenId] = _assetIdToIndex[
            _assetId
        ];

        _tokenAssetExists[nftCollectionTokenId] = true;

        _mint(_to, nftCollectionTokenId, 1, _data);

        id = _tokenId;
        internalId = nftCollectionTokenId;
        emit NFTCollectionMint(_to, _assetId, _tokenId, nftCollectionTokenId);
    }

    function _mintBatchAsset(
        address _to,
        string memory _assetId,
        uint256[] memory _ids,
        uint256[] memory _nftCollectionTokenIds,
        uint256[] memory _quantities,
        bytes memory _data
    ) internal returns (uint256[] memory, uint256[] memory) {
        _mintBatch(_to, _nftCollectionTokenIds, _quantities, _data);

        emit NFTCollectionMintBatch(
            _to,
            _assetId,
            _ids,
            _nftCollectionTokenIds
        );

        return (_ids, _nftCollectionTokenIds);
    }

    function _checkTokenNotExist(uint256 _nftCollectionTokenId) internal view {
        require(!_tokenAssetExists[_nftCollectionTokenId], "Already minted");
    }

    function _checkCapNotExceeded(
        string memory _assetId,
        uint256 _totalNewTokens
    ) internal view {
        require(
            totalSupply(_assetId).add(_totalNewTokens) <= _assets[_assetId].cap,
            "Cap exceeded"
        );
    }

    function _beforeAssetTokenTransfer(
        address from,
        address to,
        string memory assetId,
        uint256 amount
    ) internal virtual override {
        super._beforeAssetTokenTransfer(from, to, assetId, amount);
        // burn
        if (to == address(0)) {
            _decreaseBalances(assetId, from, amount);
        }

        // mint
        if (from == address(0)) {
            _onlyMinter();
            _checkCollectionMintLimit(to, amount);
            _increaseBalances(assetId, to, amount);
        }

        // transfer
        if (from != address(0) && to != address(0)) {
            _checkTransferIsApproved(from);
            // decrease sender
            _decreaseBalances(assetId, from, amount);
            // increase receiver
            _increaseBalances(assetId, to, amount);
        }
    }

    function _decreaseBalances(
        string memory assetId,
        address from,
        uint256 amount
    ) private {
        _assetAmountByUsers[assetId][from] = _assetAmountByUsers[assetId][from]
            .sub(amount, _insufficientBalanceErrorMessage());
        _assetSupply[assetId] = _assetSupply[assetId].sub(
            amount,
            _insufficientBalanceErrorMessage()
        );
    }

    function _increaseBalances(
        string memory assetId,
        address to,
        uint256 amount
    ) private {
        _checkCapNotExceeded(assetId, amount);
        _assetAmountByUsers[assetId][to] = _assetAmountByUsers[assetId][to].add(
            amount
        );
        _assetSupply[assetId] = _assetSupply[assetId].add(amount);
    }

    function _checkCollectionMintLimit(address _to, uint256 _amount) private view {
        if (collectionMintLimit == 0) {
            return;
        }

        uint256 accumulatedBalance;
        for (uint256 i = 0; i < _assetIds.length; i++) {
            accumulatedBalance = accumulatedBalance.add(
                _assetAmountByUsers[_assetIds[i]][_to]
            );
        }

        require(accumulatedBalance.add(_amount) <= collectionMintLimit, "Mint limit reached");
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.7.5;
pragma experimental ABIEncoderV2;

import "@openzeppelin/contracts/utils/Pausable.sol";
import "../base/NFTAssetCollection.sol";

abstract contract NFTAssetCollectionPausable is NFTAssetCollection, Pausable {
    function pause() public virtual {
        _onlyManager();
        _pause();
    }

    function unpause() public virtual {
        _onlyManager();
        _unpause();
    }

    function _beforeAssetTokenTransfer(
        address from,
        address to,
        string memory assetId,
        uint256 amount
    ) internal virtual override {
        _checkNotPaused();
        super._beforeAssetTokenTransfer(from, to, assetId, amount);
    }
    function _checkNotPaused() internal view {
        if (!hasRole(DEFAULT_ADMIN_ROLE, _msgSender())) {
            require(!paused(), "Contract paused");
        }
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.7.5;
pragma experimental ABIEncoderV2;

import "../base/NFTAssetCollection.sol";
import "../../RoyaltyFee.sol";

abstract contract NFTAssetCollectionRoyaltyFee is
    NFTAssetCollection,
    RoyaltyFee
{
    constructor() {
        _registerInterface(_INTERFACE_ID_ERC2981);
    }

    function createAsset(CreateAssetCommand calldata _cmd) public virtual override {
        _checkValidRoyaltyFee(_cmd.royaltyFee);
        super.createAsset(_cmd);
    }

    function modifyRoyaltyReceiver(
        string memory _assetId,
        address _newRoyaltyReceiver
    ) public override {
        _onlyManager();
        super.modifyRoyaltyReceiver(_assetId, _newRoyaltyReceiver);
    }

    function modifyRoyaltyFee(string memory _assetId, uint256 _newRoyaltyFee)
        public
        override
    {
        _onlyManager();
        super.modifyRoyaltyFee(_assetId, _newRoyaltyFee);
    }

    function getRoyaltyFee(string memory _assetId)
        public
        view
        override
        returns (uint256)
    {
        return _assets[_assetId].royaltyFee;
    }

    function getRoyaltyReceiver(string memory _assetId)
        public
        view
        override
        returns (address)
    {
        return _assets[_assetId].royaltyReceiver;
    }

    function _getRoyaltyReceiverById(uint256 _numericalId)
        internal
        view
        override
        returns (address)
    {
        return getRoyaltyReceiver(_numericalIdAsset[_numericalId]);
    }

    function _setRoyaltyReceiver(
        string memory _assetId,
        address _newRoyaltyReceiver
    ) internal override {
        _assets[_assetId].royaltyReceiver = _newRoyaltyReceiver;
    }

    function _getRoyaltyFeeById(uint256 _numericalId)
        internal
        view
        override
        returns (uint256)
    {
        return getRoyaltyFee(_numericalIdAsset[_numericalId]);
    }

    function _setRoyaltyFee(string memory _assetId, uint256 _newRoyaltyFee)
        internal
        override
    {
        _assets[_assetId].royaltyFee = _newRoyaltyFee;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.7.5;
pragma experimental ABIEncoderV2;

import "./extensions/NFTAssetCollectionPausable.sol";
import "./extensions/NFTAssetCollectionBurnable.sol";
import "./extensions/NFTAssetCollectionRoyaltyFee.sol";
import "./extensions/NFTAssetCollectionMintable.sol";

/**
 * @dev Extension of {ERC1155} that allows token holders to destroy both their
 * own tokens and those that they have been approved to use.
 *
 * _Available since v3.1._
 */
abstract contract NFTCollection is
    NFTAssetCollectionPausable,
    NFTAssetCollectionBurnable,
    NFTAssetCollectionRoyaltyFee,
    NFTAssetCollectionMintable
{
    using SafeMath for uint256;

    //solhint-disable no-empty-blocks
    constructor(NFTCollectionData memory _data)
        NFTAssetCollectionMintable(_data)
    {}

    function createAsset(CreateAssetCommand calldata _cmd)
        public
        override(
            NFTAssetCollection,
            NFTAssetCollectionRoyaltyFee,
            NFTAssetCollectionCapped
        )
    {
        super.createAsset(_cmd);
    }

    /**
     * @dev See {IERC1155MetadataURI-uri}.
     *
     * This implementation returns the same URI for *all* token types. It relies
     * on the token type ID substitution mechanism
     * https://eips.ethereum.org/EIPS/eip-1155#metadata[defined in the EIP].
     *
     * Clients calling this function must replace the `\{id\}` substring with the
     * actual token type ID.
     */
    function uri(uint256 nftCollectionId)
        public
        view
        override
        returns (string memory)
    {
        uint256 assetIdIndex = _internalTokenIdToAssetIdIndex[nftCollectionId];
        string memory assetId = _assetIds[assetIdIndex];
        string memory assetUri = _assets[assetId].uri;

        if (!_isEmptyString(assetUri)) {
            return assetUri;
        }

        return string(abi.encodePacked(_uri, "/", assetId));
    }

    function authorizeAssetBurner(address _burner)
        public
        virtual
        override(IDATSNFTCollection, NFTAssetCollectionBurnable)
        returns (bool)
    {
        return super.authorizeAssetBurner(_burner);
    }

    function burn(
        address _account,
        string memory _assetId,
        uint256 _tokenId
    ) public override(NFTAssetCollectionBurnable, IDATSNFTCollection) {
        uint256 nftCollectionTokenId = calculateNftCollectionTokenId(
            _assetId,
            _tokenId
        );

        _beforeAssetTokenTransfer(_account, address(0), _assetId, 1);

        super.burn(_account, _assetId, _tokenId);

        emit NFTCollectionBurn(
            _account,
            _assetId,
            _tokenId,
            nftCollectionTokenId
        );
    }

    function burnBatch(
        address _account,
        string memory _assetId,
        uint256[] memory _tokenIds
    ) public override(NFTAssetCollectionBurnable, IDATSNFTCollection) {
        uint256[] memory nftCollectionTokenIds = new uint256[](
            _tokenIds.length
        );

        _beforeAssetTokenTransfer(
            _account,
            address(0),
            _assetId,
            _tokenIds.length
        );

        for (uint256 i = 0; i < _tokenIds.length; i++) {
            nftCollectionTokenIds[i] = calculateNftCollectionTokenId(
                _assetId,
                _tokenIds[i]
            );
        }

        super.burnBatch(_account, _assetId, _tokenIds);

        emit NFTCollectionBurnBatch(
            _account,
            _assetId,
            _tokenIds,
            nftCollectionTokenIds
        );
    }

    /**
     * @dev See {IERC1155-safeTransferFrom}.
     */
    function safeTransferFrom(
        address _from,
        address _to,
        uint256 _nftCollectionTokenId,
        uint256 _amount,
        bytes memory _data
    ) public override {
        require(_amount == 1, "amount not 1");
        uint256 _assetIdIndex = _internalTokenIdToAssetIdIndex[
            _nftCollectionTokenId
        ];

        _beforeAssetTokenTransfer(_from, _to, _assetIds[_assetIdIndex], 1);

        _safeTransferFrom(_from, _to, _nftCollectionTokenId, 1, _data);
    }

    function safeTransferFrom(
        address _from,
        address _to,
        string memory _assetId,
        uint256 _tokenId,
        bytes memory _data
    ) public override {
        _beforeAssetTokenTransfer(_from, _to, _assetId, 1);

        uint256 nftCollectionTokenId = calculateNftCollectionTokenId(
            _assetId,
            _tokenId
        );
        _safeTransferFrom(_from, _to, nftCollectionTokenId, 1, _data);
        emit NFTCollectionTransfer(
            _from,
            _to,
            _assetId,
            _tokenId,
            nftCollectionTokenId
        );
    }

    function safeBatchTransferFrom(
        address _from,
        address _to,
        string memory _assetId,
        uint256[] memory _tokenIds,
        bytes memory _data
    ) public override {
        _beforeAssetTokenTransfer(_from, _to, _assetId, _tokenIds.length);

        uint256[] memory nftCollectionTokenIds = new uint256[](
            _tokenIds.length
        );
        uint256[] memory amounts = new uint256[](_tokenIds.length);
        for (uint256 i = 0; i < _tokenIds.length; i++) {
            nftCollectionTokenIds[i] = calculateNftCollectionTokenId(
                _assetId,
                _tokenIds[i]
            );
            amounts[i] = 1;
        }

        super.safeBatchTransferFrom(
            _from,
            _to,
            nftCollectionTokenIds,
            amounts,
            _data
        );
        emit NFTCollectionTransferBatch(
            _from,
            _to,
            _assetId,
            _tokenIds,
            nftCollectionTokenIds
        );
    }

    function safeBatchTransferFrom(
        address from,
        address to,
        uint256[] memory ids,
        uint256[] memory amounts,
        bytes memory data
    ) public override {
        _checkNotPaused();
        _checkTransferIsApproved(from);
        super.safeBatchTransferFrom(from, to, ids, amounts, data);
    }

    function withdraw(NFTCollectionWithdrawCommand calldata withdrawCommand)
        external
        override
    {
        safeTransferFrom(
            withdrawCommand.from,
            withdrawCommand.to,
            withdrawCommand.assetId,
            withdrawCommand.tokenId,
            bytes("")
        );

        emit Withdraw(
            withdrawCommand.operationId,
            withdrawCommand.from,
            withdrawCommand.to,
            withdrawCommand.assetId,
            withdrawCommand.tokenId
        );
    }

    function _beforeAssetTokenTransfer(
        address from,
        address to,
        string memory assetId,
        uint256 amount
    )
        internal
        virtual
        override(
            NFTAssetCollection,
            NFTAssetCollectionPausable,
            NFTAssetCollectionBurnable,
            NFTAssetCollectionMintable
        )
    {
        super._beforeAssetTokenTransfer(from, to, assetId, amount);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.7.5;
pragma experimental ABIEncoderV2;

import "./NFTCollection.sol";

/**
 * @dev Extension of {ERC1155} that allows token holders to destroy both their
 * own tokens and those that they have been approved to use.
 *
 * _Available since v3.1._
 */
contract NFTCollectionAutoId is NFTCollection {
    using SafeMath for uint256;

    mapping(string => uint256) internal _tokenIdsTracker;

    //solhint-disable no-empty-blocks
    constructor(NFTCollectionData memory _data) NFTCollection(_data) {}

    function isAutoIncrementalCollection()
        external
        pure
        override
        returns (bool)
    {
        return true;
    }

    /**
     * @dev Mints some amount of assets to an address
     * @param _to          Address of the future owner of the asset
     * @param _assetId     ID of the asset
     * @param _data        Data to pass if receiver is contract
     */
    function mint(
        address _to,
        string memory _assetId,
        bytes memory _data
    ) external virtual override returns (uint256 id, uint256 internalId) {
        _checkAssetExists(_assetId);
        uint256 tokenId = _tokenIdsTracker[_assetId];
        _tokenIdsTracker[_assetId] = _tokenIdsTracker[_assetId].add(1);

        return _mintAsset(_to, _assetId, tokenId, _data);
    }

    /**
     * @dev Mint assets for each id in _ids
     * @param _to          The address to mint assets to
     * @param _assetId     Id of the asset where new tokens will be minted
     * @param _totalTokens Total of new tokens to mint
     * @param _data        Data to pass if receiver is contract
     */
    function mintBatch(
        address _to,
        string memory _assetId,
        uint256 _totalTokens,
        bytes memory _data
    )
        public
        virtual
        returns (uint256[] memory ids, uint256[] memory internalIds)
    {
        _checkAssetExists(_assetId);
        _beforeAssetTokenTransfer(address(0), _to, _assetId, _totalTokens);

        uint256[] memory nftCollectionTokenIds = new uint256[](_totalTokens);
        uint256[] memory quantities = new uint256[](_totalTokens);
        uint256[] memory tokenIds = new uint256[](_totalTokens);

        for (uint256 i = 0; i < _totalTokens; i++) {
            tokenIds[i] = _tokenIdsTracker[_assetId];
            nftCollectionTokenIds[i] = calculateNftCollectionTokenId(
                _assetId,
                tokenIds[i]
            );
            _tokenAssetExists[nftCollectionTokenIds[i]] = true;
            quantities[i] = 1;
            _tokenIdsTracker[_assetId] = _tokenIdsTracker[_assetId].add(1);
        }

        return
            _mintBatchAsset(
                _to,
                _assetId,
                tokenIds,
                nftCollectionTokenIds,
                quantities,
                _data
            );
    }

    // solhint-disable no-unused-vars
    function mint(
        address _to,
        string memory _assetId,
        uint256 _tokenId,
        bytes memory _data
    ) external override returns (uint256 id, uint256 internalId) {
        revert("not supported");
    }

    function _beforeAssetTokenTransfer(
        address from,
        address to,
        string memory assetId,
        uint256 amount
    ) internal virtual override {
        super._beforeAssetTokenTransfer(from, to, assetId, amount);
    }
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

import "./Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    bool private _paused;

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor () internal {
        _paused = false;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        require(!paused(), "Pausable: paused");
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        require(paused(), "Pausable: not paused");
        _;
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.7.5;
pragma experimental ABIEncoderV2;

import "@openzeppelin/contracts/math/SafeMath.sol";
import "@openzeppelin/contracts/introspection/ERC165.sol";
import "./eips/IERC2981.sol";
import "./IRoyaltyFee.sol";

abstract contract RoyaltyFee is ERC165, IRoyaltyFee, IERC2981 {
    using SafeMath for uint256;

    // ERC165 bytes to add to interface array - set in parent contract
    // implementing this standard
    //
    // bytes4(keccak256("royaltyInfo(uint256,uint256)")) == 0x2a55205a
    bytes4 internal constant _INTERFACE_ID_ERC2981 = 0x2a55205a;

    constructor() {
        _registerInterface(_INTERFACE_ID_ERC2981);
    }

    function royaltyInfo(uint256 _tokenId, uint256 _salePrice)
        external
        view
        override
        returns (address receiver, uint256 royaltyAmount)
    {
        receiver = _getRoyaltyReceiverById(_tokenId);
        royaltyAmount = uint256(_getRoyaltyFeeById(_tokenId).mul(_salePrice).div(100));
    }

    function modifyRoyaltyReceiver(
        string memory _assetId,
        address _newRoyaltyReceiver
    ) public virtual {
        address oldReceiver = getRoyaltyReceiver(_assetId);
        require(oldReceiver != _newRoyaltyReceiver, "Receiver has not changed");
        _setRoyaltyReceiver(_assetId, _newRoyaltyReceiver);
        uint256 royaltyFee = getRoyaltyFee(_assetId);

        emit RoyaltyModified(
            _assetId,
            oldReceiver,
            _newRoyaltyReceiver,
            royaltyFee,
            royaltyFee
        );
    }

    function modifyRoyaltyFee(string memory _assetId, uint256 _newRoyaltyFee)
        public
        virtual
    {
        uint256 oldFee = getRoyaltyFee(_assetId);
        _checkValidRoyaltyFee(_newRoyaltyFee);
        require(oldFee != _newRoyaltyFee, "Fee has not changed");
        _setRoyaltyFee(_assetId, _newRoyaltyFee);
        address royaltyReceiver = getRoyaltyReceiver(_assetId);

        emit RoyaltyModified(
            _assetId,
            royaltyReceiver,
            royaltyReceiver,
            oldFee,
            _newRoyaltyFee
        );
    }

    function _checkValidRoyaltyFee(uint256 _royaltyFee) internal pure {
        require(_royaltyFee <= 100, "Fee greater than 100");
    }

    function _getRoyaltyReceiverById(uint256 _tokenId)
        internal
        view
        virtual
        returns (address);

    function getRoyaltyReceiver(string memory _assetId)
        public
        view
        virtual
        returns (address);

    function _setRoyaltyReceiver(string memory _assetId, address _receiver)
        internal
        virtual;

    function _getRoyaltyFeeById(uint256 _tokenId)
        internal
        view
        virtual
        returns (uint256);

    function getRoyaltyFee(string memory _assetId)
        public
        view
        virtual
        returns (uint256);

    function _setRoyaltyFee(string memory _assetId, uint256 _fee)
        internal
        virtual;
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

/**
 * @dev Wrappers over Solidity's arithmetic operations with added overflow
 * checks.
 *
 * Arithmetic operations in Solidity wrap on overflow. This can easily result
 * in bugs, because programmers usually assume that an overflow raises an
 * error, which is the standard behavior in high level programming languages.
 * `SafeMath` restores this intuition by reverting the transaction when an
 * operation overflows.
 *
 * Using this library instead of the unchecked operations eliminates an entire
 * class of bugs, so it's recommended to use it always.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryAdd(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        uint256 c = a + b;
        if (c < a) return (false, 0);
        return (true, c);
    }

    /**
     * @dev Returns the substraction of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function trySub(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        if (b > a) return (false, 0);
        return (true, a - b);
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryMul(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
        // benefit is lost if 'b' is also tested.
        // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
        if (a == 0) return (true, 0);
        uint256 c = a * b;
        if (c / a != b) return (false, 0);
        return (true, c);
    }

    /**
     * @dev Returns the division of two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryDiv(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        if (b == 0) return (false, 0);
        return (true, a / b);
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryMod(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        if (b == 0) return (false, 0);
        return (true, a % b);
    }

    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     *
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        require(c >= a, "SafeMath: addition overflow");
        return c;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b <= a, "SafeMath: subtraction overflow");
        return a - b;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     *
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        if (a == 0) return 0;
        uint256 c = a * b;
        require(c / a == b, "SafeMath: multiplication overflow");
        return c;
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b > 0, "SafeMath: division by zero");
        return a / b;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b > 0, "SafeMath: modulo by zero");
        return a % b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {trySub}.
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b <= a, errorMessage);
        return a - b;
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {tryDiv}.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b > 0, errorMessage);
        return a / b;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting with custom message when dividing by zero.
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {tryMod}.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b > 0, errorMessage);
        return a % b;
    }
}

{
  "compilationTarget": {
    "contracts/NFTCollection/NFTCollectionAutoId.sol": "NFTCollectionAutoId"
  },
  "evmVersion": "istanbul",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 1
  },
  "remappings": []
}