// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity >=0.8.2 <0.9.0;

import "openzeppelin-contracts/contracts/access/Ownable.sol";
import "openzeppelin-contracts/contracts/utils/Pausable.sol";

contract MemeDepotPasses is Ownable, Pausable {
    constructor(address initialOwner) Ownable(initialOwner) Pausable() {}

    address public truthArtsWallet;
    uint256 public platformFeePercent;
    uint256 public defaultDepotFeePercent;

    // address:DepotId => FeePercent
    mapping(string => uint256) public perDepotFeePercent;

    // address:DepotId => DepotOwner
    mapping(string => address) public depotOwners;

    event BuyPasses(
        address buyer,
        string depotId,
        uint256 numberOfPasses,
        uint256 ethAmount,
        uint256 platformFeeEthAmount,
        uint256 depotFeeEthAmount
    );

    event SellPasses(
        address seller,
        string depotId,
        uint256 numberOfPasses,
        uint256 ethAmount,
        uint256 platformFeeEthAmount,
        uint256 depotFeeEthAmount
    );

    // address:DepotId => (address:PassHolder => Balance)
    mapping(string => mapping(address => uint256)) public passesBalance;

    // address:DepotId => NumberOfOutstandignPasses
    mapping(string => uint256) public outstandingPasses;

    function pause() public onlyOwner {
        _pause();
    }

    function unpause() public onlyOwner {
        _unpause();
    }

    function setTruthArtsWallet(
        address _wallet
    ) public onlyOwner whenNotPaused {
        truthArtsWallet = _wallet;
    }

    function setPlatormFeePercent(
        uint256 _percent
    ) public onlyOwner whenNotPaused {
        platformFeePercent = _percent;
    }

    function setDefaultDepotFeePercent(
        uint256 _percent
    ) public onlyOwner whenNotPaused {
        defaultDepotFeePercent = _percent;
    }

    function setDepotOwnerAddress(
        string calldata depotId,
        address ownerAddress
    ) public onlyOwner whenNotPaused {
        require(depotOwners[depotId] == address(0), "Depot owner already set");

        depotOwners[depotId] = ownerAddress;
        passesBalance[depotId][ownerAddress] = 1;
        outstandingPasses[depotId] = 1;

        emit BuyPasses(ownerAddress, depotId, 1, 0, 0, 0);
    }

    function setDepotFeePercent(
        string calldata depotId,
        uint256 _percent
    ) public whenNotPaused {
        require(
            msg.sender == owner() || msg.sender == depotOwners[depotId],
            "Unauthorized"
        );
        require(_percent > 0 && _percent < 100, "Invalid percent");
        perDepotFeePercent[depotId] = _percent;
    }

    function getDepotFee(
        string calldata depotId
    ) public view returns (uint256) {
        if (perDepotFeePercent[depotId] > 0) {
            return perDepotFeePercent[depotId];
        }
        return defaultDepotFeePercent;
    }

    function getPrice(
        uint256 supply,
        uint256 amount
    ) public pure returns (uint256) {
        uint256 sum1 = supply == 0
            ? 0
            : ((supply - 1) * (supply) * (2 * (supply - 1) + 1)) / 6;
        uint256 sum2 = supply == 0 && amount == 1
            ? 0
            : ((supply - 1 + amount) *
                (supply + amount) *
                (2 * (supply - 1 + amount) + 1)) / 6;
        uint256 summation = sum2 - sum1;
        return (summation * 1 ether) / 16000;
    }

    function getBuyPrice(
        string calldata depotId,
        uint256 numberOfPasses
    ) public view returns (uint256) {
        return getPrice(outstandingPasses[depotId], numberOfPasses);
    }

    function getSellPrice(
        string calldata depotId,
        uint256 numberOfPasses
    ) public view returns (uint256) {
        return
            getPrice(
                outstandingPasses[depotId] - numberOfPasses,
                numberOfPasses
            );
    }

    function getBuyPriceAfterFee(
        string calldata depotId,
        uint256 numberOfPasses
    ) public view returns (uint256) {
        uint256 passesPrice = getBuyPrice(depotId, numberOfPasses);
        uint256 platformFee = (passesPrice * platformFeePercent) / 1 ether;
        uint256 depotFee = (passesPrice * getDepotFee(depotId)) / 1 ether;
        return passesPrice + platformFee + depotFee;
    }

    function getSellPriceAfterFee(
        string calldata depotId,
        uint256 numberOfPasses
    ) public view returns (uint256) {
        uint256 price = getSellPrice(depotId, numberOfPasses);
        uint256 platformFee = (price * platformFeePercent) / 1 ether;
        uint256 depotFee = (price * getDepotFee(depotId)) / 1 ether;
        return price - platformFee - depotFee;
    }

    function buyPasses(
        string calldata depotId,
        uint256 numberOfPasses
    ) public payable whenNotPaused {
        address depotOwnerAddress = depotOwners[depotId];
        require(
            depotOwnerAddress != address(0),
            "Depot does not support passes"
        );

        uint256 supply = outstandingPasses[depotId];
        uint256 passesPrice = getPrice(supply, numberOfPasses);
        uint256 platformFee = (passesPrice * platformFeePercent) / 1 ether;
        uint256 depotFee = (passesPrice * getDepotFee(depotId)) / 1 ether;
        require(
            msg.value >= passesPrice + platformFee + depotFee,
            "Insufficient payment"
        );
        passesBalance[depotId][msg.sender] =
            passesBalance[depotId][msg.sender] +
            numberOfPasses;
        outstandingPasses[depotId] = supply + numberOfPasses;

        emit BuyPasses(
            msg.sender,
            depotId,
            numberOfPasses,
            passesPrice,
            platformFee,
            depotFee
        );

        if (platformFee > 0) {
            (bool platformFeeSuccess, ) = truthArtsWallet.call{
                value: platformFee
            }("");
            require(platformFeeSuccess, "Unable to send platform fee");
        }

        if (depotFee > 0) {
            (bool depotFeeSuccess, ) = depotOwnerAddress.call{value: depotFee}(
                ""
            );
            require(depotFeeSuccess, "Unable to send depot fee");
        }
    }

    function sellPasses(
        string calldata depotId,
        uint256 numberOfPasses
    ) public payable whenNotPaused {
        address depotOwnerAddress = depotOwners[depotId];
        require(
            depotOwnerAddress != address(0),
            "Depot does not support passes"
        );

        uint256 supply = outstandingPasses[depotId];
        require(supply > numberOfPasses, "Cannot sell the last depot pass");

        uint256 passesPrice = getPrice(supply - numberOfPasses, numberOfPasses);
        uint256 platformFee = (passesPrice * platformFeePercent) / 1 ether;
        uint256 depotFee = (passesPrice * getDepotFee(depotId)) / 1 ether;
        require(
            passesBalance[depotId][msg.sender] >= numberOfPasses,
            "Not enough passes"
        );
        passesBalance[depotId][msg.sender] =
            passesBalance[depotId][msg.sender] -
            numberOfPasses;
        outstandingPasses[depotId] = supply - numberOfPasses;

        emit SellPasses(
            msg.sender,
            depotId,
            numberOfPasses,
            passesPrice,
            platformFee,
            depotFee
        );

        (bool success1, ) = msg.sender.call{
            value: passesPrice - platformFee - depotFee
        }("");
        require(success1, "Unable to send payment");

        if (platformFee > 0) {
            (bool platformFeeSuccess, ) = truthArtsWallet.call{
                value: platformFee
            }("");
            require(platformFeeSuccess, "Unable to send platform fee");
        }

        if (depotFee > 0) {
            (bool depotFeeSuccess, ) = depotOwnerAddress.call{value: depotFee}(
                ""
            );
            require(depotFeeSuccess, "Unable to send depot fee");
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Pausable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    bool private _paused;

    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    /**
     * @dev The operation failed because the contract is paused.
     */
    error EnforcedPause();

    /**
     * @dev The operation failed because the contract is not paused.
     */
    error ExpectedPause();

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        if (paused()) {
            revert EnforcedPause();
        }
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        if (!paused()) {
            revert ExpectedPause();
        }
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

{
  "compilationTarget": {
    "src/MemeDepotPasses.sol": "MemeDepotPasses"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": [
    ":@openzeppelin/contracts/=lib/openzeppelin-contracts/contracts/",
    ":ds-test/=lib/openzeppelin-contracts/lib/forge-std/lib/ds-test/src/",
    ":erc4626-tests/=lib/openzeppelin-contracts/lib/erc4626-tests/",
    ":forge-std/=lib/forge-std/src/",
    ":openzeppelin-contracts/=lib/openzeppelin-contracts/"
  ]
}