OpenSocial Protocol Profile

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/AccessControl.sol)

pragma solidity ^0.8.20;

import {IAccessControl} from "@openzeppelin/contracts/access/IAccessControl.sol";
import {ContextUpgradeable} from "../utils/ContextUpgradeable.sol";
import {ERC165Upgradeable} from "../utils/introspection/ERC165Upgradeable.sol";
import {Initializable} from "../proxy/utils/Initializable.sol";

/**
 * @dev Contract module that allows children to implement role-based access
 * control mechanisms. This is a lightweight version that doesn't allow enumerating role
 * members except through off-chain means by accessing the contract event logs. Some
 * applications may benefit from on-chain enumerability, for those cases see
 * {AccessControlEnumerable}.
 *
 * Roles are referred to by their `bytes32` identifier. These should be exposed
 * in the external API and be unique. The best way to achieve this is by
 * using `public constant` hash digests:
 *
 * ```solidity
 * bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
 * ```
 *
 * Roles can be used to represent a set of permissions. To restrict access to a
 * function call, use {hasRole}:
 *
 * ```solidity
 * function foo() public {
 *     require(hasRole(MY_ROLE, msg.sender));
 *     ...
 * }
 * ```
 *
 * Roles can be granted and revoked dynamically via the {grantRole} and
 * {revokeRole} functions. Each role has an associated admin role, and only
 * accounts that have a role's admin role can call {grantRole} and {revokeRole}.
 *
 * By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
 * that only accounts with this role will be able to grant or revoke other
 * roles. More complex role relationships can be created by using
 * {_setRoleAdmin}.
 *
 * WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
 * grant and revoke this role. Extra precautions should be taken to secure
 * accounts that have been granted it. We recommend using {AccessControlDefaultAdminRules}
 * to enforce additional security measures for this role.
 */
