Lucky Ghouls

// SPDX-License-Identifier: AGPL-3.0-only
pragma solidity >=0.8.0;

/// @notice Modern and gas efficient ERC20 + EIP-2612 implementation.
/// @author Solmate (https://github.com/transmissions11/solmate/blob/main/src/tokens/ERC20.sol)
/// @author Modified from Uniswap (https://github.com/Uniswap/uniswap-v2-core/blob/master/contracts/UniswapV2ERC20.sol)
/// @dev Do not manually set balances without updating totalSupply, as the sum of all user balances must not exceed it.
abstract contract ERC20 {
    /*//////////////////////////////////////////////////////////////
                                 EVENTS
    //////////////////////////////////////////////////////////////*/

    event Transfer(address indexed from, address indexed to, uint256 amount);

    event Approval(address indexed owner, address indexed spender, uint256 amount);

    /*//////////////////////////////////////////////////////////////
                            METADATA STORAGE
    //////////////////////////////////////////////////////////////*/

    string public name;

    string public symbol;

    uint8 public immutable decimals;

    /*//////////////////////////////////////////////////////////////
                              ERC20 STORAGE
    //////////////////////////////////////////////////////////////*/

    uint256 public totalSupply;

    mapping(address => uint256) public balanceOf;

    mapping(address => mapping(address => uint256)) public allowance;

    /*//////////////////////////////////////////////////////////////
                            EIP-2612 STORAGE
    //////////////////////////////////////////////////////////////*/

    uint256 internal immutable INITIAL_CHAIN_ID;

    bytes32 internal immutable INITIAL_DOMAIN_SEPARATOR;

    mapping(address => uint256) public nonces;

    /*//////////////////////////////////////////////////////////////
                               CONSTRUCTOR
    //////////////////////////////////////////////////////////////*/

    constructor(
        string memory _name,
        string memory _symbol,
        uint8 _decimals
    ) {
        name = _name;
        symbol = _symbol;
        decimals = _decimals;

        INITIAL_CHAIN_ID = block.chainid;
        INITIAL_DOMAIN_SEPARATOR = computeDomainSeparator();
    }

    /*//////////////////////////////////////////////////////////////
                               ERC20 LOGIC
    //////////////////////////////////////////////////////////////*/

    function approve(address spender, uint256 amount) public virtual returns (bool) {
        allowance[msg.sender][spender] = amount;

        emit Approval(msg.sender, spender, amount);

        return true;
    }

    function transfer(address to, uint256 amount) public virtual returns (bool) {
        balanceOf[msg.sender] -= amount;

        // Cannot overflow because the sum of all user
        // balances can't exceed the max uint256 value.
        unchecked {
            balanceOf[to] += amount;
        }

        emit Transfer(msg.sender, to, amount);

        return true;
    }

    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) public virtual returns (bool) {
        uint256 allowed = allowance[from][msg.sender]; // Saves gas for limited approvals.

        if (allowed != type(uint256).max) allowance[from][msg.sender] = allowed - amount;

        balanceOf[from] -= amount;

        // Cannot overflow because the sum of all user
        // balances can't exceed the max uint256 value.
        unchecked {
            balanceOf[to] += amount;
        }

        emit Transfer(from, to, amount);

        return true;
    }

    /*//////////////////////////////////////////////////////////////
                             EIP-2612 LOGIC
    //////////////////////////////////////////////////////////////*/

    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) public virtual {
        require(deadline >= block.timestamp, "PERMIT_DEADLINE_EXPIRED");

        // Unchecked because the only math done is incrementing
        // the owner's nonce which cannot realistically overflow.
        unchecked {
            address recoveredAddress = ecrecover(
                keccak256(
                    abi.encodePacked(
                        "\x19\x01",
                        DOMAIN_SEPARATOR(),
                        keccak256(
                            abi.encode(
                                keccak256(
                                    "Permit(address owner,address spender,uint256 value,uint256 nonce,uint256 deadline)"
                                ),
                                owner,
                                spender,
                                value,
                                nonces[owner]++,
                                deadline
                            )
                        )
                    )
                ),
                v,
                r,
                s
            );

            require(recoveredAddress != address(0) && recoveredAddress == owner, "INVALID_SIGNER");

            allowance[recoveredAddress][spender] = value;
        }

        emit Approval(owner, spender, value);
    }

    function DOMAIN_SEPARATOR() public view virtual returns (bytes32) {
        return block.chainid == INITIAL_CHAIN_ID ? INITIAL_DOMAIN_SEPARATOR : computeDomainSeparator();
    }

    function computeDomainSeparator() internal view virtual returns (bytes32) {
        return
            keccak256(
                abi.encode(
                    keccak256("EIP712Domain(string name,string version,uint256 chainId,address verifyingContract)"),
                    keccak256(bytes(name)),
                    keccak256("1"),
                    block.chainid,
                    address(this)
                )
            );
    }

    /*//////////////////////////////////////////////////////////////
                        INTERNAL MINT/BURN LOGIC
    //////////////////////////////////////////////////////////////*/

    function _mint(address to, uint256 amount) internal virtual {
        totalSupply += amount;

        // Cannot overflow because the sum of all user
        // balances can't exceed the max uint256 value.
        unchecked {
            balanceOf[to] += amount;
        }

        emit Transfer(address(0), to, amount);
    }

    function _burn(address from, uint256 amount) internal virtual {
        balanceOf[from] -= amount;

        // Cannot underflow because a user's balance
        // will never be larger than the total supply.
        unchecked {
            totalSupply -= amount;
        }

        emit Transfer(from, address(0), amount);
    }
}

