/**                                                                              
                                         ████████████████████                             
                                    ██████████████████████████████                        
                                ████████████████████████████████████                      
                             ███████████                      ████████                    
                          ██████████                             ███████                  
                        ████████                                   ██████                 
                      ████████                █     █▒              ██████                
                    ████████                 ███  ████               █████                
                   ███████                   ████████                 █████               
                  ██████                      ██████                  █████               
                 ██████                   ██████████                  █████               
                ██████                  ███████  █████                █████               
                █████                                                 █████               
               █████                                                 ██████               
              ░█████                                                ██████                
              █████                                                ██████                 
             █████                                █████████       ██████                  
             █████                         ████████████████████████████                   
            █████                       █████             ██████████░                     
            █████                                             ▓██████                     
            █████                                                ██████                   
           ▒████                                                   █████                  
           ▒█████                                                   █████                 
            █████                                                    █████                
            █████                                                     █████               
            █████                             █▒                      █████               
             █████                            ███      ████           █████               
             █████                        █   ████  ██████            █████               
              █████                       ████ █████████              █████               
               █████                        █████████                 █████               
                ██████                            █████              █████                
                 ██████                                             █████                 
                   ███████                                        ██████                  
                    ████████                                    ███████                   
                       ██████████                            ████████                     
                          ██████████████                ▓██████████                       
                              ██████████████████████████████████                          
                                    ▒███████████████████████                                                                                                                                           
 */
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.24;

import "./BogusStory.sol";

contract BogusFactory is Ownable {
    // State variables
    address public treasuryWallet;
    uint256 public treasuryFeeNumerator = 5;
    uint256 public startingUpvotePrice = 0.0001 ether;
    uint256 public startingDownvotePrice = 0.0001 ether;
    uint256 public priceIncrement = 0.00001 ether;

    // Keep track of all stories
    address[] public allStories;
    
    // Mapping from creator to their stories
    mapping(address => address[]) public creatorStories;
    
    // Events
    event StoryCreated(
        address indexed storyAddress,
        address indexed creator,
        string title,
        uint256 timestamp
    );
    
    event TreasuryUpdated(address newTreasury);
    event StoryDurationUpdated(uint256 newDuration);
    event TreasuryFeeNumeratorUpdated(uint256 newNumerator);
    event StartingUpvotePriceUpdated(uint256 newPrice);
    event StartingDownvotePriceUpdated(uint256 newPrice);
    event PriceIncrementUpdated(uint256 newIncrement);

    constructor(address _treasuryWallet) Ownable(msg.sender) {
        treasuryWallet = _treasuryWallet;
    }

    // Create new story
    function createStory(
        string memory _title,
        string memory _subtitle,
        string memory _description,
        string memory _imageSrc,
        uint256 _duration
    ) external returns (address) {
        // Deploy new story contract
        BogusStory newStory = new BogusStory(
            _title,
            _subtitle,
            _description,
            _imageSrc,
            treasuryWallet,
            msg.sender,  // creator wallet
            _duration,
            treasuryFeeNumerator,
            startingUpvotePrice,
            startingDownvotePrice,
            priceIncrement
        );
        
        // Transfer ownership of the story contract to the creator
        newStory.transferOwnership(msg.sender);
        
        // Store story address
        address storyAddress = address(newStory);
        allStories.push(storyAddress);
        creatorStories[msg.sender].push(storyAddress);
        
        emit StoryCreated(
            storyAddress,
            msg.sender,
            _title,
            block.timestamp
        );
        
        return storyAddress;
    }

    // Admin functions
    function setTreasuryWallet(address _newTreasury) external onlyOwner {
        require(_newTreasury != address(0), "Invalid treasury address");
        treasuryWallet = _newTreasury;
        emit TreasuryUpdated(_newTreasury);
    }

    function setTreasuryFeeNumerator(uint256 _newNumerator) external onlyOwner {
        require(_newNumerator <= 100, "Numerator must be less than or equal to 100");
        treasuryFeeNumerator = _newNumerator;
        emit TreasuryFeeNumeratorUpdated(_newNumerator);
    }

    function setStartingUpvotePrice(uint256 _newPrice) external onlyOwner {
        require(_newPrice > 0 ether, "Price must be greater than 0");
        startingUpvotePrice = _newPrice;
        emit StartingUpvotePriceUpdated(_newPrice);
    }

    function setStartingDownvotePrice(uint256 _newPrice) external onlyOwner {
        require(_newPrice > 0 ether, "Price must be greater than 0");
        startingDownvotePrice = _newPrice;
        emit StartingDownvotePriceUpdated(_newPrice);
    }

    function setPriceIncrement(uint256 _newIncrement) external onlyOwner {
        require(_newIncrement > 0 ether, "Increment must be greater than 0");
        priceIncrement = _newIncrement;
        emit PriceIncrementUpdated(_newIncrement);
    }

    // View functions
    function getAllStories() external view returns (address[] memory) {
        return allStories;
    }

    function getCreatorStories(address _creator) external view returns (address[] memory) {
        return creatorStories[_creator];
    }

    function getStoryCount() external view returns (uint256) {
        return allStories.length;
    }

    function getCreatorStoryCount(address _creator) external view returns (uint256) {
        return creatorStories[_creator].length;
    }
}

