// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/AccessControl.sol)

pragma solidity ^0.8.20;

import {IAccessControl} from "./IAccessControl.sol";
import {Context} from "./Context.sol";
import {ERC165} from "./ERC165.sol";

/**
 * @dev Contract module that allows children to implement role-based access
 * control mechanisms. This is a lightweight version that doesn't allow enumerating role
 * members except through off-chain means by accessing the contract event logs. Some
 * applications may benefit from on-chain enumerability, for those cases see
 * {AccessControlEnumerable}.
 *
 * Roles are referred to by their `bytes32` identifier. These should be exposed
 * in the external API and be unique. The best way to achieve this is by
 * using `public constant` hash digests:
 *
 * ```solidity
 * bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
 * ```
 *
 * Roles can be used to represent a set of permissions. To restrict access to a
 * function call, use {hasRole}:
 *
 * ```solidity
 * function foo() public {
 *     require(hasRole(MY_ROLE, msg.sender));
 *     ...
 * }
 * ```
 *
 * Roles can be granted and revoked dynamically via the {grantRole} and
 * {revokeRole} functions. Each role has an associated admin role, and only
 * accounts that have a role's admin role can call {grantRole} and {revokeRole}.
 *
 * By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
 * that only accounts with this role will be able to grant or revoke other
 * roles. More complex role relationships can be created by using
 * {_setRoleAdmin}.
 *
 * WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
 * grant and revoke this role. Extra precautions should be taken to secure
 * accounts that have been granted it. We recommend using {AccessControlDefaultAdminRules}
 * to enforce additional security measures for this role.
 */
