City Parks

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        assembly {
            size := extcodesize(account)
        }
        return size > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.4;

import "@openzeppelin/contracts/utils/Strings.sol";
import "@openzeppelin/contracts/utils/math/SafeMath.sol";

import "./CityParkUtils.sol";

library CityParkArt {

    using SafeMath for uint16;
    using Strings for uint256;
    using Strings for uint8;
    using Strings for uint16;

    function _generateFirstTriangle(CityParkUtils.ColorXY memory colorXY) private pure returns (string memory) {
        return string(abi.encodePacked( 
            "<polygon points='",
            (colorXY.x-50).toString(),
            ",",
            colorXY.y.toString(),
            ", ",
            (colorXY.x+25).toString(),
            ",",
            (colorXY.y-150).toString(),
            ", ",
            (colorXY.x+100).toString(),
            ",",
            colorXY.y.toString(),
            "' style='fill:",
            colorXY.color,
            "'/>"
        ));
    }

    function _generateSecondTriangle(CityParkUtils.ColorXY memory colorXY) private pure returns (string memory) {
        return string(abi.encodePacked( 
            "<polygon points='",
            (colorXY.x-70).toString(),
            ",",
            (colorXY.y+80).toString(),
            ", ",
            (colorXY.x+25).toString(),
            ",",
            (colorXY.y-70).toString(),
            ", ",
            (colorXY.x+120).toString(),
            ",",
            (colorXY.y+80).toString(),
            "' style='fill:",
            colorXY.color,
            "'/>"
        ));
    }

    function _generateTreeTriangles(CityParkUtils.ColorXY memory colorXY) private pure returns (string memory) {
      return string(abi.encodePacked(
            _generateFirstTriangle(colorXY),
            _generateSecondTriangle(colorXY)
      ));
    }

    function _generateTrees(CityParkUtils.Art memory artData) public pure returns (string memory) {
        string memory trees = '';
        for (uint i = 0; i < artData.numTrees; i++) {
            CityParkUtils.ColorXY memory colorXY = CityParkUtils.ColorXY({
                x: CityParkUtils.seededRandom(80,790,i*i,artData),
                y: CityParkUtils.seededRandom(150,500,i*i+1,artData),
                color: artData.overrideWhite ? CityParkUtils.getBWColor(i*2+3,artData) : CityParkUtils.getColor(i*2+3,artData)
            });
 
          trees = string(abi.encodePacked(
              trees,
              "<rect width='50' height='200' x='",
              colorXY.x.toString(),
              "' y='",
              colorXY.y.toString(),
              "'",
              " style='fill:",
              colorXY.color,
              "'/>",
              _generateTreeTriangles(colorXY)
            ));
        }

        return trees;
    }

    function _generateWindow(uint x, uint y, string memory color) private pure returns (string memory) {
        return string(abi.encodePacked(
            "<circle cx='",
            x.toString(),
            "' cy='",
            y.toString(),
            "' r='15' style='fill:",
            color,
            "' />"
        ));
    }

    function _generateWindows(CityParkUtils.Art memory artData, CityParkUtils.ColorXY memory colorXY) private pure returns (string memory) {
        string memory wc = CityParkUtils.getColor(artData.randomSeed+3, artData);
        return string(abi.encodePacked(
            _generateWindow(colorXY.x+80,colorXY.y,wc),
            _generateWindow(colorXY.x-80,colorXY.y,wc),
            _generateWindow(colorXY.x,colorXY.y,wc)
        ));
    }

    function _generateUFO(CityParkUtils.Art memory artData) public pure returns (string memory) {
        CityParkUtils.ColorXY memory colorXY = CityParkUtils.ColorXY({
            x: CityParkUtils.seededRandom(160,680,6,artData),
            y: CityParkUtils.seededRandom(60,300,9,artData),
            color: artData.overrideWhite ? CityParkUtils.getBWColor(69420,artData) : CityParkUtils.getColor(69420,artData)
        });

        return string(abi.encodePacked(
            "<ellipse rx='50' ry='80' cx='",
            colorXY.x.toString(),
            "' cy='",
            colorXY.y.toString(),
            "'",
            " style='fill:",
            colorXY.color,
            ";stroke-width:7;stroke:black'/>",
            "<ellipse rx='150' ry='50' cx='",
            colorXY.x.toString(),
            "' cy='",
            colorXY.y.toString(),
            "'",
            " style='fill:",
            colorXY.color,
            ";stroke-width:3;stroke:black'/>",
            "<ellipse rx='50' ry='80' cx='",
            colorXY.x.toString(),
            "' cy='",
            colorXY.y.toString(),
            "'",
            " style='fill:",
            colorXY.color,
            "'/>",
            _generateWindows(artData, colorXY)
        ));
    }

    function _generateSunLines(CityParkUtils.ColorXY memory colorXY) private pure returns (string memory) {
        string memory sunLines = '';
        for (uint16 i = 0; i < 8; i++) {
            sunLines = string(abi.encodePacked(
                sunLines,
                _generateSunLine(colorXY, uint16(i.mul(45)))
            ));
        }
        return sunLines;
    }

    function _generateSunLine(CityParkUtils.ColorXY memory colorXY, uint16 rotate) private pure returns (string memory) {
      return string(abi.encodePacked(
            "<path stroke='",
            colorXY.color,
            "' style='transform:rotate(",
            rotate.toString(),
            "deg);transform-origin:",
            colorXY.x.toString(),
            "px -",
            colorXY.y.toString(),
            "px' d='M",
            colorXY.x.toString(),
            " -",
            (colorXY.y+65).toString(),
            "V -",
            (colorXY.y+105).toString(),
            "' stroke-width='25' />"
      ));
    }

    function _generateSun(CityParkUtils.Art memory artData) public pure returns (string memory) {
        CityParkUtils.ColorXY memory colorXY = CityParkUtils.ColorXY({
            x: CityParkUtils.seededRandom(120,760,4,artData),
            y: CityParkUtils.seededRandom(0,200,20,artData),
            color: artData.overrideWhite ? CityParkUtils.getBWColor(6969,artData) : CityParkUtils.getColor(6969,artData)
        });

        return string(abi.encodePacked(
            "<circle  r='50' cx='",
            colorXY.x.toString(),
            "' cy='-",
            colorXY.y.toString(),
            "' style='fill:",
            colorXY.color,
            "'/>",
            _generateSunLines(colorXY)
        ));
    }

    function _generateRug(CityParkUtils.Art memory artData) public pure returns (string memory) {
        uint randDegrees =  CityParkUtils.seededRandom(0, 90, 199, artData);
        return string(abi.encodePacked(
            "<rect width='1200' height='1500' x='600' y='-460' style='fill:",
            artData.overrideWhite ? CityParkUtils.getBWColor(9876,artData) : CityParkUtils.getColor(9876,artData),
            ";stroke-width:3;stroke:black' transform='rotate(",
            randDegrees.toString(),
            ")'/>",
            _generateStripes(artData, string(abi.encodePacked("-", (90-randDegrees).toString())))
        ));
    }

    function _generateStripes(CityParkUtils.Art memory artData, string memory oppRotateStr) private pure returns (string memory) {
        string memory stripes = '';
        uint numStripes = CityParkUtils.seededRandom(1, 4, 666, artData);
        for (uint i = 0; i < numStripes; i++) {
            uint randomPlace = CityParkUtils.seededRandom(100, 1100, i*2+3, artData);
            string memory xString;
            if (randomPlace > 600) {
                xString = string(abi.encodePacked("-", (randomPlace-600).toString()));
            } else {
                xString = (600-randomPlace).toString();
            }

            stripes = string(abi.encodePacked(
                stripes,
                "<rect width='50' height='1500' x='",
                xString,
                "' y='600'",
                " style='fill:",
                CityParkUtils.getColor(i*i+3,artData),
                ";stroke-width:3;stroke:black' transform='rotate(",
                oppRotateStr,
                ")'/>"
            ));
        }
        return stripes;
    }

    function _generateAllBricks(CityParkUtils.Art memory artData) public pure returns (string memory) {
        uint numBrickStructures = CityParkUtils.seededRandom(1,3,5555555,artData);
        string memory allBricks = '';
        for (uint i = 0; i < numBrickStructures; i++) {
            bool xPos =  CityParkUtils.seededRandom(0,2,i*i+69,artData) > 1;
            uint randX = CityParkUtils.seededRandom(0,300,i*i+888,artData);

            string memory xString;
            if (xPos) {
                xString = randX.toString();
            } else {
                xString = string(abi.encodePacked("-", randX.toString()));
            }

            allBricks = string(abi.encodePacked(
                allBricks,
                "<g transform='translate(",
                xString,
                ",",
                CityParkUtils.seededRandom(0,600,i*i+777,artData).toString(),
                ")'>",
                _generateBricks(artData, i)
            ));
        }
        return allBricks;
    }

    function _generateBricks(CityParkUtils.Art memory artData, uint rand) private pure returns (string memory) {
        string memory bricks = '';
        CityParkUtils.ColorXY memory colorXY = CityParkUtils.ColorXY({
            x: 300,
            y: 600,
            color: artData.overrideWhite ? CityParkUtils.getBWColor(rand+6, artData) : CityParkUtils.getColor(rand+9, artData)
        });
        uint numBricks = CityParkUtils.seededRandom(1,10,rand*2,artData);
        uint height = CityParkUtils.seededRandom(0,10,rand*3+1,artData);
        if (height % 2 == 0) {
            height++;
        }

        // Single half brick beginning
        for (uint i = 0; i < height / 2 + 1; i++) {
            bricks = string(abi.encodePacked(
                bricks,
                "<rect width='50' height='40' x='300' y='",
                (640+(80*i)).toString(),
                "' style='fill:",
                colorXY.color,
                ";stroke-width:3;stroke:black' transform='skewY(-10)'/>"
            ));
        }

        // Main brick faces
        for (uint i = 0; i < numBricks; i++) {
            for (uint j = 0; j < height / 2 + 1; j++) {

                // Top row, full row
                bricks = string(abi.encodePacked(
                    bricks,
                    "<rect width='100' height='40' x='",
                    (300+(i*100)).toString(),
                    "' y='",
                    (600+(80*j)).toString(),
                    "' style='fill:",
                    colorXY.color,
                    ";stroke-width:3;stroke:black' transform='skewY(-10)'/>"
                ));
            }

            // Handle negative x value
            uint baseXPos = 495;
            uint xLocPos;
            uint xLocNeg;
            string memory xString;
            if (i >= 5) {
                xLocNeg = 5 + ((i-5)*100);
                xString = xLocNeg.toString();
            } else {
                xLocPos = baseXPos - (i*100);
                xString = string(abi.encodePacked("-", xLocPos.toString()));
            }

            // Top face
            bricks = string(abi.encodePacked(
                bricks,
                "<rect width='100' height='40' x='",
                xString,
                "' y='560' style='fill:",
                colorXY.color,
                ";stroke-width:3;stroke:black' transform='skewY(-10) skewX(53)'/>"
            ));

            if (i != numBricks-1) {
                for (uint j = 0; j < height / 2 + 1; j++) {
                    bricks = string(abi.encodePacked(
                        bricks,
                        "<rect width='100' height='40' x='",
                        (350+(i*100)).toString(),
                        "' y='",
                        (640+(80*j)).toString(),
                        "' style='fill:",
                        colorXY.color,
                        ";stroke-width:3;stroke:black' transform='skewY(-10)'/>"
                    ));
                }
            }
        }

        // Single half brick end
        for (uint i = 0; i < height / 2 + 1; i++) {
            bricks = string(abi.encodePacked(
                bricks,
                "<rect width='50' height='40' x='",
                (250+(numBricks*100)).toString(),
                "' y='",
                (640+(80*i)).toString(),
                "' style='fill:",
                colorXY.color,
                ";stroke-width:3;stroke:black' transform='skewY(-10)'/>"
            ));
        }


        // Brick left face
        for (uint i = 0; i < height+1; i++) {
            string memory yString = '';
            if (i >= 6) {
                yString = (600+(15+((i-6)*40))).toString();
            } else {
                yString = (600-(225-(i*40))).toString();
            }


            bricks = string(abi.encodePacked(
                bricks,
                "<rect width='50' height='40' x='250' y='",
                yString,
                "' style='fill:",
                colorXY.color,
                ";stroke-width:3;stroke:black' transform='skewY(30)'/>"
            ));
        }

        bricks = string(abi.encodePacked(bricks, '</g>'));
        return bricks;
    }

    function _generateFence(CityParkUtils.Art memory artData, uint rand) private pure returns (string memory) {
        string memory fence = '';
        uint howWide = CityParkUtils.seededRandom(1,7,rand+69,artData);

        for (uint i = 0; i < 3; i++) {
            fence = string(abi.encodePacked(
                fence,
                "<rect width='",
                (howWide*100).toString(),
                "' height='20' x='275' y='",
                (600+(50*i)).toString(),
                "' style='fill:white' />"
            ));
        }

        for (uint i = 0; i < howWide; i++) {
            uint xStart = 300+(i*100);
            fence = string(abi.encodePacked(
                fence,
                "<rect width='50' height='150' x='",
                xStart.toString(),
                "' y='600' style='fill:white' />",
                "<polygon points='",
                xStart.toString(),
                ",600, ",
                (xStart+25).toString(),
                ",550, ",
                (xStart+50).toString(),
                ",600' style='fill:white' />"
            ));
        }

        fence = string(abi.encodePacked(fence, '</g>'));
        return fence;
    }

    function _generateAllFences(CityParkUtils.Art memory artData) public pure returns (string memory) {
        uint numFenceStructures = CityParkUtils.seededRandom(1,3,333333333,artData);
        string memory allFences = '';
        for (uint i = 0; i < numFenceStructures; i++) {
            bool xPos =  CityParkUtils.seededRandom(0,2,i*i+69,artData) > 1;
            uint randX = CityParkUtils.seededRandom(0,300,i*i+888,artData);

            string memory xString;
            if (xPos) {
                xString = randX.toString();
            } else {
                xString = string(abi.encodePacked("-", randX.toString()));
            }

            allFences = string(abi.encodePacked(
                allFences,
                "<g transform='translate(",
                xString,
                ",",
                CityParkUtils.seededRandom(0,300,i*i+777,artData).toString(),
                ")'>",
                _generateFence(artData, i*i)
            ));
        }
        return allFences;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.4;

import "@openzeppelin/contracts/utils/Strings.sol";
import "@openzeppelin/contracts/utils/math/SafeMath.sol";

library CityParkUtils {

    using SafeMath for uint16;
    using Strings for uint256;
    using Strings for uint8;
    using Strings for uint16;

    struct Art {
        uint8 numTrees;
        bool hasUFO;
        bool hasSun;
        bool hasFence;
        bool hasBricks;
        bool overrideWhite;
        uint48 randomTimestamp;
        uint128 randomDifficulty;
        uint256 randomSeed;
    }

    struct ColorXY {
        uint16 x;
        uint16 y;
        string color;
    }

    string public constant _imageFooter = "</svg>";
    string public constant _borderRect = "<rect width='100%' height='166%' y='-33%' rx='20' style='fill:none;stroke:black;stroke-width:20'></rect>";

    function getColor(uint seed, Art memory artData) public pure returns(string memory) {
        return ['%23a85dee', '%2323cd73', '%23ef2839', '%230bd2fa', '%23fdd131'][seededRandom(0,5,seed,artData)];
    }

    function getBWColor(uint seed, Art memory artData) public pure returns(string memory) {
        return ['white', '%23e8e8e8', '%23e0e0e0', '%23aeaeae', '%236e6e6e'][seededRandom(0,5,seed,artData)];
    }

    function _generateHeader(uint seed, Art memory artData) public pure returns (string memory) {
        string memory header = "data:image/svg+xml;utf8,<svg xmlns='http://www.w3.org/2000/svg' width='300' height='500' viewBox='0 0 1000 1000' style='background-color:";
        return string(abi.encodePacked(
            header,
            getColor(seed, artData),
            "'><!--You are loved.-->"
        ));
    }

    function _boolToString(bool value) public pure returns (string memory) {
        if (value) {
            return "True";
        } else {
            return "False";
        }
    }

    function seededRandom(uint low, uint high, uint seed, Art memory artData) public pure returns (uint16) {
        return uint16(uint(uint256(keccak256(abi.encodePacked(seed, uint256(keccak256(abi.encodePacked(artData.randomDifficulty, artData.randomTimestamp, artData.randomSeed)))))))%high + low);
    }

    function _wrapTrait(string memory trait, string memory value) public pure returns(string memory) {
        return string(abi.encodePacked(
            '{"trait_type":"',
            trait,
            '","value":"',
            value,
            '"}'
        ));
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.4;

import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/utils/Strings.sol";
import "@openzeppelin/contracts/token/ERC721/extensions/ERC721Enumerable.sol";
import "@openzeppelin/contracts/utils/math/SafeMath.sol";

import "./CityParkArt.sol";

// You are loved!
contract CityParks is ERC721Enumerable, Ownable {

    using SafeMath for uint256;
    using Strings for uint256;
    using Strings for uint8;

    uint public constant maxSupply = 1700;

    CityParkUtils.Art[maxSupply + 1] public cityParks;

    constructor() ERC721("City Parks", "CITYPARKS") {
        _safeMint(msg.sender, 0);
    }

    function tokenURI(uint256 tokenId) public view override returns (string memory) {
        return string(abi.encodePacked(
            'data:application/json;utf8,',
            '{"name":"City Park #',
                (tokenId).toString(),
            '",',
            '"description":"City Parks are a wonderful expression of fun.",',
            '"image":"',
                _generateImage(tokenId),
            '", "attributes":[',
                getMetadata(tokenId),
            ']',
        '}'));
    }

    function getMetadata(uint256 tokenId) public view returns (string memory) {
        if (tokenId == 0) {
            return string(abi.encodePacked(
                CityParkUtils._wrapTrait("Created By", "yungwknd.eth"),
                ',',CityParkUtils._wrapTrait("Genesis Token", "True"),
                ',',CityParkUtils._wrapTrait("Live Image", "True")
            ));
        }
        return string(abi.encodePacked(
            CityParkUtils._wrapTrait("Trees", cityParks[tokenId].numTrees.toString()),
            ',',CityParkUtils._wrapTrait("UFO", CityParkUtils._boolToString(cityParks[tokenId].hasUFO)),
            ',',CityParkUtils._wrapTrait("Sun", CityParkUtils._boolToString(cityParks[tokenId].hasSun)),
            ',',CityParkUtils._wrapTrait("Fence", CityParkUtils._boolToString(cityParks[tokenId].hasFence)),
            ',',CityParkUtils._wrapTrait("Bricks", CityParkUtils._boolToString(cityParks[tokenId].hasBricks))
        ));
    }

    function mint(uint256 numberOfMints) public payable {
        require(msg.value == numberOfMints.mul(0.03 ether), 'Not enough ETH');
        require(totalSupply().add(numberOfMints) <= maxSupply, 'Not enough left');
        for (uint i = 0; i < numberOfMints; i++) {
            uint mintNum = totalSupply();
            if (mintNum < maxSupply) {
                _safeMint(msg.sender, mintNum);
                _saveImageInfo(cityParks[mintNum], mintNum);
            }
        }
    }

    function _generateImage(uint256 mintNum) private view returns (string memory) {
        CityParkUtils.Art memory artData = cityParks[mintNum];
        if (mintNum == 0) {
            artData.randomTimestamp = uint48(block.timestamp);
            artData.randomDifficulty = uint128(block.difficulty);
            artData.randomSeed = uint256(keccak256(abi.encodePacked(block.timestamp, block.difficulty, mintNum)));
            artData.numTrees = uint8(CityParkUtils.seededRandom(1, 3, block.timestamp, artData));
            artData.hasUFO = CityParkUtils.seededRandom(1,100,block.timestamp,artData) >= 90;
            artData.hasSun = !artData.hasUFO;
            artData.hasFence = CityParkUtils.seededRandom(1,100,block.difficulty,artData) >= 90;
            artData.hasBricks = !artData.hasFence;
            artData.overrideWhite = CityParkUtils.seededRandom(1,100,block.timestamp + block.difficulty,artData) >= 20;
        }

        return string(abi.encodePacked(
            CityParkUtils._generateHeader(artData.randomDifficulty,artData),
            CityParkUtils._borderRect,
            CityParkArt._generateRug(artData),
            CityParkArt._generateTrees(artData),
            artData.hasUFO ? CityParkArt._generateUFO(artData) : CityParkArt._generateSun(artData),
            artData.hasFence ? CityParkArt._generateAllFences(artData) : CityParkArt._generateAllBricks(artData),
            CityParkUtils._imageFooter
        ));
    }

    function _saveImageInfo(CityParkUtils.Art storage artInfo, uint mintNum) private {
        artInfo.randomTimestamp = uint48(block.timestamp);
        artInfo.randomDifficulty = uint128(block.difficulty);
        artInfo.randomSeed = uint256(keccak256(abi.encodePacked(block.timestamp, block.difficulty, mintNum)));
        artInfo.numTrees = uint8(CityParkUtils.seededRandom(1,3,1234,artInfo));
        artInfo.hasUFO = CityParkUtils.seededRandom(1,100,8888888,artInfo) >= 90;
        artInfo.hasSun = !artInfo.hasUFO;
        artInfo.hasFence = CityParkUtils.seededRandom(1,100,8888888,artInfo) >= 90;
        artInfo.hasBricks = !artInfo.hasFence;
        artInfo.overrideWhite = CityParkUtils.seededRandom(1,100,12345,artInfo) >= 80;
    }

    function withdraw(address _to, uint amount) public onlyOwner {
        payable(_to).transfer(amount);
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "./IERC721.sol";
import "./IERC721Receiver.sol";
import "./extensions/IERC721Metadata.sol";
import "../../utils/Address.sol";
import "../../utils/Context.sol";
import "../../utils/Strings.sol";
import "../../utils/introspection/ERC165.sol";

/**
 * @dev Implementation of https://eips.ethereum.org/EIPS/eip-721[ERC721] Non-Fungible Token Standard, including
 * the Metadata extension, but not including the Enumerable extension, which is available separately as
 * {ERC721Enumerable}.
 */
contract ERC721 is Context, ERC165, IERC721, IERC721Metadata {
    using Address for address;
    using Strings for uint256;

    // Token name
    string private _name;

    // Token symbol
    string private _symbol;

    // Mapping from token ID to owner address
    mapping(uint256 => address) private _owners;

    // Mapping owner address to token count
    mapping(address => uint256) private _balances;

    // Mapping from token ID to approved address
    mapping(uint256 => address) private _tokenApprovals;

    // Mapping from owner to operator approvals
    mapping(address => mapping(address => bool)) private _operatorApprovals;

    /**
     * @dev Initializes the contract by setting a `name` and a `symbol` to the token collection.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(ERC165, IERC165) returns (bool) {
        return
            interfaceId == type(IERC721).interfaceId ||
            interfaceId == type(IERC721Metadata).interfaceId ||
            super.supportsInterface(interfaceId);
    }

    /**
     * @dev See {IERC721-balanceOf}.
     */
    function balanceOf(address owner) public view virtual override returns (uint256) {
        require(owner != address(0), "ERC721: balance query for the zero address");
        return _balances[owner];
    }

    /**
     * @dev See {IERC721-ownerOf}.
     */
    function ownerOf(uint256 tokenId) public view virtual override returns (address) {
        address owner = _owners[tokenId];
        require(owner != address(0), "ERC721: owner query for nonexistent token");
        return owner;
    }

    /**
     * @dev See {IERC721Metadata-name}.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev See {IERC721Metadata-symbol}.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev See {IERC721Metadata-tokenURI}.
     */
    function tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
        require(_exists(tokenId), "ERC721Metadata: URI query for nonexistent token");

        string memory baseURI = _baseURI();
        return bytes(baseURI).length > 0 ? string(abi.encodePacked(baseURI, tokenId.toString())) : "";
    }

    /**
     * @dev Base URI for computing {tokenURI}. If set, the resulting URI for each
     * token will be the concatenation of the `baseURI` and the `tokenId`. Empty
     * by default, can be overriden in child contracts.
     */
    function _baseURI() internal view virtual returns (string memory) {
        return "";
    }

    /**
     * @dev See {IERC721-approve}.
     */
    function approve(address to, uint256 tokenId) public virtual override {
        address owner = ERC721.ownerOf(tokenId);
        require(to != owner, "ERC721: approval to current owner");

        require(
            _msgSender() == owner || isApprovedForAll(owner, _msgSender()),
            "ERC721: approve caller is not owner nor approved for all"
        );

        _approve(to, tokenId);
    }

    /**
     * @dev See {IERC721-getApproved}.
     */
    function getApproved(uint256 tokenId) public view virtual override returns (address) {
        require(_exists(tokenId), "ERC721: approved query for nonexistent token");

        return _tokenApprovals[tokenId];
    }

    /**
     * @dev See {IERC721-setApprovalForAll}.
     */
    function setApprovalForAll(address operator, bool approved) public virtual override {
        require(operator != _msgSender(), "ERC721: approve to caller");

        _operatorApprovals[_msgSender()][operator] = approved;
        emit ApprovalForAll(_msgSender(), operator, approved);
    }

    /**
     * @dev See {IERC721-isApprovedForAll}.
     */
    function isApprovedForAll(address owner, address operator) public view virtual override returns (bool) {
        return _operatorApprovals[owner][operator];
    }

    /**
     * @dev See {IERC721-transferFrom}.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        //solhint-disable-next-line max-line-length
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");

        _transfer(from, to, tokenId);
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        safeTransferFrom(from, to, tokenId, "");
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) public virtual override {
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");
        _safeTransfer(from, to, tokenId, _data);
    }

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * `_data` is additional data, it has no specified format and it is sent in call to `to`.
     *
     * This internal function is equivalent to {safeTransferFrom}, and can be used to e.g.
     * implement alternative mechanisms to perform token transfer, such as signature-based.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeTransfer(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) internal virtual {
        _transfer(from, to, tokenId);
        require(_checkOnERC721Received(from, to, tokenId, _data), "ERC721: transfer to non ERC721Receiver implementer");
    }

    /**
     * @dev Returns whether `tokenId` exists.
     *
     * Tokens can be managed by their owner or approved accounts via {approve} or {setApprovalForAll}.
     *
     * Tokens start existing when they are minted (`_mint`),
     * and stop existing when they are burned (`_burn`).
     */
    function _exists(uint256 tokenId) internal view virtual returns (bool) {
        return _owners[tokenId] != address(0);
    }

    /**
     * @dev Returns whether `spender` is allowed to manage `tokenId`.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function _isApprovedOrOwner(address spender, uint256 tokenId) internal view virtual returns (bool) {
        require(_exists(tokenId), "ERC721: operator query for nonexistent token");
        address owner = ERC721.ownerOf(tokenId);
        return (spender == owner || getApproved(tokenId) == spender || isApprovedForAll(owner, spender));
    }

    /**
     * @dev Safely mints `tokenId` and transfers it to `to`.
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeMint(address to, uint256 tokenId) internal virtual {
        _safeMint(to, tokenId, "");
    }

    /**
     * @dev Same as {xref-ERC721-_safeMint-address-uint256-}[`_safeMint`], with an additional `data` parameter which is
     * forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
     */
    function _safeMint(
        address to,
        uint256 tokenId,
        bytes memory _data
    ) internal virtual {
        _mint(to, tokenId);
        require(
            _checkOnERC721Received(address(0), to, tokenId, _data),
            "ERC721: transfer to non ERC721Receiver implementer"
        );
    }

    /**
     * @dev Mints `tokenId` and transfers it to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {_safeMint} whenever possible
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - `to` cannot be the zero address.
     *
     * Emits a {Transfer} event.
     */
    function _mint(address to, uint256 tokenId) internal virtual {
        require(to != address(0), "ERC721: mint to the zero address");
        require(!_exists(tokenId), "ERC721: token already minted");

        _beforeTokenTransfer(address(0), to, tokenId);

        _balances[to] += 1;
        _owners[tokenId] = to;

        emit Transfer(address(0), to, tokenId);
    }

    /**
     * @dev Destroys `tokenId`.
     * The approval is cleared when the token is burned.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     *
     * Emits a {Transfer} event.
     */
    function _burn(uint256 tokenId) internal virtual {
        address owner = ERC721.ownerOf(tokenId);

        _beforeTokenTransfer(owner, address(0), tokenId);

        // Clear approvals
        _approve(address(0), tokenId);

        _balances[owner] -= 1;
        delete _owners[tokenId];

        emit Transfer(owner, address(0), tokenId);
    }

    /**
     * @dev Transfers `tokenId` from `from` to `to`.
     *  As opposed to {transferFrom}, this imposes no restrictions on msg.sender.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     *
     * Emits a {Transfer} event.
     */
    function _transfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {
        require(ERC721.ownerOf(tokenId) == from, "ERC721: transfer of token that is not own");
        require(to != address(0), "ERC721: transfer to the zero address");

        _beforeTokenTransfer(from, to, tokenId);

        // Clear approvals from the previous owner
        _approve(address(0), tokenId);

        _balances[from] -= 1;
        _balances[to] += 1;
        _owners[tokenId] = to;

        emit Transfer(from, to, tokenId);
    }

    /**
     * @dev Approve `to` to operate on `tokenId`
     *
     * Emits a {Approval} event.
     */
    function _approve(address to, uint256 tokenId) internal virtual {
        _tokenApprovals[tokenId] = to;
        emit Approval(ERC721.ownerOf(tokenId), to, tokenId);
    }

    /**
     * @dev Internal function to invoke {IERC721Receiver-onERC721Received} on a target address.
     * The call is not executed if the target address is not a contract.
     *
     * @param from address representing the previous owner of the given token ID
     * @param to target address that will receive the tokens
     * @param tokenId uint256 ID of the token to be transferred
     * @param _data bytes optional data to send along with the call
     * @return bool whether the call correctly returned the expected magic value
     */
    function _checkOnERC721Received(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) private returns (bool) {
        if (to.isContract()) {
            try IERC721Receiver(to).onERC721Received(_msgSender(), from, tokenId, _data) returns (bytes4 retval) {
                return retval == IERC721Receiver.onERC721Received.selector;
            } catch (bytes memory reason) {
                if (reason.length == 0) {
                    revert("ERC721: transfer to non ERC721Receiver implementer");
                } else {
                    assembly {
                        revert(add(32, reason), mload(reason))
                    }
                }
            }
        } else {
            return true;
        }
    }

    /**
     * @dev Hook that is called before any token transfer. This includes minting
     * and burning.
     *
     * Calling conditions:
     *
     * - When `from` and `to` are both non-zero, ``from``'s `tokenId` will be
     * transferred to `to`.
     * - When `from` is zero, `tokenId` will be minted for `to`.
     * - When `to` is zero, ``from``'s `tokenId` will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {}
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../ERC721.sol";
import "./IERC721Enumerable.sol";

/**
 * @dev This implements an optional extension of {ERC721} defined in the EIP that adds
 * enumerability of all the token ids in the contract as well as all token ids owned by each
 * account.
 */
abstract contract ERC721Enumerable is ERC721, IERC721Enumerable {
    // Mapping from owner to list of owned token IDs
    mapping(address => mapping(uint256 => uint256)) private _ownedTokens;

    // Mapping from token ID to index of the owner tokens list
    mapping(uint256 => uint256) private _ownedTokensIndex;

    // Array with all token ids, used for enumeration
    uint256[] private _allTokens;

    // Mapping from token id to position in the allTokens array
    mapping(uint256 => uint256) private _allTokensIndex;

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(IERC165, ERC721) returns (bool) {
        return interfaceId == type(IERC721Enumerable).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev See {IERC721Enumerable-tokenOfOwnerByIndex}.
     */
    function tokenOfOwnerByIndex(address owner, uint256 index) public view virtual override returns (uint256) {
        require(index < ERC721.balanceOf(owner), "ERC721Enumerable: owner index out of bounds");
        return _ownedTokens[owner][index];
    }

    /**
     * @dev See {IERC721Enumerable-totalSupply}.
     */
    function totalSupply() public view virtual override returns (uint256) {
        return _allTokens.length;
    }

    /**
     * @dev See {IERC721Enumerable-tokenByIndex}.
     */
    function tokenByIndex(uint256 index) public view virtual override returns (uint256) {
        require(index < ERC721Enumerable.totalSupply(), "ERC721Enumerable: global index out of bounds");
        return _allTokens[index];
    }

    /**
     * @dev Hook that is called before any token transfer. This includes minting
     * and burning.
     *
     * Calling conditions:
     *
     * - When `from` and `to` are both non-zero, ``from``'s `tokenId` will be
     * transferred to `to`.
     * - When `from` is zero, `tokenId` will be minted for `to`.
     * - When `to` is zero, ``from``'s `tokenId` will be burned.
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual override {
        super._beforeTokenTransfer(from, to, tokenId);

        if (from == address(0)) {
            _addTokenToAllTokensEnumeration(tokenId);
        } else if (from != to) {
            _removeTokenFromOwnerEnumeration(from, tokenId);
        }
        if (to == address(0)) {
            _removeTokenFromAllTokensEnumeration(tokenId);
        } else if (to != from) {
            _addTokenToOwnerEnumeration(to, tokenId);
        }
    }

    /**
     * @dev Private function to add a token to this extension's ownership-tracking data structures.
     * @param to address representing the new owner of the given token ID
     * @param tokenId uint256 ID of the token to be added to the tokens list of the given address
     */
    function _addTokenToOwnerEnumeration(address to, uint256 tokenId) private {
        uint256 length = ERC721.balanceOf(to);
        _ownedTokens[to][length] = tokenId;
        _ownedTokensIndex[tokenId] = length;
    }

    /**
     * @dev Private function to add a token to this extension's token tracking data structures.
     * @param tokenId uint256 ID of the token to be added to the tokens list
     */
    function _addTokenToAllTokensEnumeration(uint256 tokenId) private {
        _allTokensIndex[tokenId] = _allTokens.length;
        _allTokens.push(tokenId);
    }

    /**
     * @dev Private function to remove a token from this extension's ownership-tracking data structures. Note that
     * while the token is not assigned a new owner, the `_ownedTokensIndex` mapping is _not_ updated: this allows for
     * gas optimizations e.g. when performing a transfer operation (avoiding double writes).
     * This has O(1) time complexity, but alters the order of the _ownedTokens array.
     * @param from address representing the previous owner of the given token ID
     * @param tokenId uint256 ID of the token to be removed from the tokens list of the given address
     */
    function _removeTokenFromOwnerEnumeration(address from, uint256 tokenId) private {
        // To prevent a gap in from's tokens array, we store the last token in the index of the token to delete, and
        // then delete the last slot (swap and pop).

        uint256 lastTokenIndex = ERC721.balanceOf(from) - 1;
        uint256 tokenIndex = _ownedTokensIndex[tokenId];

        // When the token to delete is the last token, the swap operation is unnecessary
        if (tokenIndex != lastTokenIndex) {
            uint256 lastTokenId = _ownedTokens[from][lastTokenIndex];

            _ownedTokens[from][tokenIndex] = lastTokenId; // Move the last token to the slot of the to-delete token
            _ownedTokensIndex[lastTokenId] = tokenIndex; // Update the moved token's index
        }

        // This also deletes the contents at the last position of the array
        delete _ownedTokensIndex[tokenId];
        delete _ownedTokens[from][lastTokenIndex];
    }

    /**
     * @dev Private function to remove a token from this extension's token tracking data structures.
     * This has O(1) time complexity, but alters the order of the _allTokens array.
     * @param tokenId uint256 ID of the token to be removed from the tokens list
     */
    function _removeTokenFromAllTokensEnumeration(uint256 tokenId) private {
        // To prevent a gap in the tokens array, we store the last token in the index of the token to delete, and
        // then delete the last slot (swap and pop).

        uint256 lastTokenIndex = _allTokens.length - 1;
        uint256 tokenIndex = _allTokensIndex[tokenId];

        // When the token to delete is the last token, the swap operation is unnecessary. However, since this occurs so
        // rarely (when the last minted token is burnt) that we still do the swap here to avoid the gas cost of adding
        // an 'if' statement (like in _removeTokenFromOwnerEnumeration)
        uint256 lastTokenId = _allTokens[lastTokenIndex];

        _allTokens[tokenIndex] = lastTokenId; // Move the last token to the slot of the to-delete token
        _allTokensIndex[lastTokenId] = tokenIndex; // Update the moved token's index

        // This also deletes the contents at the last position of the array
        delete _allTokensIndex[tokenId];
        _allTokens.pop();
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {safeTransferFrom} whenever possible.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes calldata data
    ) external;
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../IERC721.sol";

/**
 * @title ERC-721 Non-Fungible Token Standard, optional enumeration extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Enumerable is IERC721 {
    /**
     * @dev Returns the total amount of tokens stored by the contract.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns a token ID owned by `owner` at a given `index` of its token list.
     * Use along with {balanceOf} to enumerate all of ``owner``'s tokens.
     */
    function tokenOfOwnerByIndex(address owner, uint256 index) external view returns (uint256 tokenId);

    /**
     * @dev Returns a token ID at a given `index` of all the tokens stored by the contract.
     * Use along with {totalSupply} to enumerate all tokens.
     */
    function tokenByIndex(uint256 index) external view returns (uint256);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../IERC721.sol";

/**
 * @title ERC-721 Non-Fungible Token Standard, optional metadata extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Metadata is IERC721 {
    /**
     * @dev Returns the token collection name.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the token collection symbol.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
     */
    function tokenURI(uint256 tokenId) external view returns (string memory);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @title ERC721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be reverted.
     *
     * The selector can be obtained in Solidity with `IERC721.onERC721Received.selector`.
     */
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _setOwner(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _setOwner(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _setOwner(newOwner);
    }

    function _setOwner(address newOwner) private {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

// CAUTION
// This version of SafeMath should only be used with Solidity 0.8 or later,
// because it relies on the compiler's built in overflow checks.

/**
 * @dev Wrappers over Solidity's arithmetic operations.
 *
 * NOTE: `SafeMath` is no longer needed starting with Solidity 0.8. The compiler
 * now has built in overflow checking.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryAdd(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            uint256 c = a + b;
            if (c < a) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the substraction of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function trySub(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b > a) return (false, 0);
            return (true, a - b);
        }
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryMul(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
            // benefit is lost if 'b' is also tested.
            // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
            if (a == 0) return (true, 0);
            uint256 c = a * b;
            if (c / a != b) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the division of two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryDiv(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a / b);
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryMod(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a % b);
        }
    }

    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     *
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        return a + b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        return a - b;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     *
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        return a * b;
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator.
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        return a / b;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        return a % b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {trySub}.
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(
        uint256 a,
        uint256 b,
        string memory errorMessage
    ) internal pure returns (uint256) {
        unchecked {
            require(b <= a, errorMessage);
            return a - b;
        }
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(
        uint256 a,
        uint256 b,
        string memory errorMessage
    ) internal pure returns (uint256) {
        unchecked {
            require(b > 0, errorMessage);
            return a / b;
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting with custom message when dividing by zero.
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {tryMod}.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(
        uint256 a,
        uint256 b,
        string memory errorMessage
    ) internal pure returns (uint256) {
        unchecked {
            require(b > 0, errorMessage);
            return a % b;
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _HEX_SYMBOLS = "0123456789abcdef";

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        // Inspired by OraclizeAPI's implementation - MIT licence
        // https://github.com/oraclize/ethereum-api/blob/b42146b063c7d6ee1358846c198246239e9360e8/oraclizeAPI_0.4.25.sol

        if (value == 0) {
            return "0";
        }
        uint256 temp = value;
        uint256 digits;
        while (temp != 0) {
            digits++;
            temp /= 10;
        }
        bytes memory buffer = new bytes(digits);
        while (value != 0) {
            digits -= 1;
            buffer[digits] = bytes1(uint8(48 + uint256(value % 10)));
            value /= 10;
        }
        return string(buffer);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        if (value == 0) {
            return "0x00";
        }
        uint256 temp = value;
        uint256 length = 0;
        while (temp != 0) {
            length++;
            temp >>= 8;
        }
        return toHexString(value, length);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _HEX_SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }
}

{
  "compilationTarget": {
    "CityParks.sol": "CityParks"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}