// SPDX-License-Identifier: AGPL-3.0-only
pragma solidity >=0.8.0;

/// @notice Modern, minimalist, and gas efficient ERC-721 implementation.
/// @author Solmate (https://github.com/transmissions11/solmate/blob/main/src/tokens/ERC721.sol)
abstract contract ERC721 {
    /*//////////////////////////////////////////////////////////////
                                 EVENTS
    //////////////////////////////////////////////////////////////*/

    event Transfer(address indexed from, address indexed to, uint256 indexed id);

    event Approval(address indexed owner, address indexed spender, uint256 indexed id);

    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /*//////////////////////////////////////////////////////////////
                         METADATA STORAGE/LOGIC
    //////////////////////////////////////////////////////////////*/

    string public name;

    string public symbol;

    function tokenURI(uint256 id) public view virtual returns (string memory);

    /*//////////////////////////////////////////////////////////////
                      ERC721 BALANCE/OWNER STORAGE
    //////////////////////////////////////////////////////////////*/

    mapping(uint256 => address) internal _ownerOf;

    mapping(address => uint256) internal _balanceOf;

    function ownerOf(uint256 id) public view virtual returns (address owner) {
        require((owner = _ownerOf[id]) != address(0), "NOT_MINTED");
    }

    function balanceOf(address owner) public view virtual returns (uint256) {
        require(owner != address(0), "ZERO_ADDRESS");

        return _balanceOf[owner];
    }

    /*//////////////////////////////////////////////////////////////
                         ERC721 APPROVAL STORAGE
    //////////////////////////////////////////////////////////////*/

    mapping(uint256 => address) public getApproved;

    mapping(address => mapping(address => bool)) public isApprovedForAll;

    /*//////////////////////////////////////////////////////////////
                               CONSTRUCTOR
    //////////////////////////////////////////////////////////////*/

    constructor(string memory _name, string memory _symbol) {
        name = _name;
        symbol = _symbol;
    }

    /*//////////////////////////////////////////////////////////////
                              ERC721 LOGIC
    //////////////////////////////////////////////////////////////*/

    function approve(address spender, uint256 id) public virtual {
        address owner = _ownerOf[id];

        require(msg.sender == owner || isApprovedForAll[owner][msg.sender], "NOT_AUTHORIZED");

        getApproved[id] = spender;

        emit Approval(owner, spender, id);
    }

    function setApprovalForAll(address operator, bool approved) public virtual {
        isApprovedForAll[msg.sender][operator] = approved;

        emit ApprovalForAll(msg.sender, operator, approved);
    }

    function transferFrom(
        address from,
        address to,
        uint256 id
    ) public virtual {
        require(from == _ownerOf[id], "WRONG_FROM");

        require(to != address(0), "INVALID_RECIPIENT");

        require(
            msg.sender == from || isApprovedForAll[from][msg.sender] || msg.sender == getApproved[id],
            "NOT_AUTHORIZED"
        );

        // Underflow of the sender's balance is impossible because we check for
        // ownership above and the recipient's balance can't realistically overflow.
        unchecked {
            _balanceOf[from]--;

            _balanceOf[to]++;
        }

        _ownerOf[id] = to;

        delete getApproved[id];

        emit Transfer(from, to, id);
    }

    function safeTransferFrom(
        address from,
        address to,
        uint256 id
    ) public virtual {
        transferFrom(from, to, id);

        require(
            to.code.length == 0 ||
                ERC721TokenReceiver(to).onERC721Received(msg.sender, from, id, "") ==
                ERC721TokenReceiver.onERC721Received.selector,
            "UNSAFE_RECIPIENT"
        );
    }

    function safeTransferFrom(
        address from,
        address to,
        uint256 id,
        bytes calldata data
    ) public virtual {
        transferFrom(from, to, id);

        require(
            to.code.length == 0 ||
                ERC721TokenReceiver(to).onERC721Received(msg.sender, from, id, data) ==
                ERC721TokenReceiver.onERC721Received.selector,
            "UNSAFE_RECIPIENT"
        );
    }

    /*//////////////////////////////////////////////////////////////
                              ERC165 LOGIC
    //////////////////////////////////////////////////////////////*/

    function supportsInterface(bytes4 interfaceId) public view virtual returns (bool) {
        return
            interfaceId == 0x01ffc9a7 || // ERC165 Interface ID for ERC165
            interfaceId == 0x80ac58cd || // ERC165 Interface ID for ERC721
            interfaceId == 0x5b5e139f; // ERC165 Interface ID for ERC721Metadata
    }

    /*//////////////////////////////////////////////////////////////
                        INTERNAL MINT/BURN LOGIC
    //////////////////////////////////////////////////////////////*/

    function _mint(address to, uint256 id) internal virtual {
        require(to != address(0), "INVALID_RECIPIENT");

        require(_ownerOf[id] == address(0), "ALREADY_MINTED");

        // Counter overflow is incredibly unrealistic.
        unchecked {
            _balanceOf[to]++;
        }

        _ownerOf[id] = to;

        emit Transfer(address(0), to, id);
    }

    function _burn(uint256 id) internal virtual {
        address owner = _ownerOf[id];

        require(owner != address(0), "NOT_MINTED");

        // Ownership check above ensures no underflow.
        unchecked {
            _balanceOf[owner]--;
        }

        delete _ownerOf[id];

        delete getApproved[id];

        emit Transfer(owner, address(0), id);
    }

    /*//////////////////////////////////////////////////////////////
                        INTERNAL SAFE MINT LOGIC
    //////////////////////////////////////////////////////////////*/

    function _safeMint(address to, uint256 id) internal virtual {
        _mint(to, id);

        require(
            to.code.length == 0 ||
                ERC721TokenReceiver(to).onERC721Received(msg.sender, address(0), id, "") ==
                ERC721TokenReceiver.onERC721Received.selector,
            "UNSAFE_RECIPIENT"
        );
    }

    function _safeMint(
        address to,
        uint256 id,
        bytes memory data
    ) internal virtual {
        _mint(to, id);

        require(
            to.code.length == 0 ||
                ERC721TokenReceiver(to).onERC721Received(msg.sender, address(0), id, data) ==
                ERC721TokenReceiver.onERC721Received.selector,
            "UNSAFE_RECIPIENT"
        );
    }
}

