// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.20;

import '@openzeppelin/contracts/access/Ownable2Step.sol';
import '@openzeppelin/contracts/token/ERC20/IERC20.sol';
import '@openzeppelin/contracts/utils/ReentrancyGuard.sol';
import '@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol';
import './interfaces/IFastPriceFeed.sol';
import './interfaces/IDoubler.sol';
import './interfaces/IRBToken.sol';
import './interfaces/IWETH.sol';
import './RBToken.sol';

/**
 * @title Doubler
 * @dev A contract for managing pools and handling token deposits and withdrawals.
 * Implements IDoubler interface and uses Ownable for access control.
 */
contract Doubler is IDoubler, ReentrancyGuard, Ownable2Step {
    using SafeERC20 for IERC20;

    bool private _initialized;
    uint16 private constant _slip = 50;
    uint16 private constant _perMil = 1000;
    uint16 private _rebaseBTokenShare;
    address private _fastPriceFeed;
    address private _ecoAddr;
    address private _rewardAddr;
    address private _wethAddr;
    mapping(address => uint256) private _lastBlockCalled;
    mapping(address => Pool) private _pools;
    mapping(address => mapping(uint256 => bool)) private _dealRecord;

    /**
     * @dev Constructor that sets the initial owner of the contract.
     * @param _initOwner The initial owner of the contract.
     */
    constructor(address _initOwner) Ownable(_initOwner) {}

    /**
    * @dev Initializes the Doubler contract with initial parameters.
    * @param _initFastPriceFeed The address of the initial fast price feed contract.
    * @param _initEcoAddr The address of the initial eco address.
    * @param _initWethAddr The address of the initial WETH address.
    * @param _initRebaseBTokenShare The initial rebase BToken share value.
    */
    function initializeDoubler(
        address _initFastPriceFeed,
        address _initEcoAddr,
        address _initWethAddr,
        uint16 _initRebaseBTokenShare
    ) external onlyOwner {
        if (_initFastPriceFeed == address(0) || _initEcoAddr == address(0) || _initWethAddr == address(0)) revert E_ZeroAddr();
        if (_initialized == true) revert E_Initialized();
        _initialized = true;
        _rebaseBTokenShare = _initRebaseBTokenShare;
        _fastPriceFeed = _initFastPriceFeed;
        _ecoAddr = _initEcoAddr;
        _wethAddr = _initWethAddr;
        RBToken reward = new RBToken('Reward Token', 'Reward', address(this));
        _rewardAddr = address(reward);
    }

    /**
     * @dev Returns the private variables of the contract.
     * @return _fastPriceFeed, _ecoAddr, _rewardAddr The addresses of fast price feed, weth address, eco address, and reward address.
     */
    function getPrivateVar() external view returns (address, address, address, address, uint16) {
        return (_fastPriceFeed, _ecoAddr, _rewardAddr, _wethAddr, _rebaseBTokenShare);
    }

    /**
     * @dev Modifier to check if the asset exists in the pools mapping.
     *      Modifier to ensure that a function can only be called once per block by the same eoa address.
     * @param _asset The address of the asset.
     */
    modifier onlyAssetAndBlock(address _asset) {
        if (_pools[_asset].aToken == address(0)) revert E_Asset();
        if (_lastBlockCalled[tx.origin] >= block.number) revert E_BlockOnce();
        _;
        _lastBlockCalled[tx.origin] = block.number;
    }

    /**
     * @dev Concatenates two strings.
     * @param _a The first string.
     * @param _b The second string.
     * @return The concatenated string.
     */
    function _concatenate(string memory _a, string memory _b) private pure returns (string memory) {
        return string(abi.encodePacked(_a, _b));
    }

    /**
     * @dev Creates a new pool with the specified parameters.
     * Can only be called by the owner.
     * @param _addPool The parameters for the new pool.
     */
    function newPool(AddPool calldata _addPool) external onlyOwner {
        _checkPoolParam(_addPool);
        if (_pools[_addPool.asset].aToken != address(0)) revert E_PoolInit();
        RBToken aToken = new RBToken(
            _concatenate(_addPool.tokenPre, '-E'),
            _concatenate(_addPool.tokenPre, '-E'),
            address(this)
        );
        RBToken bToken = new RBToken(
            _concatenate(_addPool.tokenPre, '-10x'),
            _concatenate(_addPool.tokenPre, '-10x'),
            address(this)
        );
        RBToken cToken = new RBToken(
            _concatenate(_addPool.tokenPre, '-C'),
            _concatenate(_addPool.tokenPre, '-C'),
            address(this)
        );
        Pool storage pool = _pools[_addPool.asset];
        pool.aToken = address(aToken);
        pool.bToken = address(bToken);
        pool.cToken = address(cToken);
        pool.asset = _addPool.asset;
        pool.inputFee = _addPool.inputFee;
        pool.redeemFee = _addPool.redeemFee;
        pool.withdrawFee = _addPool.withdrawFee;
        pool.lowerOfInputMaximum = _addPool.lowerOfInputMaximum;
        pool.creator = _addPool.creator;
        emit NewPool(_addPool.asset, pool.aToken, pool.bToken, pool.cToken);
    }

    /**
     * @dev Checks the parameters of a pool to ensure they are valid.
     * @param _pool The pool parameters to check.
     */
    function _checkPoolParam(AddPool calldata _pool) internal pure {
        if (_pool.asset == address(0)) revert E_ZeroAddr();
        if (_pool.inputFee > 20) revert E_FeeLimit();
        if (_pool.redeemFee > 20) revert E_FeeLimit();
        if (_pool.withdrawFee > 20) revert E_FeeLimit();
    }

    /**
     * @dev Updates the parameters of an existing pool.
     * Can only be called by the owner.
     * @param _updatePool The new parameters for the pool.
     */
    function updatePool(AddPool calldata _updatePool) external onlyOwner {
        _checkPoolParam(_updatePool);
        if (_pools[_updatePool.asset].aToken == address(0)) revert E_PoolInit();
        Pool storage pool = _pools[_updatePool.asset];
        pool.inputFee = _updatePool.inputFee;
        pool.redeemFee = _updatePool.redeemFee;
        pool.withdrawFee = _updatePool.withdrawFee;
        pool.creator = _updatePool.creator;
        emit UpdatePool(
            _updatePool.asset,
            _updatePool.creator,
            _updatePool.inputFee,
            _updatePool.redeemFee,
            _updatePool.withdrawFee
        );
    }

    /**
     * @dev Retrieves the balance of a specific asset (token) held by this contract
     * @param _asset The address of the token contract
     * @return uint256 The balance of the specified token held by this contract
     */
    function _getAssetBalance(address _asset) private view returns (uint256) {
        return IERC20(_asset).balanceOf(address(this));
    }

    /**
     * @dev Gets the average value of the specified asset in the pool.
     * @param _asset The address of the asset.
     * @return The average value of the asset.
     */
    function _getAssetAvg(address _asset) private view returns (uint256) {
        uint256 assetTotal = _getAssetBalance(_asset);
        if (assetTotal == 0) {
            return 0;
        }
        return (IERC20(_pools[_asset].cToken).totalSupply() * _getUnitSize(_asset)) / assetTotal;
    }

    /**
     * @dev Gets the current price of the specified asset from the fast price feed.
     * @param _asset The address of the asset.
     * @return The current price of the asset.
     */
    function _getCurPrice(address _asset) internal view returns (uint256) {
        return IFastPriceFeed(_fastPriceFeed).getPrice(_asset);
    }

    /**
     * @dev Gets the unit size of the specified asset based on its decimals.
     * @param _asset The address of the asset.
     * @return The unit size of the asset.
     */
    function _getUnitSize(address _asset) internal view returns (uint256) {
        return 10 ** IERC20Metadata(_asset).decimals();
    }

    /**
     * @dev Calculates the total value of the token pool based on the asset price and total amount.
     * @param _asset The address of the asset.
     * @param _price The current price of the asset.
     * @return poolTotal The total value of the token pool.
     */
    function _getTokenPoolTotal(address _asset, uint256 _price) internal view returns (uint256 poolTotal) {
        poolTotal = (_price * _getAssetBalance(_asset)) / _getUnitSize(_asset) / 10;
    }

    /**
     * @dev Handles the input of ETH into the pool for the specified asset.
     * @param _qAmount The quantity of ETH to input.
     * @param _to The address to receive the input tokens.
     */
    function inputEth(
        uint256 _qAmount,
        address _to
    ) external payable nonReentrant onlyAssetAndBlock(_wethAddr) {
        if (msg.value != _qAmount) revert E_Balance();
        _input(_wethAddr, _qAmount, _to, true);
    }

    /**
     * @dev Handles the input of tokens into the pool for the specified asset.
     * @param _asset The address of the asset.
     * @param _qAmount The quantity of tokens to input.
     * @param _to The address to receive the input tokens.
     */
    function input(
        address _asset,
        uint256 _qAmount,
        address _to
    ) external nonReentrant onlyAssetAndBlock(_asset) {
        if (IERC20(_asset).balanceOf(_msgSender()) < _qAmount) revert E_Balance();
        _input(_asset, _qAmount, _to, false);
    }

    /**
     * @dev Validates the input quantity amount based on specified constraints.
     *      The minimum investment is 1 USD, and the maximum investment is greater than (x) USD but less than TVL/100.
     * @param _asset The address of the asset (token) being invested.
     * @param _qAmount The quantity amount of the asset.
     * @param _curPrice The current price of the asset.
     * @param _assetUnitSize The unit size of the asset.
     * @param _lowerOfInputMaximum The lower of input maximum.
     */
    function _checkInputQAmount(
        address _asset,
        uint256 _qAmount,
        uint256 _curPrice,
        uint256 _assetUnitSize,
        uint256 _lowerOfInputMaximum
    ) internal view {
        uint256 inputValue = (_curPrice * _qAmount) / _assetUnitSize;
        uint256 inputMax = (_curPrice * _getAssetBalance(_asset)) / _assetUnitSize / 100;
        inputMax = inputMax > _lowerOfInputMaximum ? inputMax : _lowerOfInputMaximum;
        if (inputValue < 1 ether || inputValue > inputMax) revert E_InputLimit();
    }

    /**
     * @dev Internal function to handle the input of tokens into the pool.
     * @param _asset The address of the asset.
     * @param _qAmount The quantity of tokens to input.
     * @param _to The address to receive the input tokens.
     * @param  _isNative .
     */
    function _input(address _asset, uint256 _qAmount, address _to, bool _isNative) internal {
        _rebaseCToken(_asset);
        _rebaseBToken(_asset);
        Pool storage pool = _pools[_asset];
        uint256 curPrice = _getCurPrice(_asset);
        uint256 avg = _getAssetAvg(_asset); // get last avg
        avg = avg == 0 ? curPrice : avg;
        uint256 assetUnitSize = _getUnitSize(_asset);
        _checkInputQAmount(_asset, _qAmount, curPrice, assetUnitSize, pool.lowerOfInputMaximum);
        uint256 aAmount;
        uint256 bAmount;
        uint256 cAmount;
        uint256 aTokenUnitSize = _getUnitSize(pool.aToken);
        if (curPrice <= avg) {
            aAmount = (_qAmount * aTokenUnitSize) / assetUnitSize;
            cAmount = (curPrice * _qAmount) / assetUnitSize;
            bAmount = (curPrice * _qAmount - (curPrice * curPrice * _qAmount) / avg) / assetUnitSize;
        } else {
            aAmount = (curPrice * _qAmount * aTokenUnitSize) / avg / assetUnitSize;
            cAmount = avg * _qAmount / assetUnitSize;
        }
        if (_isNative) {
            IWETH(_asset).deposit{ value: msg.value }();
        } else {
            IERC20(_asset).safeTransferFrom(_msgSender(), address(this), _qAmount);
        }
        _mintABCToken(pool, _to, aAmount, bAmount, cAmount, curPrice);
        emit Input(_asset, _to, _qAmount, aAmount, bAmount, cAmount, curPrice, avg);
    }

    /**
     * @dev Gets the service fee address for the specified creator.
     * @param _creator The address of the creator.
     * @return srvFeeAddr An array of service fee addresses.
     */
    function _getSrvFeeAddr(address _creator) internal view returns (address[] memory srvFeeAddr) {
        srvFeeAddr = new address[](2);
        srvFeeAddr[0] = _creator;
        srvFeeAddr[1] = _ecoAddr;
    }

    /**
     * @dev Mints A, B, and C tokens for the specified pool.
     * @param _pool The pool information.
     * @param _to The address to receive the tokens.
     * @param _aAmount The quantity of A tokens(E) to mint.
     * @param _bAmount The quantity of B tokens(10x) to mint.
     * @param _cAmount The quantity of C tokens(C) to mint.
     * @param _curPrice The current price of the asset.
     */
    function _mintABCToken(
        Pool memory _pool,
        address _to,
        uint256 _aAmount,
        uint256 _bAmount,
        uint256 _cAmount,
        uint256 _curPrice
    ) internal {
        if (_bAmount > 0) {
            uint256 bTotal = _getTokenPoolTotal(_pool.asset, _curPrice);
            IRBToken(_pool.bToken).limitMint(_to, _bAmount, bTotal, _getSrvFeeAddr(_pool.creator), _pool.inputFee);
        }
        IRBToken(_pool.aToken).limitMint(_to, _aAmount, 0, _getSrvFeeAddr(_pool.creator), _pool.inputFee);
        IRBToken(_pool.cToken).mint(_to, _cAmount);
    }

    /**
     * @dev Calculates the amount of asset to withdraw.
     * @param _pool The pool information.
     * @param _cAmount The amount of cToken to withdraw.
     * @param _bTotal The total amount of bToken in the pool.
     * @param _cTotal The total amount of cToken in the pool.
     * @param _spendBAmount The amount of bToken spent.
     * @param _curPrice The current price of the asset.
     * @param _avgPrice The average price of the asset.
     * @return assetAmount The amount of asset to withdraw.
     */
    function _getWithdrawAssetAmount(
        Pool memory _pool,
        uint256 _cAmount,
        uint256 _bTotal,
        uint256 _cTotal,
        uint256 _spendBAmount,
        uint256 _curPrice,
        uint256 _avgPrice
    ) internal view returns (uint256 assetAmount) {
        uint256 assetUnitSize = _getUnitSize(_pool.asset);
        if (_curPrice >= _avgPrice) {
            uint256 profit = (((_getAssetBalance(_pool.asset) * _curPrice) / assetUnitSize - _cTotal) * _spendBAmount) /
                _bTotal;
            assetAmount = ((_cAmount + profit) * assetUnitSize) / _curPrice;
        } else {
            assetAmount = (_cAmount * assetUnitSize) / _avgPrice;
        }
    }

    /**
     * @dev Calculates the amount of bToken to spend for withdrawal.
     * @param _pool The pool information.
     * @param _cAmount The amount of cToken to withdraw.
     * @param _bTotal The total amount of bToken in the pool.
     * @param _cTotal The total amount of cToken in the pool.
     * @return spendBAmount The amount of bToken to spend.
     */
    function _getSpendBAmount(
        Pool memory _pool,
        uint256 _cAmount,
        uint256 _bTotal,
        uint256 _cTotal
    ) internal view returns (uint256 spendBAmount) {
        spendBAmount = (_cAmount * _bTotal) / _cTotal;
        uint256 uBTokenBalance = IERC20(_pool.bToken).balanceOf(_msgSender());
        if (_cTotal == _cAmount && spendBAmount > uBTokenBalance) {
            // The final withdrawal allows a precision error within 1/10 token.
            if (spendBAmount - uBTokenBalance <= _getUnitSize(_pool.bToken) / 10) spendBAmount = uBTokenBalance;
        }
        if (IERC20(_pool.cToken).balanceOf(_msgSender()) < _cAmount) revert E_Balance();
        if (uBTokenBalance < spendBAmount) revert E_Balance();
    }

    /**
     * @dev Withdraws the specified quantity of C tokens from the pool.
     * @param _asset The address of the asset.
     * @param _cAmount The quantity of C tokens to withdraw.
     * @param _qAmount The quantity of asset tokens to return.
     * @param _clientSlip The slip ratio of client.
     */
    function withdraw(
        address _asset,
        uint256 _cAmount,
        uint256 _qAmount,
        uint16 _clientSlip
    ) external nonReentrant onlyAssetAndBlock(_asset) {
        _rebaseCToken(_asset);
        _rebaseBToken(_asset);
        Pool storage pool = _pools[_asset];
        uint256 curPrice = _getCurPrice(_asset);
        uint256 avgPrice = _getAssetAvg(_asset);
        uint256 bTotal = _getTokenPoolTotal(_asset, curPrice);
        uint256 cTotal = IERC20(pool.cToken).totalSupply();
        uint256 spendBAmount = _getSpendBAmount(pool, _cAmount, bTotal, cTotal);
        uint256 assetAmount = _getWithdrawAssetAmount(pool, _cAmount, bTotal, cTotal, spendBAmount, curPrice, avgPrice);
        if(_getAssetBalance(_asset) <= assetAmount) {
            assetAmount = _getAssetBalance(_asset);
        }
        uint256 srvFee = (assetAmount * pool.withdrawFee) / _perMil;
        IRBToken(pool.cToken).burnFrom(_msgSender(), _cAmount);
        IRBToken(pool.bToken).burnFrom(_msgSender(), spendBAmount);
        IERC20(_asset).safeTransfer(pool.creator, srvFee/2);
        IERC20(_asset).safeTransfer(_ecoAddr, srvFee-srvFee/2);
        IERC20(_asset).safeTransfer(_msgSender(), assetAmount - srvFee);
        _checkAmountSlip(_qAmount, assetAmount - srvFee, _clientSlip);
        _checkWithdrawLimit(_asset, curPrice);
        emit Withdraw(_asset, _msgSender(), _cAmount, spendBAmount, assetAmount, curPrice, avgPrice);
    }

    /**
    * @dev Internal function to check if the remaining balance after withdrawal meets the minimum limit.
    * @param _asset The address of the asset.
    * @param _curPrice The current price of the asset in the smallest unit (e.g., wei).
    */
    function _checkWithdrawLimit(address _asset, uint256 _curPrice) internal view {
        uint256 lastBalance = _getAssetBalance(_asset);
        // Check if the balance is not zero and if the remaining balance after withdrawal   
        // multiplied by the current price divided by the unit size of the asset is less than 1 usd
        if (lastBalance != 0 && (lastBalance * _curPrice / _getUnitSize(_asset)) < 1 ether) {
            revert E_WithdrawLimit();
        }
    }

    /**
     * @dev Internal function to check if the expected amount after slippage is less than or equal to the received amount.
     * @param _eAmount The expected amount.
     * @param _rAmount The received amount.
     * @param _clientSlip The slip ratio of client.
     */
    function _checkAmountSlip(uint256 _eAmount, uint256 _rAmount, uint16 _clientSlip) internal pure {
        if (_clientSlip > _slip) revert E_SlipLimit();
        if ((_eAmount * (_perMil - _clientSlip)) / _perMil > _rAmount) {
            revert E_Expected();
        }
    }

    /**
     * @dev Redeems the specified quantity of A tokens for the specified asset.
     * @param _asset The address of the asset.
     * @param _aAmount The quantity of A tokens(E) to redeem.
     * @param _bAmount The quantity of B tokens(10x) to return.
     * @param _clientSlip The slip ratio of client.
     */
    function redeem(
        address _asset,
        uint256 _aAmount,
        uint256 _bAmount,
        uint16 _clientSlip
    ) external nonReentrant onlyAssetAndBlock(_asset) {
        Pool memory pool = _pools[_asset];
        if (IERC20(pool.aToken).balanceOf(_msgSender()) < _aAmount) revert E_Balance();
        _rebaseBToken(_asset);
        uint256 curPrice = _getCurPrice(_asset);
        uint256 bPoolTotal = _getTokenPoolTotal(pool.asset, curPrice);
        uint256 bPooledTotal = IERC20(pool.bToken).totalSupply();
        uint256 aTotal = IERC20(pool.aToken).totalSupply();
        IRBToken(pool.aToken).burnFrom(_msgSender(), _aAmount);
        uint256 bAmount = bPoolTotal > bPooledTotal ? (_aAmount * (bPoolTotal - bPooledTotal)) / aTotal : 0;
        uint256 recipientTokenAmount;
        if (bAmount > 0) {
            recipientTokenAmount = IRBToken(pool.bToken).limitMint(
                _msgSender(),
                bAmount,
                bPoolTotal,
                _getSrvFeeAddr(pool.creator),
                pool.redeemFee
            );
        }
        _checkAmountSlip(_bAmount, recipientTokenAmount, _clientSlip);
        emit Redeem(_asset, _aAmount, bAmount);
    }

    /**
     * @dev Gets the total value of the B token pool for the specified asset.
     * @param _asset The address of the asset.
     * @return poolTotal The total value of the B token pool.
     */
    function getBTokenPoolTotal(address _asset) external view returns (uint256 poolTotal) {
        Pool memory pool = _pools[_asset];
        uint256 curPrice = _getCurPrice(_asset);
        return _getTokenPoolTotal(pool.asset, curPrice);
    }

    /**
     * @dev Rebases the B tokens for the specified asset.
     * @param _asset The address of the asset.
     */
    function _rebaseBToken(address _asset) internal {
        uint256 curPrice = _getCurPrice(_asset);
        Pool storage pool = _pools[_asset];
        uint256 poolTotal = _getTokenPoolTotal(pool.asset, curPrice);
        uint256 pooledTotal = IERC20(pool.bToken).totalSupply();
        uint256 lastBTotal = _getTokenPoolTotal(pool.asset, pool.lastPrice);
        if (poolTotal > lastBTotal && poolTotal > pooledTotal && pooledTotal > 0) {
            pooledTotal = pooledTotal + ((poolTotal - lastBTotal) * _rebaseBTokenShare) / _perMil;
            IRBToken(pool.bToken).rebase(pooledTotal);
        }
        if (poolTotal < pooledTotal) {
            IRBToken(pool.bToken).rebase(poolTotal);
        }
        pool.lastPrice = curPrice;
    }

    /**
     * @dev Rebases the C tokens for the specified asset.
     * @param _asset The address of the asset.
     */
    function rebaseCToken(address _asset) external nonReentrant {
        _rebaseCToken(_asset);
    }

    /**
     * @dev Internal function to rebase the C tokens for the specified asset.
     * @param _asset The address of the asset.
     */
    function _rebaseCToken(address _asset) internal {
        uint256 avg = _getAssetAvg(_asset);
        uint256 curPrice = _getCurPrice(_asset);
        if (avg == 0 || curPrice <= avg || block.timestamp - _pools[_asset].cLastRbTime <= 1 days) {
            // avg == 0 then cLastRbTime update
            if (avg == 0) _pools[_asset].cLastRbTime = block.timestamp;
            return;
        }
        // some ext reward
        uint256 rewardUnitSize = _getUnitSize(_rewardAddr);
        IRBToken(_rewardAddr).mint(_msgSender(), 1000 * rewardUnitSize);

        _pools[_asset].cLastRbTime = block.timestamp;
        uint256 cTokenTotal = IERC20(_pools[_asset].cToken).totalSupply();
        // rebaseTotal =  cTokenTotal + cTokenTotal  * priceDiff / avg * 1%
        cTokenTotal = cTokenTotal + (cTokenTotal * (curPrice - avg)) / avg / 100;
        IRBToken(_pools[_asset].cToken).rebase(cTokenTotal);
    }

    /**
     * @dev Gets the pool information for the specified asset.
     * @param _asset The address of the asset.
     * @return pool The pool information.
     */
    function getPool(address _asset) external view returns (Pool memory pool) {
        pool = _pools[_asset];
    }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.20;

/**
 * @title IDoubler
 * @dev Interface for the Doubler contract, including custom errors, structures, and event definitions.
 */
interface IDoubler {
    // Custom errors
    error E_Initialized(); // Error for already initialized
    error E_Asset(); // Error for invalid asset
    error E_PoolInit(); // Error for pool already initialized
    error E_FeeLimit(); // Error for fee limit exceeded
    error E_ZeroAddr(); // Error for zero address
    error E_Balance(); // Error for insufficient balance
    error E_InputLimit(); // Error for input limit
    error E_Expected();
    error E_SlipLimit();
    error E_BlockOnce();
    error E_WithdrawLimit();

    // Structure for Pool information
    struct Pool {
        uint16 inputFee; // Fee for input transactions
        uint16 redeemFee; // Fee for redeem transactions
        uint16 withdrawFee; // Fee for withdraw transactions
        uint256 lastPrice; // Last recorded price of the asset
        uint256 cLastRbTime; // Last rebase time for C tokens
        uint256 lowerOfInputMaximum; 
        address asset; // Address of the asset
        address aToken; // Address of the A token(E)
        address bToken; // Address of the B token(10x)
        address cToken; // Address of the C token(C)
        address creator; // Address of the pool creator
    }

    struct WithdrawParam {
        address asset;
        uint256 cAmount;
        uint256 qAmount;
        uint16 clientSlip;
    }

    // Structure for adding a new pool
    struct AddPool {
        uint16 inputFee; // Fee for input transactions
        uint16 redeemFee; // Fee for redeem transactions
        uint16 withdrawFee; // Fee for withdraw transactions
        uint256 lowerOfInputMaximum; 
        address asset; // Address of the asset
        address creator; // Address of the pool creator
        string tokenPre; // Prefix for the token names
    }

    // Events
    event NewPool(address indexed asset, address aToken, address bToken, address cToken);
    event Input(
        address indexed asset,
        address indexed to,
        uint256 qAmount,
        uint256 aAmount,
        uint256 bAmount,
        uint256 cAmount,
        uint256 curPrice,
        uint256 avg
    );
    event Withdraw(
        address indexed asset,
        address indexed to,
        uint256 cAmount,
        uint256 bAmount,
        uint256 assetAmount,
        uint256 curPrice,
        uint256 avg
    );
    event Redeem(address indexed asset, uint256 aAmount, uint256 bAmount);
    event UpdatePool(address indexed asset, address creator, uint16 inputFee, uint16 redeemFee, uint16 withdrawFee);
    event UpdateLowerOfInputMaximum(uint256 oldInputLowerOfMaximum, uint256 newInputLowerOfMaximum);
    // Functions
    function getPrivateVar()
        external
        view
        returns (
            address fastPriceFeed,
            address ecoAddr,
            address rewardAddr,
            address wethAddr,
            uint16 rebaseBTokenShare
        );
    function newPool(AddPool calldata _addPool) external;
    function updatePool(AddPool calldata _updatePool) external;
    function inputEth(uint256 _qAmount, address _to) external payable;
    function input(address _asset, uint256 _qAmount, address _to) external;
    function redeem(address _asset, uint256 _aAmount, uint256 _bAmount, uint16 _clientSlip) external;
    function withdraw(address _asset, uint256 _cAmount, uint256 _qAmount, uint16 _clientSlip) external;
    function getPool(address _asset) external view returns (Pool memory pool);
    function getBTokenPoolTotal(address _asset) external view returns (uint256 poolTotal);
    function rebaseCToken(address _asset) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.20;

/// @title Fast Price Feed Interface
/// @notice Provides interface for the fast price feed functionality, allowing for efficient price updates and access.
interface IFastPriceFeed {
    error E_PriceLimits();
    error E_ZeroAddr();
    error E_AssetSupported();
    error E_AssetExist();
    error E_PlanExist();
    error E_Switch();
    error E_PlanNotExist();
    error E_TimeLimit();
    error E_PriceRange();
    error E_InitOracle();
    error E_TwapInterval();

    /// @dev Enum representing the various types of price feed plans.
    enum Plan {
        DEX, // Decentralized Exchange
        CHAINLINK // Chainlink Oracle
    }

    struct PriceFeed {
        Plan plan;
        address oracleAddr;
        uint32 timeLimit; // dex: twapIntervals, other: ttl
        uint256 priceMin; // Minimum price
        uint256 priceMax; // Maximum price
    }

    event SetAssetTimeLimit(address asset, uint256 oldTimeLimit, uint256 newTimeLimit);
    event SetPriceLimit(address indexed asset, Plan plan, uint256 priceMin, uint256 priceMax);
    event SetPriceFee(
        address indexed asset,
        Plan plan,
        address oracleAddr,
        uint256 timeLimit,
        uint256 priceMin,
        uint256 priceMax
    );

    function getPrice(address _asset) external view returns (uint256 price);

    function getAssetPlan(address _asset) external view returns (Plan);

    function getPriceFeeds(address _asset, Plan _plan) external view returns (PriceFeed memory);
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.20;

import '@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol';

/**
 * @title IRBToken
 * @dev Interface for the RBToken contract, extending IERC20Metadata and including custom errors and events.
 */
interface IRBToken is IERC20Metadata {
    // Custom errors
    error E_ZeroAddr(); // Error for zero address
    error E_Rebase(); // Error for rebase operation failure
    error E_AllowanceInvalid(); // Error for invalid allowance
    error E_TransferRBContract(); // Error for transfer to RBToken contract itself
    error E_BalanceInvalid(); // Error for invalid balance
    error E_AmountInvalid(); // Error for invalid amount

    // Events
    event TransferShares(address indexed from, address indexed to, uint256 sharesValue); // Event for shares transfer
    event SharesBurnt(
        address indexed account,
        uint256 preRebaseTokenAmount,
        uint256 postRebaseTokenAmount,
        uint256 sharesAmount
    ); // Event for shares burnt during rebase
    event Rebase(address asset, uint256 originTotalSupply, uint256 newTotalSupply); // Event for rebase operation

  

    /**
     * @dev Mints new tokens for a recipient.
     * @param _recipient The address of the recipient.
     * @param _tokenAmount The amount of tokens to mint.
     */
    function mint(address _recipient, uint256 _tokenAmount) external;

    /**
     * @dev Mints new tokens with a limit and service fee.
     * @param _recipient The address of the recipient.
     * @param _tokenAmount The amount of tokens to mint.
     * @param _poolTotalLimit The total limit for the pool.
     * @param _srvFeeAddr The addresses for the service fee.
     * @param _srvFeeRatio The ratio for the service fee.
     */
    function limitMint(
        address _recipient,
        uint256 _tokenAmount,
        uint256 _poolTotalLimit,
        address[] memory _srvFeeAddr,
        uint16 _srvFeeRatio
    ) external returns (uint256 recipientTokenAmount);

    /**
     * @dev Burns tokens from a specified address.
     * @param _from The address from which to burn tokens.
     * @param _tokenAmount The amount of tokens to burn.
     */
    function burnFrom(address _from, uint256 _tokenAmount) external;

    /**
     * @dev Rebases the pooled tokens to a new total.
     * @param _newTotalSupply The new total of pooled tokens.
     */
    function rebase(uint256 _newTotalSupply) external;

    /**
     * @dev Returns the total shares in the pool.
     */
    function totalShare() external view returns (uint256);

    /**
     * @dev Returns the shares of a specific account.
     * @param _account The address of the account.
     * @return The shares of the account.
     */
    function sharesOf(address _account) external view returns (uint256);

    /**
    * @dev Transfers shares to the recipient and returns the corresponding token amount.
    * @param _recipient The address of the recipient.
    * @param _sharesAmount The amount of shares to transfer.
    * @return The corresponding token amount.
    */
    function transferShares(address _recipient, uint256 _sharesAmount) external returns (uint256);

    /**
    * @dev Transfers shares from the sender to the recipient using an allowance mechanism, and returns the corresponding token amount.
    * @param _sender The address of the sender.
    * @param _recipient The address of the recipient.
    * @param _sharesAmount The amount of shares to transfer.
    * @return The corresponding token amount.
    */
    function transferSharesFrom(
        address _sender, address _recipient, uint256 _sharesAmount
    ) external returns (uint256) ;
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

interface IWETH {
    function deposit() external payable;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable2Step.sol)

pragma solidity ^0.8.20;

import {Ownable} from "./Ownable.sol";

/**
 * @dev Contract module which provides access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is specified at deployment time in the constructor for `Ownable`. This
 * can later be changed with {transferOwnership} and {acceptOwnership}.
 *
 * This module is used through inheritance. It will make available all functions
 * from parent (Ownable).
 */
abstract contract Ownable2Step is Ownable {
    address private _pendingOwner;

    event OwnershipTransferStarted(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Returns the address of the pending owner.
     */
    function pendingOwner() public view virtual returns (address) {
        return _pendingOwner;
    }

    /**
     * @dev Starts the ownership transfer of the contract to a new account. Replaces the pending transfer if there is one.
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual override onlyOwner {
        _pendingOwner = newOwner;
        emit OwnershipTransferStarted(owner(), newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`) and deletes any pending owner.
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual override {
        delete _pendingOwner;
        super._transferOwnership(newOwner);
    }

    /**
     * @dev The new owner accepts the ownership transfer.
     */
    function acceptOwnership() public virtual {
        address sender = _msgSender();
        if (pendingOwner() != sender) {
            revert OwnableUnauthorizedAccount(sender);
        }
        _transferOwnership(sender);
    }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.20;

import '@openzeppelin/contracts/access/Ownable.sol';
import './interfaces/IRBToken.sol';

/**
 * @title RBToken
 * @dev Implementation of a rebase token with minting, burning, and rebase functionality.
 * Inherits Ownable for access control.
 */
contract RBToken is IRBToken, Ownable {
    uint16 private constant _perMil = 1000; // Basis points (per mil) constant for fee calculations
    string private _name; // Token name
    string private _symbol; // Token symbol
    uint256 internal constant INFINITE_ALLOWANCE = ~uint256(0); // Infinite allowance constant
    uint256 private _totalShare; // Total shares in the pool
    uint256 private _pooledTotal; // Total pooled tokens
    mapping(address => uint256) private _shares; // Mapping of address to shares
    mapping(address => mapping(address => uint256)) private _allowances; // Allowance mapping

    /**
     * @dev Constructor to initialize the token with a name, symbol, and owner.
     * @param _initName The name of the token.
     * @param _initSymbol The symbol of the token.
     * @param _initOwner The address of the initial owner.
     */
    constructor(string memory _initName, string memory _initSymbol, address _initOwner) Ownable(_initOwner) {
        _name = _initName;
        _symbol = _initSymbol;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /**
     * @dev Returns the total supply of the pooled tokens.
     */
    function totalSupply() external view returns (uint256) {
        return _pooledTotal;
    }

    /**
     * @dev Returns the balance of pooled tokens for a specific account.
     * @param _account The address of the account.
     */
    function balanceOf(address _account) external view returns (uint256) {
        return _getPooledTokenByShares(_shares[_account]);
    }

    /**
     * @dev Transfers tokens from the caller to a recipient.
     * @param _recipient The address of the recipient.
     * @param _amount The amount of tokens to transfer.
     */
    function transfer(address _recipient, uint256 _amount) external returns (bool) {
        _transfer(msg.sender, _recipient, _amount);
        return true;
    }

    /**
     * @dev Returns the remaining number of tokens that `spender` will be allowed to spend on behalf of `owner`.
     * @param _owner The address of the owner.
     * @param _spender The address of the spender.
     */
    function allowance(address _owner, address _spender) external view returns (uint256) {
        return _allowances[_owner][_spender];
    }

    /**
     * @dev Sets the amount of tokens that an owner allows a spender.
     * @param _spender The address of the spender.
     * @param _amount The amount of tokens to allow.
     */
    function approve(address _spender, uint256 _amount) external returns (bool) {
        _approve(msg.sender, _spender, _amount);
        return true;
    }

    /**
     * @dev Transfers tokens from a sender to a recipient using the allowance mechanism.
     * @param _sender The address of the sender.
     * @param _recipient The address of the recipient.
     * @param _amount The amount of tokens to transfer.
     */
    function transferFrom(address _sender, address _recipient, uint256 _amount) external returns (bool) {
        _spendAllowance(_sender, msg.sender, _amount);
        _transfer(_sender, _recipient, _amount);
        return true;
    }

    /**
     * @dev Converts pooled tokens to shares.
     * @param _tokenAmount The amount of pooled tokens.
     * @return The corresponding shares.
     */
    function _getSharesByPooledToken(uint256 _tokenAmount) private view returns (uint256) {
        if (_pooledTotal == 0) {
            return _tokenAmount;
        }
        return (_tokenAmount * _totalShare) / _pooledTotal;
    }

    /**
     * @dev Converts shares to pooled tokens.
     * @param _sharesAmount The amount of shares.
     * @return The corresponding pooled tokens.
     */
    function _getPooledTokenByShares(uint256 _sharesAmount) private view returns (uint256) {
        if (_totalShare == 0) {
            return _sharesAmount;
        }
        return (_sharesAmount * _pooledTotal) / _totalShare;
    }

    /**
     * @dev Internal function to handle token transfer logic.
     * @param _sender The address of the sender.
     * @param _recipient The address of the recipient.
     * @param _amount The amount of tokens to transfer.
     */
    function _transfer(address _sender, address _recipient, uint256 _amount) internal {
        uint256 _sharesToTransfer = _getSharesByPooledToken(_amount);
        _transferShares(_sender, _recipient, _sharesToTransfer);
        _emitTransferEvents(_sender, _recipient, _amount, _sharesToTransfer);
    }

    /**
     * @dev Internal function to approve tokens for spending.
     * @param _owner The address of the owner.
     * @param _spender The address of the spender.
     * @param _amount The amount of tokens to approve.
     */
    function _approve(address _owner, address _spender, uint256 _amount) internal {
        if (_spender == address(0)) revert E_ZeroAddr();
        _allowances[_owner][_spender] = _amount;
        emit Approval(_owner, _spender, _amount);
    }

    /**
     * @dev Internal function to spend the allowance.
     * @param _owner The address of the owner.
     * @param _spender The address of the spender.
     * @param _amount The amount of tokens to spend.
     */
    function _spendAllowance(address _owner, address _spender, uint256 _amount) internal {
        uint256 currentAllowance = _allowances[_owner][_spender];
        if (currentAllowance != INFINITE_ALLOWANCE) {
            if (currentAllowance < _amount) revert E_AllowanceInvalid();
            _approve(_owner, _spender, currentAllowance - _amount);
        }
    }

    /**
     * @dev Internal function to transfer shares.
     * @param _sender The address of the sender.
     * @param _recipient The address of the recipient.
     * @param _sharesAmount The amount of shares to transfer.
     */
    function _transferShares(address _sender, address _recipient, uint256 _sharesAmount) internal {
        if (_recipient == address(0)) revert E_ZeroAddr();
        if (_recipient == address(this)) revert E_TransferRBContract();
        uint256 currentSenderShares = _shares[_sender];
        if (_sharesAmount > currentSenderShares) revert E_BalanceInvalid();
        _shares[_sender] = currentSenderShares - _sharesAmount;
        _shares[_recipient] = _shares[_recipient] + _sharesAmount;
    }

    /**
     * @dev Mints new tokens for a recipient.
     * @param _recipient The address of the recipient.
     * @param _tokenAmount The amount of tokens to mint.
     */
    function mint(address _recipient, uint256 _tokenAmount) external onlyOwner {
        address[] memory srvFeeAddr;
        _limitMint(_recipient, _tokenAmount, 0, srvFeeAddr, 0);
    }

    /**
     * @dev Mints new tokens with a limit and service fee.
     * @param _recipient The address of the recipient.
     * @param _tokenAmount The amount of tokens to mint.
     * @param _poolTotalLimit The total limit for the pool.
     * @param _srvFeeAddr The addresses for the service fee.
     * @param _srvFeeRatio The ratio for the service fee.
     */
    function limitMint(
        address _recipient,
        uint256 _tokenAmount,
        uint256 _poolTotalLimit,
        address[] memory _srvFeeAddr,
        uint16 _srvFeeRatio
    ) external onlyOwner returns (uint256 recipientTokenAmount) {
        return _limitMint(_recipient, _tokenAmount, _poolTotalLimit, _srvFeeAddr, _srvFeeRatio);
    }

    /**
     * @dev Internal function to mint new tokens with a limit and service fee.
     * @param _recipient The address of the recipient.
     * @param _tokenAmount The amount of tokens to mint.
     * @param _poolTotalLimit The total limit for the pool.
     * @param _srvFeeAddr The addresses for the service fee.
     * @param _srvFeeRatio The ratio for the service fee.
     */
    function _limitMint(
        address _recipient,
        uint256 _tokenAmount,
        uint256 _poolTotalLimit,
        address[] memory _srvFeeAddr,
        uint16 _srvFeeRatio
    ) internal returns (uint256 recipientTokenAmount) {
        if (_recipient == address(0)) revert E_ZeroAddr();
        uint256 newShares;
        if (_poolTotalLimit > 0 && _pooledTotal + _tokenAmount > _poolTotalLimit) {
            // Calculate new shares based on pool total limit
            // _tokenAmount = _poolTotalLimit * _newShares / (totalShare + newShares)
            if (_poolTotalLimit > _tokenAmount) {
                newShares = (_tokenAmount * _totalShare) / (_poolTotalLimit - _tokenAmount);
            } else {
                newShares = _totalShare * 10000 == 0 ? 10000 : _totalShare * 10000;
                _tokenAmount = (_poolTotalLimit * newShares) / (_totalShare + newShares);
            }
            _pooledTotal = _poolTotalLimit;
        } else {
            newShares = _getSharesByPooledToken(_tokenAmount);
            _pooledTotal = _pooledTotal + _tokenAmount;
        }

        _totalShare = _totalShare + newShares;
        uint256 recipientNewShare = newShares;
        recipientTokenAmount = _tokenAmount;
        if (_srvFeeRatio > 0) {
            uint256 srvFee = (newShares * _srvFeeRatio) / _perMil;
            recipientTokenAmount = recipientTokenAmount - (_tokenAmount * _srvFeeRatio) / _perMil;
            uint256 shareFeeRatio = _srvFeeAddr.length;
            for (uint16 i = 0; i < _srvFeeAddr.length; i++) {
                _shares[_srvFeeAddr[i]] = _shares[_srvFeeAddr[i]] + srvFee / shareFeeRatio;
                recipientNewShare = recipientNewShare - srvFee / shareFeeRatio;
                _emitTransferEvents(address(0x0), _srvFeeAddr[i], (_tokenAmount * _srvFeeRatio) / _perMil / shareFeeRatio, srvFee /shareFeeRatio);
            }
        }
        _shares[_recipient] = _shares[_recipient] + recipientNewShare;
        _emitTransferEvents(address(0x0), _recipient, recipientTokenAmount, recipientNewShare);
    }

    /**
     * @dev Burns tokens from a specified address.
     * @param _from The address from which to burn tokens.
     * @param _tokenAmount The amount of tokens to burn.
     */
    function burnFrom(address _from, uint256 _tokenAmount) external override onlyOwner {
        if (_from == address(0)) revert E_ZeroAddr();
        if (_getPooledTokenByShares(_shares[_from]) < _tokenAmount) revert E_AmountInvalid();
        uint256 burnShares = _getSharesByPooledToken(_tokenAmount);
        _totalShare = _totalShare - burnShares;
        _pooledTotal = _pooledTotal - _tokenAmount;
        _shares[_from] = _shares[_from] - burnShares;
        _emitTransferEvents(_from, address(0x0), _tokenAmount, burnShares);
    }

    /**
     * @dev Emits transfer events for token and shares transfers.
     * @param _from The address of the sender.
     * @param _to The address of the recipient.
     * @param _tokenAmount The amount of tokens transferred.
     * @param _sharesAmount The amount of shares transferred.
     */
    function _emitTransferEvents(address _from, address _to, uint256 _tokenAmount, uint256 _sharesAmount) internal {
        emit Transfer(_from, _to, _tokenAmount);
        emit TransferShares(_from, _to, _sharesAmount);
    }

    /**
     * @dev Rebases the pooled tokens to a new total.
     * @param _newTotalPooledToken The new total of pooled tokens.
     */
    function rebase(uint256 _newTotalPooledToken) external override onlyOwner {
        if (_totalShare == 0) revert E_Rebase();
        emit Rebase(address(this), _pooledTotal, _newTotalPooledToken);
        _pooledTotal = _newTotalPooledToken;
    }
    
    /**
    * @dev Returns the shares amount corresponding to the given pooled token amount.
    * @param _tokenAmount The amount of pooled tokens to query.
    * @return The corresponding shares amount.
    */
    function getSharesByPooledToken(uint256 _tokenAmount) public view returns (uint256) {
        return _getSharesByPooledToken(_tokenAmount);
    }

    /**
    * @dev Returns the pooled token amount corresponding to the given shares amount.
    * @param _sharesAmount The amount of shares to query.
    * @return The corresponding pooled token amount.
    */
    function getPooledByShares(uint256 _sharesAmount) public view returns (uint256) {
        return _getPooledTokenByShares(_sharesAmount);
    }

    /**
     * @dev Returns the total shares in the pool.
     */
    function totalShare() external view returns (uint256) {
        return _totalShare;
    }

    /**
     * @dev Returns the shares of a specific account.
     * @param _account The address of the account.
     */
    function sharesOf(address _account) external view returns (uint256) {
        return _shares[_account];
    }
    
    /**
    * @dev Transfers shares to the recipient and returns the corresponding token amount.
    * @param _recipient The address of the recipient.
    * @param _sharesAmount The amount of shares to transfer.
    * @return The corresponding token amount.
    */
    function transferShares(address _recipient, uint256 _sharesAmount) external returns (uint256) {
        _transferShares(msg.sender, _recipient, _sharesAmount);
        uint256 tokensAmount = _getSharesByPooledToken(_sharesAmount);
        _emitTransferEvents(msg.sender, _recipient, tokensAmount, _sharesAmount);
        return tokensAmount;
    }

    /**
    * @dev Transfers shares from the sender to the recipient using an allowance mechanism, and returns the corresponding token amount.
    * @param _sender The address of the sender.
    * @param _recipient The address of the recipient.
    * @param _sharesAmount The amount of shares to transfer.
    * @return The corresponding token amount.
    */
    function transferSharesFrom(
        address _sender, address _recipient, uint256 _sharesAmount
    ) external returns (uint256) {
        uint256 tokensAmount = _getSharesByPooledToken(_sharesAmount);
        _spendAllowance(_sender, msg.sender, tokensAmount);
        _transferShares(_sender, _recipient, _sharesAmount);
        _emitTransferEvents(_sender, _recipient, tokensAmount, _sharesAmount);
        return tokensAmount;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC20Permit} from "../extensions/IERC20Permit.sol";
import {Address} from "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev An operation with an ERC20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data);
        if (returndata.length != 0 && !abi.decode(returndata, (bool))) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return success && (returndata.length == 0 || abi.decode(returndata, (bool))) && address(token).code.length > 0;
    }
}

{
  "compilationTarget": {
    "contracts/Doubler.sol": "Doubler"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs",
    "useLiteralContent": true
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}