abstract contract AccessControl is Context, IAccessControl, ERC165 {
    struct RoleData {
        mapping(address account => bool) hasRole;
        bytes32 adminRole;
    }

    mapping(bytes32 role => RoleData) private _roles;

    bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;

    /**
     * @dev Modifier that checks that an account has a specific role. Reverts
     * with an {AccessControlUnauthorizedAccount} error including the required role.
     */
    modifier onlyRole(bytes32 role) {
        _checkRole(role);
        _;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IAccessControl).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) public view virtual returns (bool) {
        return _roles[role].hasRole[account];
    }

    /**
     * @dev Reverts with an {AccessControlUnauthorizedAccount} error if `_msgSender()`
     * is missing `role`. Overriding this function changes the behavior of the {onlyRole} modifier.
     */
    function _checkRole(bytes32 role) internal view virtual {
        _checkRole(role, _msgSender());
    }

    /**
     * @dev Reverts with an {AccessControlUnauthorizedAccount} error if `account`
     * is missing `role`.
     */
    function _checkRole(bytes32 role, address account) internal view virtual {
        if (!hasRole(role, account)) {
            revert AccessControlUnauthorizedAccount(account, role);
        }
    }

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) public view virtual returns (bytes32) {
        return _roles[role].adminRole;
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleGranted} event.
     */
    function grantRole(bytes32 role, address account) public virtual onlyRole(getRoleAdmin(role)) {
        _grantRole(role, account);
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleRevoked} event.
     */
    function revokeRole(bytes32 role, address account) public virtual onlyRole(getRoleAdmin(role)) {
        _revokeRole(role, account);
    }

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been revoked `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `callerConfirmation`.
     *
     * May emit a {RoleRevoked} event.
     */
    function renounceRole(bytes32 role, address callerConfirmation) public virtual {
        if (callerConfirmation != _msgSender()) {
            revert AccessControlBadConfirmation();
        }

        _revokeRole(role, callerConfirmation);
    }

    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.
     */
    function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
        bytes32 previousAdminRole = getRoleAdmin(role);
        _roles[role].adminRole = adminRole;
        emit RoleAdminChanged(role, previousAdminRole, adminRole);
    }

    /**
     * @dev Attempts to grant `role` to `account` and returns a boolean indicating if `role` was granted.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleGranted} event.
     */
    function _grantRole(bytes32 role, address account) internal virtual returns (bool) {
        if (!hasRole(role, account)) {
            _roles[role].hasRole[account] = true;
            emit RoleGranted(role, account, _msgSender());
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Attempts to revoke `role` to `account` and returns a boolean indicating if `role` was revoked.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleRevoked} event.
     */
    function _revokeRole(bytes32 role, address account) internal virtual returns (bool) {
        if (hasRole(role, account)) {
            _roles[role].hasRole[account] = false;
            emit RoleRevoked(role, account, _msgSender());
            return true;
        } else {
            return false;
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/ERC165.sol)

pragma solidity ^0.8.20;

import {IERC165} from "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.22;

import "./IERC20.sol";
import "./SafeERC20.sol";


/**
 * @title Fund raising guild bank
 * @author BlockRocket.tech, Syndika
 */
contract FundRaisingGuild {
    using SafeERC20 for IERC20;

    address public stakingContract;

    /**
     * @notice Constructor
     * @param _stakingContract The staking contracts
     */
    constructor(address _stakingContract) {
        stakingContract = _stakingContract;
    }

    /**
     * @notice Withdraw any amount of specified token
     * @param _token The token address
     * @param _recipient Recipient address
     * @param _amount Amount of tokens
     * @dev Sender must be staking contract
     */
    function withdrawTo(IERC20 _token, address _recipient, uint256 _amount) external {
        require(msg.sender == stakingContract, "Guild.withdrawTo: Only staking contract");
        _token.safeTransfer(_recipient, _amount);
    }

    /**
     * @notice Get balance of specified token
     * @param _token The address of ERC20 token
     */
    function tokenBalance(IERC20 _token) external view returns (uint256) {
        return _token.balanceOf(address(this));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/IAccessControl.sol)

pragma solidity ^0.8.20;

/**
 * @dev External interface of AccessControl declared to support ERC165 detection.
 */
interface IAccessControl {
    /**
     * @dev The `account` is missing a role.
     */
    error AccessControlUnauthorizedAccount(address account, bytes32 neededRole);

    /**
     * @dev The caller of a function is not the expected one.
     *
     * NOTE: Don't confuse with {AccessControlUnauthorizedAccount}.
     */
    error AccessControlBadConfirmation();

    /**
     * @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
     *
     * `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
     * {RoleAdminChanged} not being emitted signaling this.
     */
    event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);

    /**
     * @dev Emitted when `account` is granted `role`.
     *
     * `sender` is the account that originated the contract call, an admin role
     * bearer except when using {AccessControl-_setupRole}.
     */
    event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Emitted when `account` is revoked `role`.
     *
     * `sender` is the account that originated the contract call:
     *   - if using `revokeRole`, it is the admin role bearer
     *   - if using `renounceRole`, it is the role bearer (i.e. `account`)
     */
    event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) external view returns (bool);

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {AccessControl-_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) external view returns (bytes32);

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function grantRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function revokeRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been granted `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `callerConfirmation`.
     */
    function renounceRole(bytes32 role, address callerConfirmation) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.22;

import "./IERC20.sol";
import "./SafeERC20.sol";
import "./ReentrancyGuard.sol";
import "./AccessControl.sol";
import {FundRaisingGuild} from "./FundRaisingGuild.sol";


/// @title Fund raising platform facilitated by launch pool
/// @author BlockRocket.tech, Syndika
/// @notice Fork of MasterChef.sol from SushiSwap
/// @dev Only the POOL_MANAGEMENT_ROLE role can add new pools
contract LaunchPoolAccessControlERC20FundRaisingWithDelayedVesting is ReentrancyGuard, AccessControl {
    // keccak256("ADMIN_ROLE")
    bytes32 public constant ADMIN_ROLE = 0xa49807205ce4d355092ef5a8a18f56e8913cf4a201fbe287825b095693c21775;
    // keccak256("POOL_MANAGEMENT_ROLE")
    bytes32 public constant POOL_MANAGEMENT_ROLE = 0x748e6e704f9e8a0607dcd3ee9838387c62f0e3ff37c2fdfde1bff8fd2bfd2729;
    // keccak256("FUND_MANAGEMENT_ROLE")
    bytes32 public constant FUND_MANAGEMENT_ROLE = 0x242fde9ae62216221a403f62519bf9b82fc4b05920f032ad90c1f21986721dc2;

    using SafeERC20 for IERC20;

    /// @dev Details about each user in a pool
    struct UserInfo {
        uint256 amount; // How many tokens are staked in a pool
        uint256 pledgeFundingAmount; // Based on staked tokens, the funding that has come from the user (or not if they choose to pull out)
        uint256 rewardDebtRewards; // Reward debt. See explanation below.
        uint256 tokenAllocDebt;
        //
        // We do some fancy math here. Basically, once vesting has started in a pool (if they have deposited), the amount of reward tokens
        // entitled to a user but is pending to be distributed is:
        //
        //   pending reward = (user.amount * pool.accRewardPerShare) - user.rewardDebtRewards
        //
        // The amount can never change once the staking period has ended
    }

    /// @dev Info of each pool.
    struct PoolInfo {
        IERC20 rewardToken; // Address of the reward token contract.
        IERC20 fundRaisingToken; // Address of the fund raising token contract.
        uint256 tokenAllocationStartTimestamp; // Timestamp when users stake counts towards earning reward token allocation
        uint256 stakingEndTimestamp; // Before this timestamp, staking is permitted
        uint256 pledgeFundingEndTimestamp; // Between stakingEndTimestamp and this number pledge funding is permitted
        uint256 targetRaise; // Amount that the project wishes to raise
        uint256 maxStakingAmountPerUser; // Max. amount of tokens that can be staked per account/user
    }

    /// @notice staking token is fixed for all pools
    IERC20 public stakingToken;

    /// @notice Container for holding all rewards
    FundRaisingGuild public rewardGuildBank;

    /// @notice List of pools that users can stake into
    PoolInfo[] public poolInfo;

    /// @notice Pool to accumulated share counters
    mapping(uint256 => uint256) public poolIdToAccPercentagePerShare;
    mapping(uint256 => uint256) public poolIdToLastPercentageAllocTimestamp;

    /// @notice Number of reward tokens distributed per timestamp for this pool
    mapping(uint256 => uint256) public poolIdToRewardPerTimestamp;

    /// @notice Last timestamp number that reward token distribution took place
    mapping(uint256 => uint256) public poolIdToLastRewardTimestamp;

    /// @notice Timestamp number when rewards start
    mapping(uint256 => uint256) public poolIdToRewardStartTimestamp;

    /// @notice Timestamp number when cliff ends
    mapping(uint256 => uint256) public poolIdToRewardCliffEndTimestamp;

    /// @notice Timestamp number when rewards end
    mapping(uint256 => uint256) public poolIdToRewardEndTimestamp;

    /// @notice Per LPOOL token staked, how much reward token earned in pool that users will get
    mapping(uint256 => uint256) public poolIdToAccRewardPerShareVesting;

    /// @notice Total rewards being distributed up to rewardEndTimestamp
    mapping(uint256 => uint256) public poolIdToMaxRewardTokensAvailableForVesting;

    /// @notice Total amount staked into the pool
    mapping(uint256 => uint256) public poolIdToTotalStaked;

    /// @notice Total amount of funding received by stakers after stakingEndTimestamp and before pledgeFundingEndTimestamp
    mapping(uint256 => uint256) public poolIdToTotalRaised;

    /// @notice For every staker that funded their pledge, the sum of all of their allocated percentages
    mapping(uint256 => uint256) public poolIdToTotalFundedPercentageOfTargetRaise;

    /// @notice True when funds have been claimed
    mapping(uint256 => bool) public poolIdToFundsClaimed;

    /// @notice Per pool, info of each user that stakes ERC20 tokens.
    /// @notice Pool ID => User Address => User Info
    mapping(uint256 => mapping(address => UserInfo)) public userInfo;

    /// @notice Available before staking ends for any given project. Essentitally 100% to 18 dp
    uint256 public constant TOTAL_TOKEN_ALLOCATION_POINTS = (100 * (10 ** 18));

    event ContractDeployed(address indexed guildBank);
    event PoolAdded(uint256 indexed pid);
    event PoolRewardTokenAdded(uint256 indexed pid, address rewardToken);
    event Pledge(address indexed user, uint256 indexed pid, uint256 amount);
    event PledgeFunded(address indexed user, uint256 indexed pid, uint256 amount);
    event RewardsSetUp(uint256 indexed pid, uint256 amount, uint256 rewardEndTimestamp);
    event RewardClaimed(address indexed user, uint256 indexed pid, uint256 amount);
    event Withdraw(address indexed user, uint256 indexed pid, uint256 amount);
    event FundRaisingClaimed(uint256 indexed pid, address indexed recipient, uint256 amount);

    /// @param _stakingToken Address of the staking token for all pools
    /// @param admins Addresses of the admins who will be able to grant roles
    constructor(IERC20 _stakingToken, address[] memory admins) {
        require(
            _checkZeroAddress(address(_stakingToken)) && _checkDeadAddress(address(_stakingToken)),
            "constructor: _stakingToken must not be zero address"
        );

        stakingToken = _stakingToken;
        rewardGuildBank = new FundRaisingGuild(address(this));

        _setRoleAdmin(POOL_MANAGEMENT_ROLE, ADMIN_ROLE);
        _setRoleAdmin(FUND_MANAGEMENT_ROLE, ADMIN_ROLE);

        for (uint256 i = 0; i < admins.length; ) {
            _grantRole(ADMIN_ROLE, admins[i]);
            unchecked {
                ++i;
            }
        }

        emit ContractDeployed(address(rewardGuildBank));
    }

    /**
     * @notice Batch grant roles. Can be called only by admin.
     * @param roles Roles to be granted
     * @param accounts Accounts
     */
    function batchGrantRole(bytes32[] memory roles, address[] memory accounts) public onlyRole(ADMIN_ROLE) {
        require(roles.length == accounts.length, "batchGrantRole: roles and accounts must be same length");

        for (uint256 i = 0; i < accounts.length; ) {
            _grantRole(roles[i], accounts[i]);
            unchecked {
                ++i;
            }
        }
    }

    /// @notice Returns the number of pools that have been added by the owner
    /// @return Number of pools
    function numberOfPools() external view returns (uint256) {
        return poolInfo.length;
    }

    /// @dev Can only be called by the contract pool manager
    function add(
        IERC20 _rewardToken,
        IERC20 _fundRaisingToken,
        uint256 _tokenAllocationStartTimestamp,
        uint256 _stakingEndTimestamp,
        uint256 _pledgeFundingEndTimestamp,
        uint256 _targetRaise,
        uint256 _maxStakingAmountPerUser,
        bool _withUpdate
    ) public onlyRole(POOL_MANAGEMENT_ROLE) {
        address fundRaisingTokenAddress = address(_fundRaisingToken);
        require(
            _checkZeroAddress(fundRaisingTokenAddress) && _checkDeadAddress(fundRaisingTokenAddress),
            "add: _fundRaisingToken is zero address"
        );
        require(
            _tokenAllocationStartTimestamp < _stakingEndTimestamp,
            "add: _tokenAllocationStartTimestamp must be before staking end"
        );
        require(_stakingEndTimestamp < _pledgeFundingEndTimestamp, "add: staking end must be before funding end");
        require(_targetRaise > 0, "add: Invalid raise amount");

        if (_withUpdate) {
            massUpdatePools();
        }

        poolInfo.push(
            PoolInfo({
                rewardToken: _rewardToken,
                fundRaisingToken: _fundRaisingToken,
                tokenAllocationStartTimestamp: _tokenAllocationStartTimestamp,
                stakingEndTimestamp: _stakingEndTimestamp,
                pledgeFundingEndTimestamp: _pledgeFundingEndTimestamp,
                targetRaise: _targetRaise,
                maxStakingAmountPerUser: _maxStakingAmountPerUser
            })
        );

        poolIdToLastPercentageAllocTimestamp[poolInfo.length - 1] = _tokenAllocationStartTimestamp;

        emit PoolAdded(poolInfo.length - 1);
    }

    /**
     * @notice Step 1. Enter to stake the `_amount` of `stakingToken`. Then the allocation mining starts.
     * @param _pid Pool Id.
     * @param _amount Amount to stake.
     */
    function pledge(uint256 _pid, uint256 _amount) external nonReentrant {
        require(_pid < poolInfo.length, "pledge: Invalid PID");

        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage user = userInfo[_pid][msg.sender];

        require(_amount > 0, "pledge: No pledge specified");
        require(block.timestamp <= pool.stakingEndTimestamp, "pledge: Staking no longer permitted");

        require(
            user.amount + _amount <= pool.maxStakingAmountPerUser,
            "pledge: can not exceed max staking amount per user"
        );

        updatePool(_pid);

        user.amount = user.amount + _amount;
        user.tokenAllocDebt = user.tokenAllocDebt + (_amount * poolIdToAccPercentagePerShare[_pid]) / 1e18;

        poolIdToTotalStaked[_pid] = poolIdToTotalStaked[_pid] + _amount;

        stakingToken.safeTransferFrom(address(msg.sender), address(this), _amount);

        emit Pledge(msg.sender, _pid, _amount);
    }

    /**
     * @notice Get the mined allocation to be funded.
     * @param _pid Pool Id.
     */
    function getPledgeFundingAmount(uint256 _pid) public view returns (uint256) {
        require(_pid < poolInfo.length, "getPledgeFundingAmount: Invalid PID");
        PoolInfo memory pool = poolInfo[_pid];
        UserInfo memory user = userInfo[_pid][msg.sender];

        (uint256 accPercentPerShare, ) = getAccPercentagePerShareAndLastAllocTimestamp(_pid);

        uint256 userPercentageAllocated = (user.amount * accPercentPerShare) / 1e18 - user.tokenAllocDebt;
        return (userPercentageAllocated * pool.targetRaise) / TOTAL_TOKEN_ALLOCATION_POINTS;
    }

    /**
     * @notice Step 2. Pay for allocation.
     * @param _pid Pool Id
     */
    function fundPledge(uint256 _pid) external nonReentrant {
        require(_pid < poolInfo.length, "fundPledge: Invalid PID");

        updatePool(_pid);

        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage user = userInfo[_pid][msg.sender];

        require(user.pledgeFundingAmount == 0, "fundPledge: Pledge has already been funded");

        require(block.timestamp > pool.stakingEndTimestamp, "fundPledge: Staking is still taking place");
        require(
            block.timestamp <= pool.pledgeFundingEndTimestamp,
            "fundPledge: Deadline has passed to fund your pledge"
        );

        require(user.amount > 0, "fundPledge: Must have staked");
        uint256 pledgeFundingAmount = getPledgeFundingAmount(_pid);
        require(pledgeFundingAmount > 0, "fundPledge: must have positive pledge amount");

        // this will fail if the sender does not have the right amount of the token
        pool.fundRaisingToken.safeTransferFrom(msg.sender, address(this), pledgeFundingAmount);

        poolIdToTotalRaised[_pid] = poolIdToTotalRaised[_pid] + pledgeFundingAmount;

        (uint256 accPercentPerShare, ) = getAccPercentagePerShareAndLastAllocTimestamp(_pid);
        uint256 userPercentageAllocated = (user.amount * accPercentPerShare) / 1e18 - user.tokenAllocDebt;
        poolIdToTotalFundedPercentageOfTargetRaise[_pid] =
            poolIdToTotalFundedPercentageOfTargetRaise[_pid] +
            userPercentageAllocated;

        user.pledgeFundingAmount = pledgeFundingAmount; // ensures pledges can only be done once

        stakingToken.safeTransfer(address(msg.sender), user.amount);

        emit PledgeFunded(msg.sender, _pid, pledgeFundingAmount);
    }

    /**
     * @param _pid Pool Id
     * @return raised - Total amount raised.
     * @return target - Target amount to be raised.
     */
    function getTotalRaisedVsTarget(uint256 _pid) external view returns (uint256 raised, uint256 target) {
        return (poolIdToTotalRaised[_pid], poolInfo[_pid].targetRaise);
    }

    /**
     * @notice Pool management role set up the reward token.
     * @param _pid Pool Id
     * @param _rewardToken Reward token that will be distributed
     */
    function setRewardTokenOnPool(uint256 _pid, IERC20 _rewardToken) external onlyRole(POOL_MANAGEMENT_ROLE) {
        require(_pid < poolInfo.length, "setRewardTokenOnPool: Invalid PID");
        address rewardTokenAddress = address(_rewardToken);
        require(
            _checkZeroAddress(rewardTokenAddress) && _checkDeadAddress(rewardTokenAddress),
            "setRewardTokenOnPool: _rewardToken is zero address"
        );
        PoolInfo storage pool = poolInfo[_pid];
        require(address(pool.rewardToken) == address(0), "setRewardTokenOnPool: rewardToken already set");
        pool.rewardToken = _rewardToken;
        emit PoolRewardTokenAdded(_pid, rewardTokenAddress);
    }

    /**
     * @notice Step 3. Setup vesting be pool management role.
     * @param _pid - Pool Id
     * @param _rewardAmount - Amount of reward tokens to be distributed
     * @param _rewardStartTimestamp - Reward Start Timestamp
     * @param _rewardCliffEndTimestamp - Timestamp number when cliff ends
     * @param _rewardEndTimestamp - Vesting end timestamp
     */
    function setupVestingRewards(
        uint256 _pid,
        uint256 _rewardAmount,
        uint256 _rewardStartTimestamp,
        uint256 _rewardCliffEndTimestamp,
        uint256 _rewardEndTimestamp
    ) external nonReentrant onlyRole(POOL_MANAGEMENT_ROLE) {
        require(_pid < poolInfo.length, "setupVestingRewards: Invalid PID");
        require(_rewardStartTimestamp > block.timestamp, "setupVestingRewards: start timestamp in the past");
        require(
            _rewardCliffEndTimestamp >= _rewardStartTimestamp,
            "setupVestingRewards: Cliff must be after or equal to start timestamp"
        );
        require(
            _rewardEndTimestamp > _rewardCliffEndTimestamp,
            "setupVestingRewards: end timestamp must be after cliff timestamp"
        );

        PoolInfo storage pool = poolInfo[_pid];
        address rewardTokenAddress = address(pool.rewardToken);
        require(
            _checkZeroAddress(rewardTokenAddress) && _checkDeadAddress(rewardTokenAddress),
            "setupVestingRewards: rewardToken is zero address"
        );

        require(block.timestamp > pool.pledgeFundingEndTimestamp, "setupVestingRewards: Stakers are still pledging");

        uint256 vestingLength = _rewardEndTimestamp - _rewardStartTimestamp;

        poolIdToMaxRewardTokensAvailableForVesting[_pid] = _rewardAmount;
        poolIdToRewardPerTimestamp[_pid] = _rewardAmount / vestingLength;

        poolIdToRewardStartTimestamp[_pid] = _rewardStartTimestamp;
        poolIdToLastRewardTimestamp[_pid] = _rewardStartTimestamp;

        poolIdToRewardCliffEndTimestamp[_pid] = _rewardCliffEndTimestamp;

        poolIdToRewardEndTimestamp[_pid] = _rewardEndTimestamp;

        pool.rewardToken.safeTransferFrom(msg.sender, address(rewardGuildBank), _rewardAmount);

        emit RewardsSetUp(_pid, _rewardAmount, _rewardEndTimestamp);
    }

    /**
     * @notice Get pending vesting rewards for user
     * @param _pid Pool Id
     * @param _user User address
     */
    function pendingRewards(uint256 _pid, address _user) external view returns (uint256) {
        require(_pid < poolInfo.length, "pendingRewards: invalid _pid");

        UserInfo memory user = userInfo[_pid][_user];

        // If they have staked but have not funded their pledge, they are not entitled to rewards
        if (user.pledgeFundingAmount == 0) {
            return 0;
        }

        uint256 accRewardPerShare = poolIdToAccRewardPerShareVesting[_pid];
        uint256 rewardEndTimestamp = poolIdToRewardEndTimestamp[_pid];
        uint256 lastRewardTimestamp = poolIdToLastRewardTimestamp[_pid];
        uint256 rewardPerTimestamp = poolIdToRewardPerTimestamp[_pid];
        if (block.timestamp > lastRewardTimestamp && rewardEndTimestamp != 0 && poolIdToTotalStaked[_pid] != 0) {
            uint256 maxEndTimestamp = block.timestamp <= rewardEndTimestamp ? block.timestamp : rewardEndTimestamp;
            uint256 multiplier = getMultiplier(lastRewardTimestamp, maxEndTimestamp);
            uint256 reward = multiplier * rewardPerTimestamp;
            accRewardPerShare = accRewardPerShare + (reward * 1e18) / poolIdToTotalFundedPercentageOfTargetRaise[_pid];
        }

        (uint256 accPercentPerShare, ) = getAccPercentagePerShareAndLastAllocTimestamp(_pid);
        uint256 userPercentageAllocated = (user.amount * accPercentPerShare) / 1e18 - user.tokenAllocDebt;
        return (userPercentageAllocated * accRewardPerShare) / 1e18 - user.rewardDebtRewards;
    }

    /**
     * @dev update all pools.
     */
    function massUpdatePools() public {
        for (uint256 pid = 0; pid < poolInfo.length; pid++) {
            updatePool(pid);
        }
    }

    /**
     * @notice Update pool parameters
     * @param _pid Pool Id
     */
    function updatePool(uint256 _pid) public {
        require(_pid < poolInfo.length, "updatePool: invalid _pid");

        PoolInfo storage _poolInfo = poolInfo[_pid];

        // staking not started
        if (block.timestamp < _poolInfo.tokenAllocationStartTimestamp) {
            return;
        }

        // if no one staked, nothing to do
        if (poolIdToTotalStaked[_pid] == 0) {
            poolIdToLastPercentageAllocTimestamp[_pid] = block.timestamp;
            return;
        }

        // token allocation not finished
        uint256 maxEndTimestampForPercentAlloc = block.timestamp <= _poolInfo.stakingEndTimestamp
            ? block.timestamp
            : _poolInfo.stakingEndTimestamp;
        uint256 timestampsSinceLastPercentAlloc = getMultiplier(
            poolIdToLastPercentageAllocTimestamp[_pid],
            maxEndTimestampForPercentAlloc
        );

        if (poolIdToRewardEndTimestamp[_pid] == 0 && timestampsSinceLastPercentAlloc > 0) {
            (uint256 accPercentPerShare, uint256 lastAllocTimestamp) = getAccPercentagePerShareAndLastAllocTimestamp(
                _pid
            );
            poolIdToAccPercentagePerShare[_pid] = accPercentPerShare;
            poolIdToLastPercentageAllocTimestamp[_pid] = lastAllocTimestamp;
        }

        // project has not sent rewards
        if (poolIdToRewardEndTimestamp[_pid] == 0) {
            return;
        }

        // cliff has not passed for pool
        if (block.timestamp < poolIdToRewardCliffEndTimestamp[_pid]) {
            return;
        }

        uint256 rewardEndTimestamp = poolIdToRewardEndTimestamp[_pid];
        uint256 lastRewardTimestamp = poolIdToLastRewardTimestamp[_pid];
        uint256 maxEndTimestamp = block.timestamp <= rewardEndTimestamp ? block.timestamp : rewardEndTimestamp;
        uint256 multiplier = getMultiplier(lastRewardTimestamp, maxEndTimestamp);

        // No point in doing any more logic as the rewards have ended
        if (multiplier == 0) {
            return;
        }

        uint256 rewardPerTimestamp = poolIdToRewardPerTimestamp[_pid];
        uint256 reward = multiplier * rewardPerTimestamp;

        poolIdToAccRewardPerShareVesting[_pid] =
            poolIdToAccRewardPerShareVesting[_pid] +
            (reward * 1e18) /
            poolIdToTotalFundedPercentageOfTargetRaise[_pid];
        poolIdToLastRewardTimestamp[_pid] = maxEndTimestamp;
    }

    /**
     * @notice Get accumulated percentage per share and last allocation timestamp
     * @param _pid Pool Id
     * @return accPercentPerShare - accumulated percentage per share
     * @return lastAllocTimestamp - last allocation timestamp
     */
    function getAccPercentagePerShareAndLastAllocTimestamp(
        uint256 _pid
    ) internal view returns (uint256 accPercentPerShare, uint256 lastAllocTimestamp) {
        PoolInfo memory _poolInfo = poolInfo[_pid];
        uint256 tokenAllocationPeriodInTimestamps = _poolInfo.stakingEndTimestamp -
            _poolInfo.tokenAllocationStartTimestamp;

        uint256 allocationAvailablePerTimestamp = TOTAL_TOKEN_ALLOCATION_POINTS / tokenAllocationPeriodInTimestamps;

        uint256 maxEndTimestampForPercentAlloc = block.timestamp <= _poolInfo.stakingEndTimestamp
            ? block.timestamp
            : _poolInfo.stakingEndTimestamp;
        uint256 multiplier = getMultiplier(poolIdToLastPercentageAllocTimestamp[_pid], maxEndTimestampForPercentAlloc);
        uint256 totalPercentageUnlocked = multiplier * allocationAvailablePerTimestamp;

        return (
            poolIdToAccPercentagePerShare[_pid] + (totalPercentageUnlocked * 1e18) / poolIdToTotalStaked[_pid],
            maxEndTimestampForPercentAlloc
        );
    }

    /**
     * @notice Claim vested rewards
     * @param _pid Pool Id
     */
    function claimReward(uint256 _pid) public nonReentrant {
        updatePool(_pid);

        require(block.timestamp >= poolIdToRewardCliffEndTimestamp[_pid], "claimReward: Not past cliff");

        UserInfo storage user = userInfo[_pid][msg.sender];
        require(user.pledgeFundingAmount > 0, "claimReward: Nice try pal");

        PoolInfo storage pool = poolInfo[_pid];
        address rewardTokenAddress = address(pool.rewardToken);
        require(
            _checkZeroAddress(address(rewardTokenAddress)) && _checkDeadAddress(address(rewardTokenAddress)),
            "claimReward: rewardToken is zero address"
        );

        uint256 accRewardPerShare = poolIdToAccRewardPerShareVesting[_pid];

        (uint256 accPercentPerShare, ) = getAccPercentagePerShareAndLastAllocTimestamp(_pid);
        uint256 userPercentageAllocated = (user.amount * accPercentPerShare) / 1e18 - user.tokenAllocDebt;
        uint256 pending = (userPercentageAllocated * accRewardPerShare) / 1e18 - user.rewardDebtRewards;

        if (pending > 0) {
            user.rewardDebtRewards = (userPercentageAllocated * accRewardPerShare) / 1e18;
            safeRewardTransfer(pool.rewardToken, msg.sender, pending);

            emit RewardClaimed(msg.sender, _pid, pending);
        }
    }

    /**
     * @notice withdraw only permitted post `pledgeFundingEndTimestamp` and you can only take out full amount if you did not fund the pledge
     * @dev functions like the old emergency withdraw as it does not concern itself with claiming rewards
     * @param _pid Pool Id
     */
    function withdraw(uint256 _pid) external nonReentrant {
        require(_pid < poolInfo.length, "withdraw: invalid _pid");

        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage user = userInfo[_pid][msg.sender];

        require(user.amount > 0, "withdraw: No stake to withdraw");
        require(user.pledgeFundingAmount == 0, "withdraw: Only allow non-funders to withdraw");
        require(block.timestamp > pool.pledgeFundingEndTimestamp, "withdraw: Not yet permitted");

        uint256 withdrawAmount = user.amount;

        // remove the record for this user
        delete userInfo[_pid][msg.sender];

        stakingToken.safeTransfer(msg.sender, withdrawAmount);

        emit Withdraw(msg.sender, _pid, withdrawAmount);
    }

    /**
     * @notice Claim fundRaising token by Pool management role.
     * @param _pid Pool Id
     */
    function claimFundRaising(uint256 _pid) external nonReentrant onlyRole(FUND_MANAGEMENT_ROLE) {
        require(_pid < poolInfo.length, "claimFundRaising: invalid _pid");
        PoolInfo storage pool = poolInfo[_pid];

        uint256 rewardPerTimestamp = poolIdToRewardPerTimestamp[_pid];
        require(rewardPerTimestamp != 0, "claimFundRaising: rewards not yet sent");
        require(poolIdToFundsClaimed[_pid] == false, "claimFundRaising: Already claimed funds");

        poolIdToFundsClaimed[_pid] = true;
        // this will fail if the sender does not have the right amount of the token
        pool.fundRaisingToken.transfer(msg.sender, poolIdToTotalRaised[_pid]);

        emit FundRaisingClaimed(_pid, msg.sender, poolIdToTotalRaised[_pid]);
    }

    ////////////
    // Private /
    ////////////

    /// @dev Safe reward transfer function, just in case if rounding error causes pool to not have enough rewards.
    function safeRewardTransfer(IERC20 _rewardToken, address _to, uint256 _amount) private {
        uint256 bal = rewardGuildBank.tokenBalance(_rewardToken);
        if (_amount > bal) {
            rewardGuildBank.withdrawTo(_rewardToken, _to, bal);
        } else {
            rewardGuildBank.withdrawTo(_rewardToken, _to, _amount);
        }
    }

    /// @notice Return reward multiplier over the given _from to _to timestamp.
    /// @param _from Timestamp number
    /// @param _to Timestamp number
    /// @return Number of timestamps that have passed
    function getMultiplier(uint256 _from, uint256 _to) private pure returns (uint256) {
        return _to - _from;
    }

    /**
     * @notice Cheap check `_wallet` to not be `0xdeaD` address
     * @param _wallet Address to check
     * @return _res false if `_wallet` equals Dead address
     */
    function _checkDeadAddress(address _wallet) internal pure returns (bool _res) {
        assembly {
            _res := true
            if eq(_wallet, 0xdEaD) {
                _res := false
            }
        }
    }

    /**
     * @notice Cheap check `_wallet` to not be `0x0` address
     * @param _wallet Address to check
     * @return _res false if `_wallet` equals Zero address
     */
    function _checkZeroAddress(address _wallet) internal pure returns (bool _res) {
        assembly {
            _res := true
            if eq(_wallet, 0x0) {
                _res := false
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC20Permit} from "./IERC20Permit.sol";
import {Address} from "./Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev An operation with an ERC20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data);
        if (returndata.length != 0 && !abi.decode(returndata, (bool))) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return success && (returndata.length == 0 || abi.decode(returndata, (bool))) && address(token).code.length > 0;
    }
}

{
  "compilationTarget": {
    "LaunchPoolAccessControlERC20FundRaisingWithDelayedVesting.sol": "LaunchPoolAccessControlERC20FundRaisingWithDelayedVesting"
  },
  "evmVersion": "shanghai",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}