/// @notice A generic interface for a contract which properly accepts ERC721 tokens.
/// @author Solmate (https://github.com/transmissions11/solmate/blob/main/src/tokens/ERC721.sol)
abstract contract ERC721TokenReceiver {
    function onERC721Received(
        address,
        address,
        uint256,
        bytes calldata
    ) external virtual returns (bytes4) {
        return ERC721TokenReceiver.onERC721Received.selector;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.23;

interface IERC721 {
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    function ownerOf(uint256 tokenId) external view returns (address owner);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.23;

interface ILuckyGhouls {
    function mintsPerWallet(address wallet) external view returns (uint256);

    function setGoldenGhoulMinted() external;

    function goldenGhoulMinted() external view returns (bool);

    function withdrawRecipient() external view returns (address);

    function royaltyRecipient() external view returns (address);

    function isMintedOut() external view returns (bool);

    function PRICE() external view returns (uint256);

    function isEverythingClosed() external view returns (bool);

    function getMintBlockNumber(
        uint256 tokenId
    ) external view returns (uint256);

    function getMintTimestamp(uint256 tokenId) external view returns (uint256);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.23;

interface ILuckyGhoulsBonusSystem {
    struct BonusClaim {
        address tokenAddress;
        uint256 amount;
        uint256 claimedAt;
    }

    function getBonusClaim(
        uint256 tokenId
    ) external view returns (BonusClaim memory);

    function getBonusClaims(
        uint256[] calldata tokenIds
    ) external view returns (BonusClaim[] memory);
}

// SPDX-License-Identifier: MIT
pragma solidity >=0.8.0;

/// @notice Efficient library for creating string representations of integers.
/// @author Solmate (https://github.com/transmissions11/solmate/blob/main/src/utils/LibString.sol)
/// @author Modified from Solady (https://github.com/Vectorized/solady/blob/main/src/utils/LibString.sol)
library LibString {
    function toString(int256 value) internal pure returns (string memory str) {
        if (value >= 0) return toString(uint256(value));

        unchecked {
            str = toString(uint256(-value));

            /// @solidity memory-safe-assembly
            assembly {
                // Note: This is only safe because we over-allocate memory
                // and write the string from right to left in toString(uint256),
                // and thus can be sure that sub(str, 1) is an unused memory location.

                let length := mload(str) // Load the string length.
                // Put the - character at the start of the string contents.
                mstore(str, 45) // 45 is the ASCII code for the - character.
                str := sub(str, 1) // Move back the string pointer by a byte.
                mstore(str, add(length, 1)) // Update the string length.
            }
        }
    }

    function toString(uint256 value) internal pure returns (string memory str) {
        /// @solidity memory-safe-assembly
        assembly {
            // The maximum value of a uint256 contains 78 digits (1 byte per digit), but we allocate 160 bytes
            // to keep the free memory pointer word aligned. We'll need 1 word for the length, 1 word for the
            // trailing zeros padding, and 3 other words for a max of 78 digits. In total: 5 * 32 = 160 bytes.
            let newFreeMemoryPointer := add(mload(0x40), 160)

            // Update the free memory pointer to avoid overriding our string.
            mstore(0x40, newFreeMemoryPointer)

            // Assign str to the end of the zone of newly allocated memory.
            str := sub(newFreeMemoryPointer, 32)

            // Clean the last word of memory it may not be overwritten.
            mstore(str, 0)

            // Cache the end of the memory to calculate the length later.
            let end := str

            // We write the string from rightmost digit to leftmost digit.
            // The following is essentially a do-while loop that also handles the zero case.
            // prettier-ignore
            for { let temp := value } 1 {} {
                // Move the pointer 1 byte to the left.
                str := sub(str, 1)

                // Write the character to the pointer.
                // The ASCII index of the '0' character is 48.
                mstore8(str, add(48, mod(temp, 10)))

                // Keep dividing temp until zero.
                temp := div(temp, 10)

                 // prettier-ignore
                if iszero(temp) { break }
            }

            // Compute and cache the final total length of the string.
            let length := sub(end, str)

            // Move the pointer 32 bytes leftwards to make room for the length.
            str := sub(str, 32)

            // Store the string's length at the start of memory allocated for our string.
            mstore(str, length)
        }
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.23;

//
//                       :::!~!!!!!:.
//                   .xUHWH!! !!?M88WHX:.
//                 .X*#M@$!!  !X!M$$$$$$WWx:.
//                :!!!!!!?H! :!$!$$$$$$$$$$8X:
//               !!~  ~:~!! :~!$!#$$$$$$$$$$8X:
//              :!~::!H!<   ~.U$X!?R$$$$$$$$MM!
//              ~!~!!!!~~ .:XW$$$U!!?$$$$$$RMM!
//                !:~~~ .:!M"T#$$$$WX??#MRRMMM!
//                ~?WuxiW*`   `"#$$$$8!!!!??!!!
//              :X- M$$$$   #   `"T#$T~!8$WUXU~
//             :%`  ~#$$$m:        ~!~ ?$$$$$$
//           :!`.-   ~T$$$$8xx.  .xWW- ~""##*"
//         //~:<` !    ~?T#$$@@W@*?$$  #   /`
//       M! .!~~ !!     .:XUW$W!~ `"~:    :
// #"~~`.:x%`!!  !H:   !WM$$$$Ti.: .!WUn+!`
// :::~:!!`:X~ .: ?H.!u "$$$B$$$!W:U!T$$M~
// .~~   :X@!.-~   ?@WTWo("*$$$W$TH$! `
// Wi.~!X$?!-~    : ?$$$B$Wu("**$RM!
// $R@i.~~ !     :   ~$$$$$B$$en:``
// ?MXT@Wx.~    :~~~  ~"##*$$$$M~
// :W$B$$$W!     :~~~~   ~$$$$~
// ~"T$$$R!      :~~~~~~
// ~#M$$$$$$     ~~~~~~~~
//
// lucky ghouls
// built by based ghouls
// 2025

import {ERC721} from "solmate/src/tokens/ERC721.sol";
import {ERC20} from "solmate/src/tokens/ERC20.sol";
import {LibString} from "solmate/src/utils/LibString.sol";
import {Owned} from "solmate/src/auth/Owned.sol";
import {SafeTransferLib} from "solmate/src/utils/SafeTransferLib.sol";
import {MerkleProofLib} from "solmate/src/utils/MerkleProofLib.sol";
import {ILuckyGhouls} from "./interfaces/ILuckyGhouls.sol";
import {IERC721} from "./interfaces/IERC721.sol";
import {ILuckyGhoulsBonusSystem} from "./interfaces/ILuckyGhoulsBonusSystem.sol";

contract LuckyGhouls is ERC721, Owned, ILuckyGhouls {
    using LibString for uint256;

    uint256 public immutable MAX_SUPPLY;
    uint256 public immutable RESERVED_COUNT;
    uint256 public PRICE;
    uint256 public DISCOUNT_PRICE;
    uint256 public immutable MAX_MINTS_PER_WALLET;
    uint256 public publicMintStart;
    uint256 public currentTokenId;
    uint256 public totalMinted;
    address public immutable withdrawRecipient;
    address public immutable royaltyRecipient;
    uint96 public constant ROYALTY_BPS = 690;
    bool _isClosedOverride;
    bool public goldenGhoulMinted;
    bool public mintingActive;

    ILuckyGhoulsBonusSystem public bonusSystem;
    string public baseUri;

    error ZeroQuantity();
    error ExceedsMaxSupply();
    error InsufficientPayment();
    error EmptyBaseURI();
    error TokenDoesNotExist();
    error MaxSupplyExceeded();
    error InvalidMerkleProof();
    error MaxMintsPerWalletExceeded();
    error NonExistentTokenURI();
    error MintingClosed();
    error Nope();
    error PublicMintNotStarted();
    error MintNotActive();

    bytes32 public discountMerkleRoot;
    bytes32 public freeMerkleRoot;

    mapping(uint256 => uint256) private _mintBlockNumber;
    mapping(uint256 => uint256) public _mintTimestamp;
    mapping(address => bool) public hasUsedSpecialPrice;
    mapping(address => uint256) public mintsPerWallet;
    mapping(address => uint256[]) public lastMintedTokens;

    enum SpecialPriceStatus {
        None, // Not in any list
        Free, // In free list
        Discount // In discount list
    }

    address public authorizedBonusSystem;

    struct MintConfig {
        uint256 totalPrice;
        bool usesSpecialPrice;
        SpecialPriceStatus specialPriceStatus;
        bool hasUsedSpecialPrice;
        uint256 mintsRemaining;
        bool isMintedOut;
        bool isEverythingClosed;
        uint256 remainingSupply;
        bool isPublicMintStarted;
    }

    constructor(
        address _withdrawRecipient,
        address _royaltyRecipient,
        string memory initialBaseUri,
        address owner,
        uint256 maxSupply,
        uint256 reservedCount,
        uint256 price,
        uint256 discountPrice,
        uint256 maxMintsPerWallet
    ) ERC721("Lucky Ghouls", "LCKY") Owned(owner) {
        withdrawRecipient = _withdrawRecipient;
        royaltyRecipient = _royaltyRecipient;
        if (bytes(initialBaseUri).length == 0) revert EmptyBaseURI();
        baseUri = initialBaseUri;
        currentTokenId = 1;

        MAX_SUPPLY = maxSupply;
        RESERVED_COUNT = reservedCount;
        PRICE = price;
        DISCOUNT_PRICE = discountPrice;
        MAX_MINTS_PER_WALLET = maxMintsPerWallet;

        // Mint reserved tokens to the deployer
        for (uint256 i = 0; i < RESERVED_COUNT; i++) {
            uint256 tokenId = MAX_SUPPLY - RESERVED_COUNT + 1 + i;
            _mint(owner, tokenId);
            totalMinted++;
            _mintBlockNumber[tokenId] = block.number;
            _mintTimestamp[tokenId] = block.timestamp;
        }
    }

    modifier validatePayment(uint256 quantity, bytes32[] calldata merkleProof) {
        (uint256 price, bool usesSpecialPrice) = getMintPrice(
            msg.sender,
            quantity,
            merkleProof
        );
        if (msg.value < price) revert InsufficientPayment();
        _;
    }

    modifier validateMint(uint256 quantity, bytes32[] calldata merkleProof) {
        if (isEverythingClosed()) revert MintingClosed();
        if (quantity == 0) revert ZeroQuantity();
        if (isMintedOut() || willBeMintedOut(quantity)) {
            revert MaxSupplyExceeded();
        }
        _;
    }

    modifier lockInEarlyAccessLists(bytes32[] calldata merkleProof) {
        if (block.timestamp < publicMintStart) {
            SpecialPriceStatus status = _checkSpecialPriceStatus(
                msg.sender,
                merkleProof
            );
            if (
                status != SpecialPriceStatus.Free &&
                status != SpecialPriceStatus.Discount
            ) revert PublicMintNotStarted();
        }
        _;
    }

    function setBonusSystem(address _bonusSystem) external onlyOwner {
        bonusSystem = ILuckyGhoulsBonusSystem(_bonusSystem);
    }

    function updatePublicMintStart(
        uint256 newPublicMintStart
    ) external onlyOwner {
        publicMintStart = newPublicMintStart;
    }

    function setMintingActive(bool active) external onlyOwner {
        mintingActive = active;
    }

    function _exists(uint256 tokenId) internal view returns (bool) {
        return _ownerOf[tokenId] != address(0);
    }

    function updatePrices(
        uint256 price,
        uint256 discountPrice
    ) external onlyOwner {
        PRICE = price;
        DISCOUNT_PRICE = discountPrice;
    }

    function mint(
        uint256 quantity,
        bytes32[] calldata merkleProof
    )
        external
        payable
        lockInEarlyAccessLists(merkleProof)
        validateMint(quantity, merkleProof)
        validatePayment(quantity, merkleProof)
    {
        if (!mintingActive) revert MintNotActive();
        if (mintsPerWallet[msg.sender] + quantity > MAX_MINTS_PER_WALLET) {
            revert MaxMintsPerWalletExceeded();
        }

        // Get price and special price status
        (, bool usesSpecialPrice) = getMintPrice(
            msg.sender,
            quantity,
            merkleProof
        );

        if (usesSpecialPrice) {
            hasUsedSpecialPrice[msg.sender] = true;
        }

        // Reset the array for new mints
        // This is only for the sake of easier logic on the front end, we don't need to persist
        // this list forever.
        delete lastMintedTokens[msg.sender];

        unchecked {
            mintsPerWallet[msg.sender] += quantity;
            for (uint256 i; i < quantity; ++i) {
                _mint(msg.sender, currentTokenId);
                _mintBlockNumber[currentTokenId] = block.number;
                _mintTimestamp[currentTokenId] = block.timestamp;
                lastMintedTokens[msg.sender].push(currentTokenId);
                currentTokenId++;
                totalMinted++;
            }
        }
    }

    function setBaseURI(string calldata newBaseUri) external onlyOwner {
        if (bytes(newBaseUri).length == 0) revert EmptyBaseURI();
        baseUri = newBaseUri;
    }

    function withdraw() external {
        SafeTransferLib.safeTransferETH(
            withdrawRecipient,
            address(this).balance
        );
    }

    function withdrawERC20(address token) external onlyOwner {
        uint256 balance = ERC20(token).balanceOf(address(this));
        SafeTransferLib.safeTransfer(ERC20(token), withdrawRecipient, balance);
    }

    function withdrawERC721(
        address token,
        address to,
        uint256 tokenId
    ) external onlyOwner {
        IERC721(token).safeTransferFrom(address(this), to, tokenId);
    }

    function supportsInterface(
        bytes4 interfaceId
    ) public pure virtual override(ERC721) returns (bool) {
        return
            interfaceId == 0x01ffc9a7 || // ERC165
            interfaceId == 0x80ac58cd || // ERC721
            interfaceId == 0x5b5e139f || // ERC721Metadata
            interfaceId == 0x2a55205a; // ERC2981
    }

    function royaltyInfo(
        uint256,
        uint256 salePrice
    ) external view returns (address receiver, uint256 royaltyAmount) {
        return (royaltyRecipient, (salePrice * ROYALTY_BPS) / 10000);
    }

    function tokenURI(
        uint256 id
    ) public view virtual override returns (string memory) {
        if (!_exists(id)) revert TokenDoesNotExist();
        return string.concat(baseUri, id.toString(), ".json");
    }

    function mintsRemaining(address wallet) external view returns (uint256) {
        return MAX_MINTS_PER_WALLET - mintsPerWallet[wallet];
    }

    function getMintBlockNumber(
        uint256 tokenId
    ) external view returns (uint256) {
        if (!_exists(tokenId)) revert TokenDoesNotExist();
        return _mintBlockNumber[tokenId];
    }

    function getMintTimestamp(uint256 tokenId) external view returns (uint256) {
        if (!_exists(tokenId)) revert TokenDoesNotExist();
        return _mintTimestamp[tokenId];
    }

    function isMintedOut() public view returns (bool) {
        return totalMinted >= MAX_SUPPLY;
    }

    function willBeMintedOut(uint256 additionalQty) public view returns (bool) {
        return totalMinted + additionalQty > MAX_SUPPLY;
    }

    function remainingSupply() public view returns (uint256) {
        return MAX_SUPPLY - totalMinted;
    }

    function setDiscountMerkleRoot(bytes32 _merkleRoot) external onlyOwner {
        discountMerkleRoot = _merkleRoot;
    }

    function setFreeMerkleRoot(bytes32 _merkleRoot) external onlyOwner {
        freeMerkleRoot = _merkleRoot;
    }

    function _checkSpecialPriceStatus(
        address user,
        bytes32[] calldata merkleProof
    ) internal view returns (SpecialPriceStatus) {
        // Check free list first
        if (
            freeMerkleRoot != bytes32(0) &&
            MerkleProofLib.verify(
                merkleProof,
                freeMerkleRoot,
                keccak256(abi.encodePacked(user))
            )
        ) {
            return SpecialPriceStatus.Free;
        }

        // Then check discount list
        if (
            discountMerkleRoot != bytes32(0) &&
            MerkleProofLib.verify(
                merkleProof,
                discountMerkleRoot,
                keccak256(abi.encodePacked(user))
            )
        ) {
            return SpecialPriceStatus.Discount;
        }

        // Not in any list
        return SpecialPriceStatus.None;
    }

    function getMintPrice(
        address user,
        uint256 quantity,
        bytes32[] calldata merkleProof
    ) public view returns (uint256 totalPrice, bool usesSpecialPrice) {
        // If user has already used their special price, charge full price
        if (hasUsedSpecialPrice[user]) {
            return (PRICE * quantity, false);
        }

        SpecialPriceStatus status = _checkSpecialPriceStatus(user, merkleProof);

        // If eligible for free mint
        if (status == SpecialPriceStatus.Free) {
            // First token is free, rest are full price
            return (PRICE * (quantity - 1), true);
        }

        // If eligible for discount
        if (status == SpecialPriceStatus.Discount) {
            // First token is discounted, rest are full price
            return (DISCOUNT_PRICE + (PRICE * (quantity - 1)), true);
        }

        // Otherwise, charge full price for all tokens
        return (PRICE * quantity, false);
    }

    function getUserSpecialPriceStatus(
        address user,
        bytes32[] calldata merkleProof
    ) public view returns (SpecialPriceStatus status, bool hasUsedPrice) {
        hasUsedPrice = hasUsedSpecialPrice[user];
        status = _checkSpecialPriceStatus(user, merkleProof);
        return (status, hasUsedPrice);
    }

    function getLastMintedTokens(
        address wallet
    ) external view returns (uint256[] memory) {
        return lastMintedTokens[wallet];
    }

    function getClaimedBonusesForLastMintedTokens(
        address wallet
    )
        external
        view
        returns (
            ILuckyGhoulsBonusSystem.BonusClaim[] memory claims,
            uint256[] memory tokenIds
        )
    {
        tokenIds = lastMintedTokens[wallet];
        claims = bonusSystem.getBonusClaims(tokenIds);
        return (claims, tokenIds);
    }

    function setMintingClosed(bool closed) external onlyOwner {
        _isClosedOverride = closed;
    }

    function isEverythingClosed() public view returns (bool) {
        return _isClosedOverride || goldenGhoulMinted;
    }

    function setAuthorizedBonusSystem(
        address _authorizedBonusSystem
    ) external onlyOwner {
        authorizedBonusSystem = _authorizedBonusSystem;
    }

    function setGoldenGhoulMinted() external {
        if (msg.sender != owner && msg.sender != authorizedBonusSystem)
            revert Nope();
        goldenGhoulMinted = true;
    }

    function getMintConfig(
        address user,
        uint256 quantity,
        bytes32[] calldata merkleProof
    ) external view returns (MintConfig memory) {
        (uint256 totalPrice, bool usesSpecialPrice) = getMintPrice(
            user,
            quantity,
            merkleProof
        );

        (
            SpecialPriceStatus specialPriceStatus,
            bool _hasUsedSpecialPrice
        ) = getUserSpecialPriceStatus(user, merkleProof);

        return
            MintConfig({
                totalPrice: totalPrice,
                usesSpecialPrice: usesSpecialPrice,
                specialPriceStatus: specialPriceStatus,
                hasUsedSpecialPrice: _hasUsedSpecialPrice,
                mintsRemaining: MAX_MINTS_PER_WALLET - mintsPerWallet[user],
                isMintedOut: isMintedOut(),
                isEverythingClosed: isEverythingClosed(),
                remainingSupply: remainingSupply(),
                isPublicMintStarted: block.timestamp >= publicMintStart
            });
    }

    receive() external payable {}
}

// SPDX-License-Identifier: MIT
pragma solidity >=0.8.0;

/// @notice Gas optimized merkle proof verification library.
/// @author Solmate (https://github.com/transmissions11/solmate/blob/main/src/utils/MerkleProofLib.sol)
/// @author Modified from Solady (https://github.com/Vectorized/solady/blob/main/src/utils/MerkleProofLib.sol)
library MerkleProofLib {
    function verify(
        bytes32[] calldata proof,
        bytes32 root,
        bytes32 leaf
    ) internal pure returns (bool isValid) {
        /// @solidity memory-safe-assembly
        assembly {
            if proof.length {
                // Left shifting by 5 is like multiplying by 32.
                let end := add(proof.offset, shl(5, proof.length))

                // Initialize offset to the offset of the proof in calldata.
                let offset := proof.offset

                // Iterate over proof elements to compute root hash.
                // prettier-ignore
                for {} 1 {} {
                    // Slot where the leaf should be put in scratch space. If
                    // leaf > calldataload(offset): slot 32, otherwise: slot 0.
                    let leafSlot := shl(5, gt(leaf, calldataload(offset)))

                    // Store elements to hash contiguously in scratch space.
                    // The xor puts calldataload(offset) in whichever slot leaf
                    // is not occupying, so 0 if leafSlot is 32, and 32 otherwise.
                    mstore(leafSlot, leaf)
                    mstore(xor(leafSlot, 32), calldataload(offset))

                    // Reuse leaf to store the hash to reduce stack operations.
                    leaf := keccak256(0, 64) // Hash both slots of scratch space.

                    offset := add(offset, 32) // Shift 1 word per cycle.

                    // prettier-ignore
                    if iszero(lt(offset, end)) { break }
                }
            }

            isValid := eq(leaf, root) // The proof is valid if the roots match.
        }
    }
}

// SPDX-License-Identifier: AGPL-3.0-only
pragma solidity >=0.8.0;

/// @notice Simple single owner authorization mixin.
/// @author Solmate (https://github.com/transmissions11/solmate/blob/main/src/auth/Owned.sol)
abstract contract Owned {
    /*//////////////////////////////////////////////////////////////
                                 EVENTS
    //////////////////////////////////////////////////////////////*/

    event OwnershipTransferred(address indexed user, address indexed newOwner);

    /*//////////////////////////////////////////////////////////////
                            OWNERSHIP STORAGE
    //////////////////////////////////////////////////////////////*/

    address public owner;

    modifier onlyOwner() virtual {
        require(msg.sender == owner, "UNAUTHORIZED");

        _;
    }

    /*//////////////////////////////////////////////////////////////
                               CONSTRUCTOR
    //////////////////////////////////////////////////////////////*/

    constructor(address _owner) {
        owner = _owner;

        emit OwnershipTransferred(address(0), _owner);
    }

    /*//////////////////////////////////////////////////////////////
                             OWNERSHIP LOGIC
    //////////////////////////////////////////////////////////////*/

    function transferOwnership(address newOwner) public virtual onlyOwner {
        owner = newOwner;

        emit OwnershipTransferred(msg.sender, newOwner);
    }
}

// SPDX-License-Identifier: AGPL-3.0-only
pragma solidity >=0.8.0;

import {ERC20} from "../tokens/ERC20.sol";

/// @notice Safe ETH and ERC20 transfer library that gracefully handles missing return values.
/// @author Solmate (https://github.com/transmissions11/solmate/blob/main/src/utils/SafeTransferLib.sol)
/// @dev Use with caution! Some functions in this library knowingly create dirty bits at the destination of the free memory pointer.
library SafeTransferLib {
    /*//////////////////////////////////////////////////////////////
                             ETH OPERATIONS
    //////////////////////////////////////////////////////////////*/

    function safeTransferETH(address to, uint256 amount) internal {
        bool success;

        /// @solidity memory-safe-assembly
        assembly {
            // Transfer the ETH and store if it succeeded or not.
            success := call(gas(), to, amount, 0, 0, 0, 0)
        }

        require(success, "ETH_TRANSFER_FAILED");
    }

    /*//////////////////////////////////////////////////////////////
                            ERC20 OPERATIONS
    //////////////////////////////////////////////////////////////*/

    function safeTransferFrom(
        ERC20 token,
        address from,
        address to,
        uint256 amount
    ) internal {
        bool success;

        /// @solidity memory-safe-assembly
        assembly {
            // Get a pointer to some free memory.
            let freeMemoryPointer := mload(0x40)

            // Write the abi-encoded calldata into memory, beginning with the function selector.
            mstore(freeMemoryPointer, 0x23b872dd00000000000000000000000000000000000000000000000000000000)
            mstore(add(freeMemoryPointer, 4), and(from, 0xffffffffffffffffffffffffffffffffffffffff)) // Append and mask the "from" argument.
            mstore(add(freeMemoryPointer, 36), and(to, 0xffffffffffffffffffffffffffffffffffffffff)) // Append and mask the "to" argument.
            mstore(add(freeMemoryPointer, 68), amount) // Append the "amount" argument. Masking not required as it's a full 32 byte type.

            // We use 100 because the length of our calldata totals up like so: 4 + 32 * 3.
            // We use 0 and 32 to copy up to 32 bytes of return data into the scratch space.
            success := call(gas(), token, 0, freeMemoryPointer, 100, 0, 32)

            // Set success to whether the call reverted, if not we check it either
            // returned exactly 1 (can't just be non-zero data), or had no return data and token has code.
            if and(iszero(and(eq(mload(0), 1), gt(returndatasize(), 31))), success) {
                success := iszero(or(iszero(extcodesize(token)), returndatasize())) 
            }
        }

        require(success, "TRANSFER_FROM_FAILED");
    }

    function safeTransfer(
        ERC20 token,
        address to,
        uint256 amount
    ) internal {
        bool success;

        /// @solidity memory-safe-assembly
        assembly {
            // Get a pointer to some free memory.
            let freeMemoryPointer := mload(0x40)

            // Write the abi-encoded calldata into memory, beginning with the function selector.
            mstore(freeMemoryPointer, 0xa9059cbb00000000000000000000000000000000000000000000000000000000)
            mstore(add(freeMemoryPointer, 4), and(to, 0xffffffffffffffffffffffffffffffffffffffff)) // Append and mask the "to" argument.
            mstore(add(freeMemoryPointer, 36), amount) // Append the "amount" argument. Masking not required as it's a full 32 byte type.

            // We use 68 because the length of our calldata totals up like so: 4 + 32 * 2.
            // We use 0 and 32 to copy up to 32 bytes of return data into the scratch space.
            success := call(gas(), token, 0, freeMemoryPointer, 68, 0, 32)

            // Set success to whether the call reverted, if not we check it either
            // returned exactly 1 (can't just be non-zero data), or had no return data and token has code.
            if and(iszero(and(eq(mload(0), 1), gt(returndatasize(), 31))), success) {
                success := iszero(or(iszero(extcodesize(token)), returndatasize())) 
            }
        }

        require(success, "TRANSFER_FAILED");
    }

    function safeApprove(
        ERC20 token,
        address to,
        uint256 amount
    ) internal {
        bool success;

        /// @solidity memory-safe-assembly
        assembly {
            // Get a pointer to some free memory.
            let freeMemoryPointer := mload(0x40)

            // Write the abi-encoded calldata into memory, beginning with the function selector.
            mstore(freeMemoryPointer, 0x095ea7b300000000000000000000000000000000000000000000000000000000)
            mstore(add(freeMemoryPointer, 4), and(to, 0xffffffffffffffffffffffffffffffffffffffff)) // Append and mask the "to" argument.
            mstore(add(freeMemoryPointer, 36), amount) // Append the "amount" argument. Masking not required as it's a full 32 byte type.

            // We use 68 because the length of our calldata totals up like so: 4 + 32 * 2.
            // We use 0 and 32 to copy up to 32 bytes of return data into the scratch space.
            success := call(gas(), token, 0, freeMemoryPointer, 68, 0, 32)

            // Set success to whether the call reverted, if not we check it either
            // returned exactly 1 (can't just be non-zero data), or had no return data and token has code.
            if and(iszero(and(eq(mload(0), 1), gt(returndatasize(), 31))), success) {
                success := iszero(or(iszero(extcodesize(token)), returndatasize())) 
            }
        }

        require(success, "APPROVE_FAILED");
    }
}

{
  "compilationTarget": {
    "src/LuckyGhouls.sol": "LuckyGhouls"
  },
  "evmVersion": "shanghai",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": [
    ":ds-test/=lib/solmate/lib/ds-test/src/",
    ":forge-std/=lib/forge-std/src/",
    ":solmate/=lib/solmate/"
  ]
}