abstract contract AccessControlUpgradeable is Initializable, ContextUpgradeable, IAccessControl, ERC165Upgradeable {
    struct RoleData {
        mapping(address account => bool) hasRole;
        bytes32 adminRole;
    }

    bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;


    /// @custom:storage-location erc7201:openzeppelin.storage.AccessControl
    struct AccessControlStorage {
        mapping(bytes32 role => RoleData) _roles;
    }

    // keccak256(abi.encode(uint256(keccak256("openzeppelin.storage.AccessControl")) - 1)) & ~bytes32(uint256(0xff))
    bytes32 private constant AccessControlStorageLocation = 0x02dd7bc7dec4dceedda775e58dd541e08a116c6c53815c0bd028192f7b626800;

    function _getAccessControlStorage() private pure returns (AccessControlStorage storage $) {
        assembly {
            $.slot := AccessControlStorageLocation
        }
    }

    /**
     * @dev Modifier that checks that an account has a specific role. Reverts
     * with an {AccessControlUnauthorizedAccount} error including the required role.
     */
    modifier onlyRole(bytes32 role) {
        _checkRole(role);
        _;
    }

    function __AccessControl_init() internal onlyInitializing {
    }

    function __AccessControl_init_unchained() internal onlyInitializing {
    }
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IAccessControl).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) public view virtual returns (bool) {
        AccessControlStorage storage $ = _getAccessControlStorage();
        return $._roles[role].hasRole[account];
    }

    /**
     * @dev Reverts with an {AccessControlUnauthorizedAccount} error if `_msgSender()`
     * is missing `role`. Overriding this function changes the behavior of the {onlyRole} modifier.
     */
    function _checkRole(bytes32 role) internal view virtual {
        _checkRole(role, _msgSender());
    }

    /**
     * @dev Reverts with an {AccessControlUnauthorizedAccount} error if `account`
     * is missing `role`.
     */
    function _checkRole(bytes32 role, address account) internal view virtual {
        if (!hasRole(role, account)) {
            revert AccessControlUnauthorizedAccount(account, role);
        }
    }

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) public view virtual returns (bytes32) {
        AccessControlStorage storage $ = _getAccessControlStorage();
        return $._roles[role].adminRole;
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleGranted} event.
     */
    function grantRole(bytes32 role, address account) public virtual onlyRole(getRoleAdmin(role)) {
        _grantRole(role, account);
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleRevoked} event.
     */
    function revokeRole(bytes32 role, address account) public virtual onlyRole(getRoleAdmin(role)) {
        _revokeRole(role, account);
    }

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been revoked `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `callerConfirmation`.
     *
     * May emit a {RoleRevoked} event.
     */
    function renounceRole(bytes32 role, address callerConfirmation) public virtual {
        if (callerConfirmation != _msgSender()) {
            revert AccessControlBadConfirmation();
        }

        _revokeRole(role, callerConfirmation);
    }

    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.
     */
    function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
        AccessControlStorage storage $ = _getAccessControlStorage();
        bytes32 previousAdminRole = getRoleAdmin(role);
        $._roles[role].adminRole = adminRole;
        emit RoleAdminChanged(role, previousAdminRole, adminRole);
    }

    /**
     * @dev Attempts to grant `role` to `account` and returns a boolean indicating if `role` was granted.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleGranted} event.
     */
    function _grantRole(bytes32 role, address account) internal virtual returns (bool) {
        AccessControlStorage storage $ = _getAccessControlStorage();
        if (!hasRole(role, account)) {
            $._roles[role].hasRole[account] = true;
            emit RoleGranted(role, account, _msgSender());
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Attempts to revoke `role` to `account` and returns a boolean indicating if `role` was revoked.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleRevoked} event.
     */
    function _revokeRole(bytes32 role, address account) internal virtual returns (bool) {
        AccessControlStorage storage $ = _getAccessControlStorage();
        if (hasRole(role, account)) {
            $._roles[role].hasRole[account] = false;
            emit RoleRevoked(role, account, _msgSender());
            return true;
        } else {
            return false;
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.20;

import {IActivityCondition} from '../../interfaces/IActivityCondition.sol';
import {IERC165} from '@openzeppelin/contracts/interfaces/IERC165.sol';
import {ConditionContext} from 'contracts/core/base/ConditionContext.sol';

abstract contract ActivityConditionBase is ConditionContext, IERC165, IActivityCondition {
    constructor(
        address osp,
        address compositeCondition
    ) ConditionContext(osp, compositeCondition) {}

    function initializeCommunityActivityCondition(
        uint256 communityId,
        bytes calldata data
    ) external onlyOspOrCompositeCondition {
        _initializeCommunityActivityCondition(communityId, data);
    }

    function processActivity(
        uint256 communityId,
        address profileOwner,
        uint256 profileId
    ) external onlyOspOrCompositeCondition {
        _processActivity(communityId, profileOwner, profileId);
    }

    function _initializeCommunityActivityCondition(
        uint256 communityId,
        bytes calldata data
    ) internal virtual;

    function _processActivity(
        uint256 communityId,
        address profileOwner,
        uint256 profileId
    ) internal virtual;

    function supportsInterface(bytes4 interfaceId) public pure virtual override returns (bool) {
        return
            interfaceId == type(IActivityCondition).interfaceId ||
            interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.20;

import {OspContext} from './OspContext.sol';
import {IERC165} from '@openzeppelin/contracts/utils/introspection/IERC165.sol';
import {IActivityExtension} from '../../interfaces/IActivityExtension.sol';
import {IActivityExtensionQueryable} from '../../interfaces/IActivityExtensionQueryable.sol';

abstract contract ActivityExtensionBase is OspContext, IActivityExtensionQueryable, IERC165 {
    constructor(address osp) OspContext(osp) {}

    function initializeActivityExtension(
        uint256 profileId,
        uint256 contentId,
        bytes calldata initData
    ) external payable onlyOsp {
        _initializeActivityExtension(profileId, contentId, initData);
    }

    function _initializeActivityExtension(
        uint256 profileId,
        uint256 contentId,
        bytes calldata initData
    ) internal virtual;

    function supportsInterface(bytes4 interfaceId) external pure override returns (bool) {
        return
            interfaceId == type(IActivityExtension).interfaceId ||
            interfaceId == type(IActivityExtensionQueryable).interfaceId ||
            interfaceId == type(IERC165).interfaceId;
    }

    function getExtensionData(
        uint256 profileId,
        uint256 contentId
    ) external view virtual override returns (bytes memory) {
        return '';
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.20;

import {IGovernanceLogic} from '../core/logics/interfaces/IGovernanceLogic.sol';
import {Proxy} from '@openzeppelin/contracts/proxy/Proxy.sol';

contract CommunityAccountProxy is Proxy {
    address immutable OSP;

    constructor() {
        OSP = msg.sender;
    }

    function _implementation() internal view override returns (address) {
        return IGovernanceLogic(OSP).getERC6551AccountImpl();
    }
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.20;

import {OspContext} from './OspContext.sol';
import {ICommunityCondition} from '../../interfaces/ICommunityCondition.sol';
import {IERC165} from '@openzeppelin/contracts/interfaces/IERC165.sol';

abstract contract CommunityCondBase is OspContext, ICommunityCondition, IERC165 {
    constructor(address osp) OspContext(osp) {}

    function processCreateCommunity(
        address to,
        string calldata handle,
        bytes calldata data
    ) external payable override onlyOsp {
        _processCreateCommunity(to, handle, data);
    }

    function supportsInterface(bytes4 interfaceId) external pure override returns (bool) {
        return
            interfaceId == type(ICommunityCondition).interfaceId ||
            interfaceId == type(IERC165).interfaceId;
    }

    function _processCreateCommunity(
        address to,
        string calldata handle,
        bytes calldata data
    ) internal virtual;
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.20;

import {OspLogicBase} from './OspLogicBase.sol';
import {ICommunityLogic} from './interfaces/ICommunityLogic.sol';
import {OspDataTypes} from 'contracts/libraries/OspDataTypes.sol';
import {OspErrors} from 'contracts/libraries/OspErrors.sol';
import {OspEvents} from 'contracts/libraries/OspEvents.sol';
import {Constants} from 'contracts/libraries/Constants.sol';
import {ICommunityNFT} from 'contracts/interfaces/ICommunityNFT.sol';
import {IJoinCondition} from 'contracts/interfaces/IJoinCondition.sol';
import {ICommunityCondition} from 'contracts/interfaces/ICommunityCondition.sol';
import {IActivityCondition} from 'contracts/interfaces/IActivityCondition.sol';
import {IViewPrivacyCondition} from 'contracts/interfaces/IViewPrivacyCondition.sol';
import {IERC6551Registry} from 'contracts/interfaces/IERC6551Registry.sol';
import {ERC6551Account} from 'contracts/core/base/ERC6551Account.sol';
import {JoinNFTProxy} from 'contracts/upgradeability/JoinNFTProxy.sol';
import {IJoinNFT} from 'contracts/interfaces/IJoinNFT.sol';

import {Strings} from '@openzeppelin/contracts/utils/Strings.sol';
import {IERC721} from '@openzeppelin/contracts/token/ERC721/IERC721.sol';
import {EnumerableSet} from '@openzeppelin/contracts/utils/structs/EnumerableSet.sol';

/**
 * @title CommunityLogic
 * @author OpenSocial Protocol
 * @dev CommunityLogic is a contract to interact with the community.
 */
contract CommunityLogic is OspLogicBase, ICommunityLogic {
    using Strings for uint256;
    using EnumerableSet for EnumerableSet.AddressSet;

    /*///////////////////////////////////////////////////////////////
                      Public functions
    //////////////////////////////////////////////////////////////*/

    /// @inheritdoc ICommunityLogic
    function createCommunity(
        OspDataTypes.CreateCommunityData calldata vars
    ) external payable override whenNotPaused returns (uint256) {
        return _createCommunity(vars);
    }

    function createCommunity(
        OspDataTypes.CreateCommunityData calldata vars,
        bytes calldata activityConditionInitCode,
        bytes calldata viewPrivacyConditionInitCode
    ) external payable override whenNotPaused returns (uint256) {
        uint256 communityId = _createCommunity(vars);
        _setActivityCondition(communityId, activityConditionInitCode);
        _setViewPrivacyCondition(communityId, viewPrivacyConditionInitCode);
        return communityId;
    }

    /// @inheritdoc ICommunityLogic
    function emitCommunityNFTTransferEvent(
        uint256 communityId,
        address from,
        address to
    ) external override {
        if (_getGovernanceStorage()._communityNFT != msg.sender) {
            revert OspErrors.NotCommunityNFT();
        }
        emit OspEvents.CommunityNFTTransferred(communityId, from, to, block.timestamp);
    }

    /// @inheritdoc ICommunityLogic
    function setJoinCondition(
        uint256 communityId,
        bytes calldata joinConditionInitCode
    ) external override whenNotPaused {
        _validateCallerHasCommunityRole(communityId, Constants.COMMUNITY_ADMIN_ACCESS);
        _setJoinCondition(communityId, joinConditionInitCode);
    }

    /// @inheritdoc ICommunityLogic
    function setActivityCondition(
        uint256 communityId,
        bytes calldata activityConditionInitCode
    ) external override whenNotPaused {
        _validateCallerHasCommunityRole(communityId, Constants.COMMUNITY_ADMIN_ACCESS);
        _setActivityCondition(communityId, activityConditionInitCode);
    }

    function setViewPrivacyCondition(
        uint256 communityId,
        bytes calldata viewPrivacyConditionInitCode
    ) external override whenNotPaused {
        _validateCallerHasCommunityRole(communityId, Constants.COMMUNITY_ADMIN_ACCESS);
        _setViewPrivacyCondition(communityId, viewPrivacyConditionInitCode);
    }

    function isViewPrivacyAllowed(
        uint256 communityId,
        uint256 profileId
    ) external view returns (bool) {
        return
            IViewPrivacyCondition(
                _getCommunityStorage()._communityById[communityId].viewPrivacyCondition
            ).isViewPrivacyAllowed(
                    communityId,
                    _getProfileStorage()._profileById[profileId].owner,
                    profileId
                );
    }

    /// @inheritdoc ICommunityLogic
    function updateTags(
        uint256 communityId,
        string[] calldata tags
    ) external override whenNotPaused {
        _validateCallerHasCommunityRole(communityId, Constants.COMMUNITY_ADMIN_ACCESS);
        if (tags.length > Constants.MAX_TAGS_NUMBER) revert OspErrors.TooManyTags();
        emit OspEvents.CommunityTagsUpdated(communityId, msg.sender, tags, block.timestamp);
    }

    /// @inheritdoc ICommunityLogic
    function setCommunityActivityExtensionWhitelist(
        uint256 communityId,
        address extension,
        bool isWhitelist
    ) external override whenNotPaused {
        _validateCallerHasCommunityRole(communityId, Constants.COMMUNITY_ADMIN_ACCESS);
        if (extension != address(0)) {
            _checkActivityExtension(extension);
        }
        EnumerableSet.AddressSet storage communityExtensionWhitelist = _getCommunityStorage()
            ._activityExtensionWhitelistByCommunity[communityId];
        if (
            isWhitelist
                ? communityExtensionWhitelist.add(extension)
                : communityExtensionWhitelist.remove(extension)
        ) {
            emit OspEvents.CommunityExtensionWhitelistSet(
                communityId,
                extension,
                isWhitelist,
                msg.sender,
                block.timestamp
            );
        }
    }

    /*///////////////////////////////////////////////////////////////
                       Public read functions
    /////////////////////////////////////////////////////////////*/
    function getCommunityTokenURI(
        uint256 communityId
    ) external view override returns (string memory) {
        string memory baseURI = _getGovernanceStorage()._baseURI;
        return
            bytes(baseURI).length > 0
                ? string(abi.encodePacked(baseURI, 'community/', communityId.toString()))
                : communityId.toString();
    }

    /// @inheritdoc ICommunityLogic
    function getCommunity(
        uint256 communityId
    ) external view override returns (OspDataTypes.CommunityStruct memory) {
        CommunityStorage storage communityStorage = _getCommunityStorage();
        OspDataTypes.CommunityStruct memory communityData = communityStorage._communityById[
            communityId
        ];
        return communityData;
    }

    /// @inheritdoc ICommunityLogic
    function getJoinNFT(uint256 communityId) external view override returns (address) {
        CommunityStorage storage communityStorage = _getCommunityStorage();
        return communityStorage._communityById[communityId].joinNFT;
    }

    /// @inheritdoc ICommunityLogic
    function getJoinCondition(uint256 communityId) external view override returns (address) {
        CommunityStorage storage communityStorage = _getCommunityStorage();
        return communityStorage._communityById[communityId].joinCondition;
    }

    /// @inheritdoc ICommunityLogic
    function getActivityCondition(uint256 communityId) external view override returns (address) {
        CommunityStorage storage communityStorage = _getCommunityStorage();
        return communityStorage._communityById[communityId].activityCondition;
    }

    /// @inheritdoc ICommunityLogic
    function getCommunityIdByHandle(string calldata handle) public view override returns (uint256) {
        return _getCommunityStorage()._communityIdByHandleHash[keccak256(bytes(handle))];
    }

    /// @inheritdoc ICommunityLogic
    function getCommunityAccount(uint256 communityId) public view override returns (address) {
        return
            IERC6551Registry(Constants.ERC6551_REGISTRY).account(
                _getGovernanceStorage()._communityAccountProxy,
                Constants.COMMUNITY_TBA_SALT,
                block.chainid,
                _getGovernanceStorage()._communityNFT,
                communityId
            );
    }

    /// @inheritdoc ICommunityLogic
    function getCommunityAccount(string calldata handle) external view override returns (address) {
        return getCommunityAccount(getCommunityIdByHandle(handle));
    }

    /// @inheritdoc ICommunityLogic
    function getCommunityActivityExtensionWhitelist(
        uint256 communityId
    ) external view override returns (address[] memory extensions) {
        EnumerableSet.AddressSet storage communityExtensionWhitelist = _getCommunityStorage()
            ._activityExtensionWhitelistByCommunity[communityId];
        uint256 length = communityExtensionWhitelist.length();
        extensions = new address[](length);
        for (uint256 i; i < length; i += 1) {
            extensions[i] = communityExtensionWhitelist.at(i);
        }
    }

    /*///////////////////////////////////////////////////////////////
                        Internal functions
    //////////////////////////////////////////////////////////////*/

    function _setJoinCondition(uint256 communityId, bytes calldata joinConditionInitCode) internal {
        address joinCondition = joinConditionInitCode.length == 0
            ? address(0)
            : _initJoinCondition(communityId, joinConditionInitCode);
        _getCommunityStorage()._communityById[communityId].joinCondition = joinCondition;
        emit OspEvents.JoinConditionSet(communityId, msg.sender, joinCondition, block.timestamp);
    }

    function _setActivityCondition(
        uint256 communityId,
        bytes calldata activityConditionInitCode
    ) internal {
        address activityCondition = activityConditionInitCode.length == 0
            ? address(0)
            : _initActivityCondition(communityId, activityConditionInitCode);
        _getCommunityStorage()._communityById[communityId].activityCondition = activityCondition;
        emit OspEvents.ActivityConditionSet(
            communityId,
            msg.sender,
            activityCondition,
            block.timestamp
        );
    }

    function _setViewPrivacyCondition(
        uint256 communityId,
        bytes calldata viewPrivacyConditionInitCode
    ) internal {
        address viewPrivacyCondition = viewPrivacyConditionInitCode.length == 0
            ? address(0)
            : _initViewPrivacyCondition(communityId, viewPrivacyConditionInitCode);
        _getCommunityStorage()
            ._communityById[communityId]
            .viewPrivacyCondition = viewPrivacyCondition;
        emit OspEvents.ViewPrivacyConditionSet(
            communityId,
            msg.sender,
            viewPrivacyCondition,
            block.timestamp
        );
    }

    function _createCommunity(
        OspDataTypes.CreateCommunityData calldata vars
    ) internal returns (uint256 communityId) {
        if (vars.tags.length > Constants.MAX_TAGS_NUMBER) revert OspErrors.TooManyTags();
        bool isSuperCreator = _hashRole(Constants.SUPER_COMMUNITY_CREATOR, msg.sender);
        if (!isSuperCreator) {
            _validateHasProfile(msg.sender);
            _validateCommunityCondition(
                msg.sender,
                vars.handle,
                vars.communityConditionAndData,
                msg.value
            );
        }
        // mint community NFT
        communityId = ICommunityNFT(_communityNFT()).mint(msg.sender);
        // validate and register handle
        _registerHandle(vars.handle, isSuperCreator, communityId);
        // deploy Join NFT
        address joinNFT = _deployJoinNFT(communityId, vars.handle);
        // deploy community TBA
        _deployCommunityTBA(communityId);
        _getCommunityStorage()._communityById[communityId].joinNFT = joinNFT;
        IJoinNFT(joinNFT).mint(msg.sender);
        //init join condition
        address joinCondition;
        if (vars.joinConditionInitCode.length != 0) {
            joinCondition = _initJoinCondition(communityId, vars.joinConditionInitCode);
            _getCommunityStorage()._communityById[communityId].joinCondition = joinCondition;
        }
        emit OspEvents.CommunityCreated(
            communityId,
            msg.sender,
            vars.handle,
            vars.communityConditionAndData,
            joinCondition,
            joinNFT,
            vars.tags,
            vars.ctx,
            block.timestamp
        );
    }

    function _initJoinCondition(
        uint256 communityId,
        bytes calldata initCode
    ) private returns (address joinCondition) {
        joinCondition = address(bytes20(initCode[:20]));
        _checkJoinCondition(joinCondition);
        bytes memory initCallData = initCode[20:];
        IJoinCondition(joinCondition).initializeCommunityJoinCondition(communityId, initCallData);
    }

    function _initActivityCondition(
        uint256 communityId,
        bytes calldata initCode
    ) private returns (address activityCondition) {
        activityCondition = address(bytes20(initCode[:20]));
        _checkActivityCondition(activityCondition);
        bytes memory initCallData = initCode[20:];
        IActivityCondition(activityCondition).initializeCommunityActivityCondition(
            communityId,
            initCallData
        );
    }

    function _initViewPrivacyCondition(
        uint256 communityId,
        bytes calldata initCode
    ) private returns (address viewPrivacyCondition) {
        viewPrivacyCondition = address(bytes20(initCode[:20]));
        _checkViewPrivacyCondition(viewPrivacyCondition);
        bytes memory initCallData = initCode[20:];
        IViewPrivacyCondition(viewPrivacyCondition).initializeCommunityViewPrivacyCondition(
            communityId,
            initCallData
        );
    }

    /**
     * @dev Deploys the given community's Join NFT contract.
     * @param communityId The token ID of the profile which Collect NFT should be deployed.
     * @param handle The profile's associated handle.
     *
     * @return address The address of the deployed Collect NFT contract.
     */
    function _deployJoinNFT(uint256 communityId, string memory handle) internal returns (address) {
        string memory idStr = communityId.toString();
        string memory name = string(abi.encodePacked(idStr, Constants.JOIN_NFT_NAME_SUFFIX));
        string memory symbol = string(abi.encodePacked(idStr, Constants.JOIN_NFT_SYMBOL_SUFFIX));

        bytes memory functionData = abi.encodeWithSelector(
            IJoinNFT.initialize.selector,
            communityId,
            name,
            symbol
        );
        address joinNFT = address(new JoinNFTProxy(functionData));
        emit OspEvents.JoinNFTDeployed(communityId, joinNFT, block.timestamp);
        return joinNFT;
    }

    function _deployCommunityTBA(uint256 communityId) internal returns (address) {
        if (_getGovernanceStorage()._erc6551AccountImpl == address(0)) {
            revert OspErrors.ERC6551AccountImplNotDeployed();
        }
        address tbaAccount = IERC6551Registry(Constants.ERC6551_REGISTRY).createAccount(
            _getGovernanceStorage()._communityAccountProxy,
            Constants.COMMUNITY_TBA_SALT,
            block.chainid,
            _communityNFT(),
            communityId
        );
        ERC6551Account(payable(tbaAccount)).initialize(communityId);
        return tbaAccount;
    }

    function _validateCommunityCondition(
        address creator,
        string calldata handle,
        bytes calldata communityConditionAndData,
        uint256 value
    ) internal {
        address communityCondition = address(bytes20(communityConditionAndData[:20]));
        _checkCommunityCondition(communityCondition);
        bytes memory callData = communityConditionAndData[20:];
        ICommunityCondition(communityCondition).processCreateCommunity{value: value}(
            creator,
            handle,
            callData
        );
    }

    function _validateHandle(
        string calldata handle,
        bool isSuperCreator,
        CommunityStorage storage communityStorage
    ) internal view returns (bytes32 hash) {
        bytes memory byteHandle = bytes(handle);
        bytes32 handleHash = keccak256(bytes(handle));
        if (byteHandle.length == 0 || byteHandle.length > Constants.MAX_COMMUNITY_NAME_LENGTH)
            revert OspErrors.HandleLengthInvalid();
        GovernanceStorage storage governanceStorage = _getGovernanceStorage();
        if (governanceStorage._reserveCommunityHandleHash[handleHash] && !isSuperCreator)
            revert OspErrors.HandleTaken();
        if (communityStorage._communityIdByHandleHash[handleHash] != 0)
            revert OspErrors.HandleTaken();
        uint256 byteHandleLength = byteHandle.length;
        for (uint256 i; i < byteHandleLength; ) {
            if (
                (byteHandle[i] < '0' ||
                    byteHandle[i] > 'z' ||
                    (byteHandle[i] > '9' && byteHandle[i] < 'a')) && byteHandle[i] != '_'
            ) revert OspErrors.HandleContainsInvalidCharacters();
            unchecked {
                ++i;
            }
        }
        return keccak256(byteHandle);
    }

    function _registerHandle(
        string calldata handle,
        bool isSuperCreator,
        uint256 communityId
    ) internal {
        CommunityStorage storage communityStorage = _getCommunityStorage();
        bytes32 handleHash = _validateHandle(handle, isSuperCreator, communityStorage);
        communityStorage._communityIdByHandleHash[handleHash] = communityId;
        communityStorage._communityById[communityId].handle = handle;
    }

    function _validateCallerHasCommunityRole(uint256 communityId, uint256 role) internal view {
        address joinNFT = _getCommunityStorage()._communityById[communityId].joinNFT;
        if (joinNFT == address(0)) revert OspErrors.InvalidCommunityId();
        if (IJoinNFT(joinNFT).hasRole(role, msg.sender)) return;
        revert OspErrors.JoinNFTUnauthorizedAccount();
    }

    function _communityNFT() internal view returns (address) {
        return _getGovernanceStorage()._communityNFT;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.20;

import './logics/interfaces/OspClient.sol';
import '../interfaces/ICommunityNFT.sol';
import '../libraries/OspErrors.sol';
import './base/OspNFTBase.sol';
import './base/IERC4906.sol';
import '@thirdweb-dev/contracts/extension/upgradeable/ContractMetadata.sol';
import '@openzeppelin/contracts-upgradeable/token/common/ERC2981Upgradeable.sol';

/**
 * @title CommunityNFT
 * @author OpenSocial Protocol
 * @dev This NFT contract is minted upon community is created.
 */
contract CommunityNFT is OspNFTBase, ContractMetadata, ICommunityNFT, IERC4906, ERC2981Upgradeable {
    address public immutable OSP;
    uint256 internal _tokenIdCounter;

    constructor(address osp) {
        if (osp == address(0)) revert OspErrors.InitParamsInvalid();
        OSP = osp;
    }

    function initialize(string calldata name, string calldata symbol) external {
        super._initialize(name, symbol);
    }

    function mint(address to) external override returns (uint256) {
        if (msg.sender != OSP) revert OspErrors.NotOSP();
        unchecked {
            uint256 tokenId = ++_tokenIdCounter;
            _mint(to, tokenId);
            return tokenId;
        }
    }

    function tokenURI(uint256 tokenId) public view override returns (string memory) {
        return ICommunityLogic(OSP).getCommunityTokenURI(tokenId);
    }

    /**
     * @dev Upon transfers, we emit the transfer event in the osp.
     */
    function _afterTokenTransfer(address from, address to, uint256 tokenId) internal override {
        ICommunityLogic(OSP).emitCommunityNFTTransferEvent(tokenId, from, to);
        super._afterTokenTransfer(from, to, tokenId);
    }

    function setTokenRoyalty(address receiver, uint96 feeNumerator) external {
        if (!OspClient(OSP).hasRole(Constants.GOVERNANCE, _msgSender())) {
            revert OspErrors.NotGovernance();
        }
        _setDefaultRoyalty(receiver, feeNumerator);
    }

    function updateMetadata() external override {
        emit BatchMetadataUpdate(1, type(uint256).max);
    }

    function burn(uint256 tokenId) public override {
        _update(address(this), tokenId, _msgSender());
    }

    function _canSetContractURI() internal view override returns (bool) {
        return OspClient(OSP).hasRole(Constants.GOVERNANCE, _msgSender());
    }

    function supportsInterface(
        bytes4 interfaceId
    ) public view virtual override(OspNFTBase, ERC2981Upgradeable) returns (bool) {
        return
            ERC2981Upgradeable.supportsInterface(interfaceId) ||
            OspNFTBase.supportsInterface(interfaceId);
    }
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.20;

import {IERC165} from '@openzeppelin/contracts/interfaces/IERC165.sol';
import {ERC165Checker} from '@openzeppelin/contracts/utils/introspection/ERC165Checker.sol';

import {OspContext} from 'contracts/core/base/OspContext.sol';
import {IActivityCondition} from 'contracts/interfaces/IActivityCondition.sol';
import {CondErrors} from '../libraries/CondErrors.sol';
import {CondHelpers} from '../libraries/CondHelpers.sol';
import {ICompositeActivityCond} from './interfaces/ICompositeActivityCond.sol';

/**
 * @title CompositeActivityCond
 * @author OpenSocial Protocol
 *
 * @notice This is the contract that implements the composable activity conditions.
 */
contract CompositeActivityCond is OspContext, ICompositeActivityCond, IERC165 {
    uint256 private constant MAX_CONDITIONS = 5;

    mapping(uint256 => CompositeData) internal _dataByCommunity;

    constructor(address osp) OspContext(osp) {}

    function initializeCommunityActivityCondition(
        uint256 communityId,
        bytes calldata data
    ) external override onlyOsp {
        (
            OperatorEnum operator,
            IActivityCondition[] memory conditions,
            bytes[] memory initDatas
        ) = abi.decode(data, (OperatorEnum, IActivityCondition[], bytes[]));
        uint256 length = conditions.length;
        if (length > MAX_CONDITIONS) revert CondErrors.TooManyConditions();
        if (length != initDatas.length) revert CondErrors.ArrayMismatch();
        for (uint256 i; i < length; ) {
            // check duplicated
            for (uint256 j; j < i; ) {
                if (conditions[i] == conditions[j]) {
                    revert CondErrors.ArrayDuplicated();
                }
                unchecked {
                    ++j;
                }
            }
            _checkActivityCondition(address(conditions[i]));
            conditions[i].initializeCommunityActivityCondition(communityId, initDatas[i]);
            unchecked {
                ++i;
            }
        }
        _dataByCommunity[communityId].operator = operator;
        _dataByCommunity[communityId].conditions = conditions;
    }

    function processActivity(
        uint256 communityId,
        address profileOwner,
        uint256 profileId
    ) external override onlyOsp {
        IActivityCondition[] storage conditions = _dataByCommunity[communityId].conditions;
        OperatorEnum operator = _dataByCommunity[communityId].operator;
        if (operator == OperatorEnum.AND) {
            for (uint256 i; i < conditions.length; i++) {
                conditions[i].processActivity(communityId, profileOwner, profileId);
            }
        } else {
            for (uint256 i; i < conditions.length; i++) {
                bool hasError = false;
                try conditions[i].processActivity(communityId, profileOwner, profileId) {} catch {
                    hasError = true;
                }
                if (!hasError) {
                    return;
                }
            }
            revert CondErrors.ActivityConditionNotMet();
        }
    }

    // @inheritdoc ICompositeActivityCond
    function getCompositeData(uint256 communityId) external view returns (CompositeData memory) {
        return _dataByCommunity[communityId];
    }

    // @inheritdoc IERC165
    function supportsInterface(bytes4 interfaceId) public pure override returns (bool) {
        return
            interfaceId == type(IActivityCondition).interfaceId ||
            interfaceId == type(IERC165).interfaceId ||
            interfaceId == type(ICompositeActivityCond).interfaceId;
    }

    function _checkActivityCondition(address condition) internal view {
        if (
            !OSP.isAppWhitelisted(condition) ||
            !ERC165Checker.supportsInterface(condition, type(IActivityCondition).interfaceId)
        ) revert CondErrors.ConditionNotWhitelisted();
    }
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.20;

import {IERC165} from '@openzeppelin/contracts/interfaces/IERC165.sol';
import {ERC165Checker} from '@openzeppelin/contracts/utils/introspection/ERC165Checker.sol';

import {OspContext} from 'contracts/core/base/OspContext.sol';
import {IViewPrivacyCondition} from 'contracts/interfaces/IViewPrivacyCondition.sol';
import {CondErrors} from '../libraries/CondErrors.sol';
import {CondHelpers} from '../libraries/CondHelpers.sol';
import {ICompositeViewPrivacyCond} from './interfaces/ICompositeViewPrivacyCond.sol';

/**
 * @title CompositeViewPrivacyCond
 * @author OpenSocial Protocol
 *
 * @notice This is the contract that implements the composable view privacy conditions.
 */
contract CompositeViewPrivacyCond is OspContext, ICompositeViewPrivacyCond, IERC165 {
    uint256 private constant MAX_CONDITIONS = 5;

    mapping(uint256 => CompositeData) internal _dataByCommunity;

    constructor(address osp) OspContext(osp) {}

    function initializeCommunityViewPrivacyCondition(
        uint256 communityId,
        bytes calldata data
    ) external override onlyOsp {
        (
            OperatorEnum operator,
            ICompositeViewPrivacyCond[] memory conditions,
            bytes[] memory initDatas
        ) = abi.decode(data, (OperatorEnum, ICompositeViewPrivacyCond[], bytes[]));
        uint256 length = conditions.length;
        if (length > MAX_CONDITIONS) revert CondErrors.TooManyConditions();
        if (length != initDatas.length) revert CondErrors.ArrayMismatch();
        for (uint256 i; i < length; ) {
            // check duplicated
            for (uint256 j; j < i; ) {
                if (conditions[i] == conditions[j]) {
                    revert CondErrors.ArrayDuplicated();
                }
                unchecked {
                    ++j;
                }
            }
            _checkViewPrivacyCondition(address(conditions[i]));
            conditions[i].initializeCommunityViewPrivacyCondition(communityId, initDatas[i]);
            unchecked {
                ++i;
            }
        }
        _dataByCommunity[communityId].operator = operator;
        _dataByCommunity[communityId].conditions = conditions;
    }

    function isViewPrivacyAllowed(
        uint256 communityId,
        address profileOwner,
        uint256 profileId
    ) external view override onlyOsp returns (bool) {
        IViewPrivacyCondition[] storage conditions = _dataByCommunity[communityId].conditions;
        OperatorEnum operator = _dataByCommunity[communityId].operator;
        if (operator == OperatorEnum.AND) {
            for (uint256 i; i < conditions.length; i++) {
                if (!conditions[i].isViewPrivacyAllowed(communityId, profileOwner, profileId)) {
                    return false;
                }
            }
            return true;
        } else {
            for (uint256 i; i < conditions.length; i++) {
                if (conditions[i].isViewPrivacyAllowed(communityId, profileOwner, profileId)) {
                    return true;
                }
            }
            return false;
        }
    }

    // @inheritdoc IViewPrivacyCondition
    function getCompositeData(uint256 communityId) external view returns (CompositeData memory) {
        return _dataByCommunity[communityId];
    }

    // @inheritdoc IERC165
    function supportsInterface(bytes4 interfaceId) public pure override returns (bool) {
        return
            interfaceId == type(IViewPrivacyCondition).interfaceId ||
            interfaceId == type(IERC165).interfaceId ||
            interfaceId == type(ICompositeViewPrivacyCond).interfaceId;
    }

    function _checkViewPrivacyCondition(address condition) internal view {
        if (
            !OSP.isAppWhitelisted(condition) ||
            !ERC165Checker.supportsInterface(condition, type(IViewPrivacyCondition).interfaceId)
        ) revert CondErrors.ConditionNotWhitelisted();
    }
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.20;

/**
 * @title CondDataTypes
 * @author OpenSocial Protocol
 *
 * @dev The CondDataTypes library contains data types used throughout the OpenSocial Protocol.
 */
library CondDataTypes {
    struct SlotNFTCondData {
        bool whitelist;
        uint256 minHandleLength;
    }

    struct FixedFeeCondData {
        uint256 price1Letter;
        uint256 price2Letter;
        uint256 price3Letter;
        uint256 price4Letter;
        uint256 price5Letter;
        uint256 price6Letter;
        uint256 price7ToMoreLetter;
        uint256 createStartTime;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.20;

library CondErrors {
    // array
    error ArrayMismatch();
    error ArrayDuplicated();

    // whitelist
    error ConditionNotWhitelisted();
    error NotWhitelisted();

    // common
    error ConditionDataMismatch();
    error InitParamsInvalid();

    // handle format
    error HandleLengthNotEnough();

    // slot nft
    error SlotNFTNotWhitelisted();
    error NotSlotNFTOwner();
    error SlotNFTAlreadyUsed();

    error NotCreateTime();
    error NotPresaleTime();
    error InvalidTicket();
    error InsufficientPayment();
    error SignatureInvalid();

    error JoinNFTTransferInvalid();
    error JoinInvalid();

    error AccessDenied();

    error ActivityConditionNotMet();

    // token
    error NotEnoughERC721Balance();

    error TooManyConditions();
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.20;

import {CondDataTypes} from './CondDataTypes.sol';

library CondHelpers {
    /**
     * @dev Get the ETH price based on the length of the handle.
     * @param handle The handle to get the ETH price for.
     * @param fixedFeeCondData The fixed fee condition data.
     * @return The ETH price.
     */
    function getHandleETHPrice(
        string calldata handle,
        CondDataTypes.FixedFeeCondData memory fixedFeeCondData
    ) internal pure returns (uint256) {
        uint256 len = bytes(handle).length;
        uint256 ethPrice;
        if (len >= 7) {
            ethPrice = fixedFeeCondData.price7ToMoreLetter;
        } else if (len == 6) {
            ethPrice = fixedFeeCondData.price6Letter;
        } else if (len == 5) {
            ethPrice = fixedFeeCondData.price5Letter;
        } else if (len == 4) {
            ethPrice = fixedFeeCondData.price4Letter;
        } else if (len == 3) {
            ethPrice = fixedFeeCondData.price3Letter;
        } else if (len == 2) {
            ethPrice = fixedFeeCondData.price2Letter;
        } else {
            ethPrice = fixedFeeCondData.price1Letter;
        }
        return ethPrice;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.20;

import '@openzeppelin/contracts/utils/Context.sol';
import 'contracts/libraries/OspErrors.sol';

abstract contract ConditionContext is Context {
    address immutable OSP;
    address immutable COMPOSITE_CONDITION;

    constructor(address osp, address compositeCondition) {
        if (osp == address(0)) revert OspErrors.InitParamsInvalid();
        if (compositeCondition == address(0)) revert OspErrors.InitParamsInvalid();
        OSP = osp;
        COMPOSITE_CONDITION = compositeCondition;
    }

    modifier onlyOsp() {
        if (_msgSender() != address(OSP)) revert OspErrors.NotOSP();
        _;
    }

    modifier onlyOspOrCompositeCondition() {
        if (_msgSender() != COMPOSITE_CONDITION && _msgSender() != address(OSP))
            revert OspErrors.InvalidSender();
        _;
    }

    modifier nonPayable() {
        if (msg.value != 0) revert OspErrors.InvalidValue();
        _;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.20;

/**
 * @title Constants
 * @author OpenSocial Protocol
 * @notice This library defines constants for the OpenSocial Protocol.
 */
library Constants {
    string internal constant FOLLOW_NFT_NAME_SUFFIX = "'s Follower";
    string internal constant FOLLOW_NFT_SYMBOL_SUFFIX = '-FOL';
    string internal constant JOIN_NFT_NAME_SUFFIX = "'s Member";
    string internal constant JOIN_NFT_SYMBOL_SUFFIX = '-MBR';
    uint8 internal constant MAX_HANDLE_LENGTH = 15;
    uint8 internal constant MIN_HANDLE_LENGTH = 4;
    uint8 internal constant MAX_COMMUNITY_NAME_LENGTH = 63;
    uint16 internal constant MAX_PROFILE_IMAGE_URI_LENGTH = 6000;
    address internal constant ERC6551_REGISTRY = 0x000000006551c19487814612e58FE06813775758;
    bytes32 internal constant COMMUNITY_TBA_SALT =
        0xd51dafa9227bb21dd4efbc739a5c611e802dd0ec1ef35b3dc8da5ad2dca64ae6;
    bytes32 internal constant APP_ADMIN = keccak256('APP_ADMIN');
    bytes32 internal constant GOVERNANCE = keccak256('GOVERNANCE');
    bytes32 internal constant OPERATION = keccak256('OPERATION');
    bytes32 internal constant STATE_ADMIN = keccak256('STATE_ADMIN');
    bytes32 internal constant SUPER_COMMUNITY_CREATOR = keccak256('SUPER_COMMUNITY_CREATOR');
    uint256 internal constant MAX_TAGS_NUMBER = 10;
    // community join nft roles
    uint256 internal constant COMMUNITY_NULL_ACCESS = 0x00000000;
    uint256 internal constant COMMUNITY_MODERATOR_ACCESS = 0x55555555;
    uint256 internal constant COMMUNITY_ADMIN_ACCESS = 0xaaaaaaaa;
    uint256 internal constant ROYALTY_DENOMINATOR = 10000;
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.20;

import {IActivityExtension} from '../../interfaces/IActivityExtension.sol';
import {IReferenceCondition} from '../../interfaces/IReferenceCondition.sol';
import {IOpenReaction} from '../../interfaces/IOpenReaction.sol';
import {OspHelpers} from '../../libraries/OspHelpers.sol';
import {OspDataTypes} from '../../libraries/OspDataTypes.sol';
import {Constants} from '../../libraries/Constants.sol';
import {OspErrors} from '../../libraries/OspErrors.sol';
import {OspEvents} from '../../libraries/OspEvents.sol';
import {IContentLogic} from './interfaces/IContentLogic.sol';
import {OspLogicBase} from './OspLogicBase.sol';
import {Payment} from '../../libraries/Payment.sol';
import {IERC721} from '@openzeppelin/contracts/token/ERC721/IERC721.sol';
import {IActivityCondition} from '../../interfaces/IActivityCondition.sol';
import {EnumerableSet} from '@openzeppelin/contracts/utils/structs/EnumerableSet.sol';

/**
 * @title ContentLogic
 * @author OpenSocial Protocol
 */
contract ContentLogic is IContentLogic, OspLogicBase {
    using EnumerableSet for EnumerableSet.AddressSet;

    /*///////////////////////////////////////////////////////////////
                        Public functions
    //////////////////////////////////////////////////////////////*/

    /// @inheritdoc IContentLogic
    function createActivity(
        OspDataTypes.CreateActivityData calldata vars
    ) external payable override whenPublishingEnabled returns (uint256 contentId) {
        contentId = _createActivity(msg.sender, vars);
    }

    /// @inheritdoc IContentLogic
    function createActivityWithSig(
        OspDataTypes.CreateActivityData calldata vars,
        OspDataTypes.EIP712Signature calldata sig
    ) external whenPublishingEnabled returns (uint256 contentId) {
        unchecked {
            _validateRecoveredAddress(
                _calculateDigest(
                    keccak256(
                        abi.encode(
                            OspDataTypes.CREATE_ACTIVITY_WITH_SIG_TYPEHASH,
                            vars.profileId,
                            vars.communityId,
                            keccak256(bytes(vars.contentURI)),
                            keccak256(vars.extensionInitCode),
                            keccak256(vars.referenceConditionInitCode),
                            keccak256(vars.ctx),
                            _getProfileStorage()._sigNonces[sig.signer]++,
                            sig.deadline
                        )
                    )
                ),
                sig
            );
        }
        contentId = _createActivity(sig.signer, vars);
    }

    /// @inheritdoc IContentLogic
    function createComment(
        OspDataTypes.CreateCommentData calldata vars
    ) external payable whenPublishingEnabled returns (uint256 contentId) {
        _validateIsProfileOwner(msg.sender, vars.profileId);
        contentId = _createComment(vars);
    }

    /// @inheritdoc IContentLogic
    function createCommentWithSig(
        OspDataTypes.CreateCommentData calldata vars,
        OspDataTypes.EIP712Signature calldata sig
    ) external whenPublishingEnabled returns (uint256 contentId) {
        unchecked {
            _validateRecoveredAddress(
                _calculateDigest(
                    keccak256(
                        abi.encode(
                            OspDataTypes.CREATE_COMMENT_WITH_SIG_TYPEHASH,
                            vars.profileId,
                            vars.communityId,
                            keccak256(bytes(vars.contentURI)),
                            vars.referencedProfileId,
                            vars.referencedContentId,
                            keccak256(vars.referenceConditionInitCode),
                            keccak256(vars.referenceConditionData),
                            keccak256(vars.ctx),
                            _getProfileStorage()._sigNonces[sig.signer]++,
                            sig.deadline
                        )
                    )
                ),
                sig
            );
        }
        _validateIsProfileOwner(sig.signer, vars.profileId);
        contentId = _createComment(vars);
    }

    /// @inheritdoc IContentLogic
    function createOpenReaction(
        OspDataTypes.CreateOpenReactionData calldata vars
    ) external payable whenPublishingEnabled {
        _validateIsProfileOwner(msg.sender, vars.profileId);
        _createOpenReaction(vars);
    }

    /// @inheritdoc IContentLogic
    function createOpenReactionWithSig(
        OspDataTypes.CreateOpenReactionData calldata vars,
        OspDataTypes.EIP712Signature calldata sig
    ) external whenPublishingEnabled {
        unchecked {
            _validateRecoveredAddress(
                _calculateDigest(
                    keccak256(
                        abi.encode(
                            OspDataTypes.CREATE_OPEN_REACTION_WITH_SIG_TYPEHASH,
                            vars.profileId,
                            vars.communityId,
                            vars.referencedProfileId,
                            vars.referencedContentId,
                            keccak256(vars.reactionAndData),
                            keccak256(vars.referenceConditionData),
                            keccak256(vars.ctx),
                            _getProfileStorage()._sigNonces[sig.signer]++,
                            sig.deadline
                        )
                    )
                ),
                sig
            );
        }
        _validateIsProfileOwner(sig.signer, vars.profileId);
        _createOpenReaction(vars);
    }

    /// @inheritdoc IContentLogic
    function createMegaphone(
        OspDataTypes.CreateMegaphoneData calldata vars
    ) external payable whenPublishingEnabled returns (uint256 megaphoneId) {
        _validateIsProfileOwner(msg.sender, vars.profileId);
        return _createMegaphone(vars);
    }

    /*///////////////////////////////////////////////////////////////
                        Public Read functions
    //////////////////////////////////////////////////////////////*/

    /// @inheritdoc IContentLogic
    function getContentCount(uint256 profileId) external view override returns (uint256) {
        return _getProfileStorage()._profileById[profileId].contentCount;
    }

    /// @inheritdoc IContentLogic
    function getContent(
        uint256 profileId,
        uint256 contentId
    ) external view override returns (OspDataTypes.ContentStruct memory) {
        return _getContentStorage()._contentByIdByProfile[profileId][contentId];
    }

    /// @inheritdoc IContentLogic
    function getCommunityIdByContent(
        uint256 profileId,
        uint256 contentId
    ) external view returns (uint256) {
        return _getContentStorage()._contentByIdByProfile[profileId][contentId].communityId;
    }

    /*///////////////////////////////////////////////////////////////
                        Internal functions
    //////////////////////////////////////////////////////////////*/

    function _createActivity(
        address profileOwner,
        OspDataTypes.CreateActivityData calldata vars
    ) internal returns (uint256 contentId) {
        _validateIsProfileOwner(profileOwner, vars.profileId);
        if (bytes(vars.contentURI).length == 0) {
            revert OspErrors.InvalidContentURI();
        }
        uint256 profileId = vars.profileId;
        _validateCallerIsJoinCommunity(profileId, vars.communityId);
        _validateActivity(vars.communityId, profileOwner, vars.profileId);

        contentId = ++_getProfileStorage()._profileById[profileId].contentCount;
        OspDataTypes.ContentStruct storage activityContent = _getContentStorage()
            ._contentByIdByProfile[vars.profileId][contentId];
        //init activity
        activityContent.contentURI = vars.contentURI;
        activityContent.communityId = vars.communityId;

        address extension;
        if (vars.extensionInitCode.length != 0) {
            extension = _initActivityExtension(
                profileId,
                contentId,
                vars.extensionInitCode,
                msg.value
            );
            activityContent.extension = extension;
        }

        EnumerableSet.AddressSet storage communityExtensionWhitelist = _getCommunityStorage()
            ._activityExtensionWhitelistByCommunity[vars.communityId];
        bool enableExtensionWhitelist = communityExtensionWhitelist.length() != 0;
        if (enableExtensionWhitelist && !communityExtensionWhitelist.contains(extension)) {
            revert OspErrors.ExtensionNotCommunityWhitelisted();
        }
        if (!enableExtensionWhitelist && vars.communityId != 0 && extension != address(0)) {
            revert OspErrors.ExtensionNotCommunityWhitelisted();
        }

        address referenceCondition;
        if (vars.referenceConditionInitCode.length != 0) {
            referenceCondition = _initReferenceCondition(
                vars.profileId,
                contentId,
                vars.communityId,
                vars.referenceConditionInitCode
            );
            activityContent.referenceCondition = referenceCondition;
        }

        emit OspEvents.ActivityCreated(
            vars.profileId,
            contentId,
            vars.communityId,
            vars.contentURI,
            extension,
            referenceCondition,
            vars.ctx,
            block.timestamp
        );
    }

    function _createComment(
        OspDataTypes.CreateCommentData calldata vars
    ) internal returns (uint256 contentId) {
        if (bytes(vars.contentURI).length == 0) {
            revert OspErrors.InvalidContentURI();
        }
        _validateCallerIsJoinCommunity(vars.profileId, vars.communityId);
        _validateReferenced(
            vars.profileId,
            vars.communityId,
            vars.referencedProfileId,
            vars.referencedContentId,
            vars.referenceConditionData,
            msg.value
        );

        contentId = ++_getProfileStorage()._profileById[vars.profileId].contentCount;
        OspDataTypes.ContentStruct storage commentContent = _getContentStorage()
            ._contentByIdByProfile[vars.profileId][contentId];

        commentContent.referencedProfileId = vars.referencedProfileId;
        commentContent.referencedContentId = vars.referencedContentId;
        commentContent.contentURI = vars.contentURI;
        commentContent.communityId = vars.communityId;

        address referenceCondition;
        if (vars.referenceConditionInitCode.length != 0) {
            referenceCondition = _initReferenceCondition(
                vars.profileId,
                contentId,
                vars.communityId,
                vars.referenceConditionInitCode
            );
            commentContent.referenceCondition = referenceCondition;
        }

        emit OspEvents.CommentCreated(
            vars.profileId,
            contentId,
            vars.communityId,
            vars.contentURI,
            vars.referencedProfileId,
            vars.referencedContentId,
            referenceCondition,
            vars.ctx,
            block.timestamp
        );
    }

    function _createMegaphone(
        OspDataTypes.CreateMegaphoneData calldata vars
    ) internal returns (uint256 megaphoneId) {
        if (vars.tags.length > Constants.MAX_TAGS_NUMBER) revert OspErrors.TooManyTags();

        ContentStorage storage contentStorage = _getContentStorage();

        if (
            vars.referencedContentId == 0 ||
            _getProfileStorage()._profileById[vars.referencedProfileId].contentCount <
            vars.referencedContentId
        ) {
            revert OspErrors.ContentDoesNotExist();
        }

        if (
            contentStorage
            ._contentByIdByProfile[vars.referencedProfileId][vars.referencedContentId]
                .referenceCondition != address(0)
        ) {
            revert OspErrors.ContentNotPublic();
        }
        if (!_getGovernanceStorage()._tokenWhitelisted[vars.currency]) {
            revert OspErrors.InvalidToken();
        }
        megaphoneId = ++_getContentStorage()._megaphoneCount;
        address treasure = _getGovernanceStorage()._treasure;
        if (treasure == address(0)) revert OspErrors.InvalidTreasure();
        if (vars.currency == address(0)) {
            if (msg.value != vars.amount) revert OspErrors.DataMismatch();
            Payment.payNative(treasure, vars.amount);
        } else {
            Payment.payERC20(vars.currency, msg.sender, treasure, vars.amount);
        }
        emit OspEvents.MegaphoneCreated(
            megaphoneId,
            vars.referencedProfileId,
            vars.referencedContentId,
            vars.profileId,
            vars.tags,
            vars.startTime,
            vars.duration,
            vars.currency,
            vars.amount,
            vars.ctx,
            block.timestamp
        );
    }

    function _createOpenReaction(OspDataTypes.CreateOpenReactionData calldata vars) internal {
        _validateCallerIsJoinCommunity(vars.profileId, vars.communityId);
        if (msg.value < vars.reactionValue) {
            revert OspErrors.InvalidValue();
        }
        _validateReferenced(
            vars.profileId,
            vars.communityId,
            vars.referencedProfileId,
            vars.referencedContentId,
            vars.referenceConditionData,
            msg.value - vars.reactionValue
        );

        (address openReaction, bytes memory openReactionData) = _initOpenReaction(
            vars.profileId,
            vars.referencedProfileId,
            vars.referencedContentId,
            vars.reactionAndData,
            vars.reactionValue
        );

        emit OspEvents.OpenReactionCreated(
            vars.profileId,
            vars.referencedProfileId,
            vars.referencedContentId,
            vars.communityId,
            openReaction,
            openReactionData,
            vars.ctx,
            block.timestamp
        );
    }

    function _initReferenceCondition(
        uint256 profileId,
        uint256 contentId,
        uint256 communityId,
        bytes calldata initCode
    ) internal returns (address referenceCondition) {
        referenceCondition = address(bytes20(initCode[:20]));
        _checkReferenceCondition(referenceCondition);
        bytes memory initCallData = initCode[20:];
        IReferenceCondition(referenceCondition).initializeReferenceCondition(
            profileId,
            contentId,
            communityId,
            initCallData
        );
    }

    function _initActivityExtension(
        uint256 profileId,
        uint256 contentId,
        bytes calldata initCode,
        uint256 value
    ) internal returns (address extension) {
        extension = address(bytes20(initCode[:20]));
        _checkActivityExtension(extension);
        bytes memory initCallData = initCode[20:];
        IActivityExtension(extension).initializeActivityExtension{value: value}(
            profileId,
            contentId,
            initCallData
        );
    }

    function _initOpenReaction(
        uint256 profileId,
        uint256 referencedProfileId,
        uint256 referencedContentId,
        bytes calldata initCode,
        uint256 value
    ) internal returns (address openReaction, bytes memory openReactionData) {
        openReaction = address(bytes20(initCode[:20]));
        _checkOpenReaction(openReaction);
        openReactionData = initCode[20:];
        IOpenReaction(openReaction).processReaction{value: value}(
            profileId,
            referencedProfileId,
            referencedContentId,
            openReactionData
        );
    }

    function _validateReferenced(
        uint256 profileId,
        uint256 communityId,
        uint256 referencedProfileId,
        uint256 referencedContentId,
        bytes calldata referenceConditionData,
        uint256 value
    ) internal {
        OspDataTypes.ContentStruct storage referencedContent = _getContentStorage()
            ._contentByIdByProfile[referencedProfileId][referencedContentId];

        // Because contentId is a Hash in the offChainServer, not an increment.
        // We cannot use the contentCount of the Profile here to determine whether the article exists.
        if (
            bytes(referencedContent.contentURI).length != 0 ||
            referencedContent.referencedProfileId != 0
        ) {
            address referenceCondition = referencedContent.referenceCondition;
            if (referenceCondition != address(0)) {
                IReferenceCondition(referenceCondition).processReactionReference{value: value}(
                    profileId,
                    communityId,
                    referencedProfileId,
                    referencedContentId,
                    referenceConditionData
                );
            }
        } else {
            revert OspErrors.ContentDoesNotExist();
        }
    }

    function _validateCallerIsJoinCommunity(uint256 profileId, uint256 communityId) internal view {
        if (communityId != 0) {
            address owner = _ownerOf(profileId);
            address joinNFT = _getCommunityStorage()._communityById[communityId].joinNFT;
            if (joinNFT == address(0)) {
                revert OspErrors.InvalidCommunityId();
            }
            uint256 isJoin = IERC721(joinNFT).balanceOf(owner);
            if (isJoin == 0) {
                revert OspErrors.NotJoinCommunity();
            }
        }
    }

    function _validateActivity(uint256 communityId, address owner, uint256 profileId) internal {
        address activityCondition = _getCommunityStorage()
            ._communityById[communityId]
            .activityCondition;
        if (activityCondition == address(0)) return;
        IActivityCondition(activityCondition).processActivity(communityId, owner, profileId);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Context.sol)

pragma solidity ^0.8.20;
import {Initializable} from "../proxy/utils/Initializable.sol";

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract ContextUpgradeable is Initializable {
    function __Context_init() internal onlyInitializing {
    }

    function __Context_init_unchained() internal onlyInitializing {
    }
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: Apache-2.0
pragma solidity ^0.8.0;

/// @author thirdweb

import "../interface/IContractMetadata.sol";

/**
 *  @author  thirdweb.com
 *
 *  @title   Contract Metadata
 *  @notice  Thirdweb's `ContractMetadata` is a contract extension for any base contracts. It lets you set a metadata URI
 *           for you contract.
 *           Additionally, `ContractMetadata` is necessary for NFT contracts that want royalties to get distributed on OpenSea.
 */

library ContractMetadataStorage {
    /// @custom:storage-location erc7201:contract.metadata.storage
    /// @dev keccak256(abi.encode(uint256(keccak256("contract.metadata.storage")) - 1)) & ~bytes32(uint256(0xff))
    bytes32 public constant CONTRACT_METADATA_STORAGE_POSITION =
        0x4bc804ba64359c0e35e5ed5d90ee596ecaa49a3a930ddcb1470ea0dd625da900;

    struct Data {
        /// @notice Returns the contract metadata URI.
        string contractURI;
    }

    function data() internal pure returns (Data storage data_) {
        bytes32 position = CONTRACT_METADATA_STORAGE_POSITION;
        assembly {
            data_.slot := position
        }
    }
}

abstract contract ContractMetadata is IContractMetadata {
    /**
     *  @notice         Lets a contract admin set the URI for contract-level metadata.
     *  @dev            Caller should be authorized to setup contractURI, e.g. contract admin.
     *                  See {_canSetContractURI}.
     *                  Emits {ContractURIUpdated Event}.
     *
     *  @param _uri     keccak256 hash of the role. e.g. keccak256("TRANSFER_ROLE")
     */
    function setContractURI(string memory _uri) external override {
        if (!_canSetContractURI()) {
            revert("Not authorized");
        }

        _setupContractURI(_uri);
    }

    /// @dev Lets a contract admin set the URI for contract-level metadata.
    function _setupContractURI(string memory _uri) internal {
        string memory prevURI = _contractMetadataStorage().contractURI;
        _contractMetadataStorage().contractURI = _uri;

        emit ContractURIUpdated(prevURI, _uri);
    }

    /// @notice Returns the contract metadata URI.
    function contractURI() public view virtual override returns (string memory) {
        return _contractMetadataStorage().contractURI;
    }

    /// @dev Returns the AccountPermissions storage.
    function _contractMetadataStorage() internal pure returns (ContractMetadataStorage.Data storage data) {
        data = ContractMetadataStorage.data();
    }

    /// @dev Returns whether contract metadata can be set in the given execution context.
    function _canSetContractURI() internal view virtual returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/cryptography/ECDSA.sol)

pragma solidity ^0.8.20;

/**
 * @dev Elliptic Curve Digital Signature Algorithm (ECDSA) operations.
 *
 * These functions can be used to verify that a message was signed by the holder
 * of the private keys of a given address.
 */
library ECDSA {
    enum RecoverError {
        NoError,
        InvalidSignature,
        InvalidSignatureLength,
        InvalidSignatureS
    }

    /**
     * @dev The signature derives the `address(0)`.
     */
    error ECDSAInvalidSignature();

    /**
     * @dev The signature has an invalid length.
     */
    error ECDSAInvalidSignatureLength(uint256 length);

    /**
     * @dev The signature has an S value that is in the upper half order.
     */
    error ECDSAInvalidSignatureS(bytes32 s);

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with `signature` or an error. This will not
     * return address(0) without also returning an error description. Errors are documented using an enum (error type)
     * and a bytes32 providing additional information about the error.
     *
     * If no error is returned, then the address can be used for verification purposes.
     *
     * The `ecrecover` EVM precompile allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {MessageHashUtils-toEthSignedMessageHash} on it.
     *
     * Documentation for signature generation:
     * - with https://web3js.readthedocs.io/en/v1.3.4/web3-eth-accounts.html#sign[Web3.js]
     * - with https://docs.ethers.io/v5/api/signer/#Signer-signMessage[ethers]
     */
    function tryRecover(bytes32 hash, bytes memory signature) internal pure returns (address, RecoverError, bytes32) {
        if (signature.length == 65) {
            bytes32 r;
            bytes32 s;
            uint8 v;
            // ecrecover takes the signature parameters, and the only way to get them
            // currently is to use assembly.
            /// @solidity memory-safe-assembly
            assembly {
                r := mload(add(signature, 0x20))
                s := mload(add(signature, 0x40))
                v := byte(0, mload(add(signature, 0x60)))
            }
            return tryRecover(hash, v, r, s);
        } else {
            return (address(0), RecoverError.InvalidSignatureLength, bytes32(signature.length));
        }
    }

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with
     * `signature`. This address can then be used for verification purposes.
     *
     * The `ecrecover` EVM precompile allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {MessageHashUtils-toEthSignedMessageHash} on it.
     */
    function recover(bytes32 hash, bytes memory signature) internal pure returns (address) {
        (address recovered, RecoverError error, bytes32 errorArg) = tryRecover(hash, signature);
        _throwError(error, errorArg);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `r` and `vs` short-signature fields separately.
     *
     * See https://eips.ethereum.org/EIPS/eip-2098[EIP-2098 short signatures]
     */
    function tryRecover(bytes32 hash, bytes32 r, bytes32 vs) internal pure returns (address, RecoverError, bytes32) {
        unchecked {
            bytes32 s = vs & bytes32(0x7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff);
            // We do not check for an overflow here since the shift operation results in 0 or 1.
            uint8 v = uint8((uint256(vs) >> 255) + 27);
            return tryRecover(hash, v, r, s);
        }
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `r and `vs` short-signature fields separately.
     */
    function recover(bytes32 hash, bytes32 r, bytes32 vs) internal pure returns (address) {
        (address recovered, RecoverError error, bytes32 errorArg) = tryRecover(hash, r, vs);
        _throwError(error, errorArg);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `v`,
     * `r` and `s` signature fields separately.
     */
    function tryRecover(
        bytes32 hash,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal pure returns (address, RecoverError, bytes32) {
        // EIP-2 still allows signature malleability for ecrecover(). Remove this possibility and make the signature
        // unique. Appendix F in the Ethereum Yellow paper (https://ethereum.github.io/yellowpaper/paper.pdf), defines
        // the valid range for s in (301): 0 < s < secp256k1n ÷ 2 + 1, and for v in (302): v ∈ {27, 28}. Most
        // signatures from current libraries generate a unique signature with an s-value in the lower half order.
        //
        // If your library generates malleable signatures, such as s-values in the upper range, calculate a new s-value
        // with 0xFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFEBAAEDCE6AF48A03BBFD25E8CD0364141 - s1 and flip v from 27 to 28 or
        // vice versa. If your library also generates signatures with 0/1 for v instead 27/28, add 27 to v to accept
        // these malleable signatures as well.
        if (uint256(s) > 0x7FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF5D576E7357A4501DDFE92F46681B20A0) {
            return (address(0), RecoverError.InvalidSignatureS, s);
        }

        // If the signature is valid (and not malleable), return the signer address
        address signer = ecrecover(hash, v, r, s);
        if (signer == address(0)) {
            return (address(0), RecoverError.InvalidSignature, bytes32(0));
        }

        return (signer, RecoverError.NoError, bytes32(0));
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `v`,
     * `r` and `s` signature fields separately.
     */
    function recover(bytes32 hash, uint8 v, bytes32 r, bytes32 s) internal pure returns (address) {
        (address recovered, RecoverError error, bytes32 errorArg) = tryRecover(hash, v, r, s);
        _throwError(error, errorArg);
        return recovered;
    }

    /**
     * @dev Optionally reverts with the corresponding custom error according to the `error` argument provided.
     */
    function _throwError(RecoverError error, bytes32 errorArg) private pure {
        if (error == RecoverError.NoError) {
            return; // no error: do nothing
        } else if (error == RecoverError.InvalidSignature) {
            revert ECDSAInvalidSignature();
        } else if (error == RecoverError.InvalidSignatureLength) {
            revert ECDSAInvalidSignatureLength(uint256(errorArg));
        } else if (error == RecoverError.InvalidSignatureS) {
            revert ECDSAInvalidSignatureS(errorArg);
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.20;

import '../../libraries/OspDataTypes.sol';
import '../../libraries/OspErrors.sol';
import '@openzeppelin/contracts/utils/cryptography/SignatureChecker.sol';

/**
 * @title EIP712Base
 * @author OpenSocial Protocol
 * @dev This contract is EIP712 implementation.
 * See https://eips.ethereum.org/EIPS/eip-712
 */
abstract contract EIP712Base {
    using SignatureChecker for address;
    bytes32 internal constant EIP712_REVISION_HASH = keccak256('1');

    /**
     * @dev Wrapper for ecrecover to reduce code size, used in meta-tx specific functions.
     */
    function _validateRecoveredAddress(
        bytes32 digest,
        OspDataTypes.EIP712Signature calldata sig
    ) internal view {
        if (sig.deadline < block.timestamp) revert OspErrors.SignatureExpired();
        if (!sig.signer.isValidSignatureNow(digest, sig.signature)) {
            revert OspErrors.SignatureInvalid();
        }
    }

    /**
     * @dev Calculates EIP712 DOMAIN_SEPARATOR based on the current contract and chain ID.
     */
    function _calculateDomainSeparator() internal view virtual returns (bytes32);

    /**
     * @dev Calculates EIP712 digest based on the current DOMAIN_SEPARATOR.
     *
     * @param hashedMessage The message hash from which the digest should be calculated.
     *
     * @return bytes32 A 32-byte output representing the EIP712 digest.
     */
    function _calculateDigest(bytes32 hashedMessage) internal view returns (bytes32) {
        bytes32 digest;
        unchecked {
            digest = keccak256(
                abi.encodePacked('\x19\x01', _calculateDomainSeparator(), hashedMessage)
            );
        }
        return digest;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/ERC165.sol)

pragma solidity ^0.8.20;

import {IERC165} from "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/ERC165Checker.sol)

pragma solidity ^0.8.20;

import {IERC165} from "./IERC165.sol";

/**
 * @dev Library used to query support of an interface declared via {IERC165}.
 *
 * Note that these functions return the actual result of the query: they do not
 * `revert` if an interface is not supported. It is up to the caller to decide
 * what to do in these cases.
 */
library ERC165Checker {
    // As per the EIP-165 spec, no interface should ever match 0xffffffff
    bytes4 private constant INTERFACE_ID_INVALID = 0xffffffff;

    /**
     * @dev Returns true if `account` supports the {IERC165} interface.
     */
    function supportsERC165(address account) internal view returns (bool) {
        // Any contract that implements ERC165 must explicitly indicate support of
        // InterfaceId_ERC165 and explicitly indicate non-support of InterfaceId_Invalid
        return
            supportsERC165InterfaceUnchecked(account, type(IERC165).interfaceId) &&
            !supportsERC165InterfaceUnchecked(account, INTERFACE_ID_INVALID);
    }

    /**
     * @dev Returns true if `account` supports the interface defined by
     * `interfaceId`. Support for {IERC165} itself is queried automatically.
     *
     * See {IERC165-supportsInterface}.
     */
    function supportsInterface(address account, bytes4 interfaceId) internal view returns (bool) {
        // query support of both ERC165 as per the spec and support of _interfaceId
        return supportsERC165(account) && supportsERC165InterfaceUnchecked(account, interfaceId);
    }

    /**
     * @dev Returns a boolean array where each value corresponds to the
     * interfaces passed in and whether they're supported or not. This allows
     * you to batch check interfaces for a contract where your expectation
     * is that some interfaces may not be supported.
     *
     * See {IERC165-supportsInterface}.
     */
    function getSupportedInterfaces(
        address account,
        bytes4[] memory interfaceIds
    ) internal view returns (bool[] memory) {
        // an array of booleans corresponding to interfaceIds and whether they're supported or not
        bool[] memory interfaceIdsSupported = new bool[](interfaceIds.length);

        // query support of ERC165 itself
        if (supportsERC165(account)) {
            // query support of each interface in interfaceIds
            for (uint256 i = 0; i < interfaceIds.length; i++) {
                interfaceIdsSupported[i] = supportsERC165InterfaceUnchecked(account, interfaceIds[i]);
            }
        }

        return interfaceIdsSupported;
    }

    /**
     * @dev Returns true if `account` supports all the interfaces defined in
     * `interfaceIds`. Support for {IERC165} itself is queried automatically.
     *
     * Batch-querying can lead to gas savings by skipping repeated checks for
     * {IERC165} support.
     *
     * See {IERC165-supportsInterface}.
     */
    function supportsAllInterfaces(address account, bytes4[] memory interfaceIds) internal view returns (bool) {
        // query support of ERC165 itself
        if (!supportsERC165(account)) {
            return false;
        }

        // query support of each interface in interfaceIds
        for (uint256 i = 0; i < interfaceIds.length; i++) {
            if (!supportsERC165InterfaceUnchecked(account, interfaceIds[i])) {
                return false;
            }
        }

        // all interfaces supported
        return true;
    }

    /**
     * @notice Query if a contract implements an interface, does not check ERC165 support
     * @param account The address of the contract to query for support of an interface
     * @param interfaceId The interface identifier, as specified in ERC-165
     * @return true if the contract at account indicates support of the interface with
     * identifier interfaceId, false otherwise
     * @dev Assumes that account contains a contract that supports ERC165, otherwise
     * the behavior of this method is undefined. This precondition can be checked
     * with {supportsERC165}.
     *
     * Some precompiled contracts will falsely indicate support for a given interface, so caution
     * should be exercised when using this function.
     *
     * Interface identification is specified in ERC-165.
     */
    function supportsERC165InterfaceUnchecked(address account, bytes4 interfaceId) internal view returns (bool) {
        // prepare call
        bytes memory encodedParams = abi.encodeCall(IERC165.supportsInterface, (interfaceId));

        // perform static call
        bool success;
        uint256 returnSize;
        uint256 returnValue;
        assembly {
            success := staticcall(30000, account, add(encodedParams, 0x20), mload(encodedParams), 0x00, 0x20)
            returnSize := returndatasize()
            returnValue := mload(0x00)
        }

        return success && returnSize >= 0x20 && returnValue > 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/ERC165.sol)

pragma solidity ^0.8.20;

import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
import {Initializable} from "../../proxy/utils/Initializable.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 */
abstract contract ERC165Upgradeable is Initializable, IERC165 {
    function __ERC165_init() internal onlyInitializing {
    }

    function __ERC165_init_unchained() internal onlyInitializing {
    }
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (proxy/ERC1967/ERC1967Proxy.sol)

pragma solidity ^0.8.20;

import {Proxy} from "../Proxy.sol";
import {ERC1967Utils} from "./ERC1967Utils.sol";

/**
 * @dev This contract implements an upgradeable proxy. It is upgradeable because calls are delegated to an
 * implementation address that can be changed. This address is stored in storage in the location specified by
 * https://eips.ethereum.org/EIPS/eip-1967[EIP1967], so that it doesn't conflict with the storage layout of the
 * implementation behind the proxy.
 */
contract ERC1967Proxy is Proxy {
    /**
     * @dev Initializes the upgradeable proxy with an initial implementation specified by `implementation`.
     *
     * If `_data` is nonempty, it's used as data in a delegate call to `implementation`. This will typically be an
     * encoded function call, and allows initializing the storage of the proxy like a Solidity constructor.
     *
     * Requirements:
     *
     * - If `data` is empty, `msg.value` must be zero.
     */
    constructor(address implementation, bytes memory _data) payable {
        ERC1967Utils.upgradeToAndCall(implementation, _data);
    }

    /**
     * @dev Returns the current implementation address.
     *
     * TIP: To get this value clients can read directly from the storage slot shown below (specified by EIP1967) using
     * the https://eth.wiki/json-rpc/API#eth_getstorageat[`eth_getStorageAt`] RPC call.
     * `0x360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc`
     */
    function _implementation() internal view virtual override returns (address) {
        return ERC1967Utils.getImplementation();
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (proxy/ERC1967/ERC1967Utils.sol)

pragma solidity ^0.8.20;

import {IBeacon} from "../beacon/IBeacon.sol";
import {Address} from "../../utils/Address.sol";
import {StorageSlot} from "../../utils/StorageSlot.sol";

/**
 * @dev This abstract contract provides getters and event emitting update functions for
 * https://eips.ethereum.org/EIPS/eip-1967[EIP1967] slots.
 */
library ERC1967Utils {
    // We re-declare ERC-1967 events here because they can't be used directly from IERC1967.
    // This will be fixed in Solidity 0.8.21. At that point we should remove these events.
    /**
     * @dev Emitted when the implementation is upgraded.
     */
    event Upgraded(address indexed implementation);

    /**
     * @dev Emitted when the admin account has changed.
     */
    event AdminChanged(address previousAdmin, address newAdmin);

    /**
     * @dev Emitted when the beacon is changed.
     */
    event BeaconUpgraded(address indexed beacon);

    /**
     * @dev Storage slot with the address of the current implementation.
     * This is the keccak-256 hash of "eip1967.proxy.implementation" subtracted by 1.
     */
    // solhint-disable-next-line private-vars-leading-underscore
    bytes32 internal constant IMPLEMENTATION_SLOT = 0x360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc;

    /**
     * @dev The `implementation` of the proxy is invalid.
     */
    error ERC1967InvalidImplementation(address implementation);

    /**
     * @dev The `admin` of the proxy is invalid.
     */
    error ERC1967InvalidAdmin(address admin);

    /**
     * @dev The `beacon` of the proxy is invalid.
     */
    error ERC1967InvalidBeacon(address beacon);

    /**
     * @dev An upgrade function sees `msg.value > 0` that may be lost.
     */
    error ERC1967NonPayable();

    /**
     * @dev Returns the current implementation address.
     */
    function getImplementation() internal view returns (address) {
        return StorageSlot.getAddressSlot(IMPLEMENTATION_SLOT).value;
    }

    /**
     * @dev Stores a new address in the EIP1967 implementation slot.
     */
    function _setImplementation(address newImplementation) private {
        if (newImplementation.code.length == 0) {
            revert ERC1967InvalidImplementation(newImplementation);
        }
        StorageSlot.getAddressSlot(IMPLEMENTATION_SLOT).value = newImplementation;
    }

    /**
     * @dev Performs implementation upgrade with additional setup call if data is nonempty.
     * This function is payable only if the setup call is performed, otherwise `msg.value` is rejected
     * to avoid stuck value in the contract.
     *
     * Emits an {IERC1967-Upgraded} event.
     */
    function upgradeToAndCall(address newImplementation, bytes memory data) internal {
        _setImplementation(newImplementation);
        emit Upgraded(newImplementation);

        if (data.length > 0) {
            Address.functionDelegateCall(newImplementation, data);
        } else {
            _checkNonPayable();
        }
    }

    /**
     * @dev Storage slot with the admin of the contract.
     * This is the keccak-256 hash of "eip1967.proxy.admin" subtracted by 1.
     */
    // solhint-disable-next-line private-vars-leading-underscore
    bytes32 internal constant ADMIN_SLOT = 0xb53127684a568b3173ae13b9f8a6016e243e63b6e8ee1178d6a717850b5d6103;

    /**
     * @dev Returns the current admin.
     *
     * TIP: To get this value clients can read directly from the storage slot shown below (specified by EIP1967) using
     * the https://eth.wiki/json-rpc/API#eth_getstorageat[`eth_getStorageAt`] RPC call.
     * `0xb53127684a568b3173ae13b9f8a6016e243e63b6e8ee1178d6a717850b5d6103`
     */
    function getAdmin() internal view returns (address) {
        return StorageSlot.getAddressSlot(ADMIN_SLOT).value;
    }

    /**
     * @dev Stores a new address in the EIP1967 admin slot.
     */
    function _setAdmin(address newAdmin) private {
        if (newAdmin == address(0)) {
            revert ERC1967InvalidAdmin(address(0));
        }
        StorageSlot.getAddressSlot(ADMIN_SLOT).value = newAdmin;
    }

    /**
     * @dev Changes the admin of the proxy.
     *
     * Emits an {IERC1967-AdminChanged} event.
     */
    function changeAdmin(address newAdmin) internal {
        emit AdminChanged(getAdmin(), newAdmin);
        _setAdmin(newAdmin);
    }

    /**
     * @dev The storage slot of the UpgradeableBeacon contract which defines the implementation for this proxy.
     * This is the keccak-256 hash of "eip1967.proxy.beacon" subtracted by 1.
     */
    // solhint-disable-next-line private-vars-leading-underscore
    bytes32 internal constant BEACON_SLOT = 0xa3f0ad74e5423aebfd80d3ef4346578335a9a72aeaee59ff6cb3582b35133d50;

    /**
     * @dev Returns the current beacon.
     */
    function getBeacon() internal view returns (address) {
        return StorageSlot.getAddressSlot(BEACON_SLOT).value;
    }

    /**
     * @dev Stores a new beacon in the EIP1967 beacon slot.
     */
    function _setBeacon(address newBeacon) private {
        if (newBeacon.code.length == 0) {
            revert ERC1967InvalidBeacon(newBeacon);
        }

        StorageSlot.getAddressSlot(BEACON_SLOT).value = newBeacon;

        address beaconImplementation = IBeacon(newBeacon).implementation();
        if (beaconImplementation.code.length == 0) {
            revert ERC1967InvalidImplementation(beaconImplementation);
        }
    }

    /**
     * @dev Change the beacon and trigger a setup call if data is nonempty.
     * This function is payable only if the setup call is performed, otherwise `msg.value` is rejected
     * to avoid stuck value in the contract.
     *
     * Emits an {IERC1967-BeaconUpgraded} event.
     *
     * CAUTION: Invoking this function has no effect on an instance of {BeaconProxy} since v5, since
     * it uses an immutable beacon without looking at the value of the ERC-1967 beacon slot for
     * efficiency.
     */
    function upgradeBeaconToAndCall(address newBeacon, bytes memory data) internal {
        _setBeacon(newBeacon);
        emit BeaconUpgraded(newBeacon);

        if (data.length > 0) {
            Address.functionDelegateCall(IBeacon(newBeacon).implementation(), data);
        } else {
            _checkNonPayable();
        }
    }

    /**
     * @dev Reverts if `msg.value` is not zero. It can be used to avoid `msg.value` stuck in the contract
     * if an upgrade doesn't perform an initialization call.
     */
    function _checkNonPayable() private {
        if (msg.value > 0) {
            revert ERC1967NonPayable();
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.20;

import {OspErrors} from '../../../libraries/OspErrors.sol';
import {FeeConditionBase} from '../FeeConditionBase.sol';
import {JoinConditionBase} from '../../base/JoinConditionBase.sol';
import {IERC20} from '@openzeppelin/contracts/token/ERC20/IERC20.sol';
import {SafeERC20} from '@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol';

/**
 * @param currency The address of the ERC20 token to be used for the fee.
 * @param amount The amount of the ERC20 token to be used for the fee.
 * @param recipient The address of the recipient of the fee.
 */
struct CommunityData {
    address currency;
    uint256 amount;
    address recipient;
}

/**
 * @title ERC20FeeJoinCond
 * @author OpenSocial
 * @notice The condition allows users to join a community by paying a fee in ERC20 tokens.
 */
contract ERC20FeeJoinCond is FeeConditionBase, JoinConditionBase {
    using SafeERC20 for IERC20;

    mapping(uint256 => CommunityData) internal _dataByCommunity;

    constructor(address osp) JoinConditionBase(osp) {}

    /**
     * @dev Initializes the condition data for a given community.
     */
    function _initializeCommunityJoinCondition(
        uint256 communityId,
        bytes calldata data
    ) internal override {
        (address currency, uint256 amount, address recipient) = abi.decode(
            data,
            (address, uint256, address)
        );
        if (!_tokenWhitelisted(currency) || recipient == address(0) || amount == 0)
            revert OspErrors.InitParamsInvalid();
        _dataByCommunity[communityId].amount = amount;
        _dataByCommunity[communityId].currency = currency;
        _dataByCommunity[communityId].recipient = recipient;
    }

    /**
     * @dev process join,transfer ERC20 token to recipient.
     */
    function _processJoin(
        address follower,
        uint256 communityId,
        bytes calldata data
    ) internal override nonPayable {
        uint256 amount = _dataByCommunity[communityId].amount;
        address currency = _dataByCommunity[communityId].currency;
        _validateDataIsExpected(data, currency, amount);
        IERC20(currency).safeTransferFrom(
            follower,
            _dataByCommunity[communityId].recipient,
            amount
        );
    }

    /**
     * @dev Returns the community data for a given community, or an empty struct if that community was not initialized
     * with this condition.
     */
    function getCommunityData(uint256 communityId) external view returns (CommunityData memory) {
        return _dataByCommunity[communityId];
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/common/ERC2981.sol)

pragma solidity ^0.8.20;

import {IERC2981} from "@openzeppelin/contracts/interfaces/IERC2981.sol";
import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
import {ERC165Upgradeable} from "../../utils/introspection/ERC165Upgradeable.sol";
import {Initializable} from "../../proxy/utils/Initializable.sol";

/**
 * @dev Implementation of the NFT Royalty Standard, a standardized way to retrieve royalty payment information.
 *
 * Royalty information can be specified globally for all token ids via {_setDefaultRoyalty}, and/or individually for
 * specific token ids via {_setTokenRoyalty}. The latter takes precedence over the first.
 *
 * Royalty is specified as a fraction of sale price. {_feeDenominator} is overridable but defaults to 10000, meaning the
 * fee is specified in basis points by default.
 *
 * IMPORTANT: ERC-2981 only specifies a way to signal royalty information and does not enforce its payment. See
 * https://eips.ethereum.org/EIPS/eip-2981#optional-royalty-payments[Rationale] in the EIP. Marketplaces are expected to
 * voluntarily pay royalties together with sales, but note that this standard is not yet widely supported.
 */
abstract contract ERC2981Upgradeable is Initializable, IERC2981, ERC165Upgradeable {
    struct RoyaltyInfo {
        address receiver;
        uint96 royaltyFraction;
    }

    /// @custom:storage-location erc7201:openzeppelin.storage.ERC2981
    struct ERC2981Storage {
        RoyaltyInfo _defaultRoyaltyInfo;
        mapping(uint256 tokenId => RoyaltyInfo) _tokenRoyaltyInfo;
    }

    // keccak256(abi.encode(uint256(keccak256("openzeppelin.storage.ERC2981")) - 1)) & ~bytes32(uint256(0xff))
    bytes32 private constant ERC2981StorageLocation = 0xdaedc9ab023613a7caf35e703657e986ccfad7e3eb0af93a2853f8d65dd86b00;

    function _getERC2981Storage() private pure returns (ERC2981Storage storage $) {
        assembly {
            $.slot := ERC2981StorageLocation
        }
    }

    /**
     * @dev The default royalty set is invalid (eg. (numerator / denominator) >= 1).
     */
    error ERC2981InvalidDefaultRoyalty(uint256 numerator, uint256 denominator);

    /**
     * @dev The default royalty receiver is invalid.
     */
    error ERC2981InvalidDefaultRoyaltyReceiver(address receiver);

    /**
     * @dev The royalty set for an specific `tokenId` is invalid (eg. (numerator / denominator) >= 1).
     */
    error ERC2981InvalidTokenRoyalty(uint256 tokenId, uint256 numerator, uint256 denominator);

    /**
     * @dev The royalty receiver for `tokenId` is invalid.
     */
    error ERC2981InvalidTokenRoyaltyReceiver(uint256 tokenId, address receiver);

    function __ERC2981_init() internal onlyInitializing {
    }

    function __ERC2981_init_unchained() internal onlyInitializing {
    }
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(IERC165, ERC165Upgradeable) returns (bool) {
        return interfaceId == type(IERC2981).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @inheritdoc IERC2981
     */
    function royaltyInfo(uint256 tokenId, uint256 salePrice) public view virtual returns (address, uint256) {
        ERC2981Storage storage $ = _getERC2981Storage();
        RoyaltyInfo memory royalty = $._tokenRoyaltyInfo[tokenId];

        if (royalty.receiver == address(0)) {
            royalty = $._defaultRoyaltyInfo;
        }

        uint256 royaltyAmount = (salePrice * royalty.royaltyFraction) / _feeDenominator();

        return (royalty.receiver, royaltyAmount);
    }

    /**
     * @dev The denominator with which to interpret the fee set in {_setTokenRoyalty} and {_setDefaultRoyalty} as a
     * fraction of the sale price. Defaults to 10000 so fees are expressed in basis points, but may be customized by an
     * override.
     */
    function _feeDenominator() internal pure virtual returns (uint96) {
        return 10000;
    }

    /**
     * @dev Sets the royalty information that all ids in this contract will default to.
     *
     * Requirements:
     *
     * - `receiver` cannot be the zero address.
     * - `feeNumerator` cannot be greater than the fee denominator.
     */
    function _setDefaultRoyalty(address receiver, uint96 feeNumerator) internal virtual {
        ERC2981Storage storage $ = _getERC2981Storage();
        uint256 denominator = _feeDenominator();
        if (feeNumerator > denominator) {
            // Royalty fee will exceed the sale price
            revert ERC2981InvalidDefaultRoyalty(feeNumerator, denominator);
        }
        if (receiver == address(0)) {
            revert ERC2981InvalidDefaultRoyaltyReceiver(address(0));
        }

        $._defaultRoyaltyInfo = RoyaltyInfo(receiver, feeNumerator);
    }

    /**
     * @dev Removes default royalty information.
     */
    function _deleteDefaultRoyalty() internal virtual {
        ERC2981Storage storage $ = _getERC2981Storage();
        delete $._defaultRoyaltyInfo;
    }

    /**
     * @dev Sets the royalty information for a specific token id, overriding the global default.
     *
     * Requirements:
     *
     * - `receiver` cannot be the zero address.
     * - `feeNumerator` cannot be greater than the fee denominator.
     */
    function _setTokenRoyalty(uint256 tokenId, address receiver, uint96 feeNumerator) internal virtual {
        ERC2981Storage storage $ = _getERC2981Storage();
        uint256 denominator = _feeDenominator();
        if (feeNumerator > denominator) {
            // Royalty fee will exceed the sale price
            revert ERC2981InvalidTokenRoyalty(tokenId, feeNumerator, denominator);
        }
        if (receiver == address(0)) {
            revert ERC2981InvalidTokenRoyaltyReceiver(tokenId, address(0));
        }

        $._tokenRoyaltyInfo[tokenId] = RoyaltyInfo(receiver, feeNumerator);
    }

    /**
     * @dev Resets royalty information for the token id back to the global default.
     */
    function _resetTokenRoyalty(uint256 tokenId) internal virtual {
        ERC2981Storage storage $ = _getERC2981Storage();
        delete $._tokenRoyaltyInfo[tokenId];
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.20;

/* solhint-disable no-empty-blocks */

import {IERC165} from '@openzeppelin/contracts/utils/introspection/IERC165.sol';
import {IERC721Receiver} from '@openzeppelin/contracts/token/ERC721/IERC721Receiver.sol';
import {IERC1155Receiver} from '@openzeppelin/contracts/token/ERC1155/IERC1155Receiver.sol';
import {OspErrors} from '../../libraries/OspErrors.sol';
import {OspClient} from '../logics/interfaces/OspClient.sol';
import {IERC721} from '@openzeppelin/contracts/token/ERC721/IERC721.sol';

contract ERC6551Account is IERC721Receiver, IERC1155Receiver {
    struct Execution {
        // The target contract for account to execute.
        address target;
        // The value for the execution.
        uint256 value;
        // The call data for the execution.
        bytes data;
    }

    address immutable OSP;

    uint256 public tokenId;

    constructor(address osp) {
        OSP = osp;
    }

    /**
     * @dev initialize communityId, only callable by OSP
     */
    function initialize(uint256 communityId) external {
        if (msg.sender != OSP) revert OspErrors.NotOSP();
        tokenId = communityId;
    }

    /**
     * @dev For previous TBA accounts，initialize communityId.
     */
    function setCommunityId(uint256 communityId) external {
        if (tokenId == 0 && OspClient(OSP).getCommunityAccount(communityId) == address(this)) {
            tokenId = communityId;
            return;
        }
        revert OspErrors.InitParamsInvalid();
    }

    /// @notice Executes a transaction from the account
    /// @param execution The execution to perform
    /// @return result The result of the execution
    function execute(
        Execution calldata execution
    ) public payable virtual returns (bytes memory result) {
        _onlyOwner(msg.sender);
        result = _exec(execution.target, execution.value, execution.data);
    }

    /// @notice Executes a batch of transactions from the account
    /// @dev If any of the transactions revert, the entire batch reverts
    /// @param executions The executions to perform
    /// @return results The results of the executions
    function executeBatch(
        Execution[] calldata executions
    ) public payable virtual returns (bytes[] memory results) {
        _onlyOwner(msg.sender);
        uint256 executionsLength = executions.length;
        results = new bytes[](executionsLength);

        for (uint256 i = 0; i < executionsLength; ) {
            results[i] = _exec(executions[i].target, executions[i].value, executions[i].data);
            unchecked {
                ++i;
            }
        }
    }

    function onERC721Received(
        address,
        address,
        uint256,
        bytes calldata
    ) external pure override returns (bytes4) {
        return IERC721Receiver.onERC721Received.selector;
    }

    function onERC1155Received(
        address,
        address,
        uint256,
        uint256,
        bytes calldata
    ) external pure override returns (bytes4) {
        return IERC1155Receiver.onERC1155Received.selector;
    }

    function onERC1155BatchReceived(
        address,
        address,
        uint256[] calldata,
        uint256[] calldata,
        bytes calldata
    ) external pure override returns (bytes4) {
        return IERC1155Receiver.onERC1155BatchReceived.selector;
    }

    function supportsInterface(bytes4 interfaceId) external view virtual override returns (bool) {
        return
            interfaceId == type(IERC721Receiver).interfaceId ||
            interfaceId == type(IERC1155Receiver).interfaceId ||
            interfaceId == type(IERC165).interfaceId;
    }

    function _exec(
        address target,
        uint256 value,
        bytes memory data
    ) internal returns (bytes memory result) {
        bool success;
        (success, result) = target.call{value: value}(data);

        if (!success) {
            // Directly bubble up revert messages
            assembly ('memory-safe') {
                revert(add(result, 32), mload(result))
            }
        }
    }

    function _onlyOwner(address account) internal view {
        if (account != IERC721(OspClient(OSP).getCommunityNFT()).ownerOf(tokenId))
            revert OspErrors.NotCommunityOwner();
    }

    // solhint-disable-next-line no-empty-blocks
    receive() external payable {}
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC721/extensions/ERC721Burnable.sol)

pragma solidity ^0.8.20;

import {ERC721Upgradeable} from "../ERC721Upgradeable.sol";
import {ContextUpgradeable} from "../../../utils/ContextUpgradeable.sol";
import {Initializable} from "../../../proxy/utils/Initializable.sol";

/**
 * @title ERC721 Burnable Token
 * @dev ERC721 Token that can be burned (destroyed).
 */
abstract contract ERC721BurnableUpgradeable is Initializable, ContextUpgradeable, ERC721Upgradeable {
    function __ERC721Burnable_init() internal onlyInitializing {
    }

    function __ERC721Burnable_init_unchained() internal onlyInitializing {
    }
    /**
     * @dev Burns `tokenId`. See {ERC721-_burn}.
     *
     * Requirements:
     *
     * - The caller must own `tokenId` or be an approved operator.
     */
    function burn(uint256 tokenId) public virtual {
        // Setting an "auth" arguments enables the `_isAuthorized` check which verifies that the token exists
        // (from != 0). Therefore, it is not needed to verify that the return value is not 0 here.
        _update(address(0), tokenId, _msgSender());
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC721/extensions/ERC721Enumerable.sol)

pragma solidity ^0.8.20;

import {ERC721Upgradeable} from "../ERC721Upgradeable.sol";
import {IERC721Enumerable} from "@openzeppelin/contracts/token/ERC721/extensions/IERC721Enumerable.sol";
import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
import {Initializable} from "../../../proxy/utils/Initializable.sol";

/**
 * @dev This implements an optional extension of {ERC721} defined in the EIP that adds enumerability
 * of all the token ids in the contract as well as all token ids owned by each account.
 *
 * CAUTION: `ERC721` extensions that implement custom `balanceOf` logic, such as `ERC721Consecutive`,
 * interfere with enumerability and should not be used together with `ERC721Enumerable`.
 */
abstract contract ERC721EnumerableUpgradeable is Initializable, ERC721Upgradeable, IERC721Enumerable {
    /// @custom:storage-location erc7201:openzeppelin.storage.ERC721Enumerable
    struct ERC721EnumerableStorage {
        mapping(address owner => mapping(uint256 index => uint256)) _ownedTokens;
        mapping(uint256 tokenId => uint256) _ownedTokensIndex;

        uint256[] _allTokens;
        mapping(uint256 tokenId => uint256) _allTokensIndex;
    }

    // keccak256(abi.encode(uint256(keccak256("openzeppelin.storage.ERC721Enumerable")) - 1)) & ~bytes32(uint256(0xff))
    bytes32 private constant ERC721EnumerableStorageLocation = 0x645e039705490088daad89bae25049a34f4a9072d398537b1ab2425f24cbed00;

    function _getERC721EnumerableStorage() private pure returns (ERC721EnumerableStorage storage $) {
        assembly {
            $.slot := ERC721EnumerableStorageLocation
        }
    }

    /**
     * @dev An `owner`'s token query was out of bounds for `index`.
     *
     * NOTE: The owner being `address(0)` indicates a global out of bounds index.
     */
    error ERC721OutOfBoundsIndex(address owner, uint256 index);

    /**
     * @dev Batch mint is not allowed.
     */
    error ERC721EnumerableForbiddenBatchMint();

    function __ERC721Enumerable_init() internal onlyInitializing {
    }

    function __ERC721Enumerable_init_unchained() internal onlyInitializing {
    }
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(IERC165, ERC721Upgradeable) returns (bool) {
        return interfaceId == type(IERC721Enumerable).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev See {IERC721Enumerable-tokenOfOwnerByIndex}.
     */
    function tokenOfOwnerByIndex(address owner, uint256 index) public view virtual returns (uint256) {
        ERC721EnumerableStorage storage $ = _getERC721EnumerableStorage();
        if (index >= balanceOf(owner)) {
            revert ERC721OutOfBoundsIndex(owner, index);
        }
        return $._ownedTokens[owner][index];
    }

    /**
     * @dev See {IERC721Enumerable-totalSupply}.
     */
    function totalSupply() public view virtual returns (uint256) {
        ERC721EnumerableStorage storage $ = _getERC721EnumerableStorage();
        return $._allTokens.length;
    }

    /**
     * @dev See {IERC721Enumerable-tokenByIndex}.
     */
    function tokenByIndex(uint256 index) public view virtual returns (uint256) {
        ERC721EnumerableStorage storage $ = _getERC721EnumerableStorage();
        if (index >= totalSupply()) {
            revert ERC721OutOfBoundsIndex(address(0), index);
        }
        return $._allTokens[index];
    }

    /**
     * @dev See {ERC721-_update}.
     */
    function _update(address to, uint256 tokenId, address auth) internal virtual override returns (address) {
        address previousOwner = super._update(to, tokenId, auth);

        if (previousOwner == address(0)) {
            _addTokenToAllTokensEnumeration(tokenId);
        } else if (previousOwner != to) {
            _removeTokenFromOwnerEnumeration(previousOwner, tokenId);
        }
        if (to == address(0)) {
            _removeTokenFromAllTokensEnumeration(tokenId);
        } else if (previousOwner != to) {
            _addTokenToOwnerEnumeration(to, tokenId);
        }

        return previousOwner;
    }

    /**
     * @dev Private function to add a token to this extension's ownership-tracking data structures.
     * @param to address representing the new owner of the given token ID
     * @param tokenId uint256 ID of the token to be added to the tokens list of the given address
     */
    function _addTokenToOwnerEnumeration(address to, uint256 tokenId) private {
        ERC721EnumerableStorage storage $ = _getERC721EnumerableStorage();
        uint256 length = balanceOf(to) - 1;
        $._ownedTokens[to][length] = tokenId;
        $._ownedTokensIndex[tokenId] = length;
    }

    /**
     * @dev Private function to add a token to this extension's token tracking data structures.
     * @param tokenId uint256 ID of the token to be added to the tokens list
     */
    function _addTokenToAllTokensEnumeration(uint256 tokenId) private {
        ERC721EnumerableStorage storage $ = _getERC721EnumerableStorage();
        $._allTokensIndex[tokenId] = $._allTokens.length;
        $._allTokens.push(tokenId);
    }

    /**
     * @dev Private function to remove a token from this extension's ownership-tracking data structures. Note that
     * while the token is not assigned a new owner, the `_ownedTokensIndex` mapping is _not_ updated: this allows for
     * gas optimizations e.g. when performing a transfer operation (avoiding double writes).
     * This has O(1) time complexity, but alters the order of the _ownedTokens array.
     * @param from address representing the previous owner of the given token ID
     * @param tokenId uint256 ID of the token to be removed from the tokens list of the given address
     */
    function _removeTokenFromOwnerEnumeration(address from, uint256 tokenId) private {
        ERC721EnumerableStorage storage $ = _getERC721EnumerableStorage();
        // To prevent a gap in from's tokens array, we store the last token in the index of the token to delete, and
        // then delete the last slot (swap and pop).

        uint256 lastTokenIndex = balanceOf(from);
        uint256 tokenIndex = $._ownedTokensIndex[tokenId];

        // When the token to delete is the last token, the swap operation is unnecessary
        if (tokenIndex != lastTokenIndex) {
            uint256 lastTokenId = $._ownedTokens[from][lastTokenIndex];

            $._ownedTokens[from][tokenIndex] = lastTokenId; // Move the last token to the slot of the to-delete token
            $._ownedTokensIndex[lastTokenId] = tokenIndex; // Update the moved token's index
        }

        // This also deletes the contents at the last position of the array
        delete $._ownedTokensIndex[tokenId];
        delete $._ownedTokens[from][lastTokenIndex];
    }

    /**
     * @dev Private function to remove a token from this extension's token tracking data structures.
     * This has O(1) time complexity, but alters the order of the _allTokens array.
     * @param tokenId uint256 ID of the token to be removed from the tokens list
     */
    function _removeTokenFromAllTokensEnumeration(uint256 tokenId) private {
        ERC721EnumerableStorage storage $ = _getERC721EnumerableStorage();
        // To prevent a gap in the tokens array, we store the last token in the index of the token to delete, and
        // then delete the last slot (swap and pop).

        uint256 lastTokenIndex = $._allTokens.length - 1;
        uint256 tokenIndex = $._allTokensIndex[tokenId];

        // When the token to delete is the last token, the swap operation is unnecessary. However, since this occurs so
        // rarely (when the last minted token is burnt) that we still do the swap here to avoid the gas cost of adding
        // an 'if' statement (like in _removeTokenFromOwnerEnumeration)
        uint256 lastTokenId = $._allTokens[lastTokenIndex];

        $._allTokens[tokenIndex] = lastTokenId; // Move the last token to the slot of the to-delete token
        $._allTokensIndex[lastTokenId] = tokenIndex; // Update the moved token's index

        // This also deletes the contents at the last position of the array
        delete $._allTokensIndex[tokenId];
        $._allTokens.pop();
    }

    /**
     * See {ERC721-_increaseBalance}. We need that to account tokens that were minted in batch
     */
    function _increaseBalance(address account, uint128 amount) internal virtual override {
        if (amount > 0) {
            revert ERC721EnumerableForbiddenBatchMint();
        }
        super._increaseBalance(account, amount);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC721/ERC721.sol)

pragma solidity ^0.8.20;

import {IERC721} from "@openzeppelin/contracts/token/ERC721/IERC721.sol";
import {IERC721Receiver} from "@openzeppelin/contracts/token/ERC721/IERC721Receiver.sol";
import {IERC721Metadata} from "@openzeppelin/contracts/token/ERC721/extensions/IERC721Metadata.sol";
import {ContextUpgradeable} from "../../utils/ContextUpgradeable.sol";
import {Strings} from "@openzeppelin/contracts/utils/Strings.sol";
import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
import {ERC165Upgradeable} from "../../utils/introspection/ERC165Upgradeable.sol";
import {IERC721Errors} from "@openzeppelin/contracts/interfaces/draft-IERC6093.sol";
import {Initializable} from "../../proxy/utils/Initializable.sol";

/**
 * @dev Implementation of https://eips.ethereum.org/EIPS/eip-721[ERC721] Non-Fungible Token Standard, including
 * the Metadata extension, but not including the Enumerable extension, which is available separately as
 * {ERC721Enumerable}.
 */
abstract contract ERC721Upgradeable is Initializable, ContextUpgradeable, ERC165Upgradeable, IERC721, IERC721Metadata, IERC721Errors {
    using Strings for uint256;

    /// @custom:storage-location erc7201:openzeppelin.storage.ERC721
    struct ERC721Storage {
        // Token name
        string _name;

        // Token symbol
        string _symbol;

        mapping(uint256 tokenId => address) _owners;

        mapping(address owner => uint256) _balances;

        mapping(uint256 tokenId => address) _tokenApprovals;

        mapping(address owner => mapping(address operator => bool)) _operatorApprovals;
    }

    // keccak256(abi.encode(uint256(keccak256("openzeppelin.storage.ERC721")) - 1)) & ~bytes32(uint256(0xff))
    bytes32 private constant ERC721StorageLocation = 0x80bb2b638cc20bc4d0a60d66940f3ab4a00c1d7b313497ca82fb0b4ab0079300;

    function _getERC721Storage() private pure returns (ERC721Storage storage $) {
        assembly {
            $.slot := ERC721StorageLocation
        }
    }

    /**
     * @dev Initializes the contract by setting a `name` and a `symbol` to the token collection.
     */
    function __ERC721_init(string memory name_, string memory symbol_) internal onlyInitializing {
        __ERC721_init_unchained(name_, symbol_);
    }

    function __ERC721_init_unchained(string memory name_, string memory symbol_) internal onlyInitializing {
        ERC721Storage storage $ = _getERC721Storage();
        $._name = name_;
        $._symbol = symbol_;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(ERC165Upgradeable, IERC165) returns (bool) {
        return
            interfaceId == type(IERC721).interfaceId ||
            interfaceId == type(IERC721Metadata).interfaceId ||
            super.supportsInterface(interfaceId);
    }

    /**
     * @dev See {IERC721-balanceOf}.
     */
    function balanceOf(address owner) public view virtual returns (uint256) {
        ERC721Storage storage $ = _getERC721Storage();
        if (owner == address(0)) {
            revert ERC721InvalidOwner(address(0));
        }
        return $._balances[owner];
    }

    /**
     * @dev See {IERC721-ownerOf}.
     */
    function ownerOf(uint256 tokenId) public view virtual returns (address) {
        return _requireOwned(tokenId);
    }

    /**
     * @dev See {IERC721Metadata-name}.
     */
    function name() public view virtual returns (string memory) {
        ERC721Storage storage $ = _getERC721Storage();
        return $._name;
    }

    /**
     * @dev See {IERC721Metadata-symbol}.
     */
    function symbol() public view virtual returns (string memory) {
        ERC721Storage storage $ = _getERC721Storage();
        return $._symbol;
    }

    /**
     * @dev See {IERC721Metadata-tokenURI}.
     */
    function tokenURI(uint256 tokenId) public view virtual returns (string memory) {
        _requireOwned(tokenId);

        string memory baseURI = _baseURI();
        return bytes(baseURI).length > 0 ? string.concat(baseURI, tokenId.toString()) : "";
    }

    /**
     * @dev Base URI for computing {tokenURI}. If set, the resulting URI for each
     * token will be the concatenation of the `baseURI` and the `tokenId`. Empty
     * by default, can be overridden in child contracts.
     */
    function _baseURI() internal view virtual returns (string memory) {
        return "";
    }

    /**
     * @dev See {IERC721-approve}.
     */
    function approve(address to, uint256 tokenId) public virtual {
        _approve(to, tokenId, _msgSender());
    }

    /**
     * @dev See {IERC721-getApproved}.
     */
    function getApproved(uint256 tokenId) public view virtual returns (address) {
        _requireOwned(tokenId);

        return _getApproved(tokenId);
    }

    /**
     * @dev See {IERC721-setApprovalForAll}.
     */
    function setApprovalForAll(address operator, bool approved) public virtual {
        _setApprovalForAll(_msgSender(), operator, approved);
    }

    /**
     * @dev See {IERC721-isApprovedForAll}.
     */
    function isApprovedForAll(address owner, address operator) public view virtual returns (bool) {
        ERC721Storage storage $ = _getERC721Storage();
        return $._operatorApprovals[owner][operator];
    }

    /**
     * @dev See {IERC721-transferFrom}.
     */
    function transferFrom(address from, address to, uint256 tokenId) public virtual {
        if (to == address(0)) {
            revert ERC721InvalidReceiver(address(0));
        }
        // Setting an "auth" arguments enables the `_isAuthorized` check which verifies that the token exists
        // (from != 0). Therefore, it is not needed to verify that the return value is not 0 here.
        address previousOwner = _update(to, tokenId, _msgSender());
        if (previousOwner != from) {
            revert ERC721IncorrectOwner(from, tokenId, previousOwner);
        }
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId) public {
        safeTransferFrom(from, to, tokenId, "");
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId, bytes memory data) public virtual {
        transferFrom(from, to, tokenId);
        _checkOnERC721Received(from, to, tokenId, data);
    }

    /**
     * @dev Returns the owner of the `tokenId`. Does NOT revert if token doesn't exist
     *
     * IMPORTANT: Any overrides to this function that add ownership of tokens not tracked by the
     * core ERC721 logic MUST be matched with the use of {_increaseBalance} to keep balances
     * consistent with ownership. The invariant to preserve is that for any address `a` the value returned by
     * `balanceOf(a)` must be equal to the number of tokens such that `_ownerOf(tokenId)` is `a`.
     */
    function _ownerOf(uint256 tokenId) internal view virtual returns (address) {
        ERC721Storage storage $ = _getERC721Storage();
        return $._owners[tokenId];
    }

    /**
     * @dev Returns the approved address for `tokenId`. Returns 0 if `tokenId` is not minted.
     */
    function _getApproved(uint256 tokenId) internal view virtual returns (address) {
        ERC721Storage storage $ = _getERC721Storage();
        return $._tokenApprovals[tokenId];
    }

    /**
     * @dev Returns whether `spender` is allowed to manage `owner`'s tokens, or `tokenId` in
     * particular (ignoring whether it is owned by `owner`).
     *
     * WARNING: This function assumes that `owner` is the actual owner of `tokenId` and does not verify this
     * assumption.
     */
    function _isAuthorized(address owner, address spender, uint256 tokenId) internal view virtual returns (bool) {
        return
            spender != address(0) &&
            (owner == spender || isApprovedForAll(owner, spender) || _getApproved(tokenId) == spender);
    }

    /**
     * @dev Checks if `spender` can operate on `tokenId`, assuming the provided `owner` is the actual owner.
     * Reverts if `spender` does not have approval from the provided `owner` for the given token or for all its assets
     * the `spender` for the specific `tokenId`.
     *
     * WARNING: This function assumes that `owner` is the actual owner of `tokenId` and does not verify this
     * assumption.
     */
    function _checkAuthorized(address owner, address spender, uint256 tokenId) internal view virtual {
        if (!_isAuthorized(owner, spender, tokenId)) {
            if (owner == address(0)) {
                revert ERC721NonexistentToken(tokenId);
            } else {
                revert ERC721InsufficientApproval(spender, tokenId);
            }
        }
    }

    /**
     * @dev Unsafe write access to the balances, used by extensions that "mint" tokens using an {ownerOf} override.
     *
     * NOTE: the value is limited to type(uint128).max. This protect against _balance overflow. It is unrealistic that
     * a uint256 would ever overflow from increments when these increments are bounded to uint128 values.
     *
     * WARNING: Increasing an account's balance using this function tends to be paired with an override of the
     * {_ownerOf} function to resolve the ownership of the corresponding tokens so that balances and ownership
     * remain consistent with one another.
     */
    function _increaseBalance(address account, uint128 value) internal virtual {
        ERC721Storage storage $ = _getERC721Storage();
        unchecked {
            $._balances[account] += value;
        }
    }

    /**
     * @dev Transfers `tokenId` from its current owner to `to`, or alternatively mints (or burns) if the current owner
     * (or `to`) is the zero address. Returns the owner of the `tokenId` before the update.
     *
     * The `auth` argument is optional. If the value passed is non 0, then this function will check that
     * `auth` is either the owner of the token, or approved to operate on the token (by the owner).
     *
     * Emits a {Transfer} event.
     *
     * NOTE: If overriding this function in a way that tracks balances, see also {_increaseBalance}.
     */
    function _update(address to, uint256 tokenId, address auth) internal virtual returns (address) {
        ERC721Storage storage $ = _getERC721Storage();
        address from = _ownerOf(tokenId);

        // Perform (optional) operator check
        if (auth != address(0)) {
            _checkAuthorized(from, auth, tokenId);
        }

        // Execute the update
        if (from != address(0)) {
            // Clear approval. No need to re-authorize or emit the Approval event
            _approve(address(0), tokenId, address(0), false);

            unchecked {
                $._balances[from] -= 1;
            }
        }

        if (to != address(0)) {
            unchecked {
                $._balances[to] += 1;
            }
        }

        $._owners[tokenId] = to;

        emit Transfer(from, to, tokenId);

        return from;
    }

    /**
     * @dev Mints `tokenId` and transfers it to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {_safeMint} whenever possible
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - `to` cannot be the zero address.
     *
     * Emits a {Transfer} event.
     */
    function _mint(address to, uint256 tokenId) internal {
        if (to == address(0)) {
            revert ERC721InvalidReceiver(address(0));
        }
        address previousOwner = _update(to, tokenId, address(0));
        if (previousOwner != address(0)) {
            revert ERC721InvalidSender(address(0));
        }
    }

    /**
     * @dev Mints `tokenId`, transfers it to `to` and checks for `to` acceptance.
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeMint(address to, uint256 tokenId) internal {
        _safeMint(to, tokenId, "");
    }

    /**
     * @dev Same as {xref-ERC721-_safeMint-address-uint256-}[`_safeMint`], with an additional `data` parameter which is
     * forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
     */
    function _safeMint(address to, uint256 tokenId, bytes memory data) internal virtual {
        _mint(to, tokenId);
        _checkOnERC721Received(address(0), to, tokenId, data);
    }

    /**
     * @dev Destroys `tokenId`.
     * The approval is cleared when the token is burned.
     * This is an internal function that does not check if the sender is authorized to operate on the token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     *
     * Emits a {Transfer} event.
     */
    function _burn(uint256 tokenId) internal {
        address previousOwner = _update(address(0), tokenId, address(0));
        if (previousOwner == address(0)) {
            revert ERC721NonexistentToken(tokenId);
        }
    }

    /**
     * @dev Transfers `tokenId` from `from` to `to`.
     *  As opposed to {transferFrom}, this imposes no restrictions on msg.sender.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     *
     * Emits a {Transfer} event.
     */
    function _transfer(address from, address to, uint256 tokenId) internal {
        if (to == address(0)) {
            revert ERC721InvalidReceiver(address(0));
        }
        address previousOwner = _update(to, tokenId, address(0));
        if (previousOwner == address(0)) {
            revert ERC721NonexistentToken(tokenId);
        } else if (previousOwner != from) {
            revert ERC721IncorrectOwner(from, tokenId, previousOwner);
        }
    }

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking that contract recipients
     * are aware of the ERC721 standard to prevent tokens from being forever locked.
     *
     * `data` is additional data, it has no specified format and it is sent in call to `to`.
     *
     * This internal function is like {safeTransferFrom} in the sense that it invokes
     * {IERC721Receiver-onERC721Received} on the receiver, and can be used to e.g.
     * implement alternative mechanisms to perform token transfer, such as signature-based.
     *
     * Requirements:
     *
     * - `tokenId` token must exist and be owned by `from`.
     * - `to` cannot be the zero address.
     * - `from` cannot be the zero address.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeTransfer(address from, address to, uint256 tokenId) internal {
        _safeTransfer(from, to, tokenId, "");
    }

    /**
     * @dev Same as {xref-ERC721-_safeTransfer-address-address-uint256-}[`_safeTransfer`], with an additional `data` parameter which is
     * forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
     */
    function _safeTransfer(address from, address to, uint256 tokenId, bytes memory data) internal virtual {
        _transfer(from, to, tokenId);
        _checkOnERC721Received(from, to, tokenId, data);
    }

    /**
     * @dev Approve `to` to operate on `tokenId`
     *
     * The `auth` argument is optional. If the value passed is non 0, then this function will check that `auth` is
     * either the owner of the token, or approved to operate on all tokens held by this owner.
     *
     * Emits an {Approval} event.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address to, uint256 tokenId, address auth) internal {
        _approve(to, tokenId, auth, true);
    }

    /**
     * @dev Variant of `_approve` with an optional flag to enable or disable the {Approval} event. The event is not
     * emitted in the context of transfers.
     */
    function _approve(address to, uint256 tokenId, address auth, bool emitEvent) internal virtual {
        ERC721Storage storage $ = _getERC721Storage();
        // Avoid reading the owner unless necessary
        if (emitEvent || auth != address(0)) {
            address owner = _requireOwned(tokenId);

            // We do not use _isAuthorized because single-token approvals should not be able to call approve
            if (auth != address(0) && owner != auth && !isApprovedForAll(owner, auth)) {
                revert ERC721InvalidApprover(auth);
            }

            if (emitEvent) {
                emit Approval(owner, to, tokenId);
            }
        }

        $._tokenApprovals[tokenId] = to;
    }

    /**
     * @dev Approve `operator` to operate on all of `owner` tokens
     *
     * Requirements:
     * - operator can't be the address zero.
     *
     * Emits an {ApprovalForAll} event.
     */
    function _setApprovalForAll(address owner, address operator, bool approved) internal virtual {
        ERC721Storage storage $ = _getERC721Storage();
        if (operator == address(0)) {
            revert ERC721InvalidOperator(operator);
        }
        $._operatorApprovals[owner][operator] = approved;
        emit ApprovalForAll(owner, operator, approved);
    }

    /**
     * @dev Reverts if the `tokenId` doesn't have a current owner (it hasn't been minted, or it has been burned).
     * Returns the owner.
     *
     * Overrides to ownership logic should be done to {_ownerOf}.
     */
    function _requireOwned(uint256 tokenId) internal view returns (address) {
        address owner = _ownerOf(tokenId);
        if (owner == address(0)) {
            revert ERC721NonexistentToken(tokenId);
        }
        return owner;
    }

    /**
     * @dev Private function to invoke {IERC721Receiver-onERC721Received} on a target address. This will revert if the
     * recipient doesn't accept the token transfer. The call is not executed if the target address is not a contract.
     *
     * @param from address representing the previous owner of the given token ID
     * @param to target address that will receive the tokens
     * @param tokenId uint256 ID of the token to be transferred
     * @param data bytes optional data to send along with the call
     */
    function _checkOnERC721Received(address from, address to, uint256 tokenId, bytes memory data) private {
        if (to.code.length > 0) {
            try IERC721Receiver(to).onERC721Received(_msgSender(), from, tokenId, data) returns (bytes4 retval) {
                if (retval != IERC721Receiver.onERC721Received.selector) {
                    revert ERC721InvalidReceiver(to);
                }
            } catch (bytes memory reason) {
                if (reason.length == 0) {
                    revert ERC721InvalidReceiver(to);
                } else {
                    /// @solidity memory-safe-assembly
                    assembly {
                        revert(add(32, reason), mload(reason))
                    }
                }
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/structs/EnumerableSet.sol)
// This file was procedurally generated from scripts/generate/templates/EnumerableSet.js.

pragma solidity ^0.8.20;

/**
 * @dev Library for managing
 * https://en.wikipedia.org/wiki/Set_(abstract_data_type)[sets] of primitive
 * types.
 *
 * Sets have the following properties:
 *
 * - Elements are added, removed, and checked for existence in constant time
 * (O(1)).
 * - Elements are enumerated in O(n). No guarantees are made on the ordering.
 *
 * ```solidity
 * contract Example {
 *     // Add the library methods
 *     using EnumerableSet for EnumerableSet.AddressSet;
 *
 *     // Declare a set state variable
 *     EnumerableSet.AddressSet private mySet;
 * }
 * ```
 *
 * As of v3.3.0, sets of type `bytes32` (`Bytes32Set`), `address` (`AddressSet`)
 * and `uint256` (`UintSet`) are supported.
 *
 * [WARNING]
 * ====
 * Trying to delete such a structure from storage will likely result in data corruption, rendering the structure
 * unusable.
 * See https://github.com/ethereum/solidity/pull/11843[ethereum/solidity#11843] for more info.
 *
 * In order to clean an EnumerableSet, you can either remove all elements one by one or create a fresh instance using an
 * array of EnumerableSet.
 * ====
 */
library EnumerableSet {
    // To implement this library for multiple types with as little code
    // repetition as possible, we write it in terms of a generic Set type with
    // bytes32 values.
    // The Set implementation uses private functions, and user-facing
    // implementations (such as AddressSet) are just wrappers around the
    // underlying Set.
    // This means that we can only create new EnumerableSets for types that fit
    // in bytes32.

    struct Set {
        // Storage of set values
        bytes32[] _values;
        // Position is the index of the value in the `values` array plus 1.
        // Position 0 is used to mean a value is not in the set.
        mapping(bytes32 value => uint256) _positions;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function _add(Set storage set, bytes32 value) private returns (bool) {
        if (!_contains(set, value)) {
            set._values.push(value);
            // The value is stored at length-1, but we add 1 to all indexes
            // and use 0 as a sentinel value
            set._positions[value] = set._values.length;
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function _remove(Set storage set, bytes32 value) private returns (bool) {
        // We cache the value's position to prevent multiple reads from the same storage slot
        uint256 position = set._positions[value];

        if (position != 0) {
            // Equivalent to contains(set, value)
            // To delete an element from the _values array in O(1), we swap the element to delete with the last one in
            // the array, and then remove the last element (sometimes called as 'swap and pop').
            // This modifies the order of the array, as noted in {at}.

            uint256 valueIndex = position - 1;
            uint256 lastIndex = set._values.length - 1;

            if (valueIndex != lastIndex) {
                bytes32 lastValue = set._values[lastIndex];

                // Move the lastValue to the index where the value to delete is
                set._values[valueIndex] = lastValue;
                // Update the tracked position of the lastValue (that was just moved)
                set._positions[lastValue] = position;
            }

            // Delete the slot where the moved value was stored
            set._values.pop();

            // Delete the tracked position for the deleted slot
            delete set._positions[value];

            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function _contains(Set storage set, bytes32 value) private view returns (bool) {
        return set._positions[value] != 0;
    }

    /**
     * @dev Returns the number of values on the set. O(1).
     */
    function _length(Set storage set) private view returns (uint256) {
        return set._values.length;
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function _at(Set storage set, uint256 index) private view returns (bytes32) {
        return set._values[index];
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function _values(Set storage set) private view returns (bytes32[] memory) {
        return set._values;
    }

    // Bytes32Set

    struct Bytes32Set {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _add(set._inner, value);
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _remove(set._inner, value);
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(Bytes32Set storage set, bytes32 value) internal view returns (bool) {
        return _contains(set._inner, value);
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(Bytes32Set storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(Bytes32Set storage set, uint256 index) internal view returns (bytes32) {
        return _at(set._inner, index);
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(Bytes32Set storage set) internal view returns (bytes32[] memory) {
        bytes32[] memory store = _values(set._inner);
        bytes32[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }

    // AddressSet

    struct AddressSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(AddressSet storage set, address value) internal returns (bool) {
        return _add(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(AddressSet storage set, address value) internal returns (bool) {
        return _remove(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(AddressSet storage set, address value) internal view returns (bool) {
        return _contains(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(AddressSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(AddressSet storage set, uint256 index) internal view returns (address) {
        return address(uint160(uint256(_at(set._inner, index))));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(AddressSet storage set) internal view returns (address[] memory) {
        bytes32[] memory store = _values(set._inner);
        address[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }

    // UintSet

    struct UintSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(UintSet storage set, uint256 value) internal returns (bool) {
        return _add(set._inner, bytes32(value));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(UintSet storage set, uint256 value) internal returns (bool) {
        return _remove(set._inner, bytes32(value));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(UintSet storage set, uint256 value) internal view returns (bool) {
        return _contains(set._inner, bytes32(value));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(UintSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(UintSet storage set, uint256 index) internal view returns (uint256) {
        return uint256(_at(set._inner, index));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(UintSet storage set) internal view returns (uint256[] memory) {
        bytes32[] memory store = _values(set._inner);
        uint256[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.20;

import {OspContext} from '../../core/base/OspContext.sol';
import {CondErrors} from './libraries/CondErrors.sol';
import {IGovernanceLogic} from '../logics/interfaces/IGovernanceLogic.sol';

/**
 * @title FeeConditionBase
 * @author OpenSocial Protocol
 *
 * @dev This is an abstract contract to be inherited from by conditions that require basic fee functionality. It
 * contains getters for condition globals parameters as well as a validation function to check expected data.
 */
abstract contract FeeConditionBase is OspContext {
    function _validateDataIsExpected(
        bytes calldata data,
        address currency,
        uint256 amount
    ) internal pure {
        (address decodedCurrency, uint256 decodedAmount) = abi.decode(data, (address, uint256));
        if (decodedAmount != amount || decodedCurrency != currency)
            revert CondErrors.ConditionDataMismatch();
    }

    function _tokenWhitelisted(address token) internal view returns (bool) {
        return IGovernanceLogic(OSP).isTokenWhitelisted(token);
    }
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.20;

import {IERC721} from '@openzeppelin/contracts/token/ERC721/IERC721.sol';
import {CommunityCondBase} from '../../base/CommunityCondBase.sol';
import {Payment} from '../../../libraries/Payment.sol';
import {ECDSA} from '@openzeppelin/contracts/utils/cryptography/ECDSA.sol';
import {CondErrors} from '../libraries/CondErrors.sol';
import {CondDataTypes} from '../libraries/CondDataTypes.sol';
import {CondHelpers} from '../libraries/CondHelpers.sol';

/**
 * @title FixedFeeCommunityCond
 * @author OpenSocial Protocol
 *
 * @dev This contract specifies that pay the specified amount of ETH to create the community.
 * The amount of ETH paid is related to the handle length of the community.
 */
contract FixedFeeCommunityCond is CommunityCondBase {
    event FixFeeCondDataSet(CondDataTypes.FixedFeeCondData data, uint256 timestamp);
    event FixFeePaid(address indexed to, uint256 price, string handle, uint256 timestamp);

    CondDataTypes.FixedFeeCondData public fixedFeeCondData;

    constructor(address osp) CommunityCondBase(osp) {}

    /**
     * @dev process create community,if the slotNFT is used, revert.
     */
    function _processCreateCommunity(
        address to,
        string calldata handle,
        bytes calldata /*data*/
    ) internal override {
        /// @dev if createStartTime is not set, indicates no initialization.
        if (
            block.timestamp < fixedFeeCondData.createStartTime ||
            fixedFeeCondData.createStartTime == 0
        ) {
            revert CondErrors.NotCreateTime();
        }
        uint256 price = CondHelpers.getHandleETHPrice(handle, fixedFeeCondData);
        _charge(price, to);
        emit FixFeePaid(to, price, handle, block.timestamp);
    }

    function setFixedFeeCondData(
        CondDataTypes.FixedFeeCondData calldata data
    ) external onlyOperation {
        fixedFeeCondData = CondDataTypes.FixedFeeCondData({
            price1Letter: data.price1Letter,
            price2Letter: data.price2Letter,
            price3Letter: data.price3Letter,
            price4Letter: data.price4Letter,
            price5Letter: data.price5Letter,
            price6Letter: data.price6Letter,
            price7ToMoreLetter: data.price7ToMoreLetter,
            createStartTime: data.createStartTime
        });
        emit FixFeeCondDataSet(data, block.timestamp);
    }

    /**
     * @dev Get the handle price based on the length of the handle.
     */
    function getHandlePrice(string calldata handle) external view returns (uint256) {
        return CondHelpers.getHandleETHPrice(handle, fixedFeeCondData);
    }

    function _charge(uint256 price, address to) internal virtual {
        if (msg.value < price) {
            revert CondErrors.InsufficientPayment();
        }
        uint256 overpayment;
        unchecked {
            overpayment = msg.value - price;
        }
        if (overpayment > 0) {
            Payment.payNative(to, overpayment);
        }
        address treasure = OSP.getTreasureAddress();
        require(treasure != address(0), 'Invalid treasure');
        Payment.payNative(treasure, price);
    }
}