/**                                                                              
                                         ████████████████████                             
                                    ██████████████████████████████                        
                                ████████████████████████████████████                      
                             ███████████                      ████████                    
                          ██████████                             ███████                  
                        ████████                                   ██████                 
                      ████████                █     █▒              ██████                
                    ████████                 ███  ████               █████                
                   ███████                   ████████                 █████               
                  ██████                      ██████                  █████               
                 ██████                   ██████████                  █████               
                ██████                  ███████  █████                █████               
                █████                                                 █████               
               █████                                                 ██████               
              ░█████                                                ██████                
              █████                                                ██████                 
             █████                                █████████       ██████                  
             █████                         ████████████████████████████                   
            █████                       █████             ██████████░                     
            █████                                             ▓██████                     
            █████                                                ██████                   
           ▒████                                                   █████                  
           ▒█████                                                   █████                 
            █████                                                    █████                
            █████                                                     █████               
            █████                             █▒                      █████               
             █████                            ███      ████           █████               
             █████                        █   ████  ██████            █████               
              █████                       ████ █████████              █████               
               █████                        █████████                 █████               
                ██████                            █████              █████                
                 ██████                                             █████                 
                   ███████                                        ██████                  
                    ████████                                    ███████                   
                       ██████████                            ████████                     
                          ██████████████                ▓██████████                       
                              ██████████████████████████████████                          
                                    ▒███████████████████████                                                                                                                                           
 */
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.24;

import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";

