// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

interface AggregatorV3Interface {
  function decimals() external view returns (uint8);

  function description() external view returns (string memory);

  function version() external view returns (uint256);

  function getRoundData(
    uint80 _roundId
  ) external view returns (uint80 roundId, int256 answer, uint256 startedAt, uint256 updatedAt, uint80 answeredInRound);

  function latestRoundData()
    external
    view
    returns (uint80 roundId, int256 answer, uint256 startedAt, uint256 updatedAt, uint80 answeredInRound);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.9;

import "@openzeppelin/contracts@4.9.3/token/ERC20/ERC20.sol";
import "@openzeppelin/contracts@4.9.3/token/ERC20/extensions/ERC20Burnable.sol";
import "@openzeppelin/contracts@4.9.3/security/Pausable.sol";
import "@openzeppelin/contracts@4.9.3/access/Ownable.sol";
import "@openzeppelin/contracts@4.9.3/security/ReentrancyGuard.sol";

contract DriftPresale is
    ERC20,
    ERC20Burnable,
    Pausable,
    Ownable,
    ReentrancyGuard
{
    mapping(address => bool) public allowedAddresses;
    uint256 public maxSupply = 5660000000 * 10**decimals(); // 5.66 Billion

    constructor() ERC20("Drift Presale Token", "PREDRIFT") {
        _mint(msg.sender, maxSupply);
    }

    modifier isAddressAllowed(address from) {
        require(
            allowedAddresses[from] || from == owner(),
            "Transfer not allowed"
        );
        _;
    }

    function pause() public onlyOwner nonReentrant {
        _pause();
    }

    function unpause() public onlyOwner nonReentrant {
        _unpause();
    }

    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal override whenNotPaused {
        super._beforeTokenTransfer(from, to, amount);
    }

    function transfer(address to, uint256 value)
        public
        virtual
        override
        isAddressAllowed(_msgSender())
        returns (bool)
    {
        super.transfer(to, value);
        return true;
    }

    function transferFrom(
        address from,
        address to,
        uint256 value
    ) public virtual override isAddressAllowed(from) returns (bool) {
        super.transferFrom(from, to, value);
        return true;
    }

    function updateAddressStatus(address _address, bool status)
        public
        onlyOwner
    {
        allowedAddresses[_address] = status;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.0;

import "./IERC20.sol";
import "./extensions/IERC20Metadata.sol";
import "../../utils/Context.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20PresetMinterPauser}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20 is Context, IERC20, IERC20Metadata {
    mapping(address => uint256) private _balances;

    mapping(address => mapping(address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual override returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual override returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual override returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address to, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `amount` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `amount`.
     */
    function transferFrom(address from, address to, uint256 amount) public virtual override returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, amount);
        _transfer(from, to, amount);
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, allowance(owner, spender) + addedValue);
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
        address owner = _msgSender();
        uint256 currentAllowance = allowance(owner, spender);
        require(currentAllowance >= subtractedValue, "ERC20: decreased allowance below zero");
        unchecked {
            _approve(owner, spender, currentAllowance - subtractedValue);
        }

        return true;
    }

    /**
     * @dev Moves `amount` of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     */
    function _transfer(address from, address to, uint256 amount) internal virtual {
        require(from != address(0), "ERC20: transfer from the zero address");
        require(to != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(from, to, amount);

        uint256 fromBalance = _balances[from];
        require(fromBalance >= amount, "ERC20: transfer amount exceeds balance");
        unchecked {
            _balances[from] = fromBalance - amount;
            // Overflow not possible: the sum of all balances is capped by totalSupply, and the sum is preserved by
            // decrementing then incrementing.
            _balances[to] += amount;
        }

        emit Transfer(from, to, amount);

        _afterTokenTransfer(from, to, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply += amount;
        unchecked {
            // Overflow not possible: balance + amount is at most totalSupply + amount, which is checked above.
            _balances[account] += amount;
        }
        emit Transfer(address(0), account, amount);

        _afterTokenTransfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        uint256 accountBalance = _balances[account];
        require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
        unchecked {
            _balances[account] = accountBalance - amount;
            // Overflow not possible: amount <= accountBalance <= totalSupply.
            _totalSupply -= amount;
        }

        emit Transfer(account, address(0), amount);

        _afterTokenTransfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(address owner, address spender, uint256 amount) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `amount`.
     *
     * Does not update the allowance amount in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Might emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 amount) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            require(currentAllowance >= amount, "ERC20: insufficient allowance");
            unchecked {
                _approve(owner, spender, currentAllowance - amount);
            }
        }
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(address from, address to, uint256 amount) internal virtual {}

    /**
     * @dev Hook that is called after any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * has been transferred to `to`.
     * - when `from` is zero, `amount` tokens have been minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens have been burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(address from, address to, uint256 amount) internal virtual {}
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (token/ERC20/extensions/ERC20Burnable.sol)

pragma solidity ^0.8.0;

import "../ERC20.sol";
import "../../../utils/Context.sol";

/**
 * @dev Extension of {ERC20} that allows token holders to destroy both their own
 * tokens and those that they have an allowance for, in a way that can be
 * recognized off-chain (via event analysis).
 */
abstract contract ERC20Burnable is Context, ERC20 {
    /**
     * @dev Destroys `amount` tokens from the caller.
     *
     * See {ERC20-_burn}.
     */
    function burn(uint256 amount) public virtual {
        _burn(_msgSender(), amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, deducting from the caller's
     * allowance.
     *
     * See {ERC20-_burn} and {ERC20-allowance}.
     *
     * Requirements:
     *
     * - the caller must have allowance for ``accounts``'s tokens of at least
     * `amount`.
     */
    function burnFrom(address account, uint256 amount) public virtual {
        _spendAllowance(account, _msgSender(), amount);
        _burn(account, amount);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.9;

import "./DriftPresale.sol";
import "@openzeppelin/contracts@4.9.3/access/Ownable.sol";
import "@chainlink/contracts/src/v0.8/interfaces/AggregatorV3Interface.sol";

contract ICO is Ownable {
    DriftPresale public tokenAddress;
     AggregatorV3Interface internal priceFeed;

    enum Tier {
        none,
        gold,
        silver,
        bronze
    }

    enum userType {
        dynamic,
        stake
    }

    struct AmbassadorInfo {
        address ambassadorAddress;
        string ambassadorCode;
        Tier userTier;
        uint256 earning;
        uint256 referrals;
        uint256 amountRaised;
    }
    
    address[] public ambassadorsList; //Ambassador Array
    uint256 public totalReceivedFunds;
    uint256 public icoStartTime;
    uint256 public limitPerUser;
    
    uint256 public icoStage;
    uint256 public eligibleSilverAmbassador = 0.5 ether;
    uint256 public eligibleBronzeAmbassador = 0.25 ether;
    uint256 public noOfAmbassadors;
    uint256 public AmbassadorPayout;
    uint256 public stakingLimit;
    // uint256 public minimumBuyLimit = ;
    bool public isSalePaused = false;

    // Mapping (Stage => Price)
    mapping(uint256 => uint256) public prices;
    // Mapping (Stage => ETH target)
    mapping(uint256 => uint256) public icoTarget;
    mapping(uint256 => uint256) public tokensTransferred;
    mapping(uint256 => uint256) public receivedFunds;
    mapping(userType => uint256) public noOfTokens;
    // Decimals 2
    mapping(Tier => uint32[]) public percent;
    mapping(userType => address[]) private users;
    mapping(address => mapping(userType => bool)) public isAddressExist;
    mapping(address => mapping(userType => uint256))
        public amountOfAddressPerType;
    // Is code is enabled/valid
    mapping(string => bool) public isEnableCode;
    // Generated promo code against address
    mapping(address => string) public codeOfAddress;
    // Generated promo code
    mapping(string => address) public promoCode;
    // How much money the address invest
    mapping(address => AmbassadorInfo) internal ambassadorInfo;
    // Mapping Stage => Tier => Amount
    mapping(uint256 => mapping(Tier => uint256)) public totalTierRaised;
    mapping(Tier => mapping(string => bool)) public ambassadorCode;
    // How much money the address invest
    mapping(address => uint256) public investAmount;
    mapping(address => bool) public isAmbassadorEligible;
    mapping(address => uint256) public ambassadorPercentExt;

    modifier isCodeValid(string memory _code) {
        require(
            isEnableCode[_code] || compareStringsbyBytes(_code, ""),
            "Code is invalid"
        );
        _;
    }

    modifier isUsingOwnCode(string memory _code) {
        require(promoCode[_code] != msg.sender, "Can't use your own code");
        _;
    }


    // Is crowdsale Open
    function changeSaleStatus(bool _status) public onlyOwner  {
       isSalePaused=_status;
    }
    // bool public isSalePaused;

    constructor(DriftPresale _tokenAddress) {
        tokenAddress = _tokenAddress;
    priceFeed = AggregatorV3Interface(0x5f4eC3Df9cbd43714FE2740f5E3616155c5b8419);
        percent[Tier.gold] = [1000, 500];
        percent[Tier.silver] = [1000, 500];
        percent[Tier.bronze] = [750, 500];
        stakingLimit = 2000000000 * 10**tokenAddress.decimals();
        limitPerUser = 150000000 * 10**tokenAddress.decimals();
    }

    // Is crowdsale Open
    function isOpen() public view returns (bool) {
        return icoTarget[icoStage] > tokensTransferred[icoStage] && block.timestamp >= icoStartTime;
    }

    function updateStakingLimit(uint256 _newLimit) public onlyOwner {
        stakingLimit = _newLimit;
    }

    // Percentage with multiplied by 100, eg. 10% => 10*100 = 1000
    function updateAmbassadorPercent(address _address, uint256 _percent) public onlyOwner {
        ambassadorPercentExt[_address] = _percent;
    }

    // Create new crowdsale stage
    function createStage(
        uint256 _price,
        uint256 _startTime,

        uint256 _target
    ) public onlyOwner {
        require(!isOpen(), "Previous ICO is open");
        require(_price > 0, "Price is zero");
        require(_startTime > block.timestamp, "Invalid Time");
        icoStartTime = _startTime;        
        icoStage += 1;
        prices[icoStage] = _price;
        icoTarget[icoStage] = _target;
    }

    function calculateTokens(uint256 _amount) internal view returns (uint256) {
        uint256 tokens = ((_amount * 10**18) / getPriceRate(prices[icoStage]));
        return tokens;
    }

//Conversion Rate
        function getPriceRate(uint _amount) public view returns (uint) {
        (, int price,,,) = priceFeed.latestRoundData();
        uint adjust_price = uint(price) * 1e10;
        uint usd = _amount ;
        uint rate = (usd * 1e18) / adjust_price;
        return rate;
    }


    // Buy tokens
    function buyTokens(string memory _code, bool _isStaker)
        public
        payable
        isCodeValid(_code)
        isUsingOwnCode(_code)
    {
        require(!isSalePaused,"Sale is Paused");
        require(msg.value >= getPriceRate(50000000000000000000), "Minimum Buy Limit is USD $50.00");
        require(tokenAddress.balanceOf(_msgSender()) <= limitPerUser, "Sorry! Looks like this wallet has reached Max. Purchase Limit per address. As per our Presale Rules, a single wallet cannot purchase more than 1.5% of total supply.");
        require(isOpen(), "Current stage of Presale has been filled completely. Please stay tuned for the next lap.");
        
        

        uint256 tokens = calculateTokens(msg.value);

        if (!compareStringsbyBytes(_code, "")) {
            Tier tier;
            if (ambassadorCode[Tier.gold][_code]) {
                tier = Tier.gold;
            } else if (ambassadorCode[Tier.silver][_code]) {
                tier = Tier.silver;
            } else if (ambassadorCode[Tier.bronze][_code]) {
                tier = Tier.bronze;
            }

            uint256 extraToken = (tokens * percent[tier][1]) / 10**4;
            tokens += extraToken;
            
            AmbassadorInfo storage _ambassadorInfoCode = ambassadorInfo[
                promoCode[_code]
            ];

            uint256 ambassadorPer = ambassadorPercentExt[_ambassadorInfoCode.ambassadorAddress] != 0 ? ambassadorPercentExt[_ambassadorInfoCode.ambassadorAddress] : percent[tier][0];

            uint256 ambassadorAmount = (msg.value * ambassadorPer) / 10**4;
            totalTierRaised[icoStage][tier] += msg.value;

            _ambassadorInfoCode.amountRaised += msg.value;
            _ambassadorInfoCode.referrals += 1;
            _ambassadorInfoCode.earning += ambassadorAmount;
            AmbassadorPayout += ambassadorAmount;

            (bool sentToAmbassador, ) = payable(promoCode[_code]).call{
                value: ambassadorAmount
            }("");

            require(sentToAmbassador, "Sent to ambassador failed");
        }

        bool success = tokenAddress.transferFrom(
            tokenAddress.owner(),
            _msgSender(),
            tokens
        );
        require(success, "Transfer failed");

        tokensTransferred[icoStage]+=tokens;

        userType _type = _isStaker ? userType.stake : userType.dynamic;

        require(
            (_type == userType.stake &&
                noOfTokens[userType.stake] < stakingLimit) ||
                _type == userType.dynamic,
            "Staking Pool Full. A max. 20% of entire supply can be staked during Presale stage. "
        );

        if (!isAddressExist[_msgSender()][_type]) {
            isAddressExist[_msgSender()][_type] = true;
            users[_type].push(_msgSender());
        }

        amountOfAddressPerType[_msgSender()][_type] += tokens;
        noOfTokens[_type] += tokens;

        receivedFunds[icoStage] += msg.value;
        totalReceivedFunds += msg.value;
        investAmount[_msgSender()] += msg.value;
        

        Tier _eligible = Tier.none;

        if (investAmount[_msgSender()] >= eligibleSilverAmbassador) {
            _eligible = Tier.silver;
        } else if (investAmount[_msgSender()] >= eligibleBronzeAmbassador) {
            _eligible = Tier.bronze;
        }

        AmbassadorInfo storage _ambassadorInfo = ambassadorInfo[_msgSender()];
        if (!isAmbassadorEligible[_msgSender()] && _eligible != Tier.none) {
            
            _ambassadorInfo.userTier = _eligible;
            _ambassadorInfo.ambassadorAddress = _msgSender();

            isAmbassadorEligible[_msgSender()] = true;
            noOfAmbassadors++;
        } else if (_ambassadorInfo.userTier == Tier.bronze) {
            string memory _codeOfAddress = codeOfAddress[_msgSender()];
            delete ambassadorCode[Tier.bronze][_codeOfAddress];
            _ambassadorInfo.userTier = _eligible;
            ambassadorCode[_eligible][_codeOfAddress] = true;
        }
    }

    function getAmbassadorInfo(address _address)
        public
        view
        returns (
            Tier _tier,
            string memory _promocode,
            address _ambassador,
            uint256 _earnings,
            uint256 _referrals,
            uint256 _raised
        )
    {
        AmbassadorInfo memory _ambassadorInfo = ambassadorInfo[_address];
        return (
            _ambassadorInfo.userTier,
            _ambassadorInfo.ambassadorCode,
            _ambassadorInfo.ambassadorAddress,
            _ambassadorInfo.earning,
            _ambassadorInfo.referrals,
            _ambassadorInfo.amountRaised
        );
    }

    function changeStatusCode(string memory _code, bool status)
        public
        onlyOwner
    {
        isEnableCode[_code] = status;
    }

    function createAmbassadorCode(
        address _address,
        Tier _tier,
        string memory _code
    ) public onlyOwner {
        require(isNotAlreadyAmbassador(_address), "Already Ambasador");
        ambassadorsList.push(_address);
        require(!isEnableCode[_code], "Code already exist");
        isAmbassadorEligible[_address] = true;
        isEnableCode[_code] = true;
        codeOfAddress[_address] = _code;
        promoCode[_code] = _address;
        ambassadorCode[_tier][_code] = true;
        AmbassadorInfo storage _ambassadorInfo = ambassadorInfo[_address];
        _ambassadorInfo.ambassadorAddress = _address;
        _ambassadorInfo.ambassadorCode = _code;
        _ambassadorInfo.userTier = _tier;
        noOfAmbassadors++;
    }

    function createCode(string memory _code) public {
        require(isAmbassadorEligible[_msgSender()], "Sorry! You are not an ambassador yet. Please visit www.drifttoken.io during Presale and purchase a minimum of 0.25 ETH to become a Bronze Tier Ambassador. ");
        require(isNotAlreadyAmbassador(_msgSender()), "You have already assigned a Promo Code to this Ambassador Wallet. Please visit www.influ3nce.me/ambassador and connect this wallet to view your promo code. ");
        require(!compareStringsbyBytes(_code, ""), "Oops! Seems like you forgot to type-in your Promo Code.");
        require(!isEnableCode[_code], "Unfortunately, this Promo Code has already been assigned to an Ambassador. Please choose another Promo Code. ");
        ambassadorsList.push(_msgSender());
        isEnableCode[_code] = true;
        codeOfAddress[_msgSender()] = _code;
        promoCode[_code] = _msgSender();
        AmbassadorInfo storage _ambassadorInfo = ambassadorInfo[_msgSender()];
        ambassadorCode[_ambassadorInfo.userTier][_code] = true;
        _ambassadorInfo.ambassadorCode = _code;
    }

    function upgradeAmbassador(address _address, Tier _tier) public onlyOwner {
        AmbassadorInfo storage _ambassadorInfo = ambassadorInfo[_address];
        delete ambassadorCode[_ambassadorInfo.userTier][
            codeOfAddress[_address]
        ];
        ambassadorCode[_tier][codeOfAddress[_address]] = true;
        _ambassadorInfo.userTier = _tier;

  
    }

    function isNotAlreadyAmbassador(address user) public view returns (bool) {
        return compareStringsbyBytes(codeOfAddress[user], "");
    }

    function getUsers(userType _type) public view returns (address[] memory) {
        return users[_type];
    }

    function getAmbassadorList() public view returns (address[] memory) {
        return ambassadorsList;
    }

    function withdrawFunds() public onlyOwner {
        (bool os, ) = payable(owner()).call{value: address(this).balance}("");
        require(os);
    }

    function compareStringsbyBytes(string memory s1, string memory s2)
        public
        pure
        returns (bool)
    {
        return
            keccak256(abi.encodePacked(s1)) == keccak256(abi.encodePacked(s2));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (security/Pausable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    bool private _paused;

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        require(!paused(), "Pausable: paused");
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        require(paused(), "Pausable: not paused");
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }
}

{
  "compilationTarget": {
    "contracts/ICO.sol": "ICO"
  },
  "evmVersion": "shanghai",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}