// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

pragma solidity ^0.8.0;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/access/Ownable.sol";

contract USDCFundraiser is Ownable {
    constructor() Ownable(msg.sender) {
        whitelistEnabled = true;
        isStopped = false;
        totalRaised = 0;
    }

    struct Investment {
        uint256 amount;
        bool exists;
    }

    address constant public FUNDRAISER_WALLET = 0x436Fd784cdF3e9F34990a754A5D43Dd0Bf1c5064;

    uint256 constant public MIN_INVESTMENT = 50 * 10**6;
    uint256 constant public MAX_INVESTMENT = 500 * 10**6;
    uint256 constant public MAX_INVESTMENT_OG = 1000 * 10**6;
    uint256 constant public HARDCAP = 250_000 * 10**6;

    bool public whitelistEnabled;
    bool public isStopped;

    uint256 public totalRaised;

    mapping(address => Investment) public investments;

    mapping(address => bool) public whitelisted;

    mapping(address => bool) public whitelistedOG;

    address[] public investors;

    event NewInvestment(address indexed investor, uint256 amount);
    event WhitelistUpdated(address indexed account, bool status);
    event WhitelistOGUpdated(address indexed account, bool status);
    event WhitelistStateChanged(bool enabled);
    event HardcapReached();

    modifier isEligible() {
        require(!whitelistEnabled || whitelisted[msg.sender] || whitelistedOG[msg.sender], "Must be whitelisted");
        require(!isStopped, "Raise is stopped");
        _;
    }

    function setWhitelistEnabled(bool _enabled) external onlyOwner {
        whitelistEnabled = _enabled;
        emit WhitelistStateChanged(_enabled);
    }

    function setStopRaise(bool _enabled) external onlyOwner {
        isStopped = _enabled;
    }

    function updateWhitelist(address account, bool status) external onlyOwner {
        whitelisted[account] = status;
        emit WhitelistUpdated(account, status);
    }

    function updateWhitelistOG(address account, bool status) external onlyOwner {
        whitelistedOG[account] = status;
        emit WhitelistOGUpdated(account, status);
    }

    function batchUpdateWhitelist(address[] calldata accounts, bool status) external onlyOwner {
        for(uint256 i = 0; i < accounts.length; i++) {
            whitelisted[accounts[i]] = status;
            emit WhitelistUpdated(accounts[i], status);
        }
    }

    function batchUpdateWhitelistOG(address[] calldata accounts, bool status) external onlyOwner {
        for(uint256 i = 0; i < accounts.length; i++) {
            whitelistedOG[accounts[i]] = status;
            emit WhitelistOGUpdated(accounts[i], status);
        }
    }

    function isWhitelisted(address account) external view returns (bool) {
        return whitelisted[account];
    }

    function isWhitelistedOG(address account) external view returns (bool) {
        return whitelistedOG[account];
    }

    function remainingToRaise() public view returns (uint256) {
        if (totalRaised >= HARDCAP) {
            return 0;
        }
        return HARDCAP - totalRaised;
    }

    function getMaxInvestment(address account) public view returns (uint256) {
        if (whitelistedOG[account]) {
            return MAX_INVESTMENT_OG;
        }
        if (whitelisted[account]) {
            return MAX_INVESTMENT;
        } 
        return 0;
    }

    function invest(uint256 amount) external isEligible {
        uint256 maxAllocation = getMaxInvestment(msg.sender);
        
        require((investments[msg.sender].amount + amount) >= MIN_INVESTMENT, "Investment too small");
        require((investments[msg.sender].amount + amount) <= maxAllocation, "Exceeds your maximum allocation");

        require(totalRaised + amount <= HARDCAP, "Would exceed hardcap");

        IERC20 usdc = IERC20(0x833589fCD6eDb6E08f4c7C32D4f71b54bdA02913); 
        require(usdc.transferFrom(msg.sender, FUNDRAISER_WALLET, amount), "Transfer failed");

        if (!investments[msg.sender].exists) {
            investments[msg.sender] = Investment(amount, true);
            investors.push(msg.sender);
        } else {
            investments[msg.sender].amount += amount;
        }

        totalRaised += amount;

        emit NewInvestment(msg.sender, amount);

        if (totalRaised >= HARDCAP) {
            emit HardcapReached();
        }
    }

    function withdraw() external onlyOwner {
        uint256 balance = address(this).balance;
        require(balance > 0, "No ETH to withdraw");

        (bool sent, ) = owner().call{value: balance}("");
        require(sent, "Failed to send ETH");
    }

    function withdrawToken(address tokenAddress) external onlyOwner {
        IERC20 token = IERC20(tokenAddress);
        uint256 balance = token.balanceOf(address(this));
        require(balance > 0, "No tokens to withdraw");

        require(token.transfer(owner(), balance), "Transfer failed");
    }

    function getListAllWallets() external onlyOwner view returns (address[] memory, uint256[] memory)  {
        uint256[] memory amounts = new uint256[](investors.length);

        for(uint256 i = 0; i < investors.length; i++) {
            amounts[i] = investments[investors[i]].amount;
        }

        return (investors, amounts);
    }

    function getInvestmentAmount(address investor) external view returns (uint256) {
        if (!investments[investor].exists) {
            return 0;
        }
        return investments[investor].amount;
    }
    

    receive() external payable {}
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

{
  "compilationTarget": {
    "contracts/Deposit.sol": "USDCFundraiser"
  },
  "evmVersion": "cancun",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}