contract BogusStory is Ownable, ReentrancyGuard {
    // Structs
    struct Metadata {
        string title;
        string subtitle;
        string description;
        string imageSrc;
    }

    struct Vote {
        uint256 amount;
        uint256 price;
        uint256 availableShares;
    }

    // State variables
    Metadata public metadata;
    address public treasuryWallet;
    address public creatorWallet;
    address[] public downvoterAddresses;
    address[] public upvoterAddresses;
    uint256 public endTime;
    uint256 public treasuryFeeNumerator;
    uint256 public upvotePrice;
    uint256 public downvotePrice;
    uint256 public priceIncrement;
    
    // Vote counts
    uint256 public upvotes;
    uint256 public downvotes;
    uint256 public totalFundsCollected;

    // Ending state
    bool public hasEnded;
    uint256 public winningShare;
    bool public isUpvotersWon;
    bool public isTie;

    // Fees
    uint256 private constant SELL_FEE_NUMERATOR = 2; // 0.2%
    uint256 private constant SELL_FEE_DENOMINATOR = 1000;
    uint256 private constant TREASURY_FEE_DENOMINATOR = 100;
    
    // Voter mappings
    mapping(address => Vote) public upvoters;
    mapping(address => Vote) public downvoters;
    
    // Voting status
    bool private isVoting;
    
    // Events
    event Upvoted(address indexed voter, uint256 numVotes, uint256 price);
    event Downvoted(address indexed voter, uint256 numVotes, uint256 price);
    event FundsDisbursed(uint256 upvoterShare, uint256 downvoterShare, uint256 treasuryShare);
    event TreasuryChanged(address newTreasury);
    event StoryConcluded(bool isUpvotersWon, bool isTie, uint256 winningShare);
    event SharesSold(address indexed seller, bool isUpvote, uint256 numShares, uint256 refundAmount);

    constructor(
        string memory _title,
        string memory _subtitle,
        string memory _description,
        string memory _imageSrc,
        address _treasuryWallet,
        address _creatorWallet,
        uint256 _duration,
        uint256 _treasuryFeeNumerator,
        uint256 _startingUpvotePrice,
        uint256 _startingDownvotePrice,
        uint256 _priceIncrement
    ) Ownable(msg.sender) ReentrancyGuard() {
        metadata = Metadata({
            title: _title,
            subtitle: _subtitle,
            description: _description,
            imageSrc: _imageSrc
        });
        treasuryWallet = _treasuryWallet;
        creatorWallet = _creatorWallet;
        endTime = block.timestamp + _duration;
        treasuryFeeNumerator = _treasuryFeeNumerator;
        upvotePrice = _startingUpvotePrice;
        downvotePrice = _startingDownvotePrice;
        priceIncrement = _priceIncrement;
    }

    // Modifiers
    modifier notVoting() {
        require(!isVoting, "Another vote in progress");
        _;
    }

    modifier storyActive() {
        require(block.timestamp < endTime, "Story voting period has ended");
        _;
    }

    modifier isTreasurySigner() {
        require(msg.sender == treasuryWallet, "Only treasury can call this function");
        _;
    }

    // Write functions
    function upvote(uint256 numVotes) external payable nonReentrant notVoting storyActive {
        require(msg.value == upvotePrice * numVotes, "Incorrect payment amount");
        if (upvoters[msg.sender].amount == 0) {
            upvoterAddresses.push(msg.sender);
        }
        isVoting = true;
        
        upvotes += numVotes;
        totalFundsCollected += msg.value;
        
        upvoters[msg.sender] = Vote({
            amount: numVotes,
            price: upvotePrice,
            availableShares: numVotes
        });
        
        // Adjust prices
        upvotePrice += priceIncrement;
        if (downvotePrice > priceIncrement) {
            downvotePrice -= priceIncrement;
        }
        
        isVoting = false;
        emit Upvoted(msg.sender, numVotes, upvotePrice);
    }

    function downvote(uint256 numVotes) external payable nonReentrant notVoting storyActive {
        require(msg.value == downvotePrice * numVotes, "Incorrect payment amount");
        if (downvoters[msg.sender].amount == 0) {
            downvoterAddresses.push(msg.sender);
        }
        isVoting = true;
        
        downvotes += numVotes;
        totalFundsCollected += msg.value;
        
        downvoters[msg.sender] = Vote({
            amount: numVotes,
            price: downvotePrice,
            availableShares: numVotes
        });
        
        // Adjust prices
        downvotePrice += priceIncrement;
        if (upvotePrice > priceIncrement) {
            upvotePrice -= priceIncrement;
        }
        
        isVoting = false;
        emit Downvoted(msg.sender, numVotes, downvotePrice);
    }

    function withdrawERC20(address token, uint256 amount, address recipient) external isTreasurySigner {
        require(recipient != address(0), "Invalid recipient address");
        IERC20(token).transfer(recipient, amount);
    }

    function withdrawETH(uint256 amount, address recipient) external isTreasurySigner {
        require(recipient != address(0), "Invalid recipient address");
        payable(recipient).transfer(amount);
    }

    function changeTreasury(address newTreasury) external isTreasurySigner {
        require(newTreasury != address(0), "Invalid treasury address");
        treasuryWallet = newTreasury;
        emit TreasuryChanged(newTreasury);
    }

    function claim() external nonReentrant {
        require(block.timestamp >= endTime, "Story voting period not ended");
        
        // Auto-conclude if not already done
        if (!hasEnded) {
            require(totalFundsCollected > 0, "No funds to distribute");
            
            hasEnded = true;
            uint256 treasuryShare = (totalFundsCollected * treasuryFeeNumerator) / TREASURY_FEE_DENOMINATOR;
            uint256 remainingFunds = totalFundsCollected - treasuryShare;
            
            // Transfer treasury share
            payable(treasuryWallet).transfer(treasuryShare);

            // Determine winners
            if (upvotes > downvotes) {
                isUpvotersWon = true;
                winningShare = remainingFunds;
            } else if (downvotes > upvotes) {
                isUpvotersWon = false;
                winningShare = remainingFunds;
            } else {
                isTie = true;
                winningShare = remainingFunds / 2;
            }

            emit StoryConcluded(isUpvotersWon, isTie, winningShare);
        }
        
        uint256 share = 0;
        if (isTie) {
            // Check both upvoters and downvoters in case of tie
            if (upvoters[msg.sender].amount > 0) {
                share += (winningShare * upvoters[msg.sender].amount) / upvotes;
                upvoters[msg.sender].amount = 0;
            }
            if (downvoters[msg.sender].amount > 0) {
                share += (winningShare * downvoters[msg.sender].amount) / downvotes;
                downvoters[msg.sender].amount = 0;
            }
        } else {
            mapping(address => Vote) storage voters = isUpvotersWon ? upvoters : downvoters;
            uint256 totalVotes = isUpvotersWon ? upvotes : downvotes;
            
            require(voters[msg.sender].amount > 0, "No rewards to claim");
            share = (winningShare * voters[msg.sender].amount) / totalVotes;
            voters[msg.sender].amount = 0;
        }

        require(share > 0, "No rewards to claim");
        payable(msg.sender).transfer(share);
    }

    // Read functions
    function getMetadata() external view returns (Metadata memory) {
        return metadata;
    }

    function getVotingStatus() external view returns (
        uint256 _upvotes,
        uint256 _downvotes,
        uint256 _upvotePrice,
        uint256 _downvotePrice,
        uint256 _totalFunds
    ) {
        return (upvotes, downvotes, upvotePrice, downvotePrice, totalFundsCollected);
    }

    // Add these view functions to help with calculations
    function getDownvoteAmount(uint256 numVotes) public view returns (uint256) {
        return downvotePrice * numVotes;
    }

    function getUpvoteAmount(uint256 numVotes) public view returns (uint256) {
        return upvotePrice * numVotes;
    }

    // Fallback and receive functions
    receive() external payable {}
    fallback() external payable {}

    function sellUpvoteShares(uint256 numShares) external payable nonReentrant notVoting storyActive {
        require(upvoters[msg.sender].availableShares >= numShares, "Insufficient shares");
        
        uint256 grossAmount = upvotePrice * numShares;
        uint256 fee = (grossAmount * SELL_FEE_NUMERATOR) / SELL_FEE_DENOMINATOR;
        uint256 refundAmount = grossAmount - fee;
        
        upvoters[msg.sender].availableShares -= numShares;
        upvoters[msg.sender].amount -= numShares;
        upvotes -= numShares;
        totalFundsCollected -= grossAmount;
        
        // Adjust prices
        for (uint256 i = 0; i < numShares; i++) {
            if (upvotePrice > priceIncrement) {
                upvotePrice -= priceIncrement;
            }
            downvotePrice += priceIncrement;
        }
        
        // Transfer fee to treasury
        payable(treasuryWallet).transfer(fee);
        // Transfer refund to seller
        payable(msg.sender).transfer(refundAmount);
        emit SharesSold(msg.sender, true, numShares, refundAmount);
    }

    function sellDownvoteShares(uint256 numShares) external payable nonReentrant notVoting storyActive {
        require(downvoters[msg.sender].availableShares >= numShares, "Insufficient shares");
        
        uint256 grossAmount = downvotePrice * numShares;
        uint256 fee = (grossAmount * SELL_FEE_NUMERATOR) / SELL_FEE_DENOMINATOR;
        uint256 refundAmount = grossAmount - fee;
        
        downvoters[msg.sender].availableShares -= numShares;
        downvoters[msg.sender].amount -= numShares;
        downvotes -= numShares;
        totalFundsCollected -= grossAmount;
        
        // Adjust prices
        for (uint256 i = 0; i < numShares; i++) {
            if (downvotePrice > priceIncrement) {
                downvotePrice -= priceIncrement;
            }
            upvotePrice += priceIncrement;
        }
        
        // Transfer fee to treasury
        payable(treasuryWallet).transfer(fee);
        // Transfer refund to seller
        payable(msg.sender).transfer(refundAmount);
        emit SharesSold(msg.sender, false, numShares, refundAmount);
    }

    // Update view functions for sell prices
    function getUpvoteSellPrice(uint256 numShares) public view returns (uint256) {
        uint256 grossAmount = upvotePrice * numShares;
        uint256 fee = (grossAmount * SELL_FEE_NUMERATOR) / SELL_FEE_DENOMINATOR;
        return grossAmount - fee;
    }

    function getDownvoteSellPrice(uint256 numShares) public view returns (uint256) {
        uint256 grossAmount = downvotePrice * numShares;
        uint256 fee = (grossAmount * SELL_FEE_NUMERATOR) / SELL_FEE_DENOMINATOR;
        return grossAmount - fee;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If EIP-1153 (transient storage) is available on the chain you're deploying at,
 * consider using {ReentrancyGuardTransient} instead.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

{
  "compilationTarget": {
    "contracts/BogusFactory.sol": "BogusFactory"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "none"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}