// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
import {Pausable} from "@openzeppelin/contracts/utils/Pausable.sol";

contract DNDArena is Ownable, Pausable {
    struct Arena {
        address creator;
        uint96 bid;
        address acceptor;
        uint96 winner;
    }

    IERC20 public DNDToken;

    uint256 public minBid;

    uint256 public currentArenaId;

    mapping(uint256 => Arena) public arenas;
    mapping(address => uint256[]) public usersToArenaIds;

    event ArenaCreated(uint256 arenaId, address arenaCreator, uint96 bid);
    event ArenaAccepted(uint256 arenaId, address arenaAcceptor);
    event ArenaCanceled(uint256 arenaId);
    event WinnerSet(uint256 arenaId, address winner);

    constructor(address tokenAddress_, uint256 minBid_) Ownable(msg.sender) {
        _setDNDToken(tokenAddress_);

        _setMinBid(minBid_);
    }

    function createArena(uint96 bid_) external whenNotPaused {
        require(bid_ >= minBid, "DNDArena: bid is below the minimal bid");

        DNDToken.transferFrom(msg.sender, address(this), bid_);

        arenas[currentArenaId] = Arena(msg.sender, bid_, address(0), 0);

        usersToArenaIds[msg.sender].push(currentArenaId);

        emit ArenaCreated(currentArenaId++, msg.sender, bid_);
    }

    function acceptArena(uint256 arenaId_) external whenNotPaused {
        Arena memory arena_ = arenas[arenaId_];

        require(arena_.creator != address(0), "DNDArena: arena doesn't exist");
        require(arena_.creator != msg.sender, "DNDArena: you cannot accept your own arena");
        require(arena_.acceptor == address(0), "DNDArena: arena already accepted");

        DNDToken.transferFrom(msg.sender, address(this), arena_.bid);

        arenas[arenaId_].acceptor = msg.sender;

        usersToArenaIds[msg.sender].push(arenaId_);

        emit ArenaAccepted(arenaId_, msg.sender);
    }

    function cancelArena(uint256 arenaId_) external whenNotPaused {
        Arena memory arena_ = arenas[arenaId_];

        require(arena_.creator == msg.sender, "DNDArena: you are not the creator of the arena");
        require(arena_.acceptor == address(0), "DNDArena: arena has been accepted");

        delete arenas[arenaId_];

        uint256[] storage userArenaIds = usersToArenaIds[msg.sender];
        uint256 arenasNumber_ = userArenaIds.length;

        for (uint256 i = 0; i < arenasNumber_; i++) {
            if (userArenaIds[i] == arenaId_) {
                userArenaIds[i] = userArenaIds[arenasNumber_ - 1];

                userArenaIds.pop();

                break;
            }
        }

        DNDToken.transfer(msg.sender, arena_.bid);

        emit ArenaCanceled(arenaId_);
    }

    function setWinner(uint256 arenaId_, address winner_) external onlyOwner whenNotPaused {
        Arena memory arena_ = arenas[arenaId_];

        require(arena_.acceptor != address(0), "DNDArena: arena has not been accepted yet");
        require(arena_.winner == 0, "DNDArena: winner is already set");
        require(
            arena_.creator == winner_ || arena_.acceptor == winner_,
            "DNDArena: invalid winner address"
        );

        arenas[arenaId_].winner = arena_.creator == winner_ ? 1 : 2;

        DNDToken.transfer(winner_, arena_.bid * 2);

        emit WinnerSet(arenaId_, winner_);
    }

    function setDNDToken(address tokenAddress_) external onlyOwner {
        _setDNDToken(tokenAddress_);
    }

    function setMinBid(uint256 minBid_) external onlyOwner {
        _setMinBid(minBid_);
    }

    function pause() external onlyOwner {
        _pause();
    }

    function unpause() external onlyOwner {
        _unpause();
    }

    function getUserArenaIds(address user_) external view returns (uint256[] memory) {
        return usersToArenaIds[user_];
    }

    function getUserArenas(address user_) external view returns (Arena[] memory) {
        uint256[] storage arenaIds = usersToArenaIds[user_];

        Arena[] memory userArenas_ = new Arena[](arenaIds.length);

        for (uint256 i = 0; i < userArenas_.length; i++) {
            userArenas_[i] = arenas[arenaIds[i]];
        }

        return userArenas_;
    }

    function _setDNDToken(address tokenAddress_) private {
        require(tokenAddress_ != address(0), "DNDArena: zero address is not allowed");

        DNDToken = IERC20(tokenAddress_);
    }

    function _setMinBid(uint256 minBid_) private {
        require(minBid_ > 0, "DNDArena: minimal bid amount must be above zero");

        minBid = minBid_;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Pausable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    bool private _paused;

    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    /**
     * @dev The operation failed because the contract is paused.
     */
    error EnforcedPause();

    /**
     * @dev The operation failed because the contract is not paused.
     */
    error ExpectedPause();

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        if (paused()) {
            revert EnforcedPause();
        }
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        if (!paused()) {
            revert ExpectedPause();
        }
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

{
  "compilationTarget": {
    "contracts/DNDArena.sol": "DNDArena"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}