// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";

interface IArbswapToken is IERC20 {
    function mintByLiquidityMining(address _to, uint256 _amount) external;

    function mintByStaking(address _to, uint256 _amount) external;

    function mintByMiner(address _to, uint256 _amount) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

interface IVestingMaster {
    struct LockedReward {
        uint256 locked;
        uint256 timestamp;
    }
    // ----------- Events -----------

    event Lock(address indexed user, uint256 amount);
    event Claim(address indexed user, uint256 amount);

    // ----------- Farms only State changing api -----------

    function lock(address, uint256) external;

    // ----------- state changing API -----------

    function claim() external;

    // ----------- Getters -----------

    function period() external view returns (uint256);

    function lockedPeriodAmount() external view returns (uint256);

    function vestingToken() external view returns (address);

    function userLockedRewards(address account, uint256 idx) external view returns (uint256, uint256);

    function totalLockedRewards() external view returns (uint256);

    function getVestingAmount() external view returns (uint256, uint256);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "./interfaces/IArbswapToken.sol";
import "./interfaces/IVestingMaster.sol";

// The Contract is a fork of MasterChef by SushiSwap
// The biggest change made is using per second instead of per block for rewards
// This is due to Arbitrum extremely inconsistent block times
// The other biggest change was the removal of the migration functions
//
// Note that it's ownable and the owner wields tremendous power. The ownership
// will be transferred to a governance smart contract once ARBS is sufficiently
// distributed and the community can show to govern itself.
//
// Have fun reading it. Hopefully it's bug-free.
contract MasterChefV3 is Ownable {
    using SafeERC20 for IERC20;

    // Info of each user.
    struct UserInfo {
        uint256 amount; // How many LP tokens the user has provided.
        uint256 boostAmount; // In order to give users higher reward
        uint256 rewardDebt; // Reward debt.
        uint256 lockStartTime;
        uint256 lockEndTime;
    }

    // Info of each pool.
    struct PoolInfo {
        IERC20 lpToken; // Address of LP token contract.
        uint256 allocPoint; // How many allocation points assigned to this pool. ARBSs to distribute per block.
        uint256 lastRewardTime; // Last block time that ARBSs distribution occurs.
        uint256 accArbsPerShare; // Accumulated ARBSs per share, times 1e12. See below.
        bool lock;
        uint256 maxLockDuration;
        uint256 minLockDuration;
        uint256 durationFactor;
        uint256 boostWeight;
        uint256 boostAmount;
    }

    // Arbswap Token
    IArbswapToken public ARBS;

    IVestingMaster public Vesting;

    // Dev address.
    address public devaddr;
    // arbs tokens created per block.
    uint256 public arbsPerSecond;

    // set a max arbs per second, which can never be higher than 10 per second
    uint256 public constant maxArbsPerSecond = 100e18;

    uint256 public constant MaxAllocPoint = 40000000000000;

    uint256 public constant PRECISION = 1e12;

    uint256 public constant MAX_BOOST_WEIGHT = 50e12; // 5000%

    uint256 public constant MIN_BOOST_WEIGHT = 1e12; //100%

    // Info of each pool.
    PoolInfo[] public poolInfo;
    // Record whether pool is whitelist
    mapping(uint256 => bool) isWhitelistPool;
    // Record whether LP was added.
    mapping(address => bool) public LPTokenAdded;
    // Info of each user that stakes LP tokens.
    mapping(uint256 => mapping(address => UserInfo)) public userInfo;
    // Total allocation points. Must be the sum of all allocation points in all pools.
    uint256 public totalAllocPoint = 0;
    // The block time when arbs mining starts.
    uint256 public immutable startTime;

    event Deposit(address indexed user, uint256 indexed pid, uint256 amount);
    event DepositLockPool(
        address indexed user,
        uint256 indexed pid,
        uint256 amount,
        uint256 boostAmount,
        uint256 start,
        uint256 end
    );
    event Withdraw(address indexed user, uint256 indexed pid, uint256 amount);
    event EmergencyWithdraw(address indexed user, uint256 indexed pid, uint256 amount);
    event NewVesting(address indexed vesting);
    event Harvest(address indexed user, uint256 pid, uint256 pending);
    event NewArbsPerSecond(uint256 arbsPerSecond);
    event NewWhitelist(uint256 pid, bool valid);

    constructor(
        IArbswapToken _arbs,
        address _devaddr,
        uint256 _arbsPerSecond,
        uint256 _startTime
    ) {
        ARBS = _arbs;
        devaddr = _devaddr;
        arbsPerSecond = _arbsPerSecond;
        startTime = _startTime;
    }

    function poolLength() external view returns (uint256) {
        return poolInfo.length;
    }

    function setVesting(address _vesting) external onlyOwner {
        // Vesing can be zero address when we do not need vesting.
        Vesting = IVestingMaster(_vesting);
        emit NewVesting(_vesting);
    }

    function setWhitelistPool(uint256 _pid, bool _isValid) external onlyOwner {
        isWhitelistPool[_pid] = _isValid;
        emit NewWhitelist(_pid, _isValid);
    }

    // Changes arbs token reward per second, with a cap of maxarbs per second
    // Good practice to update pools without messing up the contract
    function setArbsPerSecond(uint256 _arbsPerSecond, bool _withUpdate) external onlyOwner {
        require(_arbsPerSecond <= maxArbsPerSecond, "setArbsPerSecond: too many arbs!");

        // This MUST be done or pool rewards will be calculated with new arbs per second
        // This could unfairly punish small pools that dont have frequent deposits/withdraws/harvests
        if (_withUpdate) {
            massUpdatePools();
        }

        arbsPerSecond = _arbsPerSecond;
        emit NewArbsPerSecond(_arbsPerSecond);
    }

    // Add a new lp to the pool. Can only be called by the owner.
    function add(
        uint256 _allocPoint,
        IERC20 _lpToken,
        bool _withUpdate,
        bool _lock,
        uint256 _maxLockDuration,
        uint256 _minLockDuration,
        uint256 _durationFactor,
        uint256 _boostWeight
    ) external onlyOwner {
        require(_allocPoint <= MaxAllocPoint, "add: too many alloc points!!");
        if (_lock) {
            require(
                _boostWeight >= MIN_BOOST_WEIGHT && _boostWeight <= MAX_BOOST_WEIGHT,
                "_boostWeight must be between MIN_BOOST_WEIGHT and MAX_BOOST_WEIGHT"
            );
            require(_minLockDuration > 0 && _maxLockDuration > _minLockDuration, "Invalid duration");
            require(_durationFactor > 0, "_durationFactor can not be zero");
        }

        // ensure you can not add duplicate pools
        require(!LPTokenAdded[address(_lpToken)], "Pool already exists!!!!");
        LPTokenAdded[address(_lpToken)] = true;

        if (_withUpdate) {
            massUpdatePools();
        }

        uint256 lastRewardTime = block.timestamp > startTime ? block.timestamp : startTime;
        totalAllocPoint += _allocPoint;
        poolInfo.push(
            PoolInfo({
                lpToken: _lpToken,
                allocPoint: _allocPoint,
                lastRewardTime: lastRewardTime,
                accArbsPerShare: 0,
                lock: _lock,
                maxLockDuration: _maxLockDuration,
                minLockDuration: _minLockDuration,
                durationFactor: _durationFactor,
                boostWeight: _boostWeight,
                boostAmount: 0
            })
        );
    }

    // Update the given pool's ARBS allocation point. Can only be called by the owner.
    function set(
        uint256 _pid,
        uint256 _allocPoint,
        bool _withUpdate
    ) external onlyOwner {
        require(_allocPoint <= MaxAllocPoint, "add: too many alloc points!!");
        if (_withUpdate) {
            massUpdatePools();
        }

        totalAllocPoint = totalAllocPoint - poolInfo[_pid].allocPoint + _allocPoint;
        poolInfo[_pid].allocPoint = _allocPoint;
    }

    function set(
        uint256 _pid,
        bool _withUpdate,
        uint256 _maxLockDuration,
        uint256 _minLockDuration,
        uint256 _durationFactor,
        uint256 _boostWeight
    ) external onlyOwner {
        PoolInfo storage pool = poolInfo[_pid];
        require(pool.lock, "Not lock pool");
        require(
            _boostWeight >= MIN_BOOST_WEIGHT && _boostWeight <= MAX_BOOST_WEIGHT,
            "_boostWeight must be between MIN_BOOST_WEIGHT and MAX_BOOST_WEIGHT"
        );
        require(_minLockDuration > 0 && _maxLockDuration > _minLockDuration, "Invalid duration");
        require(_durationFactor > 0, "_durationFactor can not be zero");
        if (_withUpdate) {
            massUpdatePools();
        }
        pool.maxLockDuration = _maxLockDuration;
        pool.minLockDuration = _minLockDuration;
        pool.durationFactor = _durationFactor;
        pool.boostWeight = _boostWeight;
    }

    // Return reward multiplier over the given _from to _to block.
    function getMultiplier(uint256 _from, uint256 _to) public view returns (uint256) {
        _from = _from > startTime ? _from : startTime;
        if (_to < startTime) {
            return 0;
        }
        return _to - _from;
    }

    // View function to see pending ARBSs on frontend.
    function pendingARBS(uint256 _pid, address _user) external view returns (uint256) {
        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage user = userInfo[_pid][_user];
        uint256 accArbsPerShare = pool.accArbsPerShare;
        uint256 lpSupply = pool.lpToken.balanceOf(address(this));
        if (pool.lock) {
            lpSupply = pool.boostAmount;
        }
        if (block.timestamp > pool.lastRewardTime && lpSupply != 0) {
            uint256 multiplier = getMultiplier(pool.lastRewardTime, block.timestamp);
            uint256 arbsReward = (multiplier * arbsPerSecond * (pool.allocPoint)) / totalAllocPoint;
            accArbsPerShare += (arbsReward * PRECISION) / lpSupply;
        }
        if (pool.lock) {
            return (user.boostAmount * accArbsPerShare) / PRECISION - user.rewardDebt;
        } else {
            return (user.amount * accArbsPerShare) / PRECISION - user.rewardDebt;
        }
    }

    // Update reward variables for all pools. Be careful of gas spending!
    function massUpdatePools() public {
        uint256 length = poolInfo.length;
        for (uint256 pid = 0; pid < length; ++pid) {
            updatePool(pid);
        }
    }

    // Update reward variables of the given pool to be up-to-date.
    function updatePool(uint256 _pid) public {
        PoolInfo storage pool = poolInfo[_pid];
        if (block.timestamp <= pool.lastRewardTime) {
            return;
        }
        uint256 lpSupply = pool.lpToken.balanceOf(address(this));
        if (lpSupply == 0) {
            pool.lastRewardTime = block.timestamp;
            return;
        }
        uint256 multiplier = getMultiplier(pool.lastRewardTime, block.timestamp);
        uint256 arbsReward = (multiplier * arbsPerSecond * pool.allocPoint) / totalAllocPoint;

        ARBS.mintByLiquidityMining(devaddr, arbsReward / 10);
        ARBS.mintByLiquidityMining(address(this), arbsReward);
        if (pool.lock) {
            lpSupply = pool.boostAmount;
        }
        pool.accArbsPerShare += (arbsReward * PRECISION) / lpSupply;
        pool.lastRewardTime = block.timestamp;
    }

    // Deposit LP tokens to MasterChef flexiable pool for ARBS allocation.
    function depositFlexible(uint256 _pid, uint256 _amount) public {
        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage user = userInfo[_pid][msg.sender];
        require(!pool.lock, "Lock pool");

        updatePool(_pid);

        uint256 pending = (user.amount * pool.accArbsPerShare) / PRECISION - user.rewardDebt;

        user.amount += _amount;
        user.rewardDebt = (user.amount * pool.accArbsPerShare) / PRECISION;

        if (pending > 0) {
            safeArbsTransfer(msg.sender, pending);
            emit Harvest(msg.sender, _pid, pending);
        }
        pool.lpToken.safeTransferFrom(address(msg.sender), address(this), _amount);

        emit Deposit(msg.sender, _pid, _amount);
    }

    // Deposit LP tokens to MasterChef lock pool for ARBS allocation.
    function depositLocked(
        uint256 _pid,
        uint256 _amount,
        uint256 _duration
    ) public {
        PoolInfo storage pool = poolInfo[_pid];
        require(pool.lock, "Not lock pool");
        UserInfo storage user = userInfo[_pid][msg.sender];
        if (user.amount > 0) {
            require(_amount > 0 || _duration > 0, "_amount and _duration can not be zero at the same time");
        } else {
            require(_amount > 0 && _duration > 0, "_amount and _duration can not be zero");
        }

        updatePool(_pid);

        uint256 totalLockDuration = _duration;
        if (user.lockEndTime >= block.timestamp) {
            if (_amount > 0) {
                user.lockStartTime = block.timestamp;
            }
            totalLockDuration += user.lockEndTime - user.lockStartTime;
        } else {
            user.lockStartTime = block.timestamp;
        }
        if (totalLockDuration < pool.minLockDuration) {
            totalLockDuration = pool.minLockDuration;
        }
        if (totalLockDuration > pool.maxLockDuration) {
            totalLockDuration = pool.maxLockDuration;
        }
        user.lockEndTime = user.lockStartTime + totalLockDuration;

        uint256 pending = (user.boostAmount * pool.accArbsPerShare) / PRECISION - user.rewardDebt;
        pool.boostAmount -= user.boostAmount;
        user.amount += _amount;
        user.boostAmount = (user.amount * totalLockDuration * pool.boostWeight) / pool.durationFactor / PRECISION;
        user.rewardDebt = (user.boostAmount * pool.accArbsPerShare) / PRECISION;
        pool.boostAmount += user.boostAmount;

        if (pending > 0) {
            safeArbsTransfer(msg.sender, pending);
            emit Harvest(msg.sender, _pid, pending);
        }
        pool.lpToken.safeTransferFrom(address(msg.sender), address(this), _amount);

        emit DepositLockPool(msg.sender, _pid, _amount, user.boostAmount, user.lockStartTime, user.lockEndTime);
    }

    // Harvest Arbs from pool.
    function harvest(uint256 _pid) external {
        UserInfo storage user = userInfo[_pid][msg.sender];
        require(user.amount > 0, "No LP");
        PoolInfo storage pool = poolInfo[_pid];
        updatePool(_pid);
        uint256 userReward;
        if (pool.lock) {
            userReward = (user.boostAmount * pool.accArbsPerShare) / PRECISION;
        } else {
            userReward = (user.amount * pool.accArbsPerShare) / PRECISION;
        }
        uint256 pending = userReward - user.rewardDebt;
        user.rewardDebt = userReward;

        if (pending > 0) {
            safeArbsTransfer(msg.sender, pending);
        }
        emit Harvest(msg.sender, _pid, pending);
    }

    // Withdraw LP tokens from MasterChef.
    function withdraw(uint256 _pid, uint256 _amount) public {
        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage user = userInfo[_pid][msg.sender];
        if (pool.lock) {
            require(user.lockEndTime < block.timestamp, "Still in lock");
        }
        require(user.amount >= _amount, "withdraw: not good");

        updatePool(_pid);

        uint256 pending;
        if (pool.lock) {
            pending = (user.boostAmount * pool.accArbsPerShare) / PRECISION - user.rewardDebt;
            pool.boostAmount -= user.boostAmount;
        } else {
            pending = (user.amount * pool.accArbsPerShare) / PRECISION - user.rewardDebt;
        }

        user.amount -= _amount;
        if (pool.lock) {
            user.boostAmount = user.amount;
            pool.boostAmount += user.boostAmount;
            user.lockStartTime = 0;
            user.lockEndTime = 0;
        }
        user.rewardDebt = (user.amount * pool.accArbsPerShare) / PRECISION;

        if (pending > 0) {
            safeArbsTransfer(msg.sender, pending);
            emit Harvest(msg.sender, _pid, pending);
        }
        pool.lpToken.safeTransfer(address(msg.sender), _amount);

        emit Withdraw(msg.sender, _pid, _amount);
    }

    // Withdraw without caring about rewards, Only for whitelist pool. EMERGENCY ONLY.
    function emergencyWithdraw(uint256 _pid) public {
        require(isWhitelistPool[_pid], "Not whitelist");
        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage user = userInfo[_pid][msg.sender];

        uint256 withdrawAmount = user.amount;
        user.amount = 0;
        user.rewardDebt = 0;

        pool.lpToken.safeTransfer(address(msg.sender), withdrawAmount);
        emit EmergencyWithdraw(msg.sender, _pid, withdrawAmount);
    }

    // Safe arbs transfer function, just in case if rounding error causes pool to not have enough ARBSs.
    function safeArbsTransfer(address _to, uint256 _amount) internal {
        uint256 arbsBal = ARBS.balanceOf(address(this));
        uint256 amount = _amount;
        if (_amount > arbsBal) {
            amount = arbsBal;
        }
        if (address(Vesting) != address(0)) {
            IERC20(address(ARBS)).safeTransfer(address(Vesting), amount);
            Vesting.lock(msg.sender, amount);
        } else {
            IERC20(address(ARBS)).safeTransfer(_to, amount);
        }
    }

    // Update dev address by the previous dev.
    function dev(address _devaddr) public {
        require(msg.sender == devaddr, "dev: wut?");
        devaddr = _devaddr;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    function safeTransfer(
        IERC20 token,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(
        IERC20 token,
        address from,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        uint256 newAllowance = token.allowance(address(this), spender) + value;
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            uint256 newAllowance = oldAllowance - value;
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address.functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        if (returndata.length > 0) {
            // Return data is optional
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}

{
  "compilationTarget": {
    "contracts/MasterChefV3.sol": "MasterChefV3"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 999999
  },
  "remappings": []
}