// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.20;

import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";

interface IZk0mni is IERC20 {
    function stakingMint(address user, uint amount) external;
    function stakingBurn(address user, uint amount) external;
}

contract Zk0Staking is ReentrancyGuard, Ownable {
    IZk0mni public zk0mni;
    address private feesReceiver;

    bool public depositAllowed = false;
    bool public claimAllowed = false;
    bool public rewardsLive = true;

    uint public lastRewardTimestamp; // timestamp of the last reward (set when rewards live set to false)
    uint public totalStaked;
    uint public totalRewarded;
    uint public forfeitCost = 20; // forfeit initially cost 20% of user's stake

    uint private constant PRECISION_DECIMALS = 1e18;
    uint private constant MIN_LOCK = 1 days;
    uint private constant MAX_LOCK = 7 days;

    address[] public stakers;
    mapping(address => uint) public stakersIndex; // position of each user in stakers array
    mapping(address => StakingData) public stakes;

    struct StakingData {
        bool isStaking;
        uint lockEndTimestamp;
        uint lastClaimTimestamp;
        uint totalAmountStaked;
        uint rewardsPerDay; // reward multiplication factor (in PRECISION_DECIMALS)
        uint lockPeriod;
    }

    constructor(address zk0mniAddress) Ownable(msg.sender) {
        zk0mni = IZk0mni(zk0mniAddress);

        feesReceiver = msg.sender;
    }

    function setFeesReceiver(address newFeesReceiver) external onlyOwner {
        feesReceiver = newFeesReceiver;
    }

    function setForfeitCost(uint newCost) external onlyOwner {
        require(newCost <= 100);
        forfeitCost = newCost;
    }

    function setRewardsLive(bool areRewardsLive) external onlyOwner {
        rewardsLive = areRewardsLive;
        lastRewardTimestamp = block.timestamp;
    }

    function setStakingStatus(
        bool isDepositAllowed,
        bool isClaimAllowed
    ) external onlyOwner {
        depositAllowed = isDepositAllowed;
        claimAllowed = isClaimAllowed;
    }

    // enter staking by depositing *tokenAmount* of ZK0 and locking token for *lockDelay*
    function deposit(uint tokenAmount, uint lockDelay) external nonReentrant {
        require(depositAllowed && rewardsLive, "Not allowed to enter staking.");
        address user = msg.sender;
        uint amountToAdd;

        zk0mni.stakingBurn(user, tokenAmount);

        // if the user has already entered staking
        if (stakes[user].isStaking) {
            require(
                lockDelay >= stakes[user].lockPeriod && lockDelay <= MAX_LOCK,
                "Invalid locking delay."
            );

            uint claimableRewards = claimAllowed
                ? getClaimableRewards(user)
                : 0;

            // amount to add is last stake amount + compounded rewards + new token amount
            amountToAdd = claimableRewards + tokenAmount;
            totalRewarded += claimableRewards;
        }
        // else, if the user has no current staking position
        else {
            require(
                lockDelay >= MIN_LOCK && lockDelay <= MAX_LOCK,
                "Invalid locking delay."
            );

            stakersIndex[user] = _addStakerArray(user);
            amountToAdd = tokenAmount; // amount to add is simply tokenAmount
        }

        stakes[user] = StakingData(
            true,
            block.timestamp + lockDelay,
            block.timestamp,
            stakes[user].totalAmountStaked + amountToAdd,
            getRewardsPerDay(lockDelay),
            lockDelay
        );
        totalStaked += tokenAmount;
    }

    // exit staking (automatically forfeit if locking period is not ended (cost *forfeitCost*% of user's staking))
    function withdraw() external nonReentrant {
        address user = msg.sender;

        require(stakes[user].isStaking, "User is not staking.");

        uint amountStaked = stakes[user].totalAmountStaked;

        if (claimAllowed) _claim(user);

        if (stakes[user].lockEndTimestamp <= block.timestamp) {
            // classic withdraw after lock period
            zk0mni.stakingMint(user, amountStaked);
        } else {
            // forfeit : withdraw (100-forfeitCost)% of staked token immediately
            uint fees = (forfeitCost * amountStaked) / 100;
            zk0mni.stakingMint(user, amountStaked - fees);
            zk0mni.stakingMint(feesReceiver, fees);
        }

        _removeStakerArray(user);
        delete stakes[user];
        totalStaked -= amountStaked;
    }

    // claim rewards of msg.sender
    function claim() external nonReentrant {
        require(claimAllowed, "Not allowed to claim.");

        address user = msg.sender;
        require(stakes[user].isStaking, "User is not staking.");

        _claim(user);
    }

    // internal claim function
    function _claim(address user) internal {
        uint claimableRewards = getClaimableRewards(user);

        // set last claim to block.timestamp if rewards continue or last reward timestamp if rewards are stopped
        stakes[user].lastClaimTimestamp = rewardsLive
            ? block.timestamp
            : lastRewardTimestamp;
        zk0mni.stakingMint(user, claimableRewards);

        totalRewarded += claimableRewards;
    }

    // add new staker to stakers array (used to track all existing users)
    function _addStakerArray(address user) private returns (uint index) {
        index = stakers.length;
        stakers.push(user);
    }

    // remove staker from stakers array (used to track all existing users)
    function _removeStakerArray(address user) private {
        uint index = stakersIndex[user];
        stakers[index] = stakers[stakers.length - 1];
        stakers.pop();
        delete stakersIndex[user];
    }

    // return the rewards per day for a certain lock delay (multiplication factor. PRECISION_DECIMALS = 100% per day)
    function getRewardsPerDay(uint lockDelay) public pure returns (uint) {
        // note : lockDelay is the amount of time the stake will be lock in seconds
        return
            ((lockDelay * PRECISION_DECIMALS) / (1 days) + PRECISION_DECIMALS) /
            100;
    }

    // return elapsed time between now (or last reward timestamp if rewards are off) and last claim of user
    function getElapsedDelay(address user) public view returns (uint) {
        return
            (rewardsLive ? block.timestamp : lastRewardTimestamp) -
            stakes[user].lastClaimTimestamp;
    }

    // return claimable reward at block.timestamp of user
    function getClaimableRewards(
        address user
    ) public view returns (uint rewards) {
        uint actualizedRate = (getElapsedDelay(user) *
            stakes[user].rewardsPerDay) / (1 days);
        rewards =
            (actualizedRate * stakes[user].totalAmountStaked) /
            PRECISION_DECIMALS;
    }

    // return total claimable rewards by all users
    function getTotalClaimableRewards(
        uint start,
        uint end
    ) external view returns (uint total) {
        if (end == 0) end = stakers.length;
        for (uint i = start; i < end; i++) {
            total += getClaimableRewards(stakers[i]);
        }
    }

    // return all unique current stakers
    function getStakers(
        uint start,
        uint end
    ) external view returns (address[] memory) {
        if (end == 0) end = stakers.length;
        address[] memory returnedStakers = new address[](end - start);

        for (uint i = start; i < end; i++) {
            returnedStakers[i] = stakers[i];
        }

        return returnedStakers;
    }
}

{
  "compilationTarget": {
    "contracts/Zk0Staking.sol": "Zk0Staking"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}