// SPDX-License-Identifier: MIT

pragma solidity ^0.6.2;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // According to EIP-1052, 0x0 is the value returned for not-yet created accounts
        // and 0xc5d2460186f7233c927e7db2dcc703c0e500b653ca82273b7bfad8045d85a470 is returned
        // for accounts without code, i.e. `keccak256('')`
        bytes32 codehash;
        bytes32 accountHash = 0xc5d2460186f7233c927e7db2dcc703c0e500b653ca82273b7bfad8045d85a470;
        // solhint-disable-next-line no-inline-assembly
        assembly { codehash := extcodehash(account) }
        return (codehash != accountHash && codehash != 0x0);
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        // solhint-disable-next-line avoid-low-level-calls, avoid-call-value
        (bool success, ) = recipient.call{ value: amount }("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain`call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
      return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        return _functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value, string memory errorMessage) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        return _functionCallWithValue(target, data, value, errorMessage);
    }

    function _functionCallWithValue(address target, bytes memory data, uint256 weiValue, string memory errorMessage) private returns (bytes memory) {
        require(isContract(target), "Address: call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.call{ value: weiValue }(data);
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                // solhint-disable-next-line no-inline-assembly
                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.6.0;

/*
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with GSN meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address payable) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes memory) {
        this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.5.0 <0.7.0;

import './Trib.sol';
import './Genesis.sol';
import './interfaces/IVault.sol';
import './utils/MathUtils.sol';
import '@openzeppelin/contracts/token/ERC20/IERC20.sol';
import '@openzeppelin/contracts/token/ERC20/SafeERC20.sol';
import '@openzeppelin/contracts/math/SafeMath.sol';
import '@openzeppelin/contracts/utils/ReentrancyGuard.sol';

/// @title Contribute
/// @notice A capital coordination tool.
/// @author Kento Sadim
contract Contribute is ReentrancyGuard {
  using SafeMath for uint256;
  using MathUtils for uint256;
  using SafeERC20 for IERC20;

  event TokensBought(address indexed from, uint256 amountInvested, uint256 tokensMinted);
  event TokensSold(address indexed from, uint256 tokensSold, uint256 amountReceived);
  event MintAndBurn(uint256 reserveAmount, uint256 tokensBurned);
  event InterestClaimed(address indexed from, uint256 initerestAmount);

  /// @notice A 10% tax is applied to every purchase or sale of tokens.
  uint256 public constant TAX = 10;

  /// @notice The slope of the bonding curve.
  uint256 public constant DIVIDER = 1000000; // 1 / multiplier 0.000001 (so that we don't deal with decimals)

  /// @notice Address in which tokens are sent to be burned.
  /// These tokens can't be redeemed by the reserve.
  address constant BURN_ADDRESS = 0x000000000000000000000000000000000000dEaD;

  /// @notice Trib token instance.
  Trib public token;

  /// @notice Genesis Mint Event contract instance.
  Genesis public genesis;

  /// @notice Token price at the Genesis Mint Event.
  uint256 public genesisAveragePrice;

  /// @notice Total funds invested in the Genesis Mint Event.
  uint256 public genesisReserve;

  /// @notice Total interests earned since the contract deployment.
  uint256 public totalInterestClaimed;

  /// @notice Total reserve value that backs all tokens in circulation.
  /// @dev Area below the bonding curve.
  uint256 public totalReserve;

  /// @notice mUSD reserve instance.
  /// ropsten - 0x4E1000616990D83e56f4b5fC6CC8602DcfD20459
  /// mainnet - 0xe2f2a5C287993345a840Db3B0845fbC70f5935a5
  address public reserve;

  /// @notice Interface for integration with lending platform.
  address public vault;

  /// @notice Current state of the application.
  /// GME is either open (true) or finished (false).
  bool public GME = true;

  modifier onlyGenesis() {
    require(msg.sender == address(genesis), 'Genesis contract only');
    _;
  }

  modifier GMEOpen() {
    require(GME, 'Genesis Mint Event is over');
    _;
  }

  modifier GMEOver() {
    require(!GME, 'Genesis Mint Event is not over');
    _;
  }

  constructor(address _vault, uint256 _endTime) public {
    vault = _vault;
    reserve = IVault(vault).reserve();
    token = new Trib(address(this));
    genesis = new Genesis(reserve, address(this), _endTime);
    _approveMax(reserve, vault);
  }

  /// @notice Invests funds contributed in the Genesis Mint Event.
  /// @dev Updates average price on each investment.
  /// @param contributedAmount Total value in reserve to exchange for tokens.
  function genesisInvest(uint256 contributedAmount) external onlyGenesis GMEOpen {
    genesisReserve = genesisReserve.add(contributedAmount);
    _invest(contributedAmount);
    genesisAveragePrice = genesisReserve.mul(1e18).div(genesis.totalTokenBalance());
  }

  /// @notice Concludes the Genesis Mint Event.
  /// @dev Can only be called by the Genesis Contract after the GME is over.
  function concludeGME() external onlyGenesis GMEOpen {
    GME = false;
  }

  /// @notice Exchanges reserve to tokens according to the bonding curve formula.
  /// @dev Amount to be invested needs to be approved first.
  /// @param reserveAmount Value in wei that will be exchanged to tokens.
  function invest(uint256 reserveAmount) external GMEOver {
    _invest(reserveAmount);
  }

  /// @notice Exchanges token for reserve according to the bonding curve formula.
  /// @param tokenAmount Token value in wei that will be exchanged to reserve
  function sell(uint256 tokenAmount) external GMEOver {
    _sell(tokenAmount);
  }

  /// @notice Sells the maximum amount of tokens required to claim the most interest.
  function claimInterest() external GMEOver {
    uint256 totalToClaim = token.balanceOf(msg.sender) < totalClaimRequired()
      ? token.balanceOf(msg.sender)
      : totalClaimRequired();
    _sell(totalToClaim);
  }

  /// @notice Calculates the amount of tokens required to claim the outstanding interest.
  /// @return Amount of tokens required to claim all the outstanding interest.
  function totalClaimRequired() public view returns (uint256) {
    return _calculateClaimRequired(getInterest());
  }

  /// @notice Calculates the amount of tokens required to claim a specific interest amount.
  /// @param amountToClaim Interest amount to be claimed.
  /// @return Amount of tokens required to claim all specified interest.
  function claimRequired(uint256 amountToClaim) public view returns (uint256) {
    return _calculateClaimRequired(amountToClaim);
  }

  /// @notice Total amount that has been paid in Taxes
  /// and is now forever locked in the protocol.
  function totalContributed() external view returns (uint256) {
    return _calculateReserveFromSupply(getBurnedTokensAmount());
  }

  /// @notice Total outstanding interest accumulated.
  /// @return Interest in reserve accumulated in lending protocol.
  function getInterest() public view returns (uint256) {
    uint256 vaultBalance = IVault(vault).getBalance();
    // Sometimes mStable returns a value lower than the
    // deposit because their exchange rate gets updated after the deposit.
    if (vaultBalance < totalReserve) {
      vaultBalance = totalReserve;
    }
    return vaultBalance.sub(totalReserve);
  }

  /// @notice Total supply of tokens. This includes burned tokens.
  /// @return Total supply of token in wei.
  function getTotalSupply() public view returns (uint256) {
    return token.totalSupply();
  }

  /// @notice Total tokens that have been burned.
  /// @dev These tokens are still in circulation therefore they
  /// are still considered on the bonding curve formula.
  /// @return Total burned token amount in wei.
  function getBurnedTokensAmount() public view returns (uint256) {
    return token.balanceOf(BURN_ADDRESS);
  }

  /// @notice Token's price in wei according to the bonding curve formula.
  /// @return Current token price in wei.
  function getCurrentTokenPrice() external view returns (uint256) {
    // price = supply * multiplier
    return getTotalSupply().roundedDiv(DIVIDER);
  }

  /// @notice Calculates the amount of tokens in exchange for reserve after applying the 10% tax.
  /// @param reserveAmount Reserve value in wei to use in the conversion.
  /// @return Token amount in wei after the 10% tax has been applied.
  function getReserveToTokensTaxed(uint256 reserveAmount) external view returns (uint256) {
    if (reserveAmount == 0) {
      return 0;
    }
    uint256 fee = SafeMath.div(reserveAmount, TAX);
    uint256 totalTokens = getReserveToTokens(reserveAmount);
    uint256 taxedTokens = getReserveToTokens(fee);
    return totalTokens.sub(taxedTokens);
  }

  /// @notice Calculates the amount of reserve in exchange for tokens after applying the 10% tax.
  /// @param tokenAmount Token value in wei to use in the conversion.
  /// @return Reserve amount in wei after the 10% tax has been applied.
  function getTokensToReserveTaxed(uint256 tokenAmount) external view returns (uint256) {
    if (tokenAmount == 0) {
      return 0;
    }
    uint256 reserveAmount = getTokensToReserve(tokenAmount);
    uint256 fee = SafeMath.div(reserveAmount, TAX);
    return SafeMath.sub(reserveAmount, fee);
  }

  /// @notice Calculates the amount of tokens in exchange for reserve.
  /// @param reserveAmount Reserve value in wei to use in the conversion.
  /// @return Token amount in wei.
  function getReserveToTokens(uint256 reserveAmount) public view returns (uint256) {
    return _calculateReserveToTokens(reserveAmount, totalReserve, getTotalSupply());
  }

  /// @notice Calculates the amount of reserve in exchange for tokens.
  /// @param tokenAmount Token value in wei to use in the conversion.
  /// @return Reserve amount in wei.
  function getTokensToReserve(uint256 tokenAmount) public view returns (uint256) {
    return _calculateTokensToReserve(tokenAmount, getTotalSupply(), totalReserve);
  }

  /// @notice Worker function that exchanges reserve to tokens.
  /// Extracts 10% fee from the reserve supplied and exchanges the rest to tokens.
  /// Total amount is then sent to the lending protocol so it can start earning interest.
  /// @dev User must approve the reserve to be spent before investing.
  /// @param _reserveAmount Total reserve value in wei to be exchanged to tokens.
  function _invest(uint256 _reserveAmount) internal nonReentrant {
    uint256 fee = SafeMath.div(_reserveAmount, TAX);
    require(fee >= 1, 'Transaction amount not sufficient to pay fee');

    uint256 totalTokens = getReserveToTokens(_reserveAmount);
    uint256 taxedTokens = getReserveToTokens(fee);
    uint256 userTokens = totalTokens.sub(taxedTokens);

    require(taxedTokens > 0, 'This is not enough to buy a token');

    IERC20(reserve).safeTransferFrom(msg.sender, address(this), _reserveAmount);

    if (IERC20(reserve).allowance(address(this), vault) < _reserveAmount) {
      _approveMax(reserve, vault);
    }

    IVault(vault).deposit(_reserveAmount);

    totalReserve = SafeMath.add(totalReserve, _reserveAmount);

    token.mint(BURN_ADDRESS, taxedTokens);
    token.mint(msg.sender, userTokens);

    emit TokensBought(msg.sender, _reserveAmount, userTokens);
    emit MintAndBurn(fee, taxedTokens);
  }

  /// @notice Worker function that exchanges token for reserve.
  /// Tokens are decreased from the total supply according to the bonding curve formula.
  /// A 10% tax is applied to the reserve amount. 90% is retrieved
  /// from the lending protocol and sent to the user and 10% is used to mint and burn tokens.
  /// @param _tokenAmount Token value in wei that will be exchanged to reserve.
  function _sell(uint256 _tokenAmount) internal nonReentrant {
    require(_tokenAmount <= token.balanceOf(msg.sender), 'Insuficcient balance');
    require(_tokenAmount > 0, 'Must sell something');

    uint256 reserveAmount = getTokensToReserve(_tokenAmount);
    uint256 fee = SafeMath.div(reserveAmount, TAX);

    require(fee >= 1, 'Must pay minimum fee');

    uint256 net = SafeMath.sub(reserveAmount, fee);
    uint256 taxedTokens = _calculateReserveToTokens(
      fee,
      totalReserve.sub(reserveAmount),
      getTotalSupply().sub(_tokenAmount)
    );
    uint256 claimable = _calculateClaimableAmount(reserveAmount);
    uint256 totalClaim = net.add(claimable);

    totalReserve = SafeMath.sub(totalReserve, net);
    totalInterestClaimed = SafeMath.add(totalInterestClaimed, claimable);

    token.decreaseSupply(msg.sender, _tokenAmount);
    token.mint(BURN_ADDRESS, taxedTokens);

    IVault(vault).redeem(totalClaim);
    IERC20(reserve).safeTransfer(msg.sender, totalClaim);

    emit TokensSold(msg.sender, _tokenAmount, net);
    emit MintAndBurn(fee, taxedTokens);
    emit InterestClaimed(msg.sender, claimable);
  }

  function _approveMax(address tkn, address spender) internal {
    uint256 max = uint256(-1);
    IERC20(tkn).safeApprove(spender, max);
  }

  /// @notice Calculates the tokens required to claim a specific amount of interest.
  /// @param _amount The interest to be claimed.
  /// @return The amount of tokens in wei that are required to claim the interest.
  function _calculateClaimRequired(uint256 _amount) internal view returns (uint256) {
    uint256 newReserve = totalReserve.sub(_amount);
    uint256 newReserveSupply = _calculateReserveToTokens(newReserve, 0, 0);
    return getTotalSupply().sub(newReserveSupply);
  }

  /// @notice Calculates the maximum amount of interest that can be claimed
  /// given a certain value.
  /// @param _amount Value to be used in the calculation.
  /// @return The interest amount in wei that can be claimed for the given value.
  function _calculateClaimableAmount(uint256 _amount) internal view returns (uint256) {
    uint256 interest = getInterest();
    uint256 claimable = _amount > interest ? interest : _amount;
    return claimable == 0 ? 0 : claimable;
  }

  /**
   * Supply (s), reserve (r) and token price (p) are in a relationship defined by the bonding curve:
   *      p = m * s
   * The reserve equals to the area below the bonding curve
   *      r = s^2 / 2
   * The formula for the supply becomes
   *      s = sqrt(2 * r / m)
   *
   * In solidity computations, we are using divider instead of multiplier (because its an integer).
   * All values are decimals with 18 decimals (represented as uints), which needs to be compensated for in
   * multiplications and divisions
   */

  /// @notice Computes the increased supply given an amount of reserve.
  /// @param _reserveDelta The amount of reserve in wei to be used in the calculation.
  /// @param _totalReserve The current reserve state to be used in the calculation.
  /// @param _supply The current supply state to be used in the calculation.
  /// @return token amount in wei.
  function _calculateReserveToTokens(
    uint256 _reserveDelta,
    uint256 _totalReserve,
    uint256 _supply
  ) internal pure returns (uint256) {
    uint256 _reserve = _totalReserve;
    uint256 _newReserve = _reserve.add(_reserveDelta);
    // s = sqrt(2 * r / m)
    uint256 _newSupply = MathUtils.sqrt(
      _newReserve
        .mul(2)
        .mul(DIVIDER) // inverse the operation (Divider instead of multiplier)
        .mul(1e18) // compensation for the squared unit
    );

    uint256 _supplyDelta = _newSupply.sub(_supply);
    return _supplyDelta;
  }

  /// @notice Computes the decrease in reserve given an amount of tokens.
  /// @param _supplyDelta The amount of tokens in wei to be used in the calculation.
  /// @param _supply The current supply state to be used in the calculation.
  /// @param _totalReserve The current reserve state to be used in the calculation.
  /// @return Reserve amount in wei.
  function _calculateTokensToReserve(
    uint256 _supplyDelta,
    uint256 _supply,
    uint256 _totalReserve
  ) internal pure returns (uint256) {
    require(_supplyDelta <= _supply, 'Token amount must be less than the supply');

    uint256 _newSupply = _supply.sub(_supplyDelta);

    uint256 _newReserve = _calculateReserveFromSupply(_newSupply);

    uint256 _reserveDelta = _totalReserve.sub(_newReserve);

    return _reserveDelta;
  }

  /// @notice Calculates reserve given a specific supply.
  /// @param _supply The token supply in wei to be used in the calculation.
  /// @return Reserve amount in wei.
  function _calculateReserveFromSupply(uint256 _supply) internal pure returns (uint256) {
    // r = s^2 * m / 2
    uint256 _reserve = _supply
      .mul(_supply)
      .div(DIVIDER) // inverse the operation (Divider instead of multiplier)
      .div(2);

    return _reserve.roundedDiv(1e18); // correction of the squared unit
  }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.6.0;

import "../../GSN/Context.sol";
import "./IERC20.sol";
import "../../math/SafeMath.sol";
import "../../utils/Address.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20PresetMinterPauser}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.zeppelin.solutions/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * We have followed general OpenZeppelin guidelines: functions revert instead
 * of returning `false` on failure. This behavior is nonetheless conventional
 * and does not conflict with the expectations of ERC20 applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20 is Context, IERC20 {
    using SafeMath for uint256;
    using Address for address;

    mapping (address => uint256) private _balances;

    mapping (address => mapping (address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;
    uint8 private _decimals;

    /**
     * @dev Sets the values for {name} and {symbol}, initializes {decimals} with
     * a default value of 18.
     *
     * To select a different value for {decimals}, use {_setupDecimals}.
     *
     * All three of these values are immutable: they can only be set once during
     * construction.
     */
    constructor (string memory name, string memory symbol) public {
        _name = name;
        _symbol = symbol;
        _decimals = 18;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5,05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the value {ERC20} uses, unless {_setupDecimals} is
     * called.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view returns (uint8) {
        return _decimals;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view override returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view override returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `recipient` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address recipient, uint256 amount) public virtual override returns (bool) {
        _transfer(_msgSender(), recipient, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public virtual override returns (bool) {
        _approve(_msgSender(), spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20};
     *
     * Requirements:
     * - `sender` and `recipient` cannot be the zero address.
     * - `sender` must have a balance of at least `amount`.
     * - the caller must have allowance for ``sender``'s tokens of at least
     * `amount`.
     */
    function transferFrom(address sender, address recipient, uint256 amount) public virtual override returns (bool) {
        _transfer(sender, recipient, amount);
        _approve(sender, _msgSender(), _allowances[sender][_msgSender()].sub(amount, "ERC20: transfer amount exceeds allowance"));
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
        _approve(_msgSender(), spender, _allowances[_msgSender()][spender].add(addedValue));
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
        _approve(_msgSender(), spender, _allowances[_msgSender()][spender].sub(subtractedValue, "ERC20: decreased allowance below zero"));
        return true;
    }

    /**
     * @dev Moves tokens `amount` from `sender` to `recipient`.
     *
     * This is internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `sender` cannot be the zero address.
     * - `recipient` cannot be the zero address.
     * - `sender` must have a balance of at least `amount`.
     */
    function _transfer(address sender, address recipient, uint256 amount) internal virtual {
        require(sender != address(0), "ERC20: transfer from the zero address");
        require(recipient != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(sender, recipient, amount);

        _balances[sender] = _balances[sender].sub(amount, "ERC20: transfer amount exceeds balance");
        _balances[recipient] = _balances[recipient].add(amount);
        emit Transfer(sender, recipient, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements
     *
     * - `to` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply = _totalSupply.add(amount);
        _balances[account] = _balances[account].add(amount);
        emit Transfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        _balances[account] = _balances[account].sub(amount, "ERC20: burn amount exceeds balance");
        _totalSupply = _totalSupply.sub(amount);
        emit Transfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner`s tokens.
     *
     * This is internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(address owner, address spender, uint256 amount) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Sets {decimals} to a value other than the default one of 18.
     *
     * WARNING: This function should only be called from the constructor. Most
     * applications that interact with token contracts will not expect
     * {decimals} to ever change, and may work incorrectly if it does.
     */
    function _setupDecimals(uint8 decimals_) internal {
        _decimals = decimals_;
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be to transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(address from, address to, uint256 amount) internal virtual { }
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.5.0 <0.7.0;

import './interfaces/IContribute.sol';
import './utils/MathUtils.sol';
import '@openzeppelin/contracts/token/ERC20/IERC20.sol';
import '@openzeppelin/contracts/token/ERC20/SafeERC20.sol';
import '@openzeppelin/contracts/math/SafeMath.sol';
import '@openzeppelin/contracts/utils/ReentrancyGuard.sol';

contract Genesis is ReentrancyGuard {
  using SafeMath for uint256;
  using MathUtils for uint256;
  using SafeERC20 for IERC20;

  event Deposit(address indexed from, uint256 amount);
  event Claim(address indexed user, uint256 amount);

  /// @notice End date and time of the Genesis Mint Event (GME).
  uint256 public endTime;

  /// @notice Total tokens acquired during the GME.
  uint256 public totalTokensReceived;

  /// @notice Total invested in the GME.
  uint256 public totalInvested;

  /// @notice mUSD reserve instance.
  address public reserve;

  /// @notice Minter contract instance.
  address public contribute;

  /// @notice Balance tracker of accounts who have deposited funds.
  mapping(address => uint256) balance;

  bool private _toggle;

  modifier GMEOpen {
    require(block.timestamp <= endTime, 'GME is over');
    _;
  }

  modifier GMEOver {
    require(block.timestamp > endTime, 'GME not over');
    _;
  }

  constructor(
    address _reserve,
    address _contribute,
    uint256 _endTime
  ) public {
    reserve = _reserve;
    contribute = _contribute;
    endTime = _endTime;
  }

  /// @notice Receives mUSD from accounts participating in the GME
  /// updating their internal balance.
  /// @dev Value to be deposited needs to be approved first.
  /// @param value The reserve amount being contributed.
  function deposit(uint256 value) external GMEOpen {
    require(value >= 0.01 ether, 'Minimum contribution is 0.01');
    IERC20(reserve).safeTransferFrom(msg.sender, address(this), value);

    balance[msg.sender] = balance[msg.sender].add(value);
    totalInvested = totalInvested.add(value);

    require(_invest(value), 'Investment failed');
    totalTokensReceived = totalTokenBalance();

    emit Deposit(msg.sender, value);
  }

  /// @notice Allows anyone to conclude the GME.
  function concludeGME() external GMEOver {
    IContribute(contribute).concludeGME();
  }

  /// @notice Calculates account share and sends acquired tokens
  // to account after GME event is over.
  function claim() external nonReentrant GMEOver {
    require(balance[msg.sender] > 0, 'No tokens to claim');

    uint256 share = _calculateShare(msg.sender);
    balance[msg.sender] = 0;

    IERC20(IContribute(contribute).token()).safeTransfer(msg.sender, share);
    emit Claim(msg.sender, share);
  }

  /// @notice Calculates account share
  /// @param account Address of the account to calculate the shares from.
  /// @return Total shares of given account.
  function getShare(address account) external view returns (uint256) {
    return _calculateShare(account);
  }

  /// @notice Funds deposited per account.
  /// @param account Address of the account to retrieve the balance from.
  /// @return Total funds deposited.
  function getBalance(address account) external view returns (uint256) {
    return balance[account];
  }

  /// @notice Total funds deposited into the Genesis contract.
  /// @return Current reserve balance of this contract.
  function totalReserveBalance() public view returns (uint256) {
    return IERC20(reserve).balanceOf(address(this));
  }

  /// @notice Total tokens minted to this contract.
  /// @return Current token balance of this contract.
  function totalTokenBalance() public view returns (uint256) {
    return IERC20(IContribute(contribute).token()).balanceOf(address(this));
  }

  /// @notice Worker function which invests the deposited amount.
  /// @param _amount Value to be invested.
  /// @return True if successful.
  function _invest(uint256 _amount) internal returns (bool) {
    IERC20(reserve).safeApprove(contribute, _amount);
    IContribute(contribute).genesisInvest(_amount);
    return true;
  }

  /// @notice Calculates share of a given account.
  /// @param _account Account to calculate the share from.
  /// @return Shares of given account.
  function _calculateShare(address _account) internal view returns (uint256) {
    // userShare*tokenSupply/totalInvested
    uint256 a = balance[_account].mul(totalTokensReceived);
    uint256 b = totalInvested;
    uint256 share = a.roundedDiv(b);
    return share;
  }
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.5.0 <0.7.0;

/**
 * This interface is only to facilitate
 * interacting with the contract in remix.ethereum.org
 * after it has been deployed to a testnet or mainnet.
 *
 * Just copy/paste the interface in Remix and deploy
 * at contract address.
 */

interface IContribute {
  function TAX() external view returns (uint256);

  function DIVIDER() external view returns (uint256);

  function GME() external view returns (bool);

  function token() external view returns (address);

  function genesis() external view returns (address);

  function genesisAveragePrice() external view returns (uint256);

  function genesisReserve() external view returns (uint256);

  function totalInterestClaimed() external view returns (uint256);

  function totalReserve() external view returns (uint256);

  function reserve() external view returns (address);

  function vault() external view returns (address);

  function genesisInvest(uint256) external;

  function concludeGME() external;

  function invest(uint256) external;

  function sell(uint256) external;

  function claimInterest() external;

  function totalClaimRequired() external view returns (uint256);

  function claimRequired(uint256) external view returns (uint256);

  function totalContributed() external view returns (uint256);

  function getInterest() external view returns (uint256);

  function getTotalSupply() external view returns (uint256);

  function getBurnedTokensAmount() external view returns (uint256);

  function getCurrentTokenPrice() external view returns (uint256);

  function getReserveToTokensTaxed(uint256) external view returns (uint256);

  function getTokensToReserveTaxed(uint256) external view returns (uint256);

  function getReserveToTokens(uint256) external view returns (uint256);

  function getTokensToReserve(uint256) external view returns (uint256);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.6.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.5.0 <0.7.0;

interface IVault {
  function reserve() external view returns (address);

  function deposit(uint256) external returns (bool);

  function redeem(uint256) external returns (bool);

  // @dev Must return the total balance in reserve.
  function getBalance() external view returns (uint256);
}

// SPDX-License-Identifier: MIT
pragma solidity >=0.5.16 <0.7.0;

import '@openzeppelin/contracts/math/SafeMath.sol';

library MathUtils {
  using SafeMath for uint256;

  /// @notice Calculates the square root of a given value.
  function sqrt(uint256 x) internal pure returns (uint256 y) {
    uint256 z = (x + 1) / 2;
    y = x;
    while (z < y) {
      y = z;
      z = (x / z + z) / 2;
    }
  }

  /// @notice Rounds a division result.
  function roundedDiv(uint256 a, uint256 b) internal pure returns (uint256) {
    require(b > 0, 'div by 0');

    uint256 halfB = (b.mod(2) == 0) ? (b.div(2)) : (b.div(2).add(1));
    return (a.mod(b) >= halfB) ? (a.div(b).add(1)) : (a.div(b));
  }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.6.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor () internal {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and make it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        // On the first call to nonReentrant, _notEntered will be true
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;

        _;

        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.6.0;

import "./IERC20.sol";
import "../../math/SafeMath.sol";
import "../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using SafeMath for uint256;
    using Address for address;

    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        // solhint-disable-next-line max-line-length
        require((value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 newAllowance = token.allowance(address(this), spender).add(value);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 newAllowance = token.allowance(address(this), spender).sub(value, "SafeERC20: decreased allowance below zero");
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address.functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        if (returndata.length > 0) { // Return data is optional
            // solhint-disable-next-line max-line-length
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.6.0;

/**
 * @dev Wrappers over Solidity's arithmetic operations with added overflow
 * checks.
 *
 * Arithmetic operations in Solidity wrap on overflow. This can easily result
 * in bugs, because programmers usually assume that an overflow raises an
 * error, which is the standard behavior in high level programming languages.
 * `SafeMath` restores this intuition by reverting the transaction when an
 * operation overflows.
 *
 * Using this library instead of the unchecked operations eliminates an entire
 * class of bugs, so it's recommended to use it always.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     *
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        require(c >= a, "SafeMath: addition overflow");

        return c;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        return sub(a, b, "SafeMath: subtraction overflow");
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b <= a, errorMessage);
        uint256 c = a - b;

        return c;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     *
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
        // benefit is lost if 'b' is also tested.
        // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
        if (a == 0) {
            return 0;
        }

        uint256 c = a * b;
        require(c / a == b, "SafeMath: multiplication overflow");

        return c;
    }

    /**
     * @dev Returns the integer division of two unsigned integers. Reverts on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        return div(a, b, "SafeMath: division by zero");
    }

    /**
     * @dev Returns the integer division of two unsigned integers. Reverts with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b > 0, errorMessage);
        uint256 c = a / b;
        // assert(a == b * c + a % b); // There is no case in which this doesn't hold

        return c;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * Reverts when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        return mod(a, b, "SafeMath: modulo by zero");
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * Reverts with custom message when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b != 0, errorMessage);
        return a % b;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.5.0 <0.7.0;

import '@openzeppelin/contracts/token/ERC20/ERC20.sol';

contract Trib is ERC20 {
  address minter;

  modifier onlyMinter {
    require(msg.sender == minter, 'Only minter can call this function.');
    _;
  }

  constructor(address _minter) public ERC20('Contribute', 'TRIB') {
    minter = _minter;
  }

  function mint(address account, uint256 amount) external onlyMinter {
    _mint(account, amount);
  }

  function decreaseSupply(address account, uint256 amount) external onlyMinter {
    _burn(account, amount);
  }
}

{
  "compilationTarget": {
    "contracts/Contribute.sol": "Contribute"
  },
  "evmVersion": "istanbul",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs",
    "useLiteralContent": true
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}